TreeViewItems als Array

Gremlin78

Hallo Leute,

ich möchte aus einem TreeView die Namen der Items zurückgegeben bekommen. Da es sehr viele sind und ich sie alle einzeln abfragen möchte, dachte ich mir, dass es vielleicht mit einem Array gehen könnte. Dieser Code ist nur als Beispiel gedacht:

Spoiler anzeigen

C

#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>
#include <StaticConstants.au3>
#include <TreeViewConstants.au3>
#include <GUITreeView.au3>
#include <WindowsConstants.au3>

Example_Tree()
Func Example_Tree()
    GUICreate("My test treeview GUI", 350, 210)
    Local $idTreeview = GUICtrlCreateTreeView(5, 5, 340, 200)
    Local $idTreeview1 = GUICtrlCreateTreeViewItem("#1",$idTreeview)
    Local $idTreeview2 = GUICtrlCreateTreeViewItem("#2",$idTreeview)
    Local $idTreeview3 = GUICtrlCreateTreeViewItem("#3",$idTreeview)
    Local $idTreeviewArray[4]
    $idTreeviewArray[0] = GUICtrlCreateTreeViewItem("#1.1",$idTreeview1)
    $idTreeviewArray[1] = GUICtrlCreateTreeViewItem("#1.2",$idTreeview1)
    $idTreeviewArray[2] = GUICtrlCreateTreeViewItem("#2.1",$idTreeview2)
    $idTreeviewArray[3] = GUICtrlCreateTreeViewItem("#2.2",$idTreeview2)
    GUICtrlSetState($idTreeview2, BitOR($GUI_EXPAND, $GUI_DEFBUTTON))
    GUISetState(@SW_SHOW)
    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                ExitLoop
            Case $idTreeviewArray[3]
                MsgBox(0,"you pressed",_GUICtrlTreeView_GetText($idTreeview))
        EndSwitch
    WEnd
EndFunc

Alles anzeigen

Leider bisher ohne Erfolg, weshalb ich nun um Eure Unterstützung bitte.

Beste Grüße, Gremlin

**alpines**

Du kannst im Case angeben von wo bis wohin das greifen soll. Da AutoIt intern alle Controls aufsteigend durchnummeriert kannst du dir das zu nutze machen, wenn du die TreeViews alle hintereinander erzeugst.

Anschließend musst du dem GetText nur noch das selektierte Item übergeben, und das findest du ebenfalls mit der entsprechenden Funktion raus.

C

#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>
#include <StaticConstants.au3>
#include <TreeViewConstants.au3>
#include <GUITreeView.au3>
#include <WindowsConstants.au3>

Example_Tree()
Func Example_Tree()
    GUICreate("My test treeview GUI", 350, 210)
    Local $idTreeview = GUICtrlCreateTreeView(5, 5, 340, 200)
    Local $idTreeview1 = GUICtrlCreateTreeViewItem("#1",$idTreeview)
    Local $idTreeview2 = GUICtrlCreateTreeViewItem("#2",$idTreeview)
    Local $idTreeview3 = GUICtrlCreateTreeViewItem("#3",$idTreeview)
    Local $idTreeviewArray[4]
    $idTreeviewArray[0] = GUICtrlCreateTreeViewItem("#1.1",$idTreeview1)
    $idTreeviewArray[1] = GUICtrlCreateTreeViewItem("#1.2",$idTreeview1)
    $idTreeviewArray[2] = GUICtrlCreateTreeViewItem("#2.1",$idTreeview2)
    $idTreeviewArray[3] = GUICtrlCreateTreeViewItem("#2.2",$idTreeview2)
    GUICtrlSetState($idTreeview2, BitOR($GUI_EXPAND, $GUI_DEFBUTTON))
    GUISetState(@SW_SHOW)
    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                ExitLoop
            Case $idTreeview1 To $idTreeviewArray[3]
                MsgBox(0,"you pressed",_GUICtrlTreeView_GetText($idTreeview, _GUICtrlTreeView_GetSelection($idTreeview)))
        EndSwitch
    WEnd
EndFunc

Alles anzeigen

Gremlin78

Fantastisch,

vielen Dank.

**autoBert**

Hallo Gremlin78,

_GUICtrlTreeView_GetText erwartet das zugehörige Item, ansonsonsten gibt es das 1. aus. Du must du dir also diese merken und mitübergeben:

AutoIt

#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>
#include <StaticConstants.au3>
#include <TreeViewConstants.au3>
#include <GUITreeView.au3>
#include <WindowsConstants.au3>

Example_Tree()
Func Example_Tree()
    GUICreate("My test treeview GUI", 350, 210)
    Local $idTreeview = GUICtrlCreateTreeView(5, 5, 340, 200)
    Local $idTreeview1 = GUICtrlCreateTreeViewItem("#1",$idTreeview)
    Local $idTreeview2 = GUICtrlCreateTreeViewItem("#2",$idTreeview)
    Local $idTreeview3 = GUICtrlCreateTreeViewItem("#3",$idTreeview)
    Local $idTreeviewArray[4]
    $idTreeviewArray[0] = GUICtrlCreateTreeViewItem("#1.1",$idTreeview1)
    $idTreeviewArray[1] = GUICtrlCreateTreeViewItem("#1.2",$idTreeview1)
    $idTreeviewArray[2] = GUICtrlCreateTreeViewItem("#2.1",$idTreeview2)
    $idTreeviewArray[3] = GUICtrlCreateTreeViewItem("#2.2",$idTreeview2)
    GUICtrlSetState($idTreeview2, BitOR($GUI_EXPAND, $GUI_DEFBUTTON))
    GUISetState(@SW_SHOW)
    While 1
        $iMsg = GUIGetMsg()
        Switch $iMsg
            Case $GUI_EVENT_CLOSE
                ExitLoop
            Case $idTreeviewArray[0] to $idTreeviewArray[3]
                MsgBox(0,"you pressed",_GUICtrlTreeView_GetText($idTreeview, $iMsg))
        EndSwitch
    WEnd
EndFunc

Alles anzeigen

Variante 2 mit Dummy-Controls

C

#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>
#include <StaticConstants.au3>
#include <TreeViewConstants.au3>
#include <GUITreeView.au3>
#include <WindowsConstants.au3>

Example_Tree()
Func Example_Tree()
    GUICreate("My test treeview GUI", 350, 210)
    Local $idTreeview = GUICtrlCreateTreeView(5, 5, 340, 200)
    Local $idTV_Start = GUICtrlCreateDummy()
    Local $idTreeview1 = GUICtrlCreateTreeViewItem("#1",$idTreeview)
    Local $idTreeview2 = GUICtrlCreateTreeViewItem("#2",$idTreeview)
    Local $idTreeview3 = GUICtrlCreateTreeViewItem("#3",$idTreeview)
    GUICtrlCreateTreeViewItem("#1.1",$idTreeview1)
    GUICtrlCreateTreeViewItem("#1.2",$idTreeview1)
    GUICtrlCreateTreeViewItem("#2.1",$idTreeview2)
    GUICtrlCreateTreeViewItem("#2.2",$idTreeview2)
    GUICtrlSetState($idTreeview2, BitOR($GUI_EXPAND, $GUI_DEFBUTTON))
     Local $idTV_End = GUICtrlCreateDummy()
    GUISetState(@SW_SHOW)
    While 1
        $iMsg = GUIGetMsg()
        Switch $iMsg
            Case $GUI_EVENT_CLOSE
                ExitLoop
            Case $idTV_Start to $idTV_End
                MsgBox(0,"you pressed",_GUICtrlTreeView_GetText($idTreeview, $iMsg))
        EndSwitch
    WEnd
EndFunc

Alles anzeigen

mfg (auto)Bert

Gremlin78

Super,

auch sehr gute Möglichkeiten, danke.

Gremlin78 9. April 2020 um 12:15