Recursiv Verzeichnisse und Dateien umbenennen

bazii · 19. Mai 2020

Hallo

mit folgendem Beispielcode ist es möglich, bis zu sechs verschiedene Zeichenersetzungen, in Datei- und Verzeichnisnamen recursiv vorzunehmen.

Versuche ich beispielsweise 10 verschiedene Zeichenersetzungen, bekomme ich einen Fehler:

Array variable has incorrect number of subscripts or subscript dimension range exceeded.:

If BitAND($aFilesFolder[$i][7], $FILE_ATTRIBUTE_DIRECTORY) Then _RenameRecursive($sPath & $aFilesFolder[$i][0])

If BitAND(^ ERROR

Warum das ganze:

Es dürfen nur Buchstaben, Zahlen, Binde- und Unterstrich in meinenDatei- und Verzeichnisnamen zugelassen werden. Alle anderen Zeichen müssen aus bestimmten Gründen aus den Verzeichnis und Dateinamen entfernt werden.

C

#include <APIFilesConstants.au3>
#include <APIShellExConstants.au3>
#include <GDIPlus.au3>
#include <GDIPlusConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WinAPI.au3>
#include <WinAPIConstants.au3>
#include <WinAPIFiles.au3>
#include <WinAPIShellEx.au3>
#include <WindowsConstants.au3>

Global $sPath = FileSelectFolder('     Bitte Verzeichnis auswählen !', '')
If Not FileExists($sPath) Then Exit

;===================================================================
;Codebeginn für die Animation UEZ
;===================================================================

_GDIPlus_Startup()
Global $iW = 400, $iH = 250
Global Const $hGUI = GUICreate("Loading Spinner", $iW, $iH, -1, -1, $WS_POPUP); $WS_EX_TOPMOST)
Global Const $iPic = GUICtrlCreatePic("", 0, 0, $iW, $iH)
GUICtrlSetState(-1, $GUI_DISABLE)
GUISetState()

Global $hHBmp_BG, $hB, $iPerc = 0, $iSleep = 30, $s = 0, $t, $m = 0
GUIRegisterMsg($WM_TIMER, "PlayAnim")
DllCall("user32.dll", "int", "SetTimer", "hwnd", $hGUI, "int", 0, "int", $iSleep, "int", 0)

;===================================================================
;Code-Beginn für das umbenennen der Verzeichnisse und Dateien
;===================================================================

_RenameRecursive($sPath)

Func _RenameRecursive($sPath)
    If StringRight($sPath, 1) <> '\' Then $sPath &= '\'
    Local $aFilesFolder = _WinAPI_EnumFiles($sPath,0)
    If @error Then Return
    For $i = 1 To $aFilesFolder[0][0]
        If BitAND($aFilesFolder[$i][4], $FILE_ATTRIBUTE_DIRECTORY) Then _RenameRecursive($sPath & $aFilesFolder[$i][0])
        _WinAPI_ShellFileOperation($sPath & $aFilesFolder[$i][0], $sPath & StringReplace(StringReplace(StringReplace(StringReplace(StringReplace($aFilesFolder[$i][0], "ä","ae"), "ö","oe"), "ü","ue"), " ","_"), "ß","ss"), $FO_RENAME, $FOF_SILENT)
    Next
EndFunc

GUIRegisterMsg($WM_TIMER, "")
_WinAPI_DeleteObject($hHBmp_BG)
_GDIPlus_Shutdown()
GUIDelete()
Sleep(200)
MsgBox(64,"", "Die Verzeichnisse und Dateien wurden umbenannt!")
Exit

;===================================================================
;Code für die Animation von UEZ
;===================================================================

Func PlayAnim()
    $hHBmp_BG = _GDIPlus_MultiColorLoader($iW, $iH, "Die Verzeichnisse und Dateien werden umbenannt. Bitte warten! ")
    $hB = GUICtrlSendMsg($iPic, $STM_SETIMAGE, $IMAGE_BITMAP, $hHBmp_BG)
    If $hB Then _WinAPI_DeleteObject($hB)
    _WinAPI_DeleteObject($hHBmp_BG)
EndFunc   ;==>PlayAnim


Func _GDIPlus_MultiColorLoader($iW, $iH, $sText = "", $sFont = "Verdana", $bHBitmap = True)
    Local Const $hBitmap = _GDIPlus_BitmapCreateFromScan0($iW, $iH)
    Local Const $hGfx = _GDIPlus_ImageGetGraphicsContext($hBitmap)
    _GDIPlus_GraphicsSetSmoothingMode($hGfx, 4 + (@OSBuild > 5999))
    _GDIPlus_GraphicsSetTextRenderingHint($hGfx, 3)
    _GDIPlus_GraphicsSetPixelOffsetMode($hGfx, $GDIP_PIXELOFFSETMODE_HIGHQUALITY)
    _GDIPlus_GraphicsClear($hGfx, 0xFF232323)

    Local $iRadius = ($iW > $iH) ? $iH * 0.6 : $iW * 0.6

    Local Const $hPath = _GDIPlus_PathCreate()
    _GDIPlus_PathAddEllipse($hPath, ($iW - ($iRadius + 24)) / 2, ($iH - ($iRadius + 24)) / 2, $iRadius + 24, $iRadius + 24)

    Local $hBrush = _GDIPlus_PathBrushCreateFromPath($hPath)
    _GDIPlus_PathBrushSetCenterColor($hBrush, 0xFFFFFFFF)
    _GDIPlus_PathBrushSetSurroundColor($hBrush, 0x08101010)
    _GDIPlus_PathBrushSetGammaCorrection($hBrush, True)

    Local $aBlend[4][2] = [[3]]
    $aBlend[1][0] = 0 ;0% center color
    $aBlend[1][1] = 0 ;position = boundary
    $aBlend[2][0] = 0.33 ;70% center color
    $aBlend[2][1] = 0.1 ;10% of distance boundary->center point
    $aBlend[3][0] = 1 ;100% center color
    $aBlend[3][1] = 1 ;center point
    _GDIPlus_PathBrushSetBlend($hBrush, $aBlend)

    Local $aRect = _GDIPlus_PathBrushGetRect($hBrush)
    _GDIPlus_GraphicsFillRect($hGfx, $aRect[0], $aRect[1], $aRect[2], $aRect[3], $hBrush)

    _GDIPlus_PathDispose($hPath)
    _GDIPlus_BrushDispose($hBrush)

    Local Const $hBrush_Black = _GDIPlus_BrushCreateSolid(0xFF161616)
    _GDIPlus_GraphicsFillEllipse($hGfx, ($iW - ($iRadius + 10)) / 2, ($iH - ($iRadius + 10)) / 2, $iRadius + 10, $iRadius + 10, $hBrush_Black)

    Local Const $hBitmap_Gradient = _GDIPlus_BitmapCreateFromScan0($iRadius, $iRadius)
    Local Const $hGfx_Gradient = _GDIPlus_ImageGetGraphicsContext($hBitmap_Gradient)
    _GDIPlus_GraphicsSetSmoothingMode($hGfx_Gradient, 4 + (@OSBuild > 5999))
    Local Const $hMatrix = _GDIPlus_MatrixCreate()
    Local Static $r = 0
    _GDIPlus_MatrixTranslate($hMatrix, $iRadius / 2, $iRadius / 2)
    _GDIPlus_MatrixRotate($hMatrix, $r)
    _GDIPlus_MatrixTranslate($hMatrix, -$iRadius / 2, -$iRadius / 2)
    _GDIPlus_GraphicsSetTransform($hGfx_Gradient, $hMatrix)
    $r += 10
    Local Const $hBrush_Gradient = _GDIPlus_LineBrushCreate($iRadius, $iRadius / 2, $iRadius, $iRadius, 0xFF000000, 0xFF33CAFD, 1)
    _GDIPlus_LineBrushSetGammaCorrection($hBrush_Gradient)
    _GDIPlus_GraphicsFillEllipse($hGfx_Gradient, 0, 0, $iRadius, $iRadius, $hBrush_Gradient)
    _GDIPlus_GraphicsFillEllipse($hGfx_Gradient, 4, 4, $iRadius - 8, $iRadius - 8, $hBrush_Black)
    _GDIPlus_GraphicsDrawImageRect($hGfx, $hBitmap_Gradient, ($iW - $iRadius) / 2, ($iH - $iRadius) / 2, $iRadius, $iRadius)
    _GDIPlus_BrushDispose($hBrush_Gradient)
    _GDIPlus_BrushDispose($hBrush_Black)
    _GDIPlus_GraphicsDispose($hGfx_Gradient)
    _GDIPlus_BitmapDispose($hBitmap_Gradient)
    _GDIPlus_MatrixDispose($hMatrix)

    Local Const $hFormat = _GDIPlus_StringFormatCreate()
    Local Const $hFamily = _GDIPlus_FontFamilyCreate($sFont)
    Local Const $hFont = _GDIPlus_FontCreate($hFamily, $iRadius / 10)
    _GDIPlus_StringFormatSetAlign($hFormat, 1)
    _GDIPlus_StringFormatSetLineAlign($hFormat, 1)
    Local $tLayout = _GDIPlus_RectFCreate(0, 0, $iW, $iH)
    Local Static $iColor = 0x00, $iDir = 13
    Local $hBrush_txt = _GDIPlus_BrushCreateSolid(0xFF000000 + 0x010000 * $iColor + 0x0100 * $iColor + $iColor)
    _GDIPlus_GraphicsDrawStringEx($hGfx, $sText, $hFont, $tLayout, $hFormat, $hBrush_txt)
    $iColor += $iDir
    If $iColor > 0xFF Then
        $iColor = 0xFF
        $iDir *= -1
    ElseIf $iColor < 0x16 Then
        $iDir *= -1
        $iColor = 0x16
    EndIf
    _GDIPlus_BrushDispose($hBrush_txt)
    _GDIPlus_FontDispose($hFont)
    _GDIPlus_FontFamilyDispose($hFamily)
    _GDIPlus_StringFormatDispose($hFormat)
    _GDIPlus_GraphicsDispose($hGfx)

    If $bHBitmap Then
        Local $hHBITMAP = _GDIPlus_BitmapCreateHBITMAPFromBitmap($hBitmap)
        _GDIPlus_BitmapDispose($hBitmap)
        Return $hHBITMAP
    EndIf
    Return $hBitmap
EndFunc

Alles anzeigen

Jetzt sollte ich aber bis zu (geschätzten) 30 Varianten für verschiedene Zeichenersetzungen, in Datei- und Verzeichnisnamen recursiv vorzunehmen können.

Würdet Ihr mir bitte das eine oder andere Beispiel nennen, wie Ihr das Vorhaben am sinnvollsten umsetzen würdet?

**Bitnugger** · 20. Mai 2020

Zuerst das Wichtigste: _WinAPI_EnumFiles unterschlägt definitiv Files und womöglich auch Folders, denn es sind bei meinem Test 6 Einträge weniger im Array, als mit _FileListToArrayRec! Der Sache werde ich aber noch nachgehen.

Zitat von bazii

If BitAND($aFilesFolder[$i][7], $FILE_ATTRIBUTE_DIRECTORY) Then _RenameRecursive($sPath & $aFilesFolder[$i][0])
If BitAND(^ ERROR

Der erste Index in einem Array fängt immer bei 0 an. Wenn das Array also 7 Spalten hat, gehen diese von 0 - 6!

In der AutoIt-Hilfe zu _WinAPI_EnumFiles steht es sogar drin:

Code

; a 2D array containing the following information:
; [0][0] - Number of rows in array (n)
; [0][i] - Unused
; [n][0] - The name of the file.
; [n][1] - The time (UTC) when the file was created.
; [n][2] - The time (UTC) when the file was last accessed.
; [n][3] - The time (UTC) when the file was last changed.
; [n][4] - The size of the file, in bytes.
; [n][5] - The allocation size of the file, in bytes.
; [n][6] - The file attributes ($FILE_ATTRIBUTE_*). <<<=== <<<=== <<<===

Deine obige Zeile müsste ergo so aussehen:

AutoIt

If BitAND($aFilesFolder[$i][6], $FILE_ATTRIBUTE_DIRECTORY) Then _RenameRecursive($sPath & $aFilesFolder[$i][0])

Bei Verwendung von _FileListToArrayRec nimmst du dann anstelle von

If BitAND($aFilesFolder[$i][6], $FILE_ATTRIBUTE_DIRECTORY) Then ...

If StringRight($aFilesFolder[$i], 1) = '\' Then ...

Und was Geschwindigkeit angeht, ist _FileListToArrayRec sogar noch ein wenig schneller!

Code

; _WinAPI_EnumFiles      ==>> Files + Folders = 47, Time = 14.2644, [n][1] - [n][6] brauchst du doch gar nicht?!
; _FileListToArrayRec    ==>> Files + Folders = 53, Time =  8.5151, $FLTAR_SORT, $FLTAR_FULLPATH
; _FileListToArrayRec    ==>> Files + Folders = 53, Time = 10.7491, $FLTAR_SORT, $FLTAR_NOPATH

Zitat von bazii

Jetzt sollte ich aber bis zu (geschätzten) 30 Varianten für verschiedene Zeichenersetzungen, in Datei- und Verzeichnisnamen recursiv vorzunehmen können.

Oh, was ein lecker Deutsch...

Ja, es soll also dynamisch werden... dann solltest du keine fixen Werte nehmen, sondern die Zeichen für jede Variante in ein Input-Control eingeben, diese dann auslesen und in einer Datei (*.ini) speichern. Beim Start lädst du dann diese Ini-Datei, in der du dir dann auch merkst, welches Tabelle beim letzten Start aktiv war. Eine würde ich zumindest als Default speichern, dann hast du auch direkt schon etwas Futter für die Haie.

Ich habe das in einigen meiner Projekte etwa so gelöst:

Code: LPS_Manager.ini

[UDP]
# Pattern|Replace¦Pattern|Replace¦...
LastUsedTable=ConversionTable_02
TableSeparator="¦" # Chr(166)
ConversionTable_01=Ã¤|ä¦Ã„|Ä¦Ã¶|ö¦Ã–|Ö¦Ã¼|ü¦Ãœ|Ü¦ÃŸ|ß
ConversionTable_02=ä|ae¦ö|oe¦ü|ue¦ |_¦ß|ss
ConversionTable_03=Reiner|Rainer¦Neustatt|Neustadt¦Marwel|Marvel¦Mar Wel|Marvel

Die ConversionTables lade ich mir dann alle als Array in ein Array... ändert der User den Index für die aktuelle Tabelle, kopiere ich das benötigte Table-Array aus $g_aConversionTables[n] nach $g_aCurrentConversionTable.

AutoIt

$g_iCurrentConversionTable += 1
If $g_iCurrentConversionTable < Ubound($g_aConversionTables) Then
    $g_aCurrentConversionTable = $g_aConversionTables[$g_iCurrentConversionTable]
Else
    $g_iCurrentConversionTable -= 1
EndIf

bazii · 20. Mai 2020

Zitat von Bitnugger

Der erste Index in einem Array fängt immer bei 0 an. Wenn das Array also 7 Spalten hat, gehen diese von 0 - 6!
In der AutoIt-Hilfe zu _WinAPI_EnumFiles steht es sogar drin:

Hallo

und danke erstmal für die ausführliche Antwort.

Ich habe mich schlecht ausgedrückt. Sorry.

In meinem Beispiel-Code mit der Animation funktioniert das umbenennen der Dateinamen sehr gut.

Das mit der Zahl 7 war nur ein Beispiel dafür, dass ab [$i][7] der nachfolgende Fehler auftritt.

If BitAND(^ ERROR Du hast ja aber erklärt warum. Hatte das nicht berücksichtigt.

Zitat von Bitnugger

Ich habe das in einigen meiner Projekte etwa so gelöst: Code: LPS_Manager.ini

Das ganze Vorhaben mit einer .ini oder. txt umzusetzen wäre mir auch viel lieber.

Zitat von Bitnugger

Die ConversionTables lade ich mir dann alle als Array in ein Array... ändert der User den Index für die aktuelle Tabelle, kopiere ich das benötigte Table-Array aus $g_aConversionTables[n] nach $g_aCurrentConversionTable.

Vielen Dank für Deine sehr guten Lösungsansatz.

Es wird für mich aber ohne weitere Hilfe, zu meinem geposteteten Code, wahrscheinlich nicht umsetzbar werden.

Aber das eigentliche Problem das ich mit dem Array hatte, hast Du ja bereits gelöst.

Zitat von Bitnugger

Zuerst das Wichtigste: _WinAPI_EnumFiles unterschlägt definitiv Files und womöglich auch Folders, denn es sind bei meinem Test 6 Einträge weniger im Array, als mit _FileListToArrayRec!

Das hatt ich auch schon am Rande in mehreren Verzeichnissen bemerkt. Die Recursion funktioniert irgendwie nicht richtig.

_FileListToArrayRec! : Schaue ich mir gleich mal an.

Vielen Dank für den Hinweis.

Teilen