Inputwert eingrenzen neg. & pos. Werte

**Alina**

Moin.

Ich würde gerne das im Input-1 folgende Werte zugelassen sind: -750 bis -250 UND 250 bis 750. Bei anderen Werten eine MsgBox(0,"Info","Wert nicht zulässig").

*) MsgBox ist nur ein Beispieltext. Kommt was sinnvolleres später rein.

C

#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("Form1", 121, 61, 192, 124)
$Input1 = GUICtrlCreateInput("500", 72, 8, 41, 28)
GUICtrlSetFont(-1, 12, 400, 0, "MS Sans Serif")
$Label1 = GUICtrlCreateLabel("Input 1", 8, 8, 61, 32)
GUICtrlSetFont(-1, 12, 800, 0, "MS Sans Serif")
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit

    EndSwitch
WEnd

Alles anzeigen

**AspirinJunkie**

Bin nicht so fit mit GUIs, könnte deswegen sein, dass es elegantere Methoden gibt um Wertebereiche vorzugeben.
Aber spontan hätte ich es einfach mit einer Prüfung gemacht, sobald der Wert im Input sich ändert.
Und hierbei nehme ich persönlich lieber den OnEventMode anstatt der Message-Loop:

AutoIt

#include <GUIConstantsEx.au3>
Opt("GUIOnEventMode", 1)

GUICreate("", 121, 61)
GUISetOnEvent($GUI_EVENT_CLOSE, "_raus")

$idInput = GUICtrlCreateInput("500", 72, 8, 41, 28)
GUICtrlSetOnEvent(-1, "_InputPruefen") ; ruft bei Änderungen die angegebene Funktion auf

GUICtrlCreateLabel("Input: ", 8, 8, 61, 32)

GUISetState(@SW_SHOW)


; Endlosschleife um GUI am Leben zu erhalten
While Sleep(100)
WEnd


Func _InputPruefen()
    Local Static $iVorher = 500    ; der vorherige Wert auf den zurückgesetzt werden kann
    Local $iVal = Int(GUICtrlRead(@GUI_CtrlId))    ; der aktuelle Wert des Input-Feldes

    If Abs($iVal) > 750 OR Abs($iVal) < 250 Then
        MsgBox(48, "Falsche Eingabe", "Wert außerhalb des Wertebereiches")
        GUICtrlSetData(@GUI_CtrlId, $iVorher)
    Else
        $iVorher = $iVal
    EndIf
EndFunc


Func _raus()
    Exit
EndFunc

Alles anzeigen

**funkey**

Hier noch sowas wie die Luxus-Variante mit Code-Teilen aus der RestrictControlRegExp-UDF von peethebee.

AutoIt

#include <GUIConstantsEx.au3>
#include <GuiConstants.au3>

Opt("GUIOnEventMode", 1)

Global $iMin = -750, $iMax = 750
Global $iBetweenMin = -250, $iBetweenMax = 250

Global $hGui = GUICreate("", 121, 61)
GUISetOnEvent($GUI_EVENT_CLOSE, "_raus")
Global $idInput = GUICtrlCreateInput("500", 72, 8, 41, 28)
GUICtrlSetOnEvent(-1, "_InputPruefen") ; ruft bei Änderungen die angegebene Funktion auf
GUIRegisterMsg($WM_COMMAND, "_CheckInput")
GUICtrlCreateLabel("Input: ", 8, 8, 61, 32)
GUISetState(@SW_SHOW)

; Endlosschleife um GUI am Leben zu erhalten
While Sleep(100)
WEnd

Func _CheckInput($hWnd, $msg, $wParam, $lParam)
    Local Static $oldValue = 0
    Local $_re_rc_regex_res
    Local $nNotifyCode = _HiWord($wParam)
    Local $nID = _LoWord($wParam)
    Local $sText, $iText
    If $nID = $idInput And $nNotifyCode = $EN_CHANGE Then
        $sText = GUICtrlRead($nID)
        For $i = 0 To StringLen($iMin)
            $_re_rc_regex_res = 1
            If StringRegExp($sText & StringTrimLeft($iMin, $i), "^-{0,1}\d{1,3}$") Then ExitLoop    ;3 -stellige Zahlen mit Vorzeichen zulassen
            $_re_rc_regex_res = 0
        Next
        $iText = Number($sText)
        If $_re_rc_regex_res = 1 Then
            If $iText < $iMin Then
                GUICtrlSetData($nID, $iMin)
                $oldValue = $iMin
                GUICtrlSetBkColor($nID, Default)
            ElseIf $iText > $iMax Then
                GUICtrlSetData($nID, $iMax)
                $oldValue = $iMax
                GUICtrlSetBkColor($nID, Default)
            ElseIf $iText > $iBetweenMin And $iText < $iBetweenMax Then
                GUICtrlSetBkColor($nID, 0xFF0000)
                $oldValue = $iText
            Else
                GUICtrlSetBkColor($nID, Default)
                $oldValue = $iText
            EndIf
        Else
            GUICtrlSetData($nID, $oldValue)
        EndIf
    EndIf


EndFunc

Func _InputPruefen()
    Local $iVal = Int(GUICtrlRead(@GUI_CtrlId))    ; der aktuelle Wert des Input-Feldes

    If Abs($iVal) < $iBetweenMax Then
        MsgBox(48, "Falsche Eingabe", "Wert außerhalb des Wertebereiches")
    EndIf
EndFunc

Func _raus()
    Exit
EndFunc

; helping function by gafrost
Func _HiWord($x)
    Return BitShift($x, 16)
EndFunc   ;==>_HiWord

; helping function by gafrost
Func _LoWord($x)
    Return BitAND($x, 0xFFFF)
EndFunc   ;==>_LoWord

Alles anzeigen

**Alina**

DANKE DANKE ! ! !