_OL_Wrapper_SendMail gibt den Fehler 6002 aus

Daniel

Hallo,

ich hab mir ein kleines Programm geschrieben welches Daten aus einer .csv liest und mir als E-Mail schickt.

Lief auch jetzt mehrere Wochen ohne Problem aber seit ca. 14 Tagen erhalte ich immer folgenden Fehler:

Die Mail wird auch im Ausgangsordner angezeigt, kann aber nicht direkt versendet werden.

Erst wenn sie in einen anderen Ordner verschoben wurde kann ich senden und kommt dann auch ohne Probleme an.

Code

      Global $oOutlook = _OL_Open()
      If @error <> 0 Then Exit MsgBox(16, "OutlookEX UDF", "Error creating a connection to Outlook. @error = " & @error & ", @extended = " & @extended)


      Global $sCurrentUser = $oOutlook.GetNameSpace("MAPI").CurrentUser.Name
      _OL_Wrapper_SendMail($oOutlook, $sCurrentUser, "", "", "Geschriebene Stunden", $mitarbeiterzeit[1]&" "&$mitarbeiter[1]&"<br>"&$mitarbeiterzeit[2]&" "&$mitarbeiter[2]&"<br>"&$mitarbeiterzeit[3]&" "&$mitarbeiter[3]&"<br>"&$mitarbeiterzeit[4]&" "&$mitarbeiter[4]&"<br>"&$mitarbeiterzeit[5]&" "&$mitarbeiter[5]&"<br>"&$mitarbeiterzeit[6]&" "&$mitarbeiter[6]&"<br>"&$mitarbeiterzeit[7]&" "&$mitarbeiter[7]&"<br>"&$mitarbeiterzeit[8]&" "&$mitarbeiter[8]&"<br>"&$mitarbeiterzeit[9]&" "&$mitarbeiter[9]&"<br>"&$mitarbeiterzeit[10]&" "&$mitarbeiter[10]&"<br>"&$mitarbeiterzeit[11]&" "&$mitarbeiter[11]&"<br>"&$mitarbeiterzeit[12]&" "&$mitarbeiter[12]&"<br>","" , $olFormatHTML, $olImportanceHigh)
      If @error <> 0 Then Exit MsgBox(16, "OutlookEX UDF: _OutlookSendMail Wrapper Script", "Error sending mail. @error = " & @error & ", @extended: " & @extended)

      _OL_Close($oOutlook)

**Bitnugger**

Hm, das funktioniert so bei mir:

AutoIt

#include <OutlookEX.au3>

Global $mitarbeiterzeit[13] = [12, '08:00', '08:00', '08:00', '08:00', '08:00', '08:00', '08:00', '08:00', '08:00', '08:00', '08:00', '08:00']
Global $mitarbeiter[13]     = [12, 'Rainer', 'Peter', 'Uwe', 'Dieter', 'Jens', 'Udo', 'Jörg', 'Franz', 'Wolfgang', 'Siegfried', 'Willi', 'Günter']

Global $oOutlook = _OL_Open()
If @error <> 0 Then Exit MsgBox(16, "OutlookEX UDF", "Error creating a connection to Outlook. @error = " & @error & ", @extended = " & @extended)

Global $sCurrentUser = $oOutlook.GetNameSpace("MAPI").CurrentUser.Name
If @error Or $sCurrentUser = "" Then Exit MsgBox(16, "OutlookEX UDF: _OutlookEX", "Error $sCurrentUser = " & $sCurrentUser & " @error = " & @error & ", @extended: " & @extended)

;~ _OL_Wrapper_SendMail($oOutlook, $sCurrentUser, "", "", "Geschriebene Stunden", $mitarbeiterzeit[1]&" "&$mitarbeiter[1]&"<br>"&$mitarbeiterzeit[2]&" "&$mitarbeiter[2]&"<br>"&$mitarbeiterzeit[3]&" "&$mitarbeiter[3]&"<br>"&$mitarbeiterzeit[4]&" "&$mitarbeiter[4]&"<br>"&$mitarbeiterzeit[5]&" "&$mitarbeiter[5]&"<br>"&$mitarbeiterzeit[6]&" "&$mitarbeiter[6]&"<br>"&$mitarbeiterzeit[7]&" "&$mitarbeiter[7]&"<br>"&$mitarbeiterzeit[8]&" "&$mitarbeiter[8]&"<br>"&$mitarbeiterzeit[9]&" "&$mitarbeiter[9]&"<br>"&$mitarbeiterzeit[10]&" "&$mitarbeiter[10]&"<br>"&$mitarbeiterzeit[11]&" "&$mitarbeiter[11]&"<br>"&$mitarbeiterzeit[12]&" "&$mitarbeiter[12]&"<br>","" , $olFormatHTML, $olImportanceHigh)

_OL_Wrapper_SendMail($oOutlook, $sCurrentUser, "", "", "Geschriebene Stunden", _SliceArraysToString($mitarbeiterzeit, $mitarbeiter), "", $olFormatHTML, $olImportanceHigh)
If @error Then Exit MsgBox(16, "OutlookEX UDF: _OutlookSendMail Wrapper Script", "Error sending mail. @error = " & @error & ", @extended: " & @extended)

_OL_Close($oOutlook)

Func _SliceArraysToString($mitarbeiterzeit, $mitarbeiter)
    If UBound($mitarbeiterzeit) < 1 Or UBound($mitarbeiterzeit) <> UBound($mitarbeiter) Then Return SetError(1, 0, '')
    Local $sRet
    For $i = 1 To UBound($mitarbeiter) -1 Step 1
        $sRet &= $mitarbeiterzeit[$i]&" "&$mitarbeiter[$i]&"<br>"
    Next
    Return $sRet
EndFunc

Alles anzeigen

@extended = -2147024809 ==>> 0x80070057

Daniel

Super Danke für die Hilfe

Ist natürlich deutlich schöner mit ner Funktion aber mein Fehler bleibt leider der gleiche!

Ich werde heute mal nach der Outlookinstallation schauen....

**Bitnugger**

Schöner wäre so:

AutoIt

#include <OutlookEX.au3>

_OL_ErrorNotify(2)

Global $g_aZeiten[13][2] = [[12], _
        ['08:00', 'Rainer'], ['08:00', 'Peter'], ['08:00', 'Uwe'     ], ['08:00', 'Dieter'   ], ['08:00', 'Jens' ], ['08:00', 'Udo'   ], _
        ['08:00', 'Jörg'  ], ['08:00', 'Franz'], ['08:00', 'Wolfgang'], ['08:00', 'Siegfried'], ['08:00', 'Willi'], ['08:00', 'Günter']]

Global $g_sZeiten = _ArrayToString($g_aZeiten, ' ', 1, -1, '<br>')
If @error <> 0 Then Exit MsgBox(16, "OutlookEX UDF", "Error by _ArrayToString($g_aZeiten, ...). @error = " & @error & ", @extended = " & @extended)

Global $oOutlook = _OL_Open()
If @error <> 0 Then Exit MsgBox(16, "OutlookEX UDF", "Error creating a connection to Outlook. @error = " & @error & ", @extended = " & @extended)

Global $sCurrentUser = $oOutlook.GetNameSpace("MAPI").CurrentUser.Name
If @error Or $sCurrentUser = "" Then Exit MsgBox(16, "OutlookEX UDF: _OutlookEX", "Error $sCurrentUser = " & $sCurrentUser & " @error = " & @error & ", @extended: " & @extended)

_OL_Wrapper_SendMail($oOutlook, $sCurrentUser, "", "", "Geschriebene Stunden", $g_sZeiten, "", $olFormatHTML, $olImportanceHigh)
If @error Then Exit MsgBox(16, "OutlookEX UDF: _OutlookSendMail Wrapper Script", "Error sending mail. @error = " & @error & ", @extended: " & @extended)

_OL_Close($oOutlook)

Alles anzeigen

Evtl. reicht es, ein neues Profil anzulegen. Die Konten darin dann manuell anlegen, nicht mit Assistent - nur so weiß du genau, was gesetzt wird.

**Bitnugger**

Ich habe das Script in Post #4 noch ein wenig geändert... teste es mal bitte und poste hier die Ausgaben, wenn damit auch wieder ein Fehler auftritt.

Daniel

Sorry für meine späte Antwort, bin gerade gut eingespannt....

Was ich noch nicht ganz verstehe, warum es von heut auf morgen nicht mehr geht,

es wurde in der Zeit auch kein Update gefahren.

**Bitnugger**

Zitat von Daniel

Was ich noch nicht ganz verstehe, warum es von heut auf morgen nicht mehr geht,
es wurde in der Zeit auch kein Update gefahren.

Mit "kein Update gefahren" meinst du wohl "kein Windows-Update"... doch wenn du es in Outlook nicht umgestellt hast, macht es das unabhängig davon automatisch im Hintergrund bei jedem Start.

Um dir die Version von Outlook anzeigen zu lassen, gibst du in der Outlook-Hilfe einfach "version" ein... dort steht dann, wie/wo du sie ablesen kannst. Ich habe dann wohl eine andere/älterere Version als du...

"C:\Program Files (x86)\Microsoft Office\root\Office16\OUTLOOK.EXE"

In der MsBox (dann ist es ein COM-Error) wird als Ursache WinDescription = Falscher Parameter angegeben.

Welcher Parameter das ist, kannst du evtl. herausbekommen, wenn du die Funktion nur mit den ersten beiden (weniger geht nicht) Parametern aufrufst... und dann einen weiteren anhängst, bis der Fehler wieder auftritt:

~~_OL_Wrapper_SendMail($oOutlook, $sCurrentUser, "", "", "Geschriebene Stunden", _ArrayToString($g_aZeiten, ' ', 1, -1, '<br>'), "", $olFormatHTML, $olImportanceHigh)~~

_OL_Wrapper_SendMail($oOutlook, $sCurrentUser) ; Test 1

_OL_Wrapper_SendMail($oOutlook, $sCurrentUser, "") ; Test 2

...

Oder du testest es so:

AutoIt

;-- TIME_STAMP   2020-09-19 06:56:02   v 0.1

Opt('MustDeclareVars', 1)

#include <OutlookEX.au3>

_OL_ErrorNotify(2) ; 2  - Enable Debugging. Output the debug info to a MsgBox

Global $g_aZeiten[13][2] = [[12], _
        ['08:00', 'Rainer'], ['08:00', 'Peter'], ['08:00', 'Uwe'     ],    ['08:00', 'Dieter'   ],    ['08:00', 'Jens' ], ['08:00', 'Udo'   ], _
        ['08:00', 'Jörg'  ], ['08:00', 'Franz'], ['08:00', 'Wolfgang'], ['08:00', 'Siegfried'], ['08:00', 'Willi'], ['08:00', 'Günter']]

Global $oOutlook = _OL_Open()
If @error Then Exit MsgBox(16, "OutlookEX UDF", "Error creating a connection to Outlook. @error = " & @error & ", @extended = " & @extended)

Global $sCurrentUser = $oOutlook.GetNameSpace("MAPI").CurrentUser.Name
If @error Or $sCurrentUser = "" Then Exit MsgBox(16, "OutlookEX UDF: _OutlookEX", "Error $sCurrentUser = " & $sCurrentUser & " @error = " & @error & ", @extended: " & @extended)

;~ _OL_Wrapper_SendMail($oOutlook, $sCurrentUser, "", "", "Geschriebene Stunden", _ArrayToString($g_aZeiten, ' ', 1, -1, '<br>'), "", $olFormatHTML, $olImportanceHigh)
__OL_Wrapper_SendMail($oOutlook, $sCurrentUser, "", "", "Geschriebene Stunden", _ArrayToString($g_aZeiten, ' ', 1, -1, '<br>'), "", $olFormatHTML, $olImportanceHigh)
If @error Then Exit MsgBox(16, "OutlookEX UDF: _OutlookSendMail Wrapper Script", "Error sending mail. @error = " & @error & ", @extended: " & @extended)

_OL_Close($oOutlook)

Func __OL_Wrapper_SendMail($oOL, $sTo = "", $sCc = "", $sBCc = "", $sSubject = "", $sBody = "", $sAttachments = "", $iBodyFormat = $olFormatPlain, $iImportance = $olImportanceNormal)

    If $sTo = Default Then $sTo = ""
    If $sCc = Default Then $sCc = ""
    If $sBCc = Default Then $sBCc = ""
    If $sSubject = Default Then $sSubject = ""
    If $sBody = Default Then $sBody = ""
    If $sAttachments = Default Then $sAttachments = ""
    If $iBodyFormat = Default Then $iBodyFormat = $olFormatPlain
    If $iImportance = Default Then $iImportance = $olImportanceNormal
    If Not IsInt($iBodyFormat) Then SetError(1, 0, 0)
    If StringStripWS($sBody, 3) = "" Then SetError(2, 0, 0)
    If StringStripWS($sTo, 3) = "" And StringStripWS($sCc, 3) = "" And StringStripWS($sBCc, 3) = "" Then SetError(3, 0, 0)
    ; Access the default outbox folder
    Local $aFolder = _OL_FolderAccess($oOL, "", $olFolderDrafts)
    If @error Then Return SetError(@error + 1000, @extended, 0)
    ConsoleWrite('+ _OL_FolderAccess OK' & @CRLF)
    ; Create a mail item in the default folder
    Local $oItem = _OL_ItemCreate($oOL, $olMailItem, $aFolder[1], "", "Subject=" & $sSubject, "BodyFormat=" & $iBodyFormat, "Importance=" & $iImportance)
    If @error Then Return SetError(@error + 2000, @extended, 0)
    ConsoleWrite('+ _OL_ItemCreate OK' & @CRLF)
    ; Set the body according to $iBodyFormat
    If $iBodyFormat = $olFormatHTML Then
        _OL_ItemModify($oOL, $oItem, Default, "HTMLBody=" & $sBody)
    Else
        _OL_ItemModify($oOL, $oItem, Default, "Body=" & $sBody)
    EndIf
    If @error Then Return SetError(@error + 3000, @extended, 0)
    ConsoleWrite('+ _OL_ItemModify OK' & @CRLF)
    ; Add recipients (to, cc and bcc)
    Local $aRecipients
    If $sTo <> "" Then
        $aRecipients = StringSplit($sTo, ";", 2)
        _OL_ItemRecipientAdd($oOL, $oItem, Default, $olTo, $aRecipients)
        If @error Then Return SetError(@error + 4000, @extended, 0)
        ConsoleWrite('+ _OL_ItemRecipientAdd $sTo OK' & @CRLF)
    EndIf
    If $sCc <> "" Then
        $aRecipients = StringSplit($sCc, ";", 2)
        _OL_ItemRecipientAdd($oOL, $oItem, Default, $olCC, $aRecipients)
        If @error Then Return SetError(@error + 4000, @extended, 0)
        ConsoleWrite('+ _OL_ItemRecipientAdd $sCc OK' & @CRLF)
    EndIf
    If $sBCc <> "" Then
        $aRecipients = StringSplit($sBCc, ";", 2)
        _OL_ItemRecipientAdd($oOL, $oItem, Default, $olBCC, $aRecipients)
        If @error Then Return SetError(@error + 4000, @extended, 0)
        ConsoleWrite('+ _OL_ItemRecipientAdd $sBCc OK' & @CRLF)
    EndIf
    ; Add attachments
    If $sAttachments <> "" Then
        Local $aAttachments = StringSplit($sAttachments, ";", 2)
        _OL_ItemAttachmentAdd($oOL, $oItem, Default, $aAttachments)
        If @error Then Return SetError(@error + 5000, @extended, 0)
        ConsoleWrite('+ _OL_ItemAttachmentAdd $sAttachments OK' & @CRLF)
    EndIf
    ; Send mail
    _OL_ItemSend($oOL, $oItem, Default)
    If @error Then Return SetError(@error + 6000, @extended, 0)
    ConsoleWrite('+ _OL_ItemSend OK' & @CRLF)
    Return $oItem

EndFunc   ;==>__OL_Wrapper_SendMail

Alles anzeigen

Die Ausgabe sollte dann so aussehen, wenn kein Fehler aufgetreten ist:

+ _OL_FolderAccess OK

+ _OL_ItemCreate OK

+ _OL_ItemModify OK

+ _OL_ItemRecipientAdd $sTo OK

+ _OL_ItemSend OK

Daniel

+ _OL_FolderAccess OK

+ _OL_ItemCreate OK

+ _OL_ItemModify OK

+ _OL_ItemRecipientAdd $sTo OK

Bis dahin gleich und dann kommt mein bekannter Fehler

Hab den gleichen Updatestand wie du nur bei mir ists die 365ger Version.

_OL_Wrapper_SendMail($oOutlook, $sCurrentUser)

Auch schon damit bekomm ich meinen schönen Fehler...

Bleibt auch nach neuinstallation von Office 365 bestehen....

Ich muss wohl damit leben das die Mails im Entwürfeordner liegen bleiben

oder ich schreib mir noch was um diese Mails in einen anderen Ordner zu verschieben und dann zu senden (was zumindest manuell funktioniert)

aber das übersteigt ein wenig meine Kenntnisse....hab zwar schon ne schöne Oberfläche für meine Mitarbeiter geschrieben mit der

alle Daten in csv`s abgelegt werden aber wenn ich in water`s quelltext schau hörts bei mir auf....

**Bitnugger**

Geht es dir nur darum, Mails via AutoIt zu versenden? Dann hätte ich evtl. eine funktionierende Alternative, mit der ich es mache...

Daniel

Ich zieh die gespeicherten Stunden aus verschiedenen .csv und sende die dann per Mail!

Bitte nicht zu genau anschauen, bin nur Hobbyprogrammierer

Code

Global $merk = 0

While 1
   if @HOUR = 23 And $merk = 0 Then
      $merk = 1
      Global $sPath = "\\pfad"
      Global $sFilter = "*.csv";"*.mp3"

      Global $sListFile = _FileListToArray($sPath, $sFilter)
      Global $mitarbeiter[13]= ["","","","","","","","","","","","",""]
      Global $mitarbeitermerker [] = 0

         For $i = 1 To $sListFile[0]
                  $mitarbeitermerker  =StringSplit($sListFile[$i],".")
                  $mitarbeiter [$i] = $mitarbeitermerker [1]
         Next


      Global $mitarbeiterzeit[13]= ["0","0","0","0","0","0","0","0","0","0","0","0","0"]

        For $i = 1 To $sListFile[0]
            Local $Mitarbeiterdaten1 [][] = 0
            _FileReadToArray ("\\pfad\"&$sListFile[$i],$Mitarbeiterdaten1,$FRTA_NOCOUNT, ";")
            Local $iRows1 = UBound($Mitarbeiterdaten1, $UBOUND_ROWS)
      ;~   ConsoleWrite($iRows1&@CRLF)
            if $Mitarbeiterdaten1[$iRows1-1][0]=_NowDate() Then
            $mitarbeiterzeit[$i]=$Mitarbeiterdaten1[$iRows1-1][1]
            Else
            $mitarbeiterzeit[$i]="0"
            EndIf
         Next






      ; *****************************************************************************
      ; Connect to Outlook
      ; *****************************************************************************
      Global $oOutlook = _OL_Open()
      If @error <> 0 Then Exit MsgBox(16, "OutlookEX UDF", "Error creating a connection to Outlook. @error = " & @error & ", @extended = " & @extended)


      Global $sCurrentUser = $oOutlook.GetNameSpace("MAPI").CurrentUser.Name
;~       _OL_Wrapper_SendMail($oOutlook, $sCurrentUser, "", "", "Geschriebene Stunden", $mitarbeiterzeit[1]&" "&$mitarbeiter[1]&"<br>"&$mitarbeiterzeit[2]&" "&$mitarbeiter[2]&"<br>"&$mitarbeiterzeit[3]&" "&$mitarbeiter[3]&"<br>"&$mitarbeiterzeit[4]&" "&$mitarbeiter[4]&"<br>"&$mitarbeiterzeit[5]&" "&$mitarbeiter[5]&"<br>"&$mitarbeiterzeit[6]&" "&$mitarbeiter[6]&"<br>"&$mitarbeiterzeit[7]&" "&$mitarbeiter[7]&"<br>"&$mitarbeiterzeit[8]&" "&$mitarbeiter[8]&"<br>"&$mitarbeiterzeit[9]&" "&$mitarbeiter[9]&"<br>"&$mitarbeiterzeit[10]&" "&$mitarbeiter[10]&"<br>"&$mitarbeiterzeit[11]&" "&$mitarbeiter[11]&"<br>"&$mitarbeiterzeit[12]&" "&$mitarbeiter[12]&"<br>","" , $olFormatHTML, $olImportanceHigh)
      _OL_Wrapper_SendMail($oOutlook, $sCurrentUser, "", "", "Geschriebene Stunden", _SliceArraysToString($mitarbeiterzeit, $mitarbeiter), "", $olFormatHTML, $olImportanceHigh)
;~       If @error <> 0 Then Exit MsgBox(16, "OutlookEX UDF: _OutlookSendMail Wrapper Script", "Error sending mail. @error = " & @error & ", @extended: " & @extended)

      _OL_Close($oOutlook)

   EndIf

   if @HOUR = 0 Then $merk = 0

   Sleep (10000)
WEnd



Func _SliceArraysToString($mitarbeiterzeit, $mitarbeiter)
    If UBound($mitarbeiterzeit) < 1 Or UBound($mitarbeiterzeit) <> UBound($mitarbeiter) Then Return SetError(1, 0, '')
    Local $sRet
    For $i = 1 To UBound($mitarbeiter) -1 Step 1
        $sRet &= $mitarbeiterzeit[$i]&" "&$mitarbeiter[$i]&"<br>"
    Next
    Return $sRet
EndFunc

Alles anzeigen

**water**

Ich habe langsam eine dunkle Ahnung, dass das an Outlook liegt.
Es wird ein Mail-Objekt mit einer eindeutigen ID (EntryID) erstellt. Ist die Mail fertig erstellt, dann wird sie in den Ordner "Entwürfe" verschoben und erhält eine neue EntryID (was natürlich Schwachsinn ist).
Somit ist das in der Funktion gespeicherte und von _OL_ItemCreate zurückgegebene Objekt ungültig.

==> Ich muss da noch forschen gehen, da dieses Problem schon mal aufgetreten ist.

Ich melde mich.

**Bitnugger**

Auf deinen Code in Post #10 werde ich jetzt mal besser nicht eingehen... nur 1 Syntax-Error, das ist für einen blutigen Anfänger schon eine ziemlich gute Leistung. Was dir fehlt, sind die Grundlagen zu AutoIt und ohne die geht es nun mal nicht! Ich Programmiere übrigens auch nur, weil ich es gerne mache.

Zitat von Daniel

_OL_Wrapper_SendMail($oOutlook, $sCurrentUser)
Auch schon damit bekomm ich meinen schönen Fehler...

Damit ist doch schon alles gesagt... wenn das nicht geht, liegt es definitiv an deinem MS-Office 365! Um das zu Testen, lässt man den ganzen anderen Rotz einfach weg... so hat man dann auch mehr Durchblick.

water hat seiner UDF bereits ein Bsp. dafür beigelegt:

AutoIt: _OL_Wrapper_SendMail.au3

#include <OutlookEX.au3>

; *****************************************************************************
; Connect to Outlook
; *****************************************************************************
Global $oOutlook = _OL_Open()
If @error <> 0 Then Exit MsgBox(16, "OutlookEX UDF", "Error creating a connection to Outlook. @error = " & @error & ", @extended = " & @extended)

; *****************************************************************************
; Example 1
; Send a html mail to the current user.
; Add an attachment and set importance to high.
; *****************************************************************************
Global $sCurrentUser = $oOutlook.GetNameSpace("MAPI").CurrentUser.Name
_OL_Wrapper_SendMail($oOutlook, $sCurrentUser, "", "", "TestSubject", "Body<br><b>fett</b> normal.", @ScriptDir & "\_OL_Wrapper_SendMail.au3", $olFormatHTML, $olImportanceHigh)
If @error <> 0 Then Exit MsgBox(16, "OutlookEX UDF: _OutlookSendMail Wrapper Script", "Error sending mail. @error = " & @error & ", @extended: " & @extended)
MsgBox(64, "OutlookEX UDF: _OutlookSendMail Wrapper Script", "Mail successfully sent to user '" & $sCurrentUser & "'!")

_OL_Close($oOutlook)

Alles anzeigen

Wenn das nicht funktioniert, liegt es definitiv nicht an dir... sondern an Outlook.

Hier das Script, mit dem ich meine Mails via AutoIt versende:

AutoIt: _INetSmtpMailCom.au3

;-- TIME_STAMP   2020-09-21 16:57:53   v 0.1

#include <File.au3>

Opt('MustDeclareVars', 1)

#cs
    $SmtpServer  = "MailServer"              ; address for the smtp-server to use - REQUIRED
    $FromName    = "Name"                    ; name from who the email was sent
    $FromAddress = "your@Email.Address.com"  ; address from where the mail should come
    $ToAddress   = "your@Email.Address.com"  ; destination address of the email - REQUIRED
    $Subject     = "Userinfo"                ; subject from the email - can be anything you want it to be
    $Body        = ""                        ; the messagebody from the mail - can be left blank but then you get a blank mail
    $AttachFiles = ""                        ; the file(s) you want to attach seperated with a ; (Semicolon) - leave blank if not needed
    $CcAddress   = "CCadress1@test.com"      ; address for cc - leave blank if not needed
    $BccAddress  = "BCCadress1@test.com"     ; address for bcc - leave blank if not needed
    $Importance  = "Normal"                  ; Send message priority: "High", "Normal", "Low"
    $Username    = "******"                  ; username for the account used from where the mail gets sent - REQUIRED
    $Password    = "********"                ; password for the account used from where the mail gets sent - REQUIRED
    $Port        = 25                        ; port used for sending the mail
    $SSL         = 0                         ; enables/disables secure socket layer sending - put to 1 if using https
;~     $Port     = 465                       ; GMAIL port used for sending the mail
;~     $SSL      = 1                         ; GMAIL enables/disables secure socket layer sending - put to 1 if using https
#ce

; - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
; Hier noch ein konkretes Bsp.: Max Mustermann sendet seiner Frau Ilse Mustermann eine Mail.
; - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
Global $SmtpServer  = "securesmtp.t-online.de"
Global $FromName    = "Max Mustermann <MaxMustermann@t-online.de>"
Global $FromAddress = "MaxMustermann@t-online.de"
Global $ToAddress   = "Ilse.Mustermann@gmx.de"
Global $Subject     = "Bin unterwegs..."
Global $Body        = "Hallo Schatz, was gibt es heute leckeres zu Essen?"
Global $AttachFiles = ""
Global $CcAddress   = ""
Global $BccAddress  = ""
Global $Importance  = "Normal"
Global $Username    = "MaxMustermann@t-online.de"
Global $Password    = "Max@0815!ez"
Global $Port        = 465
Global $SSL         = 1

Global $aErrRet[2], $oMyError = ObjEvent("AutoIt.Error", "MyErrFunc")
Global $sSend = _INetSmtpMailCom($SmtpServer, $FromName, $FromAddress, $ToAddress, $Subject, $Body, $AttachFiles, $CcAddress, $BccAddress, $Importance, $Username, $Password, $Port, $SSL)
If @error Then MsgBox(0, "Error sending message", "Error code:" & @error & "  Description:" & $sSend)


Func _INetSmtpMailCom($s_SmtpServer, $s_FromName, $s_FromAddress, $s_ToAddress, $s_Subject = "", $s_Body = "", $s_AttachFiles = "", $s_CcAddress = "", $s_BccAddress = "", $s_Importance = "Normal", $s_Username = "", $s_Password = "", $_iPort = 25, $_iSSL = 0)

    Local $objEmail = ObjCreate("CDO.Message")

    $objEmail.From = '"' & $s_FromName & '" <' & $s_FromAddress & '>'
    $objEmail.To = $s_ToAddress
    If $s_CcAddress <> "" Then $objEmail.Cc = $s_CcAddress
    If $s_BccAddress <> "" Then $objEmail.Bcc = $s_BccAddress
    $objEmail.Subject = $s_Subject
    If StringInStr($s_Body, "<") And StringInStr($s_Body, ">") Then
        $objEmail.HTMLBody = $s_Body
    Else
        $objEmail.Textbody = $s_Body & @CRLF
    EndIf
    If $s_AttachFiles <> "" Then
        Local $a_Files2Attach = StringSplit($s_AttachFiles, ";")
        For $x = 1 To $a_Files2Attach[0]
            $a_Files2Attach[$x] = _PathFull($a_Files2Attach[$x])
            If FileExists($a_Files2Attach[$x]) Then
                ConsoleWrite('+> File attachment added: ' & $a_Files2Attach[$x] & @LF)
                $objEmail.AddAttachment($a_Files2Attach[$x])
            Else
                Return SetError(1, 0, '!> File not found to attach: ' & $a_Files2Attach[$x])
            EndIf
        Next
    EndIf
    $objEmail.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2
    $objEmail.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpserver") = $s_SmtpServer
    If Number($_iPort) = 0 Then $_iPort = 25
    $objEmail.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = $_iPort

    ; Authenticated SMTP
    If $s_Username <> "" Then
        $objEmail.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpauthenticate") = 1
        $objEmail.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/sendusername") = $s_Username
        $objEmail.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/sendpassword") = $s_Password
    EndIf
    If $_iSSL Then
        $objEmail.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpusessl") = True
    EndIf

    ; Update settings
    $objEmail.Configuration.Fields.Update

    ; Set Email Importance
    Switch $s_Importance
        Case "High", "Low", "Normal"
            ; Nope
        Case Else
            $s_Importance = "Normal"
    EndSwitch
    $objEmail.Fields.Item("urn:schemas:mailheader:Importance") = $s_Importance

    ; Update settings
    $objEmail.Fields.Update

    ; Sent the Message
    $objEmail.Send
    If @error Then Return SetError(2, 0, $aErrRet[1])
EndFunc   ;==>_INetSmtpMailCom

; COM ERROR HANDLER
Func MyErrFunc()
    Local $sHexNumber = Hex($oMyError.number, 8)
    $aErrRet[0] = $sHexNumber
    $aErrRet[1] = StringStripWS($oMyError.description, 3)
    ConsoleWrite("### COM Error !  Number: 0x" & $sHexNumber & "   ScriptLine: " & $oMyError.scriptline & "   Description: " & $aErrRet[1] & @LF)
    Return SetError(1) ; something to check for when this function returns
EndFunc   ;==>MyErrFunc

Alles anzeigen

Bei EntryID klingelt auch bei mir etwas...

Daniel

Zitat von Bitnugger

Wenn das nicht funktioniert, liegt es definitiv nicht an dir... sondern an Outlook.

Liegt an Outlook...

Hängt wieder genau so im Entwürfe Ordner

@Bittnugger Ich hab mir Autoit nur über die Hilfe Stück für Stück angelesen und Grundlagen Programmierung gabs in der Technikerschule auch nur so lala.

Gibt zum Glück viele Foren in denen man sich viel Beispiele anschauen kann, für mich ist es hier das erste mal das ich meine Probleme nicht selbst lösen konnte

Wenn ich hier meine Oberfläche poste gibt´s wohl gleich einen Seitenbann... aber so sieht es halt aus wenn man was zusammen Bastelt und mehr ausprobiert als wirklich zu

wissen ob es so funktioniert.

Aber das Ergebnis funktioniert super, meine Mitarbeiter sind 50% schneller als mit em Papier und ich spar mir sicher jeden Tag 30-60 Minuten Aufträge abschreiben da ich die

eingegebenen Daten direkt in mein Dispoprogramm eintragen lassen kann und alles Dank AutoIt

Eingabe, Oberfläche und speichern der Daten wären wahrscheinlich mit Access sinnvoller gewesen aber jetzt läuft es auch so recht sicher!

**water**

Zur COM Fehlermeldung in Post #6. Die Zeilennummer zeigt auf $vItem.Send() in Funktion _OL_ItemSend.

An was das liegt, ist mir aber immer noch ein Rätsel.
An der EntryID scheint es nicht zu liegen, denn dann müsste es ja nie funktionieren.

Workaround könnte sein, dass nach _OL_Wrapper_SendMail auf den @error = 6002 geprüft wird. Falls zutreffend, mit _OL_ItemFind im Entwurfs-Ordner die Mail suchen und danach senden.

**water**

Welche Version der OutlookEX UDF verwendest Du? Ab Version 1.6.3.1 wird ein Fehler von Outlook abgefangen und mit einem (nicht übertrieben schönen) Workaround behoben:

Zitat

_OL_ItemSend:
The function handles the MAPI_E_INVALID_PARAMETER (HRESULT 0x80070057) error found in Outlook 365 Version 2009.

It creates and activates an Inspector for the item, minimizes the window and sends the item again to work around the error.

Described here and the following posts: https://www.autoitscript.com/forum/topic/12…comment=1466457