GUI mit FileRead aktualisieren und Opt("GUIOnEventMode", 1)

shakoon

Guten Morgen,

ich komme gerade bei einem Programm nicht weiter.

Ich möchte etwas aus einer .csv Datei auslesen und in diesem programm anzeigen und danach verarbeiten.

habe euch mal einen gekürzten Code geben um es übersichtlicher zu machen.

Plan ist, das Programm soll den ganzen Tag offen bleiben und die Informationen aus den .csv Dateien sollen alle 10 minuten oder so aktualisiert werden, da sich die .csv Dateien ständig aktualisieren.

ist sowas irgendwie einfach möglich?

Code

Opt("GUIOnEventMode", 1) ; Change to OnEvent mode

Global $hARTIKELDISPOGUI = GUICreate("GUI", $guibreite, $guihoehe,0,0,$WS_POPUP)
;GUISetOnEvent($hGUI, "GUI")
            GUISetBkColor(0xFFFFFF)



;###### Buttons um die einzelnen Tabs anzuwählen

Local $tab1Button = GUICtrlCreateButton("1", 100, 0, 100,50)
GUICtrlSetColor(-1, 0xFFFFFF)
GUICtrlSetBkColor(-1, 0x56085e)
GUICtrlSetFont(-1, $fontsizebuttonunten, $FW_BOLD)
GUICtrlSetOnEvent($tab1Button, "tab1Button")

Local $tab2Button = GUICtrlCreateButton("2", 300, 0, 100,50)
GUICtrlSetColor(-1, 0xFFFFFF)
GUICtrlSetBkColor(-1, 0x56085e)
GUICtrlSetFont(-1, $fontsizebuttonunten, $FW_BOLD)
GUICtrlSetOnEvent($tab2Button, "tab2Button")

Local $tab3Button = GUICtrlCreateButton("3", 500, 0, 100,50)
GUICtrlSetColor(-1, 0xFFFFFF)
GUICtrlSetBkColor(-1, 0x56085e)
GUICtrlSetFont(-1, $fontsizebuttonunten, $FW_BOLD)
GUICtrlSetOnEvent($tab3Button, "tab3Button")

Local $tab4Button = GUICtrlCreateButton("4", 700, 0, 100,50)
GUICtrlSetColor(-1, 0xFFFFFF)
GUICtrlSetBkColor(-1, 0x56085e)
GUICtrlSetFont(-1, $fontsizebuttonunten, $FW_BOLD)
GUICtrlSetOnEvent($tab4Button, "tab4Button")

Local $tab5Button = GUICtrlCreateButton("5", 900, 0, 300,50)
GUICtrlSetColor(-1, 0xFFFFFF)
GUICtrlSetBkColor(-1, 0x56085e)
GUICtrlSetFont(-1, $fontsizebuttonunten, $FW_BOLD)
GUICtrlSetOnEvent($tab5Button, "tab5Button")


;######## FileRead

$csv = FileRead("1.csv")
$csv = StringStripWS($csv, 100)
$rows = StringSplit($csv, @CRLF)
Dim $aDetail[$rows[0] + 1][100 + 1]
$aDetail[0][0] = $rows[0]
For $i = 1 to $rows[0]
    $temp = StringSplit($rows[$i], ";", 2)
    For $j = 0 to UBound($temp) - 1
       $aDetail[$i][$j] = $temp[$j] ;
    Next
Next
;_ArrayDisplay($aDetail)

;####################################################

$csv1 = FileRead("2.csv")
$csv1 = StringStripWS($csv1, 100)
$rows1 = StringSplit($csv1, @CRLF)
Dim $aDetaila[$rows1[0] + 1][100 + 1]
$aDetaila[0][0] = $rows1[0]
For $i1 = 1 to $rows1[0]
    $temp1 = StringSplit($rows1[$i1], ";", 2)
    For $j1 = 0 to UBound($temp1) - 1
        $aDetaila[$i1][$j1] = $temp1[$j1] ;
    Next
Next
;_ArrayDisplay($aDetail)

;####################################################

$csv2 = FileRead("3.csv")
$csv2 = StringStripWS($csv2, 100)
$rows2 = StringSplit($csv2, @CRLF)
Dim $aDetailb[$rows2[0] + 1][100 + 1]
$aDetailb[0][0] = $rows2[0]
For $i2 = 1 to $rows2[0]
    $temp2 = StringSplit($rows2[$i2], ";", 2)
    For $j2 = 0 to UBound($temp2) - 1
        $aDetailb[$i2][$j2] = $temp2[$j2] ;
    Next
Next
;_ArrayDisplay($aDetail)

;####################################################

$csv3 = FileRead("4.csv")
$csv3 = StringStripWS($csv3, 100)
$rows3 = StringSplit($csv3, @CRLF)
Dim $aDetailc[$rows3[0] + 1][100 + 1]
$aDetailc[0][0] = $rows3[0]
For $i3 = 1 to $rows3[0]
    $temp3 = StringSplit($rows3[$i3], ";", 2)
    For $j3 = 0 to UBound($temp3) - 1
        $aDetailc[$i3][$j3] = $temp3[$j3] ;
    Next
Next
;_ArrayDisplay($aDetail)

;####################################################

$csv4 = FileRead("5.csv")
$csv4 = StringStripWS($csv4, 100)
$rows4 = StringSplit($csv4, @CRLF)
Dim $aDetaild[$rows4[0] + 1][100 + 1]
$aDetaild[0][0] = $rows4[0]
For $i4 = 1 to $rows4[0]
    $temp4 = StringSplit($rows4[$i4], ";", 2)
    For $j4 = 0 to UBound($temp4) - 1
        $aDetaild[$i4][$j4] = $temp4[$j4] ;
    Next
Next
;_ArrayDisplay($aDetail)



$tab = GUICtrlCreateTab(10, 85, 1900, 900)


$tab1 = GUICtrlCreateTabItem("1")

If IsDeclared("rows") And IsDeclared("i") Then
   If $i >= 3  Then
   $aDetailsaegen11 = $aDetail[2][0]
   $aDetailsaegen12 = $aDetail[2][1]
   $aDetailsaegen13 = $aDetail[2][7]
   $aDetailsaegen14 = $aDetail[2][8]
   $aDetailsaegen15 = $aDetail[2][10]
   $aDetailsaegen16 = $aDetail[2][11]
   $aDetailsaegen17 = $aDetail[2][12]
   $aDetailsaegen18 = $aDetail[2][15]
   $aDetailsaegen19 = $aDetail[2][16]
   $aDetailsaegen110 = $aDetail[2][17]
   $aDetailsaegen111 = $aDetail[2][2]
   Else
   $aDetailsaegen11 = ""
   $aDetailsaegen12 = ""
   $aDetailsaegen13 = ""
   $aDetailsaegen14 = ""
   $aDetailsaegen15 = ""
   $aDetailsaegen16 = ""
   $aDetailsaegen17 = ""
   $aDetailsaegen18 = ""
   $aDetailsaegen19 = ""
   $aDetailsaegen110 = ""
   $aDetailsaegen111 = ""
   EndIf
Else
 $aDetailsaegen11 = ""
 $aDetailsaegen12 = ""
 $aDetailsaegen13 = ""
 $aDetailsaegen14 = ""
 $aDetailsaegen15 = ""
 $aDetailsaegen16 = ""
 $aDetailsaegen17 = ""
 $aDetailsaegen18 = ""
 $aDetailsaegen19 = ""
 $aDetailsaegen110 = ""
 $aDetailsaegen111 = ""
Endif

   If $aDetailsaegen110 = "Offen"  Then
   $labelbgcolor1 = 0xF5A9A9
   Else
   $labelbgcolor1 = 0xA9F5A9
   EndIf

GUICtrlCreateLabel($aDetailsaegen11, $labelxs1, $labelyz1, $labelbreites1, $labelhoehez1, BitOR($SS_CENTER, $SS_CENTERIMAGE, $WS_BORDER))
         GUICtrlSetBkColor(-1, $labelbgcolor1)
            GUICtrlSetColor(-1, $labeltextcolor)
         GUICtrlSetFont(-1, $fontsizelabel, $FW_BOLD)

GUICtrlCreateLabel($aDetailsaegen12, $labelxs2, $labelyz1, $labelbreites2, $labelhoehez1/2, BitOR($SS_CENTER, $SS_CENTERIMAGE, $WS_BORDER))
         GUICtrlSetBkColor(-1, $labelbgcolor1)
            GUICtrlSetColor(-1, $labeltextcolor)
         GUICtrlSetFont(-1, $fontsizelabel, $FW_BOLD)

GUICtrlCreateLabel($aDetailsaegen13, $labelxs3, $labelyz1+$labelhoehez1/2, $labelbreites3, $labelhoehez1/2, BitOR($SS_CENTER, $SS_CENTERIMAGE, $WS_BORDER))
         GUICtrlSetBkColor(-1, $labelbgcolor1)
            GUICtrlSetColor(-1, $labeltextcolor)
         GUICtrlSetFont(-1, $fontsizelabel, $FW_BOLD)

GUICtrlCreateLabel($aDetailsaegen14, $labelxs4, $labelyz1, $labelbreites4, $labelhoehez1/2, BitOR($SS_CENTER, $SS_CENTERIMAGE, $WS_BORDER))
         GUICtrlSetBkColor(-1, $labelbgcolor1)
            GUICtrlSetColor(-1, $labeltextcolor)
         GUICtrlSetFont(-1, $fontsizelabel, $FW_BOLD)

GUICtrlCreateLabel($aDetailsaegen15, $labelxs5, $labelyz1+$labelhoehez1/2, $labelbreites5, $labelhoehez1/2, BitOR($SS_CENTER, $SS_CENTERIMAGE, $WS_BORDER))
         GUICtrlSetBkColor(-1, $labelbgcolor1)
            GUICtrlSetColor(-1, $labeltextcolor)
         GUICtrlSetFont(-1, $fontsizelabel, $FW_BOLD)

GUICtrlCreateLabel($aDetailsaegen16, $labelxs6, $labelyz1, $labelbreites6, $labelhoehez1, BitOR($SS_CENTER, $SS_CENTERIMAGE, $WS_BORDER))
         GUICtrlSetBkColor(-1, $labelbgcolor1)
            GUICtrlSetColor(-1, $labeltextcolor)
         GUICtrlSetFont(-1, $fontsizelabel, $FW_BOLD)

GUICtrlCreateLabel($aDetailsaegen17, $labelxs7, $labelyz1, $labelbreites7, $labelhoehez1/2, BitOR($SS_LEFT, $SS_CENTERIMAGE, $WS_BORDER))
         GUICtrlSetBkColor(-1, $labelbgcolor1)
            GUICtrlSetColor(-1, $labeltextcolor)
         GUICtrlSetFont(-1, $fontsizelabel, $FW_BOLD)

GUICtrlCreateLabel($aDetailsaegen18, $labelxs8, $labelyz1+$labelhoehez1/2, $labelbreites8, $labelhoehez1/2, BitOR($SS_LEFT, $SS_CENTERIMAGE, $WS_BORDER))
         GUICtrlSetBkColor(-1, $labelbgcolor1)
            GUICtrlSetColor(-1, $labeltextcolor)
         GUICtrlSetFont(-1, $fontsizelabel, $FW_BOLD)

GUICtrlCreateLabel($aDetailsaegen19, $labelxs9, $labelyz1, $labelbreites9, $labelhoehez1/2, BitOR($SS_LEFT, $SS_CENTERIMAGE, $WS_BORDER))
         GUICtrlSetBkColor(-1, $labelbgcolor1)
            GUICtrlSetColor(-1, $labeltextcolor)
         GUICtrlSetFont(-1, $fontsizelabel, $FW_BOLD)

GUICtrlCreateLabel($aDetailsaegen110, $labelxs9, $labelyz1+$labelhoehez1/2, $labelbreites9, $labelhoehez1/2, BitOR($SS_LEFT, $SS_CENTERIMAGE, $WS_BORDER))
         GUICtrlSetBkColor(-1, $labelbgcolor1)
            GUICtrlSetColor(-1, $labeltextcolor)
         GUICtrlSetFont(-1, $fontsizelabel, $FW_BOLD)

GUICtrlCreateLabel($aDetailsaegen111, $labelxs10, $labelyz1, $labelbreites10, $labelhoehez1, BitOR($SS_CENTER, $SS_CENTERIMAGE, $WS_BORDER))
         GUICtrlSetBkColor(-1, $labelbgcolor1)
            GUICtrlSetColor(-1, $labeltextcolor)
         GUICtrlSetFont(-1, $fontsizelabel, $FW_BOLD)


usw........ für alle 5 Tabs gibts unmengen GUICtrlCreateLabel. Diese beziehen all ihre Daten aus den FileRead Arrays.


;###### Ende

GUISwitch($hGUI)
GUISetState(@SW_SHOW)


While 1
    Sleep(100) ; Sleep to reduce CPU usage
 WEnd




Func ZURUEKButton()
     Exit
  EndFunc

Func tab1Button()
    ; Note: At this point @GUI_CtrlId would equal $iOKButton
_GUICtrlTab_SetCurFocus($Tab, 0)
EndFunc

Func tab2Button()
    ; Note: At this point @GUI_CtrlId would equal $iOKButton
_GUICtrlTab_SetCurFocus($Tab, 1)
EndFunc

Func tab3Button()
    ; Note: At this point @GUI_CtrlId would equal $iOKButton
_GUICtrlTab_SetCurFocus($Tab, 2)
EndFunc

Func tab4Button()
    ; Note: At this point @GUI_CtrlId would equal $iOKButton
_GUICtrlTab_SetCurFocus($Tab, 3)
EndFunc

Func tab5Button()
    ; Note: At this point @GUI_CtrlId would equal $iOKButton
_GUICtrlTab_SetCurFocus($Tab, 4)
EndFunc

Alles anzeigen

**Moombas**

Vorab: Mach dir Gedanken über eine bessere Namensgebung:

$csv = 1.csv ABER $csv1 = 2.csv ... das kann schnell verwirren.

Du hast mehrere Möglichkeiten das anzugehen.

1. Das Einlesen: Entweder lässt du alle x Minuten (du sagtest 10) ALLE *.csv einlesen und verarbeiten oder (etwas schöner) du prüfst das Änderungsdatum gegen und wenn sich das nicht geändert hat, lässt du die *.csv in Ruhe.

2. Das sequentielle einlesen löst du über eine Schleife.

shakoon

Danke

die namen muss ich leider so lassen, da die Dateien aus einem anderen programm kommen und ich sie nicht umbenennen kann in diesem

Das einlesen nach Änderungsdatum wäre schon ganz cool.

Schleife wäre aber auch ok.

Nur wie baue ich sowas auf?

Ich habe schonmal mit schleifen herumgespielt, aber irgendwie bekomme ich es nicht hin.

**Moombas**

Die Dateinamen vielleicht, aber die Variablennamen kannst du ja frei bestimmen.

Würde ich in dem Falle 1:1 nehmen. Also: $csv1 = 1.csv $csv2 = 2.csv usw.

AutoIt

;Grobes Beispiel:
$i = 0


While 1
    $msg = GuiGetMsg() ;Rückmeldung deiner Buttons
    Select
        Case $msg = $GUI_EVENT_CLOSE Or $msg = $Exit ;Schleife oder Programm verlassen
             exitloop ;oder: Exit
        Case $i = 600 ;10 Minuten um
             FunctionCSVEinlesen()
             $i = 0 ;"Timer" reset
        Case Else
             sleep(1000) ;1 Sek. Warten
             $i = $i + 1 
    EndSelect
WEnd

Alles anzeigen

shakoon

und die ersetze ich quasi einfach mit meiner Whlie schleife? und passe den rest an?

**Kanashius**

Du solltest unbedingt Arrays verwenden!

Ich hab mal deinen Code umgeschrieben:

AutoIt

#include <WindowsConstants.au3>
#include <GUIConstantsEx.au3>
#include <FontConstants.au3>
#include <GuiListView.au3>
#include <Date.au3>
Opt("GUIOnEventMode", 1) ; Change to OnEvent mode

Global $arTabButtons[0]

Global $iWidth=800,$iHeight=600
Global $iFontSizeTabButtons=20,$iTabButtonWidth=100,$iTabButtonHeight=50,$iSpace=5
Global $arFiles=["1.csv","2.csv","3.csv","4.csv","5.csv"],$sLastFile,$sLastFileAccessRefresh

$hGuiArtikelDispo=GUICreate("GUI", $iWidth, $iHeight,-1,-1,$WS_POPUP)
GUISetBkColor(0xFFFFFF)
$hListview=GUICtrlCreateListView("",$iSpace,$iSpace*2+$iTabButtonHeight,$iWidth-$iSpace*2,$iHeight-$iSpace*3-$iTabButtonHeight)
$hButtonClose=GUICtrlCreateButton("X",$iWidth-$iSpace-30,$iSpace,30,$iTabButtonHeight)
GUICtrlSetOnEvent(-1,"_close")
GUISetOnEvent($GUI_EVENT_CLOSE,"_close")
GUISetState(@SW_SHOW,$hGuiArtikelDispo)

;AdlibRegister("_refreshFile",1000*60*10)
AdlibRegister("_refreshFile",1000)
_initGui($arFiles)

While Sleep(10)
WEnd

Func _close()
    exit
EndFunc

Func _refreshFile()
    If $sLastFile<>"" Then
        local $sLastFileAccess=StringRegExpReplace(FileGetTime($sLastFile,0,1),"(\d{4})(\d{2})(\d{2})(\d{2})(\d{2})(\d{2})","$1/$2/$3 $4:$5:$6")
        If $sLastFileAccessRefresh<>$sLastFileAccess Then
            $sLastFileAccessRefresh=$sLastFileAccess
            If _DateDiff('s',$sLastFileAccess,StringFormat("%04i",@YEAR)&"/"&StringFormat("%02i",@MON)&"/"&StringFormat("%02i",@MDAY)&" "&StringFormat("%02i",@HOUR)&":"&StringFormat("%02i",@MIN)&":"&StringFormat("%02i",@SEC))>1 Then
                _loadFileToGui($sLastFile)
            EndIf
        EndIf
    EndIf
EndFunc

Func _initGui($arFiles)
    ; Delete all controls of the old Gui
    If IsArray($arTabButtons) Then
        For $i=0 to UBound($arTabButtons)-1 step 1
            GUICtrlDelete($arTabButtons[$i])
        Next
    EndIf
    _GUICtrlListView_DeleteAllItems($hListView)
    ReDim $arTabButtons[UBound($arFiles)]
    For $i=0 to UBound($arFiles)-1 step 1
        $arTabButtons[$i]=GUICtrlCreateButton(StringSplit($arFiles[$i],".",1+2)[0],$iSpace+$i*$iTabButtonWidth,$iSpace,$iTabButtonWidth-$iSpace*2,$iTabButtonHeight)
        GUICtrlSetColor(-1,0xFFFFFF)
        GUICtrlSetBkColor(-1,0x56085e)
        GUICtrlSetFont(-1,$iFontSizeTabButtons,$FW_BOLD)
        GUICtrlSetOnEvent(-1,"_tabButtonPressed")
    Next
EndFunc

Func _tabButtonPressed()
    For $i=0 to UBound($arTabButtons)-1 step 1
        If @GUI_CtrlId=$arTabButtons[$i] Then
            _loadFileToGui($arFiles[$i])
        EndIf
    Next
EndFunc

Func _loadFileToGui($sFile)
    $sLastFile=$sFile
    _GUICtrlListView_DeleteAllItems($hListView)
    While _GUICtrlListView_GetColumnCount($hListview)>0
        _GUICtrlListView_DeleteColumn($hListview,0)
    WEnd
    local $arCsvData=_loadFileData($sFile)
    For $i=0 to UBound($arCsvData,2)-1 step 1
        _GUICtrlListView_AddColumn($hListview,$i+1,($iWidth-2*$iSpace-4)/UBound($arCsvData,2))
    Next
    _GUICtrlListView_AddArray($hListview,$arCsvData)
EndFunc

Func _loadFileData($sFile)
    local $sFileData=FileRead($sFile)
    local $arFileRows=StringSplit($sFileData,@CRLF,1+2)
    local $arDetail[UBound($arFileRows)][0]
    For $i=0 to UBound($arFileRows)-1 step 1
        $arCols=StringSplit($arFileRows[$i],";",1+2)
        If UBound($arCols)>UBound($arDetail,2) Then
            ReDim $arDetail[UBound($arDetail)][UBound($arCols)]
        EndIf
        For $j=0 to UBound($arCols)-1 step 1
            $arDetail[$i][$j]=$arCols[$j]
        Next
    Next
    return $arDetail
EndFunc

Alles anzeigen

Ich hoffe, du verstehst, was dort gemacht wird und kannst das dann in dem Stil weiterentwickeln :).

Das erspart dir sehr viel Copy&Paste

MfG Kanashius.

shakoon

Wunderbar

habt mir beide sehr geholfen

Habs jetzt erstmal mit der Schleife gelöst.

Aber deine Lösung Kanashius, werde ich jetzt mal versuchen zu verstehen nur so lernt man

Wird dann die langfristige Lösung