Control relativ positionieren

**BugFix**

Jeder kennt das:

Entwicklung eines Projektes, es kommen immer mehr Control hinzu und die Gui muss angepasst werden, was auch bedeutet, dass alle(viele) Controlpositionen angepasst werden müssen.

Das war mir jetzt zu blöd und deshalb habe ich diese kleine Funktion zum Positionieren der Control geschrieben. Somit kann die Änderung bei Controls deutlich minimiert werden.

AutoIt: _CtrlPosRelative( )

;-- TIME_STAMP   2020-10-29 12:22:58

#include <WinAPISysWin.au3>
#include <WinAPIDlg.au3>

Opt('MustDeclareVars', 1)


GUICreate('Test')
Local $bt1 = GUICtrlCreateButton('Test Button 1', 0, 0, 150, 25)
_CtrlPosRelative(-1, -10, -10)   ; 10px Rand rechts und unten
Local $bt2 = GUICtrlCreateButton('Test Button 2', 0, 0, 150, 25)
_CtrlPosRelative(-1, 10, -10)    ; x ist fix, y relativ mit 10px Rand unten

GUISetState()

; Größe der Gui ändern und Ctrl verschieben an relative Position
Sleep(5000)
WinMove('Test', '', 100, 50, 800, 600)
_CtrlPosRelative($bt1, -10, -10)
_CtrlPosRelative($bt2, 10, -10)


Do
Until GUIGetMsg() = -3


Func _CtrlPosRelative($_iID, $_x, $_y, $_w=-1, $_h=-1)
    Local $hCtrl = IsHWnd($_iID) ? $_iID : GUICtrlGetHandle($_iID)
    Local $hParent = _WinAPI_GetParent($hCtrl)
    Local $iID = _WinAPI_GetDlgCtrlID($hCtrl)
    Local $aSize = ControlGetPos($hParent, '', $iID)
    If $_w = -1 Or $_w = Default Then $_w = $aSize[2]
    If $_h = -1 Or $_h = Default Then $_h = $aSize[3]
    Local $clientW = _WinAPI_GetClientWidth($hParent)
    Local $clientH = _WinAPI_GetClientHeight($hParent)
    If $_x < 0 Then $_x = $clientW - $_w - Abs($_x)
    If $_y < 0 Then $_y = $clientH - $_h - Abs($_y)
    ControlMove($hParent, '', $iID, $_x, $_y, $_w, $_h)
EndFunc

Alles anzeigen

**Bitnugger**

Dafür hatte ich mir auch mal eine Funktion geschrieben... und habe dabei festgestellt, dass ControlMove und GUICtrlSetPos unterschiedliche Auswirkungen haben.

Bei ControlMove wird die Position der Controls wieder zurückgesetzt, wenn sich die Größe des Fensters verändert, bei GUICtrlSetPos bleibt sie erhalten.

ControlMove verwende ich deshalb nur bei fremden Controls... wenn ein Handle übergeben wurde, und GUICtrlSetPos bei eigenen Controls... wenn eine Ctrl-ID übergeben wurde.

Hier eine kleine Demo, die dies zeigt...

AutoIt

;-- TIME_STAMP   2020-10-29 18:53:45   v 0.1

#include <WinAPIDlg.au3>

_Test1()

Func _Test1()
    Local $hGUI = GUICreate('Test')
    Local $bt1 = GUICtrlCreateButton('Test Button 1', 0, 0, 150, 25)
    GUISetState()
    _ToolTip($hGUI, 'Position des Buttons nach Start...')
    Sleep(3000)

    Local $hParent = WinGetHandle('Test')
    Local $hCtrl = ControlGetHandle($hParent, 'Test Button 1', '')
    ControlMove($hCtrl, '', '', 50, 50)
    _ToolTip($hGUI, 'Position des Buttons nach ControlMove...')
    Sleep(3000)

    WinMove($hParent, '', Default, Default, 456, 429)
    _ToolTip($hGUI, 'Position des Buttons nach WinMove... Fenster schließen, um _Test2() zu starten.')

    Do
    Until GUIGetMsg() = -3
    GUIDelete($hGUI)
    _Test2()
EndFunc

Func _Test2()
    Local $hGUI = GUICreate('Test')
    Local $bt1 = GUICtrlCreateButton('Test Button 1', 0, 0, 150, 25)
    GUISetState()
    _ToolTip($hGUI, 'Position des Buttons nach Start...')
    Sleep(3000)

    Local $hParent = WinGetHandle('Test')
    Local $hCtrl = ControlGetHandle($hParent, 'Test Button 1', '')
    Local $iID = _WinAPI_GetDlgCtrlID($hCtrl)
    GUICtrlSetPos($iID, 50, 50)
    _ToolTip($hGUI, 'Position des Buttons nach GUICtrlSetPos...')
    Sleep(3000)

    WinMove($hParent, '', Default, Default, 456, 429)
    _ToolTip($hGUI, 'Position des Buttons nach WinMove... Position wird nicht zurückgesetzt! (Ende)')

    Do
    Until GUIGetMsg() = -3
EndFunc

Func _ToolTip($hWnd, $sTip)
    Local $aPos = WinGetPos($hWnd)
    ToolTip($sTip, $aPos[0], $aPos[1] - 30)
EndFunc

Alles anzeigen

Und hier deine angepasste Funktion...

AutoIt

;-- TIME_STAMP   2020-10-29 20:45:27

;~ #include <WinAPISysWin.au3> ; _WinAPI_GetParent

Opt('MustDeclareVars', 1)


GUICreate('Test')
Local $bt1 = GUICtrlCreateButton('Test Button 1', 0, 0, 150, 25)
_CtrlPosRelative(-1, -10, -10)   ; 10px Rand rechts und unten
Local $bt2 = GUICtrlCreateButton('Test Button 2', 0, 0, 150, 25)
_CtrlPosRelative(-1, 10, -10)    ; x ist fix, y relativ mit 10px Rand unten

GUISetState()

; Größe der Gui ändern und Ctrl verschieben an relative Position
Sleep(5000)
WinMove('Test', '', 100, 50, 800, 600)
_CtrlPosRelative($bt1, -10, -10)
_CtrlPosRelative($bt2, 10, -10)


Do
Until GUIGetMsg() = -3


Func _CtrlPosRelative($_iID, $_x, $_y, $_w = -1, $_h = -1)
    Local $hCtrl = IsHWnd($_iID) ? $_iID : GUICtrlGetHandle($_iID)
    Local $aSize = ControlGetPos($hCtrl, '', '')
    If $_w = -1 Or $_w = Default Then $_w = $aSize[2]
    If $_h = -1 Or $_h = Default Then $_h = $aSize[3]
    Local $aResult = DllCall("user32.dll", "hwnd", "GetParent", "hwnd", $hCtrl)
    If @error Then Return SetError(@error, @extended, 0)
    Local $aClientSize = WinGetClientSize($aResult[0])
    If $_x < 0 Then $_x = $aClientSize[0] - $_w - Abs($_x)
    If $_y < 0 Then $_y = $aClientSize[1] - $_h - Abs($_y)
    Return IsHWnd($_iID) ? ControlMove($hCtrl, '', '', $_x, $_y, $_w, $_h) : GUICtrlSetPos($_iID, $_x, $_y, $_w, $_h)
EndFunc   ;==>_CtrlPosRelative

Alles anzeigen

**BugFix**

Danke.