Hilfe bei Regex

Windi

Hallo ihr Experten,

hab mal wieder ein kleines Problem mit Regex.

Als Anfänger sehr sehr schwierig.

Ich benötige die lat und lon Row 23 und Row 24

Vielleicht kann mir jemand helfen.

Vielen Dank im Voraus!

Gruß Windi

C

#include <Inet.au3>
#include <MsgBoxConstants.au3>
#include <String.au3>
#include <StringConstants.au3>
#include <Array.au3>
#include <Constants.au3>



$Url = "https://www.google.de/maps/search/mainz+bahnhof/@49.9996883,8.2279501,15z/data=!3m1!4b1"
Run ("C:\Users\xx2\AppData\Roaming\Microsoft\Windows\Start Menu\Programs\Mozilla Firefox\firefox.exe" & $Url, "")
Local $oJson = _INetGetSource($Url)
;MsgBox(0,"",$oJson)
Local $aArray = StringRegExp(($oJson ), "\d{1,}.\d{1,}\w", 3)
_ArrayDisplay($aArray)

; ich benötige die Zahlen im Array
; Row 23
; Row 24

Alles anzeigen

Ich kann leider keine Original Daten reinstellen, sie sind mit API key geschützt.

**Andy**

Hmmm, ich scheine das Problem nicht verstanden zu haben...du HAST doch bereits die Daten im Array?!

AutoIt

#include <Inet.au3>
#include <MsgBoxConstants.au3>
#include <String.au3>
#include <StringConstants.au3>
#include <Array.au3>
#include <Constants.au3>



$Url = "https://www.google.de/maps/search/mainz+bahnhof/@49.9996883,8.2279501,15z/data=!3m1!4b1"
Run ("C:\Users\xx2\AppData\Roaming\Microsoft\Windows\Start Menu\Programs\Mozilla Firefox\firefox.exe" & $Url, "")
Local $oJson = _INetGetSource($Url)
;MsgBox(0,"",$oJson)
Local $aArray = StringRegExp(($oJson ), "\d{1,}.\d{1,}\w", 3)
;_ArrayDisplay($aArray)

; ich benötige die Zahlen im Array
; Row 23
; Row 24
$lat=$aArray[23]
ConsoleWrite('@@ Debug(' & @ScriptLineNumber & ') : $lat = ' & $lat & @CRLF & '>Error code: ' & @error & @CRLF) ;### Debug Console
$ion=$aArray[24]
ConsoleWrite('@@ Debug(' & @ScriptLineNumber & ') : $ion = ' & $ion & @CRLF & '>Error code: ' & @error & @CRLF) ;### Debug Console

Alles anzeigen

Windi

Hi Andy,

danke für die Rückmeldung!

Ich habe die Daten im Array richtig.

Kann man die noch ein bischen mehr eingrenzen.

Hier das Original Array!

Ich brauch davon Row 4 und 5

Row 1 hat manchmal die gleiche Größe an Ziffern.

Und Row 5 ist manchmal 2 Stellig.

Mir würde schon helfen wenn Row 0, Row 2 und Row 3 draus wären.

Ist das überhaupt möglich?

Gruß Windi

**Musashi**

Mir geht es so wie Andy - das Array ist doch bereits vorhanden

Wenn Du die Werte aus Row 4 und 5 benötigst, dann kannst Du sie doch einfach ansprechen/ausgeben. Hast Du möglicherweise noch Verständnisprobleme mit Arrays im allgemeinen ?

Mit z.B. _ArrayDelete lassen sich Elemente aus einem Array entfernen, aber das ist überhaupt nicht erforderlich.

**Musashi**

Zitat von Windi

Ich brauch davon Row 4 und 5

Beispiel mit dein Originalarray aus Beitrag 3 :

AutoIt

#include <Array.au3>
Local $aArray[10] = ["0/2355632",    _
                     "3.9823999405", _
                     "55116",        _
                     "55116",        _
                     "50.00125",     _
                     "8.2614",       _
                     "50.00143",     _
                     "8.26024",      _
                     "50.00045",     _
                     "8.26333"]

_ArrayDisplay($aArray) ; *** nur zur Ansicht

; Row 4 und 5 anzeigen :
MsgBox(0, "Row 4 und 5: ", $aArray[4] & @CRLF & $aArray[5] & @CRLF)

Alles anzeigen

Windi

Hi Musashi,

Danke für deine Rückmeldung.

mit dem Ansprechen von Arrays habe ich keine Probleme.

Ich muss ca 100 Adressen geocodieren und hab festgestellt, dass die lat und lon Werte, nicht immer auf den gleichen Positionen ausgegeben werden.

Siehe Bild 2

Gruß Windi

Daher meine Frage ob man es noch enger begrenzen kann.

Windi

Hier die Rohdaten:

Code

{"summary":{"query":"wilnsdorf hohe roth 6","queryType":"NON_NEAR","queryTime":149,"numResults":1,"offset":0,"totalResults":7314,"fuzzyLevel":2},"results":[{"type":"Point Address","id":"DE/PAD/p0/21286756","score":7.0448002815,"matchConfidence":{"score":0.9350328916967534},"address":{"streetNumber":"6","streetName":"Hoheroth","municipality":"Wilnsdorf","countrySecondarySubdivision":"Siegen-Wittgenstein","countrySubdivision":"Nordrhein-Westfalen","postalCode":"57234","countryCode":"DE","country":"Deutschland","countryCodeISO3":"DEU","freeformAddress":"Hoheroth 6, 57234 Wilnsdorf","localName":"Wilnsdorf"},"position":{"lat":50.82027,"lon":8.11352},"viewport":{"topLeftPoint":{"lat":50.82117,"lon":8.1121},"btmRightPoint":{"lat":50.81937,"lon":8.11494}},"entryPoints":[{"type":"main","position":{"lat":50.82024,"lon":8.11361}}]}]}

Code

"position":{"lat":50.82027,"lon":8.11352

Diese Werte bräuchte ich.

**AspirinJunkie**

RegEx hat hier nichts zu suchen.
Die Ergebnisse sind im JSON-Format und sollten daher auch entsprechend behandelt werden.
Es gibt diverse UDFs hierzu für AutoIt.

Ein Beispiel zum Geocoden über Google mit Hilfe >dieser UDF< habe ich dir mal erstellt (das Rohergebnis von dir sagt mir nix, da meine Google-API-Abfragen eine andere Struktur zurückgeben):

AutoIt

#include "JSON.au3"

; Parameter für die Geocoding-Abfrage (ANPASSEN!):
$sAPIKey = "...."
$sSuchAdresse = "Wilnsdorf Hohe Roth 6"

; URL zusammenbauen
$sURL = StringFormat('https://maps.googleapis.com/maps/api/geocode/json?address=%s&key=%s', _URIEncode($sSuchAdresse), $sAPIKey)

; Abfrage senden und Ergebnis in Variable speichern:
$sJSONReturn = BinaryToString(InetRead($sURL))

; JSON in AutoIt-Struktur parsen:
$oResult = _JSON_Parse($sJSONReturn)

; lat und lon auslesen:
$fLat = _JSON_Get($oResult, "results[0].geometry.location.lat")
$fLng = _JSON_Get($oResult, "results[0].geometry.location.lng")

; Ergebnis ausgeben:
MsgBox(0, "Koordinaten", "Lat: " & $fLat & @CRLF & "Lon: " & $fLng)


; Funktion um Adresse innerhalb der URI zu kodieren:
Func _URIEncode($sData)
    ; Prog@ndy
    Local $aData = StringSplit(BinaryToString(StringToBinary($sData, 4), 1), "")
    Local $nChar
    $sData = ""
    For $i = 1 To $aData[0]
        $nChar = Asc($aData[$i])
        Switch $nChar
            Case 45, 46, 48 To 57, 65 To 90, 95, 97 To 122, 126
                $sData &= $aData[$i]
            Case 32
                $sData &= "+"
            Case Else
                $sData &= "%" & Hex($nChar, 2)
        EndSwitch
    Next
    Return $sData
EndFunc   ;==>_URIEncode

Alles anzeigen

Windi

Danke für deine Mühe, kriege folgende Fehlermeldung.

Die Url ist von TomTom und der Key kann ich nicht veröffentlichen.

Code

>"C:\Program Files (x86)\AutoIt3\SciTE\..\autoit3.exe" /ErrorStdOut "C:\Users\xx2\Desktop\Regex test.au3"    
"C:\Users\xx2\Desktop\Regex test.au3" (36) : ==> Unknown function name.:
$oResult = _JSON_Parse($sJSONReturn)
$oResult = ^ ERROR
>Exit code: 1    Time: 0.3565

Ich hatte es mit StringinStr probiert aber es ist verdammt langsam.

Da sind zum Teil ein paar Tauusend zeichen drin.

Deshalb kam ich auf die idee mit Regex.

**Musashi**

Dumme Frage, aber hast Du auch die json-udf eingebunden ?

"C:\Users\xx2\Desktop\Regex test.au3" (36) : ==> Unknown function name.:$oResult = _JSON_Parse($sJSONReturn)$oResult = ^ ERROR

Unknown function name lässt vermuten, dass das nicht der Fall ist.

Bitte auch folgendes beachten :

Zitat

2022/10/19
Script-Breaking!: _JSON_Parse generiert für JSON-Objekte nun AutoIt-Maps anstatt Scripting.Dictionary-Objekte. Die letzte Version mit Dictionary liegt im Anhang als JSON_Dictionary.au3.
__JSON_FormatString(): @Tab wird nun durch \t escaped. (thx mko)

Windi

Hab die neue Version runtergeladen.

Jetzt kommt der Fehler:

Code

>"C:\Program Files (x86)\AutoIt3\SciTE\..\autoit3.exe" /ErrorStdOut "C:\Users\xx2\Desktop\Regex test.au3"    
"C:\Users\xx2\Desktop\JSON.au3" (184) : ==> Variable subscript badly formatted.:
Local $o_Current[]
Local $o_Current[^ ERROR
>Exit code: 1    Time: 0.3685

**Musashi**

Welche Version von AutoIt verwendest Du ?

Verwende mal die Variante JSON_Dictionary.au3

Windi -> Edit : Damit hat es wahrscheinlich nichts zu tun.

Das Problem ist :

Zitat von Windi

==> Variable subscript badly formatted

Windi

Jetzt funktioniert es.

Danke!

Werde mich morgen mal drüber machen.

Euch allen morgen einen schönen 2 Advent

Gruß Windi

Windi

Edit: heute

**Musashi**

RegEx ist, wie AspirinJunkie bereits schrieb, nicht die erste Wahl.

Ich habe trotzdem mal zwei Pattern zusammengestümpert - mehr fällt mir um diese Zeit nicht mehr ein

Die beiden Arrays kannst Du bei Bedarf joinen.

AutoIt

 #include <Array.au3>

Local $sSource = '{"summary":{"query":"wilnsdorf hohe roth 6","queryType":"NON_NEAR","queryTime":149,"numResults":1,"offset":0,"totalResults":7314,"fuzzyLevel":2},"results":[{"type":"Point Address","id":"DE/PAD/p0/21286756","score":7.0448002815,"matchConfidence":{"score":0.9350328916967534},"address":{"streetNumber":"6","streetName":"Hoheroth","municipality":"Wilnsdorf","countrySecondarySubdivision":"Siegen-Wittgenstein","countrySubdivision":"Nordrhein-Westfalen","postalCode":"57234","countryCode":"DE","country":"Deutschland","countryCodeISO3":"DEU","freeformAddress":"Hoheroth 6, 57234 Wilnsdorf","localName":"Wilnsdorf"},"position":{"lat":50.82027,"lon":8.11352},"viewport":{"topLeftPoint":{"lat":50.82117,"lon":8.1121},"btmRightPoint":{"lat":50.81937,"lon":8.11494}},"entryPoints":[{"type":"main","position":{"lat":50.82024,"lon":8.11361}}]}]}'

Local $aArrayLat = StringRegExp($sSource, "(?U)position.*lat.*(\d+.\d+),", 3)
Local $aArrayLon = StringRegExp($sSource, "(?U)position.*lon.*(\d+.\d+)\}", 3)
_ArrayDisplay($aArrayLat, "Latitude :")
_ArrayDisplay($aArrayLon, "Longitude :")

P.S. Oscar oder BugFix

Könnte einer das Thema aus dem Testforum nach H&U verschieben. Ist ggf. ja von allgemeinem Interesse.

Windi

OK Danke!

**AspirinJunkie**

Zitat von Windi

Die Url ist von TomTom und der Key kann ich nicht veröffentlichen.

Dann musst du die Abfrage natürlich noch an die JSON-Struktur die TomTom liefert anpassen:

AutoIt

#include "JSON.au3"

; Der Rückgabewert der TomTom-API
Local $sSource = '{"summary":{"query":"wilnsdorf hohe roth 6","queryType":"NON_NEAR","queryTime":149,"numResults":1,"offset":0,"totalResults":7314,"fuzzyLevel":2},"results":[{"type":"Point Address","id":"DE/PAD/p0/21286756","score":7.0448002815,"matchConfidence":{"score":0.9350328916967534},"address":{"streetNumber":"6","streetName":"Hoheroth","municipality":"Wilnsdorf","countrySecondarySubdivision":"Siegen-Wittgenstein","countrySubdivision":"Nordrhein-Westfalen","postalCode":"57234","countryCode":"DE","country":"Deutschland","countryCodeISO3":"DEU","freeformAddress":"Hoheroth 6, 57234 Wilnsdorf","localName":"Wilnsdorf"},"position":{"lat":50.82027,"lon":8.11352},"viewport":{"topLeftPoint":{"lat":50.82117,"lon":8.1121},"btmRightPoint":{"lat":50.81937,"lon":8.11494}},"entryPoints":[{"type":"main","position":{"lat":50.82024,"lon":8.11361}}]}]}'

; JSON in AutoIt-Struktur parsen:
$oResult = _JSON_Parse($sSource)

;  lat und lon auslesen:
$fLat = _JSON_Get($oResult, "results[0].position.lat")
$fLng = _JSON_Get($oResult, "results[0].position.lon")

; Ergebnis ausgeben:
MsgBox(0, "Koordinaten", "Lat: " & $fLat & @CRLF & "Lon: " & $fLng)

Alles anzeigen

Ansonsten grundsätzlicher Hinweis: Fehlermeldungen ohne ein minimales Skript zu posten, welches diese verursacht helfen in der Regel nicht wirklich weiter.

Edit Musashi : Die Funktion _ArrayAinATo2d() findet sich auch mittlerweile in der ArrayPlus-UDF.

**Musashi**

Nachtrag :

Du solltest, wie schon erwähnt, versuchen, die JSON Variante von AspirinJunkie umzusetzen.

Hier ein erweiterter RegEx Ansatz :

Dabei wird im Aufruf von StringRegExp das Flag 4 verwendet (Rückgabe : Array of Arrays).

AspirinJunkie hat im EN-Forum eine Funktion veröffentlicht, die daraus ein 2-D Array erstellt.

AutoIt

#include <Array.au3>

Local $sSource = '{"summary":{"query":"wilnsdorf hohe roth 6","queryType":"NON_NEAR","queryTime":149,"numResults":1,"offset":0,"totalResults":7314,"fuzzyLevel":2},"results":[{"type":"Point Address","id":"DE/PAD/p0/21286756","score":7.0448002815,"matchConfidence":{"score":0.9350328916967534},"address":{"streetNumber":"6","streetName":"Hoheroth","municipality":"Wilnsdorf","countrySecondarySubdivision":"Siegen-Wittgenstein","countrySubdivision":"Nordrhein-Westfalen","postalCode":"57234","countryCode":"DE","country":"Deutschland","countryCodeISO3":"DEU","freeformAddress":"Hoheroth 6, 57234 Wilnsdorf","localName":"Wilnsdorf"},"position":{"lat":50.82027,"lon":8.11352},"viewport":{"topLeftPoint":{"lat":50.82117,"lon":8.1121},"btmRightPoint":{"lat":50.81937,"lon":8.11494}},"entryPoints":[{"type":"main","position":{"lat":50.82024,"lon":8.11361}}]}]}'

Local $aArrayAdressLatLon = StringRegExp($sSource, "(?U)freeformAddress.*:(.*,.*),.*position.*lat.*(\d+.\d+),.*lon.*(\d+.\d+)\}", 4)
Local $aArrayResult
$aArrayResult = __ArrayAinATo2d($aArrayAdressLatLon)
_ArrayDisplay($aArrayResult, "Result :", default, default, default, "Bereich|FreeFormAddress|Latitude|Longitude")

; #FUNCTION# ======================================================================================
; Name ..........: __ArrayAinATo2d()
; Description ...: Convert a Arrays in Array into a 2D array
; Syntax ........: __ArrayAinATo2d(ByRef $A)
; Parameters ....: $A             - the arrays in array which should be converted
; Return values .: Success: a 2D Array build from the input array
;                  Failure: False
;                     @error = 1: $A is not an 1D array
;                            = 2: $A is empty
;                            = 3: first element is not aa array
; Author ........: AspirinJunkie
; =================================================================================================
Func __ArrayAinATo2d(ByRef $A)
    If UBound($A, 0) <> 1 Then Return SetError(1, UBound($A, 0), False)
    Local $N = UBound($A)
    If $N < 1 Then Return SetError(2, $N, False)
    Local $u = UBound($A[0])
    If $u < 1 Then Return SetError(3, $u, False)

    Local $a_Ret[$N][$u]

    For $i = 0 To $N - 1
        Local $t = $A[$i]
        If UBound($t) > $u Then ReDim $a_Ret[$N][UBound($t)]
        For $j = 0 To UBound($t) - 1
            $a_Ret[$i][$j] = $t[$j]
        Next
    Next
    Return $a_Ret
EndFunc   ;==>__ArrayAinATo2d

Alles anzeigen

Das Pattern selbst ist sicherlich noch optimierbar .

Windi

Ok Danke,

bin dabei.

Versuche es in den Webdriver von Dan einzuarbeiten.

Ich glaube, ich muß mal alles neu updaten.

Hatte festgestellt, dass der webdriver nicht mehr lief wenn die Datei

JSON_Dictionary.au3 eingebunden ist.

Wie ist das eigentlich, laufen die alten Sripte noch nach dem Update, oder muss da was angepasst werden.

**AspirinJunkie**

Zitat von Windi

Versuche es in den Webdriver von Dan einzuarbeiten.

WebDriver?
Das ist doch für die Steuerung von Browsern - oder?
Das ist aber doch Kanonen auf Spatzen für eine Web-API.

TomTom wird doch sehr wahrscheinlich ähnlich funktionieren wie alle anderen entsprechenden APIs auch.
Sprich: Man bastelt eine URL zusammen, setzt einen Request hierzu ab und bekommt einen Return.
Dafür benötigt man doch aber keinen Overhead eines Browsers - ein simples InetRead macht alles was man braucht (siehe mein Beispiel oben mit der Google Geocode-API). Das geht flotter, einfacher und mit weitaus weniger Overhead.

Oder die TomTom-API ist ganz obskur und macht völlig andere Dinge.

Zitat von Windi

Wie ist das eigentlich, laufen die alten Sripte noch nach dem Update, oder muss da was angepasst werden.

Nicht pauschal.
Wenn man mit der UDF Objekte extrahiert hat und diese direkt in AutoIt weiterverwendet hat und diese dann halt als Dictionary angesprochen hat dann muss man anpassen.
Wenn man die Objekte aber nicht manuell angefasst hat sondern z.B. nur einzelne Werte mit json_get gezogen hat oder sowas dann gibt es keinen Unterschied.

Wenn du die UDF verwenden willst und ein Skript neu bastelst dann würde ich stark dazu tendieren die normale json.au3 zu verwenden.
Dann werden nur native AutoIt-Strukturen verwendet. Außerdem will ich die json_dictionary.au3 nicht weiterpflegen.

Edit Windi : So hab mir die TomTom-API mal angeschaut und natürlich arbeitet die wie jede andere Web-API auch.
Sprich - man braucht auch hier kein WebDriver oder sonstiges - ein einfaches InetRead ist hier die korrekte Wahl.
Dann kann man sich das auch in eine einfache Funktion zur Wiederverwendung gießen:

AutoIt

#include "JSON.au3"
; ANPASSEN!
Global CONST $SAPIKEY_TOMTOM = "..."

; Koordinaten zu Adresse abfragen:
$aKoordinaten = _tomtom_geocodeAdress("Wilnsdorf Hohe Roth 6")

If @error Then ; Fehler
    MsgBox(48, "Fehler", "@error: " & @error & @CRLF & "@extended: " & @extended)
Else ; Ergebnis anzeigen
    _ArrayDisplay($aKoordinaten)
EndIf



; gibt die Koordinaten einer Adresse mit Hilfe der TomTom Geocode-Api zurück
Func _tomtom_geocodeAdress($sAdresse, $sApiKey = $SAPIKEY_TOMTOM)
    ; URL zusammenbauen
    Local $sURL = StringFormat('https://api.tomtom.com/search/2/geocode/%s.json?key=%s', _URIEncode($sAdresse), $sApiKey)

    ; Abfrage senden und Ergebnis in Variable speichern:
    Local $sJSONReturn = InetRead($sURL)
    If @error Then Return SetError(1, @error, Null)
    $sJSONReturn = BinaryToString($sJSONReturn)

    ; JSON in AutoIt-Struktur parsen:
    Local $oResult = _JSON_Parse($sJSONReturn)
    If @error Then Return SetError(2, @error, Null)

    ; Lat und Lon aus Ergebnis extrahieren
    Local $fLat = _JSON_Get($oResult, "results[0].position.lat")
    If @error Then Return SetError(3, @error, Null)
    Local $fLon = _JSON_Get($oResult, "results[0].position.lon")
    If @error Then Return SetError(4, @error, Null)

    Local $aRet[2] = [ $fLat, $fLon]
    Return $aRet
EndFunc

; Funktion um Adresse innerhalb der URI zu kodieren:
Func _URIEncode($sData)
    ; Prog@ndy
    Local $aData = StringSplit(BinaryToString(StringToBinary($sData, 4), 1), "")
    Local $nChar
    $sData = ""
    For $i = 1 To $aData[0]
        $nChar = Asc($aData[$i])
        Switch $nChar
            Case 45, 46, 48 To 57, 65 To 90, 95, 97 To 122, 126
                $sData &= $aData[$i]
            Case 32
                $sData &= "+"
            Case Else
                $sData &= "%" & Hex($nChar, 2)
        EndSwitch
    Next
    Return $sData
EndFunc   ;==>_URIEncode

Alles anzeigen

Hilfe bei Regex

Ähnliche Themen

Wildcards in Suchstring bei _ArrayFindAll

LimeSurvey Remote API json

Wie suche ich Spalten in Excel?