Kontextmenü auslesen

Hallo zusammen!

Ist es möglich mit AutoIt das Kontextmenü eines fremden Programms auszulesen? Da dieses Programm einen kleinen Bug hat, den man nicht beheben kann, ist es nicht sicher, ob immer alle Einträge vorhanden sind, oder nicht. Ich würde gerne den Handle in einem Array abspeichern für alle Einträge, bei denen das Kontextmenü nicht vollständig war um später darauf zurück zu kehren.

Zur Erläuterung des Bugs: Ich lade einen Datensatz und es erscheint der Titel in einem TreeView-Fenster. Auf dem Titel in dem FEnster kann ich das Kontextmenü öffnen. Bei manchen Datensätzen ist das Kontextmenü unvollständig. Wenn ich allerdings einen anderen Datensatz lade, bei dem das Kontextmenü vollständig ist und kehre dann zu dem ersten Datensatz zurück, dann ist dort das Kontextmenü auch vollständig. Ich habe leider keinen Plan, warum das so ist und wie man das ändern kann. Ich muss halt damit leben -.- (ist ein Fremdprogramm)

Zitat von Bitnugger

Schau mal, ob dir das hier weiterhilft:

Das Ermitteln des Handles für $hWnd, $hMain, $hDatei und die Keys bei ControlSend musst du natürlich entsprechend anpassen!

AutoIt

;-- TIME_STAMP   2021-11-10 21:53:36   v 0.1

#include <AutoItConstants.au3>
#include <GuiMenu.au3>

Opt('SendKeyDelay', 10) ; Mit ControlSend kommt der Text oft fehlerhaft an, wenn KeyDelay auf 5 (Default) steht! Bei mir funktioniert es mit 10 sehr gut.
;~ Opt('SendKeyDownDelay', 20)
Example_GUICtrlMenu_GetMenu()
Opt('SendKeyDelay', 5)
;~ Opt('SendKeyDownDelay', 5)

Func Example_GUICtrlMenu_GetMenu()
    Local $hWnd, $hMain, $hDatei

    ; Open Notepad
    Local $iPID = Run("notepad.exe")
    WinWaitActive("[CLASS:Notepad]")
    $hWnd = WinGetHandle("[CLASS:Notepad]")
    $hMain = _GUICtrlMenu_GetMenu($hWnd)

    Local $hDatei = _GUICtrlMenu_GetItemSubMenu($hMain, 0) ; Handle für das Menu "Datei"
    Writeln("@@_Debug_line" & @TAB & @TAB & @ScriptLineNumber & "   var: $hDatei      --> " & $hDatei & @LF)
    Local $sItemText, $aSplit, $iItemCount = _GUICtrlMenu_GetItemCount($hDatei)
    For $iItem = 0 To $iItemCount - 1 Step 1
        $sItemText = _GUICtrlMenu_GetItemText($hDatei, $iItem)
        If $sItemText = '' Then $sItemText = '--------------------------------' ; Separator line
        $aSplit = StringSplit($sItemText & @TAB, @TAB, $STR_NOCOUNT)
        Writeln(StringFormat('> $sItemText #%02i: %-32s %s\n', $iItem, $aSplit[0], $aSplit[1]))
    Next
    Writeln(@CRLF)

    ; - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
    ; Namen der SubMenues, deren AcceleratorKeys und den dazu passenden ControlSend ausgeben.
    Local $sMenuText, $iMenuCount = _GUICtrlMenu_GetItemCount($hMain), $iKeyPos, $sAccelatorKey, $sSend
    Writeln("@@_Debug_line" & @TAB & @TAB & @ScriptLineNumber & "   var: $iMenuCount --> " & $iMenuCount & @LF)
    For $iMenu = 0 To $iMenuCount - 1 Step 1 ; Datei | Bearbeiten | Format | Ansicht | Hilfe
        $sMenuText = _GUICtrlMenu_GetItemText($hMain, $iMenu)
        $iKeyPos = StringInStr(StringReplace($sMenuText, '&&', '##'), '&') + 1
        $sAccelatorKey = $iKeyPos ? StringMid($sMenuText, $iKeyPos, 1) : '' ; Das ist das Zeichen hinter dem "&" - falls vorhanden!
        $sSend = $sAccelatorKey ? "ControlSend($hWnd, '', '', '" & '!' & $sAccelatorKey & "', $SEND_DEFAULT)" : ''
        Writeln(StringFormat('> $sMenuText #%02i: %-32s Alt+%-32s %s\n', $iMenu, $sMenuText, $sAccelatorKey, $sSend))
    Next
    Writeln(@CRLF)

    ; Get/Set File menu help context ID
    Writeln("> File (Datei) help context ID: " & _GUICtrlMenu_GetMenuContextHelpID($hDatei) & '\n')
    _GUICtrlMenu_SetMenuContextHelpID($hDatei, 1234)
    Writeln("> File (Datei) help context ID: " & _GUICtrlMenu_GetMenuContextHelpID($hDatei) & '\n')

    ; Möchten Sie die Änderungen an Unbekannt speichern?
    ; Wenn kein HotKey vorhanden ist.
;~     ControlSend($hWnd, "", "", StringFormat('!du{Enter}'), $SEND_DEFAULT) ; Send AcceleratorKey (Alt+du{Enter}) "Dateimenu öffnen"
    ; Wenn ein HotKey vorhanden ist.
    ControlSend($hWnd, "", "", StringFormat('^+s{Enter}'), $SEND_DEFAULT) ; Send HotKey (Strg+Shift+s{Enter}) "Dateimenu öffnen"

    MsgBox(64 + 262144, @ScriptName, 'Press Ok for Exit')
    ProcessClose($iPID)
EndFunc   ;==>Example_GUICtrlMenu_GetMenu

; Write a line of text to Notepad
Func Writeln($sText)
    ControlSend("[CLASS:Notepad]", "", "Edit1", StringFormat($sText), $SEND_RAW)
EndFunc   ;==>Writeln

Alles anzeigen

OK, danke, aber das ist leider nicht das, was ich wollte.

Ich möchte das Kontextmenü auslesen, also das, was erscheint, wenn man die rechte Maustaste bzw. die Kontextmenütaste drückt, auslesen.

Im Fall von Editor wäre das bei einem leeren Dokument:

01: Rückgängig (inaktiv)

02: ------------------------------

03: Ausschneiden (inaktiv)

04: Kopieren (inaktiv)

05: Einfügen (aktiv wenn etwas in der Zwischenablage ist)

06: Löschen (inaktiv)

07: ------------------------------

08: Alle Auswählen (inaktiv)

09: ------------------------------

10: Rechts-nach-Links-Lesefolge

11: ...

Und falls es noch Unterpunkte gibt, dann die natürlich auch.

Kann man das?

Zitat von Bitnugger

AutoIt: _GUICtrlMenu_GetContextMenu_Example.au3

;-- TIME_STAMP   2021-11-13 22:20:09   

;~ #include <AutoItConstants.au3>
#include <WindowsConstants.au3>
;~ #include <Array.au3>
#include <GuiMenu.au3>
#include <Process.au3>
#include <SendMessage.au3>
#include <WinAPISysWin.au3>


_GUICtrlMenu_GetContextMenu_Example()

Func _GUICtrlMenu_GetContextMenu_Example()
    Local $hDesktop = _WinAPI_GetDesktopWindow()

    Local $hWnd, $hPopUp, $hActive, $hParent, $hRoot, $hRootOwner, $sMenuText
    $hActive = WinGetHandle('[ACTIVE]')
    ConsoleWrite("@@_Debug_line" & @TAB & @TAB & @ScriptLineNumber & "   var: $hActive    --> " & $hActive & @CRLF & @CRLF & 'Open a popup menu...' & @CRLF & @CRLF)
    Do
        Sleep(250)
        $hWnd = WinGetHandle('[CLASS:#32768]')
    Until $hWnd
    $hParent = _WinAPI_GetAncestor($hWnd, $GA_PARENT)
    $hRoot = _WinAPI_GetAncestor($hWnd, $GA_ROOT)
    $hRootOwner = _WinAPI_GetAncestor($hWnd, $GA_ROOTOWNER)
    Local $iPID = WinGetProcess($hWnd)
    $sProcessName = _ProcessGetName($iPID)
    ConsoleWrite("@@_Debug_line" & @TAB & @TAB & @ScriptLineNumber & "   var: $iPID         --> " & $iPID & @CRLF)
    ConsoleWrite("@@_Debug_line" & @TAB & @TAB & @ScriptLineNumber & "   var: $sProcessName --> " & $sProcessName & @CRLF)
    ConsoleWrite("@@_Debug_line" & @TAB & @TAB & @ScriptLineNumber & "   var: $hWnd         --> " & $hWnd & @TAB & 'Title = "' & WinGetTitle($hWnd) & '"' & @CRLF)
    ConsoleWrite("@@_Debug_line" & @TAB & @TAB & @ScriptLineNumber & "   var: $hParent      --> " & $hParent & @TAB & 'Title = "' & WinGetTitle($hParent) & '"' & @CRLF)
    ConsoleWrite("@@_Debug_line" & @TAB & @TAB & @ScriptLineNumber & "   var: $hRoot        --> " & $hRoot & @TAB & 'Title = "' & WinGetTitle($hRoot) & '"' & @CRLF)
    ConsoleWrite("@@_Debug_line" & @TAB & @TAB & @ScriptLineNumber & "   var: $hRootOwner   --> " & $hRootOwner & @TAB & 'Title = "' & WinGetTitle($hRootOwner) & '"' & @CRLF)

    $hPopUp = _SendMessage($hWnd, $MN_GETHMENU)
    ConsoleWrite("@@_Debug_line" & @TAB & @TAB & @ScriptLineNumber & "   var: $hPopUp       --> " & $hPopUp & @CRLF)

    Local $sItemText, $aSplit, $aRect, $iItemCount = _GUICtrlMenu_GetItemCount($hPopUp), $hSub, $iSubItemCount, $sSubItemText, $iIndent = 16
    ConsoleWrite("@@_Debug_line" & @TAB & @TAB & @ScriptLineNumber & "   var: $iItemCount   --> " & $iItemCount & @CRLF)
    For $iItem = 0 To $iItemCount - 1 Step 1
        $sItemText = _GUICtrlMenu_GetItemText($hPopUp, $iItem)
        If $sItemText = '' Then $sItemText = '--------------------------------' ; Separator line
        $aSplit = StringSplit($sItemText & @TAB, @TAB, $STR_NOCOUNT)
        $aRect = _GUICtrlMenu_GetItemRect($hDesktop, $hPopUp, $iItem); Mit $hPopUp funktioniert es!
        ConsoleWrite(StringFormat('> $sItemText #%02i: %-48s %s $aRect[%5i,%5i,%5i,%5i]\n', $iItem, $aSplit[0], $aSplit[1], $aRect[0], $aRect[1], $aRect[2], $aRect[3]))

        $hSub = _GUICtrlMenu_GetItemSubMenu($hPopUp, $iItem)
        If $hSub Then
            $iSubItemCount = _GUICtrlMenu_GetItemCount($hSub)
            ConsoleWrite("@@_Debug_line" & @TAB & @TAB & @ScriptLineNumber & "   var: $hSub         --> " & $hSub & @CRLF)
            For $iSubItem = 0 To $iSubItemCount - 1 Step 1
                $sSubItemText = _GUICtrlMenu_GetItemText($hSub, $iSubItem)
                $aSplit = StringSplit($sSubItemText & @TAB, @TAB, $STR_NOCOUNT)
                $aRect = _GUICtrlMenu_GetItemRect($hDesktop, $hSub, $iSubItem) ; Mit $hSub funktioniert es nicht!
                ConsoleWrite(StringFormat('+ %'&$iIndent&'s$sSubItemText #%02i: %-48s %s $aRect[%5i,%5i,%5i,%5i]\n', '', $iSubItem, $aSplit[0], $aSplit[1], $aRect[0], $aRect[1], $aRect[2], $aRect[3]))
            Next
        EndIf
    Next
EndFunc   ;==>_GUICtrlMenu_GetContextMenu_Example

Alles anzeigen

Ah super! Genau sowas hab ich gesucht! DANKE!!