Controller auslesen

Gofel · 18. Januar 2021

Hallo,

ich versuche meinen Controller auzulesen, dafür gibt es ja reichlich Beispiele. Hier nur ein paar:

https://www.autoitscript.com/forum/topic/10953-joystick-udf/

https://www.autoitscript.com/f…36-xbox-controller-input/

Das Beispiel aus dem ersten Link (joystick-udf) läuft bei mir wunderbar (Post 4). Wenn ich mir den Code allerdings für meine Bedürfnisse umbaue geht nichts mehr. Ich benötige nämlich kein GUI. Wenn ich das aber weglasse funktioniert es nicht. Ist das nur bei mir so?

Zum testen bitte mal Zeile 1 und 2 ein bzw auskommentieren und mich erleuchten

Danke

Code

;GUICreate("",1,1,-1,-1)
;GUISetState()

Global $myGamePadHandle = GPExInitialize()

While 1
    Sleep(10)
    $testrawdata = GPExGetRawData($myGamePadHandle, 0) ; Get almost every data possible from the gamepad. Returns in an array with 8 elements.
    ;
    ; Display the RAW output.
    ; --->
    ; ---> Resize the console area so that you can have all the outputs and then move the gamepad. <---
    ; --->
    ConsoleWrite(@CRLF & "==========================================================")
    ConsoleWrite(@CRLF & "[0]" & $testrawdata[0]) ; X Axis
    ConsoleWrite(@CRLF & "[1]" & $testrawdata[1]) ; Y Axis
    ConsoleWrite(@CRLF & "[2]" & $testrawdata[2]) ; Z Axis
    ConsoleWrite(@CRLF & "[3]" & $testrawdata[3]) ; R Axis
    ConsoleWrite(@CRLF & "[4]" & $testrawdata[4]) ; U Axis
    ConsoleWrite(@CRLF & "[5]" & $testrawdata[5]) ; V Axis
    ConsoleWrite(@CRLF & "[6]" & $testrawdata[6]) ; Point of View
    ConsoleWrite(@CRLF & "[7]" & $testrawdata[7]) ; Buttons
    ConsoleWrite(@CRLF & "==========================================================")

WEnd


Func GPExInitialize()
    Local $joy
    Local $JOYINFOEX_struct = "dword[13]"
    $joy = DllStructCreate($JOYINFOEX_struct)
    If @error Then Return 0
    DllStructSetData($joy, 1, DllStructGetSize($joy), 1) ; dwSize  = sizeof(struct)
    DllStructSetData($joy, 1, 255, 2) ; dwFlags = GetAll
    Return $joy
EndFunc   ;==>GPExInitialize

Func GPExGetRawData($tempHandle, $tempID)
    Local $coor
    Dim $coor[8]
    DllCall("Winmm.dll", "int", "joyGetPosEx", _
            "int", $tempID, "ptr", DllStructGetPtr($tempHandle))
    If Not @error Then
        $coor[0] = DllStructGetData($tempHandle, 1, 3) ; X Axis
        $coor[1] = DllStructGetData($tempHandle, 1, 4) ; Y Axis
        $coor[2] = DllStructGetData($tempHandle, 1, 5) ; Z Axis
        $coor[3] = DllStructGetData($tempHandle, 1, 6) ; R Axis
        $coor[4] = DllStructGetData($tempHandle, 1, 7) ; U Axis
        $coor[5] = DllStructGetData($tempHandle, 1, 8) ; V Axis
        $coor[6] = DllStructGetData($tempHandle, 1, 11) ; POV Value
        $coor[7] = DllStructGetData($tempHandle, 1, 9) ; Buttons Mask
    EndIf
    Return $coor
EndFunc   ;==>GPExGetRawData

Alles anzeigen

**Bitnugger** · 18. Januar 2021

Teste mal dieses Script:

AutoIt

;-- TIME_STAMP   2021-01-18 20:04:48

;~ https://autoit.de/thread/87245-controller-auslesen/#wcf22

#include <Array.au3>
#include <WinAPIDiag.au3>

Opt('MustDeclareVars', 1)

;~ GUICreate("");,1,1,-1,-1)
;~ GUISetState()

;~ Global Const $tagJOYINFOEX = "dword[13]"
Global Const $tagJOYINFOEX = 'STRUCT; DWORD dwSize; DWORD dwFlags; DWORD dwXpos; DWORD dwYpos; DWORD dwZpos; DWORD dwRpos; DWORD dwUpos; DWORD dwVpos; DWORD dwButtons; DWORD dwButtonNumber; DWORD dwPOV; DWORD dwReserved1; DWORD dwReserved2; ENDSTRUCT;'

Global $myGamePadHandle = GPExInitialize(), $aTestRawData

While 1
    $aTestRawData = GPExGetRawData($myGamePadHandle, 0) ; Get almost every data possible from the gamepad. Returns in an array with 8 elements.
    ;
    ; Display the RAW output.
    ; --->
    ; ---> Resize the console area so that you can have all the outputs and then move the gamepad. <---
    ; --->
    ConsoleWrite(@CRLF & "==========================================================")
    ConsoleWrite(@CRLF & "[0]" & $aTestRawData[0]) ; X Axis
    ConsoleWrite(@CRLF & "[1]" & $aTestRawData[1]) ; Y Axis
    ConsoleWrite(@CRLF & "[2]" & $aTestRawData[2]) ; Z Axis
    ConsoleWrite(@CRLF & "[3]" & $aTestRawData[3]) ; R Axis
    ConsoleWrite(@CRLF & "[4]" & $aTestRawData[4]) ; U Axis
    ConsoleWrite(@CRLF & "[5]" & $aTestRawData[5]) ; V Axis
    ConsoleWrite(@CRLF & "[6]" & $aTestRawData[6]) ; Point of View
    ConsoleWrite(@CRLF & "[7]" & $aTestRawData[7]) ; Buttons
    ConsoleWrite(@CRLF & "==========================================================" & @CRLF & @CRLF)
    Sleep(3000)
WEnd

Func GPExInitialize()
    ; https://docs.microsoft.com/en-us/previous-versions/ms709358(v=vs.85)
    Local $tJOYINFOEX = DllStructCreate($tagJOYINFOEX)
    If @error Then
        ConsoleWrite('Error by DllStructCreate($tagJOYINFOEX) : ' & @LF & "!@ " & @TAB & "#Error: " & @error & @LF)
        Exit
    EndIf

    ; Mit Global Const $tagJOYINFOEX = "dword[13]"
    DllStructSetData($tJOYINFOEX, 1, DllStructGetSize($tJOYINFOEX), 1) ; dwSize  = sizeof(struct)
    DllStructSetData($tJOYINFOEX, 1, 255, 2) ; dwFlags = GetAll

    ; Mit Global Const $tagJOYINFOEX = 'STRUCT; ...
    DllStructSetData($tJOYINFOEX, 1, DllStructGetSize($tJOYINFOEX)) ; dwSize  = sizeof(struct)
    DllStructSetData($tJOYINFOEX, 2, 255) ; dwFlags = GetAll
    ; oder so...
;~     DllStructSetData($tJOYINFOEX, 'dwSize', DllStructGetSize($tJOYINFOEX)) ; dwSize  = sizeof(struct)
;~     DllStructSetData($tJOYINFOEX, 'dwFlags', 255) ; dwFlags = GetAll

    _WinAPI_DisplayStruct($tJOYINFOEX, $tagJOYINFOEX, 'GPExInitialize: $tJOYINFOEX')
    Return $tJOYINFOEX
EndFunc   ;==>GPExInitialize

Func GPExGetRawData($tempHandle, $tempID)
    Local Const _
            $MMSYSERR_NOERROR      =   0, _ ; successful
            $MMSYSERR_ERROR        =   1, _
            $MMSYSERR_BADDEVICEID  =   2, _ ; Windows 95/98/Me: The specified joystick identifier is invalid.
            $MMSYSERR_NOTENABLED   =   3, _
            $MMSYSERR_ALLOCATED    =   4, _
            $MMSYSERR_INVALHANDLE  =   5, _
            $MMSYSERR_NODRIVER     =   6, _ ; The joystick driver is not present.
            $MMSYSERR_NOMEM        =   7, _
            $MMSYSERR_NOTSUPPORTED =   8, _
            $MMSYSERR_BADERRNUM    =   9, _
            $MMSYSERR_INVALFLAG    =  10, _
            $MMSYSERR_INVALPARAM   =  11, _ ; An invalid parameter was passed. Windows 95/98/Me: The specified joystick identifier is invalid.
            $MMSYSERR_HANDLEBUSY   =  12, _
            $MMSYSERR_INVALIDALIAS =  13, _
            $MMSYSERR_BADDB        =  14, _
            $MMSYSERR_KEYNOTFOUND  =  15, _
            $MMSYSERR_READERROR    =  16, _
            $MMSYSERR_WRITEERROR   =  17, _
            $MMSYSERR_DELETEERROR  =  18, _
            $MMSYSERR_VALNOTFOUND  =  19, _
            $MMSYSERR_NODRIVERCB   =  20, _
            $WAVERR_BADFORMAT      =  32, _
            $WAVERR_STILLPLAYING   =  33, _
            $WAVERR_UNPREPARED     =  34, _
            $JOYERR_PARMS          = 165, _ ; Windows NT/2000/XP: The specified joystick identifier is invalid.
            $JOYERR_UNPLUGGED      = 167    ; The specified joystick is not connected to the system.

    Local $aJoy[8]

    ; https://docs.microsoft.com/en-us/previous-versions/ms709354(v=vs.85)
    Local $aRet = DllCall("Winmm.dll", "INT", "joyGetPosEx", _
            "UINT", $tempID, "LONG_PTR", DllStructGetPtr($tempHandle))
    If Not @error And $aRet[0] = $MMSYSERR_NOERROR Then
        ConsoleWrite("@@_Debug_line" & @TAB & @TAB & @ScriptLineNumber & "   var: $aRet --> " & _ArrayToString($aRet, ', ') & @LF)
        ; Mit Global Const $tagJOYINFOEX = "dword[13]"
;~         $aJoy[0] = DllStructGetData($tempHandle, 1, 3) ; X Axis
;~         $aJoy[1] = DllStructGetData($tempHandle, 1, 4) ; Y Axis
;~         $aJoy[2] = DllStructGetData($tempHandle, 1, 5) ; Z Axis
;~         $aJoy[3] = DllStructGetData($tempHandle, 1, 6) ; R Axis
;~         $aJoy[4] = DllStructGetData($tempHandle, 1, 7) ; U Axis
;~         $aJoy[5] = DllStructGetData($tempHandle, 1, 8) ; V Axis
;~         $aJoy[6] = DllStructGetData($tempHandle, 1, 11) ; POV Value
;~         $aJoy[7] = DllStructGetData($tempHandle, 1, 9) ; Buttons Mask

        ; Mit Global Const $tagJOYINFOEX = 'STRUCT; ...
        $aJoy[0] = DllStructGetData($tempHandle, 3) ; X Axis
        $aJoy[1] = DllStructGetData($tempHandle, 4) ; Y Axis
        $aJoy[2] = DllStructGetData($tempHandle, 5) ; Z Axis
        $aJoy[3] = DllStructGetData($tempHandle, 6) ; R Axis
        $aJoy[4] = DllStructGetData($tempHandle, 7) ; U Axis
        $aJoy[5] = DllStructGetData($tempHandle, 8) ; V Axis
        $aJoy[6] = DllStructGetData($tempHandle, 11) ; POV Value
        $aJoy[7] = DllStructGetData($tempHandle, 9) ; Buttons Mask
    Else
        Local $sErr, $iError = @error, $iExtended = @extended
        Switch $aRet[0]
            Case $MMSYSERR_BADDEVICEID
                $sErr = '$MMSYSERR_BADDEVICEID (2)'
            Case $MMSYSERR_NODRIVER
                $sErr = '$MMSYSERR_NODRIVER (6)'
            Case $MMSYSERR_INVALPARAM
                $sErr = '$MMSYSERR_INVALPARAM (11)'
            Case $JOYERR_PARMS
                $sErr = '$JOYERR_PARMS (165)'
            Case $JOYERR_UNPLUGGED
                $sErr = '$JOYERR_UNPLUGGED (167)'
            Case Else
                $sErr = 'Case Else'
        EndSwitch
;~         DllStructGetPtr($tempHandle)
        ConsoleWrite("@@_Debug_line" & @TAB & @TAB & @ScriptLineNumber & "   var: $aRet --> " & _ArrayToString($aRet, ', ') & @LF & _
                "!@ " & @TAB & "$sErr: " & $sErr & @TAB & "#Error: " & $iError & @TAB & "#Extended: " & $iExtended & @LF)
        Exit
    EndIf

    _WinAPI_DisplayStruct($tempHandle, $tagJOYINFOEX, 'GPExGetRawData: $tempHandle')
    Return $aJoy
EndFunc   ;==>GPExGetRawData

Alles anzeigen

Gofel · 18. Januar 2021

Da passiert jetzt mit und ohne GUI gar nichts

Code

==========================================================
[0]0
[1]0
[2]0
[3]0
[4]0
[5]0
[6]0
[7]0
==========================================================

**Bitnugger** · 18. Januar 2021

Zitat von Gofel

Da passiert jetzt mit und ohne GUI gar nichts

Ich hatte noch ein paar Fehler in dem Script, die ich nun korrigiert habe... teste noch mal... passiert nichts... du bekommst nur das als Ausgabe, was du hier gepostet hast?

PS: Sleep(3000) hast du gesehen?

Gofel · 18. Januar 2021

Danke das du dich reinfuchst!

Sleep hatte ich gesehen, aber hier kommt in der:

Code

$aTestRawData

wieder nichts an.

**Bitnugger** · 18. Januar 2021

Ich Idiot!!!

$aJoy[0] = DllStructGetData($tempHandle, 1, 3) ; X Axis

...

Das kann so nicht gehen... weil die Struct ist ja kein Array mehr, deshalb muss die 1 bei DllStructGetData weg!

$aJoy[0] = DllStructGetData($tempHandle, 3) ; X Axis

...

Habe die Stellen nun auch korrigiert, jetzt sollte es aber funktionieren!

Gofel · 18. Januar 2021

Wir nähern uns der Sache

Aber leider bleiben die Werte unverändert, egal was ich mit dem Gampad auch anstelle.

Code

@@_Debug_line		96   var: $aRet --> 0, 0, 64485024


==========================================================
[0]32767
[1]32767
[2]32767
[3]32767
[4]32767
[5]0
[6]65535
[7]0
==========================================================


@@_Debug_line		96   var: $aRet --> 0, 0, 64485024


==========================================================
[0]32767
[1]32767
[2]32767
[3]32767
[4]32767
[5]0
[6]65535
[7]0
==========================================================

Alles anzeigen

**Bitnugger** · 18. Januar 2021

Kannst du mir mal eine Ausgabe deines Scripts aus Post #1 (mit GUI) geben, in der ich etwa 3-5 Durchläufe mit verschiedenen Ergebniswerten sehe...

Gofel · 18. Januar 2021

Klar, mit GUI verändert sich jeder Wert:

Code

==========================================================
[0]32767
[1]32767
[2]32767
[3]32767
[4]32767
[5]0
[6]65535
[7]0
==========================================================
==========================================================
[0]32533
[1]32477
[2]32767
[3]32599
[4]31713
[5]0
[6]65535
[7]0
==========================================================
==========================================================
[0]65535
[1]48931
[2]32767
[3]15368
[4]64870
[5]0
[6]65535
[7]8
==========================================================
==========================================================
[0]49571
[1]0
[2]65408
[3]4576
[4]57500
[5]0
[6]65535
[7]29
==========================================================
==========================================================
[0]22897
[1]65535
[2]65408
[3]65535
[4]24024
[5]0
[6]65535
[7]31
==========================================================

Alles anzeigen

**Bitnugger** · 18. Januar 2021

Hast du den letzten Test mit meinem Script ohne und mit GUI gemacht?

Zitat von Gofel

Wenn ich mir den Code allerdings für meine Bedürfnisse umbaue geht nichts mehr.

geht nichts mehr... was heißt das konkret?

Gofel · 18. Januar 2021

Zitat von Bitnugger

Hast du den letzten Test mit meinem Script ohne und mit GUI gemacht?

Mit GUI läuft dein Script jetzt auch, hatte ich ganz vergessen zu testen...

Zitat von Bitnugger

geht nichts mehr... was heißt das konkret?

Naja, in der Ausgabevariablen stehen immer Nullen wenn ich keine GUI dabei habe (siehe Post 3). Sobald ich eine GUI verwende werden alle Controller Werte korrekt ausgeben (siehe Post 9).

Und das in den Orginalscripts von 2005, in meinen Versuch die GUI loszuwerden (Post 1) und in deiner Variante.

Funktioniert es den bei dir ohne GUI?

**Bitnugger** · 18. Januar 2021

Zitat von Gofel

Funktioniert es den bei dir ohne GUI?

Ich habe momentan kein GamePad angeschlossen und bekomme deshalb den Error $JOYERR_PARMS... werde morgen versuchen das von meiner PS4 anzuschließen... melde mich dann wieder.

$JOYERR_PARMS = 165 ; Windows NT/2000/XP: The specified joystick identifier is invalid.

**Bitnugger** · 18. Januar 2021

Habe das PS4-GamePad vorhin dann doch noch angeschlossen... und bei mir funktioniert es mit und ohne GUI!

PS4-GamePad Testdaten - ohne GUI!

Hier noch mal zur Sicherheit, die Version ohne GUI, mit der ich erfolgreich getestet habe.

AutoIt

;-- TIME_STAMP   2021-01-18 22:43:57

;~ https://autoit.de/thread/87245-controller-auslesen/#wcf22

#include <Array.au3>
#include <WinAPIDiag.au3>

Opt('MustDeclareVars', 1)

;~ GUICreate("");,1,1,-1,-1)
;~ GUISetState()
HotKeySet('{ESC}', '_Exit')

Global Const $tagJOYINFOEX_OLD = "dword[13]"
Global Const $tagJOYINFOEX = 'STRUCT; DWORD dwSize; DWORD dwFlags; DWORD dwXpos; DWORD dwYpos; DWORD dwZpos; DWORD dwRpos; DWORD dwUpos; DWORD dwVpos; DWORD dwButtons; DWORD dwButtonNumber; DWORD dwPOV; DWORD dwReserved1; DWORD dwReserved2; ENDSTRUCT;'

Global $myGamePadHandle = GPExInitialize(), $aTestRawData

While 1
;~ While GUIGetMsg() <> -3
    $aTestRawData = GPExGetRawData($myGamePadHandle, 0) ; Get almost every data possible from the gamepad. Returns in an array with 8 elements.
    ;
    ; Display the RAW output.
    ; --->
    ; ---> Resize the console area so that you can have all the outputs and then move the gamepad. <---
    ; --->
    ConsoleWrite(@CRLF & "==========================================================")
    ConsoleWrite(@CRLF & "[0]" & $aTestRawData[0]) ; X Axis
    ConsoleWrite(@CRLF & "[1]" & $aTestRawData[1]) ; Y Axis
    ConsoleWrite(@CRLF & "[2]" & $aTestRawData[2]) ; Z Axis
    ConsoleWrite(@CRLF & "[3]" & $aTestRawData[3]) ; R Axis
    ConsoleWrite(@CRLF & "[4]" & $aTestRawData[4]) ; U Axis
    ConsoleWrite(@CRLF & "[5]" & $aTestRawData[5]) ; V Axis
    ConsoleWrite(@CRLF & "[6]" & $aTestRawData[6]) ; Point of View
    ConsoleWrite(@CRLF & "[7]" & $aTestRawData[7]) ; Buttons
    ConsoleWrite(@CRLF & "==========================================================" & @CRLF & @CRLF)
    Sleep(1000)
WEnd

Func GPExInitialize()
    ; https://docs.microsoft.com/en-us/previous-versions/ms709358(v=vs.85)
;~     Local $tJOYINFOEX_OLD = DllStructCreate($tagJOYINFOEX_OLD)
    Local $tJOYINFOEX = DllStructCreate($tagJOYINFOEX)
    If @error Then
        ConsoleWrite('Error by DllStructCreate($tagJOYINFOEX) : ' & @LF & "!@ " & @TAB & "#Error: " & @error & @LF)
        Exit
    EndIf

    ; Mit Global Const $tagJOYINFOEX_OLD = "dword[13]"
;~     DllStructSetData($tJOYINFOEX_OLD, 1, DllStructGetSize($tJOYINFOEX), 1) ; dwSize  = sizeof(struct)
;~     DllStructSetData($tJOYINFOEX_OLD, 1, 255, 2) ; dwFlags = GetAll
;~     _WinAPI_DisplayStruct($tJOYINFOEX_OLD, $tagJOYINFOEX_OLD, 'GPExInitialize: $tJOYINFOEX_OLD dword[13]')

    ; Mit Global Const $tagJOYINFOEX = 'STRUCT; ...
    DllStructSetData($tJOYINFOEX, 1, DllStructGetSize($tJOYINFOEX)) ; dwSize  = sizeof(struct)
    DllStructSetData($tJOYINFOEX, 2, 255) ; dwFlags = GetAll
    ; oder so...
;~     DllStructSetData($tJOYINFOEX, 'dwSize', DllStructGetSize($tJOYINFOEX)) ; dwSize  = sizeof(struct)
;~     DllStructSetData($tJOYINFOEX, 'dwFlags', 255) ; dwFlags = GetAll

;~     _WinAPI_DisplayStruct($tJOYINFOEX, $tagJOYINFOEX, 'GPExInitialize: $tJOYINFOEX STRUCT; ...')
    Return $tJOYINFOEX
EndFunc   ;==>GPExInitialize

Func GPExGetRawData($tempHandle, $tempID)
    Local Const _
            $MMSYSERR_NOERROR      =   0, _ ; successful
            $MMSYSERR_ERROR        =   1, _
            $MMSYSERR_BADDEVICEID  =   2, _ ; Windows 95/98/Me: The specified joystick identifier is invalid.
            $MMSYSERR_NOTENABLED   =   3, _
            $MMSYSERR_ALLOCATED    =   4, _
            $MMSYSERR_INVALHANDLE  =   5, _
            $MMSYSERR_NODRIVER     =   6, _ ; The joystick driver is not present.
            $MMSYSERR_NOMEM        =   7, _
            $MMSYSERR_NOTSUPPORTED =   8, _
            $MMSYSERR_BADERRNUM    =   9, _
            $MMSYSERR_INVALFLAG    =  10, _
            $MMSYSERR_INVALPARAM   =  11, _ ; An invalid parameter was passed. Windows 95/98/Me: The specified joystick identifier is invalid.
            $MMSYSERR_HANDLEBUSY   =  12, _
            $MMSYSERR_INVALIDALIAS =  13, _
            $MMSYSERR_BADDB        =  14, _
            $MMSYSERR_KEYNOTFOUND  =  15, _
            $MMSYSERR_READERROR    =  16, _
            $MMSYSERR_WRITEERROR   =  17, _
            $MMSYSERR_DELETEERROR  =  18, _
            $MMSYSERR_VALNOTFOUND  =  19, _
            $MMSYSERR_NODRIVERCB   =  20, _
            $WAVERR_BADFORMAT      =  32, _
            $WAVERR_STILLPLAYING   =  33, _
            $WAVERR_UNPREPARED     =  34, _
            $JOYERR_PARMS          = 165, _ ; Windows NT/2000/XP: The specified joystick identifier is invalid.
            $JOYERR_UNPLUGGED      = 167    ; The specified joystick is not connected to the system.

    Local $aJoy[8]

    ; https://docs.microsoft.com/en-us/previous-versions/ms709354(v=vs.85)
    Local $aRet = DllCall("Winmm.dll", "INT", "joyGetPosEx", _
            "UINT", $tempID, "LONG_PTR", DllStructGetPtr($tempHandle))
    If Not @error And $aRet[0] = $MMSYSERR_NOERROR Then
;~         ConsoleWrite("@@_Debug_line" & @TAB & @TAB & @ScriptLineNumber & "   var: $aRet --> " & _ArrayToString($aRet, ', ') & @LF)
        ; Mit Global Const $tagJOYINFOEX = "dword[13]"
;~         $aJoy[0] = DllStructGetData($tempHandle, 1, 3) ; X Axis
;~         $aJoy[1] = DllStructGetData($tempHandle, 1, 4) ; Y Axis
;~         $aJoy[2] = DllStructGetData($tempHandle, 1, 5) ; Z Axis
;~         $aJoy[3] = DllStructGetData($tempHandle, 1, 6) ; R Axis
;~         $aJoy[4] = DllStructGetData($tempHandle, 1, 7) ; U Axis
;~         $aJoy[5] = DllStructGetData($tempHandle, 1, 8) ; V Axis
;~         $aJoy[6] = DllStructGetData($tempHandle, 1, 11) ; POV Value
;~         $aJoy[7] = DllStructGetData($tempHandle, 1, 9) ; Buttons Mask

        ; Mit Global Const $tagJOYINFOEX = 'STRUCT; ...
        ; DWORD dwSize; DWORD dwFlags; DWORD dwXpos; DWORD dwYpos; DWORD dwZpos; DWORD dwRpos; DWORD dwUpos; DWORD dwVpos; DWORD dwButtons; DWORD dwButtonNumber; DWORD dwPOV; DWORD dwReserved1; DWORD dwReserved2;'
        $aJoy[0] = DllStructGetData($tempHandle, 3)  ; X Axis, dwXpos
        $aJoy[1] = DllStructGetData($tempHandle, 4)  ; Y Axis, dwYpos
        $aJoy[2] = DllStructGetData($tempHandle, 5)  ; Z Axis, dwZpos
        $aJoy[3] = DllStructGetData($tempHandle, 6)  ; R Axis, dwRpos
        $aJoy[4] = DllStructGetData($tempHandle, 7)  ; U Axis, dwUpos
        $aJoy[5] = DllStructGetData($tempHandle, 8)  ; V Axis, dwVpos
        $aJoy[6] = DllStructGetData($tempHandle, 11) ; POV Value, dwPOV
        $aJoy[7] = DllStructGetData($tempHandle, 9)  ; Buttons Mask, dwButtons
    Else
        Local $sErr, $iError = @error, $iExtended = @extended
        Switch $aRet[0]
            Case $MMSYSERR_BADDEVICEID
                $sErr = '$MMSYSERR_BADDEVICEID (2)'
            Case $MMSYSERR_NODRIVER
                $sErr = '$MMSYSERR_NODRIVER (6)'
            Case $MMSYSERR_INVALPARAM
                $sErr = '$MMSYSERR_INVALPARAM (11)'
            Case $JOYERR_PARMS
                $sErr = '$JOYERR_PARMS (165)'
            Case $JOYERR_UNPLUGGED
                $sErr = '$JOYERR_UNPLUGGED (167)'
            Case Else
                $sErr = 'Case Else'
        EndSwitch
;~         DllStructGetPtr($tempHandle)
        ConsoleWrite("@@_Debug_line" & @TAB & @TAB & @ScriptLineNumber & "   var: $aRet --> " & _ArrayToString($aRet, ', ') & @LF & _
                "!@ " & @TAB & "$sErr: " & $sErr & @TAB & "#Error: " & $iError & @TAB & "#Extended: " & $iExtended & @LF)
        Exit
    EndIf

;~     _WinAPI_DisplayStruct($tempHandle, $tagJOYINFOEX, 'GPExGetRawData: $tempHandle')
    Return $aJoy
EndFunc   ;==>GPExGetRawData

Func _Exit()
    Exit
EndFunc

Alles anzeigen

Gofel · 19. Januar 2021

Sehr merkwürdig. Mein XBox Controller braucht weiterhin eine GUI um ausgelesen werden zu können. Trotzdem danke für deine Hilfe.

Ich werde da wohl erstmal mit leben müssen.

Edit: Oh wow, Xbox ist das Stichwort. Der 8Bitdo Controller funktioniert sofort^^

Nicht das es die Sache mit der GUI erklärt, aber das ist ja jetzt mal ein ganz anderer Ansatz.

Edit 2: Um die Sache rund zu machen: https://www.autoitscript.com/f…-for-xbox-360-controller/

Funktioniert auch bei xbox Controllern völlig ohne GUI. Ich brech ab hier

**Bitnugger** · 19. Januar 2021

Zitat von Gofel

Ich werde da wohl erstmal mit leben müssen.

Nun ja, das ist aber nicht wirklich ein Problem... wenn du die GUI nicht brauchst, dann minimiere sie doch einfach beim Start...

Hier noch eine letzte Version mit minimierter GUI, in der ich auch alle nicht mehr benötigten Zeilen entfernt habe.

AutoIt

;-- TIME_STAMP   2021-01-19 16:21:58

;~ https://autoit.de/thread/87245-controller-auslesen/#wcf22

#NoTrayIcon

#include <Array.au3> ; _ArrayToString
#include <WinAPIDiag.au3> ; _WinAPI_DisplayStruct

Opt('MustDeclareVars', 1)

GUICreate("") ;,1,1,-1,-1)
GUISetState(@SW_SHOWMINIMIZED)

;~ If Not HotKeySet('{ESC}', '_Exit') Then Exit 1

Global Const $tagJOYINFOEX = 'STRUCT; DWORD dwSize; DWORD dwFlags; DWORD dwXpos; DWORD dwYpos; DWORD dwZpos; DWORD dwRpos; DWORD dwUpos; DWORD dwVpos; DWORD dwButtons; DWORD dwButtonNumber; DWORD dwPOV; DWORD dwReserved1; DWORD dwReserved2; ENDSTRUCT;'

Global $g_tJOYINFOEX = _GPExInitialize(), $g_aJoyRawData

AdlibRegister('_Adlib_GPExGetRawData', 1000) ; 1000 = 1x pro Sekunde

Do
Until GUIGetMsg() = -3

Func _Adlib_GPExGetRawData()
    Local Static $aOldJoyRawData, $sColor = '>'
    $g_aJoyRawData = _GPExGetRawData($g_tJOYINFOEX, 0) ; Get almost every data possible from the gamepad. Returns in an array with 8 elements.
    ;
    ; Display the RAW output.
    ;
    ; ---> Resize the console area so that you can have all the outputs and then move the gamepad. <---
    ;
    If _ArrayToString($g_aJoyRawData, '') <> _ArrayToString($aOldJoyRawData, '') Then
        $aOldJoyRawData = $g_aJoyRawData
        ConsoleWrite(@CRLF & $sColor& " ==========================================================")
        ConsoleWrite(@CRLF & $sColor& " [0] " & $g_aJoyRawData[0]) & ' X Axis'
        ConsoleWrite(@CRLF & $sColor& " [1] " & $g_aJoyRawData[1]) & ' Y Axis'
        ConsoleWrite(@CRLF & $sColor& " [2] " & $g_aJoyRawData[2]) & ' Z Axis'
        ConsoleWrite(@CRLF & $sColor& " [3] " & $g_aJoyRawData[3]) & ' R Axis'
        ConsoleWrite(@CRLF & $sColor& " [4] " & $g_aJoyRawData[4]) & ' U Axis'
        ConsoleWrite(@CRLF & $sColor& " [5] " & $g_aJoyRawData[5]) & ' V Axis'
        ConsoleWrite(@CRLF & $sColor& " [6] " & $g_aJoyRawData[6]) & ' Point of View'
        ConsoleWrite(@CRLF & $sColor& " [7] " & $g_aJoyRawData[7]) & ' Buttons'
        ConsoleWrite(@CRLF & $sColor& " ==========================================================" & @CRLF)
        $sColor = $sColor = '>' ? '-' : '>'
    EndIf
EndFunc   ;==>_Adlib_GPExGetRawData

Func _GPExInitialize()
    ; https://docs.microsoft.com/en-us/previous-versions/ms709358(v=vs.85)
    Local $tJOYINFOEX = DllStructCreate($tagJOYINFOEX)
    If @error Then
        ConsoleWrite('Error by DllStructCreate($tagJOYINFOEX) : ' & @LF & "!@ " & @TAB & "#Error: " & @error & @LF)
        Exit
    EndIf

    DllStructSetData($tJOYINFOEX, 'dwSize', DllStructGetSize($tJOYINFOEX)) ; sizeof(struct)
    DllStructSetData($tJOYINFOEX, 'dwFlags', 255) ; GetAll

;~     _WinAPI_DisplayStruct($tJOYINFOEX, $tagJOYINFOEX, 'GPExInitialize: $tJOYINFOEX STRUCT; ...')
    Return $tJOYINFOEX
EndFunc   ;==>_GPExInitialize

Func _GPExGetRawData($tJOYINFOEX, $iJoyID)
    #Tidy_Off
    Local Const _
            $MMSYSERR_NOERROR      =   0, _ ; successful
            $MMSYSERR_ERROR        =   1, _
            $MMSYSERR_BADDEVICEID  =   2, _ ; Windows 95/98/Me: The specified joystick identifier is invalid.
            $MMSYSERR_NOTENABLED   =   3, _
            $MMSYSERR_ALLOCATED    =   4, _
            $MMSYSERR_INVALHANDLE  =   5, _
            $MMSYSERR_NODRIVER     =   6, _ ; The joystick driver is not present.
            $MMSYSERR_NOMEM        =   7, _
            $MMSYSERR_NOTSUPPORTED =   8, _
            $MMSYSERR_BADERRNUM    =   9, _
            $MMSYSERR_INVALFLAG    =  10, _
            $MMSYSERR_INVALPARAM   =  11, _ ; An invalid parameter was passed. Windows 95/98/Me: The specified joystick identifier is invalid.
            $MMSYSERR_HANDLEBUSY   =  12, _
            $MMSYSERR_INVALIDALIAS =  13, _
            $MMSYSERR_BADDB        =  14, _
            $MMSYSERR_KEYNOTFOUND  =  15, _
            $MMSYSERR_READERROR    =  16, _
            $MMSYSERR_WRITEERROR   =  17, _
            $MMSYSERR_DELETEERROR  =  18, _
            $MMSYSERR_VALNOTFOUND  =  19, _
            $MMSYSERR_NODRIVERCB   =  20, _
            $WAVERR_BADFORMAT      =  32, _
            $WAVERR_STILLPLAYING   =  33, _
            $WAVERR_UNPREPARED     =  34, _
            $JOYERR_PARMS          = 165, _ ; Windows NT/2000/XP: The specified joystick identifier is invalid.
            $JOYERR_UNPLUGGED      = 167    ; The specified joystick is not connected to the system.
    #Tidy_On

    ; https://docs.microsoft.com/en-us/previous-versions/ms709354(v=vs.85)
    Local $aJoy[8], $aRet = DllCall("Winmm.dll", "INT", "joyGetPosEx", _
            "UINT", $iJoyID, "LONG_PTR", DllStructGetPtr($tJOYINFOEX))
    If Not @error And $aRet[0] = $MMSYSERR_NOERROR Then
        ; 1       2        3       4       5       6       7       8       9          10              11     12           13
        ; dwSize; dwFlags; dwXpos; dwYpos; dwZpos; dwRpos; dwUpos; dwVpos; dwButtons; dwButtonNumber; dwPOV; dwReserved1; dwReserved2;'
        #Tidy_Off
        $aJoy[0] = DllStructGetData($tJOYINFOEX, 'dwXpos')    ;  3 X Axis
        $aJoy[1] = DllStructGetData($tJOYINFOEX, 'dwYpos')    ;  4 Y Axis
        $aJoy[2] = DllStructGetData($tJOYINFOEX, 'dwZpos')    ;  5 Z Axis
        $aJoy[3] = DllStructGetData($tJOYINFOEX, 'dwRpos')    ;  6 R Axis
        $aJoy[4] = DllStructGetData($tJOYINFOEX, 'dwUpos')    ;  7 U Axis
        $aJoy[5] = DllStructGetData($tJOYINFOEX, 'dwVpos')    ;  8 V Axis
        $aJoy[6] = DllStructGetData($tJOYINFOEX, 'dwPOV')     ; 11 POV Value
        $aJoy[7] = DllStructGetData($tJOYINFOEX, 'dwButtons') ;  9 Buttons Mask
        #Tidy_On
    Else
        Local $sErr, $iError = @error, $iExtended = @extended
        Switch $aRet[0]
            Case $MMSYSERR_BADDEVICEID
                $sErr = '$MMSYSERR_BADDEVICEID (2)'
            Case $MMSYSERR_NODRIVER
                $sErr = '$MMSYSERR_NODRIVER (6)'
            Case $MMSYSERR_INVALPARAM
                $sErr = '$MMSYSERR_INVALPARAM (11)'
            Case $JOYERR_PARMS
                $sErr = '$JOYERR_PARMS (165)'
            Case $JOYERR_UNPLUGGED
                $sErr = '$JOYERR_UNPLUGGED (167)'
            Case Else
                $sErr = 'Case Else (other error)'
        EndSwitch

        ConsoleWrite("@@_Debug_line" & @TAB & @TAB & @ScriptLineNumber & "   var: $aRet --> " & _ArrayToString($aRet, ', ') & @LF & _
                "!@ " & @TAB & "$sErr: " & $sErr & @TAB & "#Error: " & $iError & @TAB & "#Extended: " & $iExtended & @LF)
        Exit
    EndIf

;~     _WinAPI_DisplayStruct($tempHandle, $tagJOYINFOEX, 'GPExGetRawData: $tempHandle')
    Return $aJoy
EndFunc   ;==>_GPExGetRawData

Func _Exit()
    Exit
EndFunc   ;==>_Exit

Alles anzeigen

Im Anhang noch XInput inkl. Demo aus deinem 2. Link, etwas aufgepeppt und von Fehlern bereinigt.

Gofel · 19. Januar 2021

Nochmals danke für deine Mühe!

Controller auslesen

Teilen

Ähnliche Themen

Daten sichern und redundant speichern --- Vorschläge?