Labelaktualisierung will wieder mal nicht

**Kanashius**

Ich hab selbst keinen echten Drucker (nur Software wie Adobe PDF), kann dir da also leider nicht weiterhelfen

Deshalb hab ich bei dem Drucker-Zeug eigentlich nur deinen Code genommen und wiederverwendet (und reduntantes rausgenommen; Das waren aber nur String Ersetzungen).

GGf. ersetz mal alle Run commands mit nem Consolewrite und vergleich die Ausgabe, die der Code jetzt gibt, mit der, die der Code vorher gegeben hat.

Dann siehst du die Unterschiede und man kann das Beheben.

casi4712

Hm dass wär aber sehr merkwürdig, meine beiden Codezeilen hatten ja funktioniert, ok dann werde ich das mal probieren.^Ich denke es hängt mit den Leerzeichen im Druckernamen zusammen, nur so ein dumpfer Verdacht, in meinem Script war ihm das aber egal, das ist ja das komische.

Danke für den Tip

casi4712

ok dein Tip mit ConsoleWrite war natürlich Gold Wert, es muss so heissen:

AutoIt

      RunWait(@SystemDir & "\RUNDLL32 PRINTUI.DLL,PrintUIEntry /in /n  " & '"' & "\\" & $sPrintServer & "\" & $sText & '"')
      RunWait(@SystemDir & "\RUNDLL32 PRINTUI.DLL,PrintUIEntry /q /y /n " & '"' & "\\" & $sPrintServer & "\" & $sText & '"')

Wie gesagt, nur komisch, dass ihm das bei meiner vorherigen Version egal war.

Aber um noch mal zurückzukommen zu Deiner Aussage bzgl. wenn ich die Button nutzen will für die verbundenen Drucker, dass er dass einer Variable entnehmen müsste, dem ist leider nicht so. Dort wird nirgends reagiert, das funktioniert nur bei den lokalen Druckern. Da vielleicht noch ne Idee

Recht herzlichen Dank noch mal für die Unterstützung

lg

**BugFix**

Zitat von casi4712

Tip mit ConsoleWrite

Da man mit dem Verketten von Strings und den notwendigen Anführungszeichen leicht mal daneben greift, bevorzuge ich StringFormat.

AutoIt

$sPrintServer = 'PRINT:SERVER'
$sText = 'TEXT'

ConsoleWrite(@SystemDir & "\RUNDLL32 PRINTUI.DLL,PrintUIEntry /q /y /n " & '"' & "\\" & $sPrintServer & "\" & $sText & '"' & @CRLF)

; mit Stringformat muss "\" maskiert werden, also immer doppelt 
ConsoleWrite(StringFormat('%s\\RUNDLL32 PRINTUI.DLL,PrintUIEntry /q /y /n "\\\\%s\\%s"', @SystemDir, $sPrintServer, $sText) & @CRLF)

Eine weitere vereinfachende Schreibmöglichkeit ist: AutoItSetOption "ExpandVarStrings".

**Moombas**

Naja, wenn man generell ' anstatt " nutzt, finde ich ist es wesentlich einfacher:

AutoIt

$sPrintServer = 'PRINT:SERVER'
$sText = 'TEXT'

ConsoleWrite(@SystemDir & "\RUNDLL32 PRINTUI.DLL,PrintUIEntry /q /y /n " & '"' & "\\" & $sPrintServer & "\" & $sText & '"' & @CRLF)

; mit Stringformat muss "\" maskiert werden, also immer doppelt 
ConsoleWrite(StringFormat('%s\\RUNDLL32 PRINTUI.DLL,PrintUIEntry /q /y /n "\\\\%s\\%s"', @SystemDir, $sPrintServer, $sText) & @CRLF)

; generell ' nutzen ansatt ", das man ' in einem Pfad-String braucht ist eher unwahrscheinlich und man braucht kaum wechseln und auch keine Maskierung
ConsoleWrite(@SystemDir & '\RUNDLL32 PRINTUI.DLL,PrintUIEntry /q /y /n "\\' & $sPrintServer & '\' & $sText & '"' & @CRLF)

Ich fahre seit dem Wechsel von ' auf " wesentlich besser aber das ist ein wenig Geschmackssache.

casi4712

okidoki, danke für den Input,

wie gesagt fand es nur verwunderlich dass bei meinem Ansatz es Wurscht war ob das Anführungszeichen im Druckernamen stehen, klar ist es eleganter es so zu definieren

Dann noch mal zur Function _GetSelectedPrinter, ich habe die Buttons noch mal überprüft mit ConsoleWrite, bei Druckern die aus dem Lokalen Fenster gewählt wurden, macht er es richtig, also zB so

rundll32 printui.dll,PrintUIEntry /n "\\lokalerPC\Microsoft Print to PDF" /k , bei einem Drucker aus dem unteren, haut er nur einen Fehler raus, er schreibt auch nichts in die Console. Der Fehler: Vorgang konnte nicht abgeschlossen werden (0x00000709).

Noch mal das fast fertige Modul, vielleicht fällt ja noch jemanden was auf:

AutoIt

#include-once
#include <ButtonConstants.au3>
#include <WindowsConstants.au3>
#include <Array.au3>
#include <ComboConstants.au3>
#include <MsgBoxConstants.au3>
#include <GUIConstantsEx.au3>
#include <GuiListBox.au3>
#include <GuiComboBox.au3>

Opt("GUIOnEventMode", 1)
#NoTrayIcon

Global $SubBack = 0xFFFFFF, $sBeepFile="", $mPrinterGuis[]
Global $sPrintServer = "Druck.vwlt.antrax-berlin.de"
$hMainGui = GUICreate("Some Window", 600, 400)
GUISetOnEvent($GUI_EVENT_CLOSE, "_close", $hMainGui)

$idButton = GUICtrlCreateButton("Printers", 10, 10)
GUICtrlSetOnEvent(-1, "_openPrinters")

Global $mPrinter = _createPrinterGui($hMainGui)
If @error Then MsgBox(16, "Error", "Fehler bei der Initialisierung des Druckerfensters: "&@error&":"&@extended)


GUISetState(@SW_SHOW, $hMainGui)

While Sleep(100)
WEnd



Func _openPrinters()
    _updatePrinters($mPrinter)
    GUISetState(@SW_SHOW, $mPrinter.Gui)
EndFunc



Func _close()
    Exit
EndFunc

Func _createPrinterGui($hParent)
    Local $iWidth = 430, $iHeight = 430, $iBorder = 10, $iWidthRight = 100, $iListHeight = 120, $iLineHeight = 30
    Local $iWidthLeft = $iWidth-$iWidthRight-$iBorder*3
    Local $mPrinterGuiData[]
    Global $aList = _getNetworkPrinters()

    ; Create Gui
    $mPrinterGuiData.Gui = GUICreate("DRUCKER ZUWEISEN", $iWidth, $iHeight, -1, -1, -1, -1, $hParent)
    If @error Then Return SetError(1, 0, -1)
    GUISetOnEvent($GUI_EVENT_CLOSE, "_closePrinterGui", $mPrinterGuiData.Gui)
    GUISetBkColor($SubBack, $mPrinterGuiData.Gui)

    ; create left column
    Local $iTop = $iBorder

    ; default printer
    GUICtrlCreateLabel("Standarddrucker: ", $iBorder, $iTop, $iWidth-$iBorder*2, $iLineHeight)
    $iTop += $iLineHeight
    GUICtrlSetFont(-1, 9, 900) ; bold
    $mPrinterGuiData.idDefaultPrinter = GUICtrlCreateLabel("", $iBorder, $iTop, $iWidth-$iBorder*2, $iLineHeight)
    $iTop += $iLineHeight
    GUICtrlSetFont(-1, 9, 900) ; bold
    _updateDefaultPrinter($mPrinterGuiData.idDefaultPrinter)

    ; installed printers
    ;$iTop += $iLineHeight
    GUICtrlCreateLabel("Installierte Drucker: ", $iBorder, $iTop, $iWidthLeft, $iLineHeight)
    $iTop += $iLineHeight
    GUICtrlSetFont(-1, 9, 900) ; bold
    Local $iRightColumnTop = $iTop
    $mPrinterGuiData.idInstalledPrinters = GUICtrlCreateList("", $iBorder, $iTop, $iWidthLeft, $iListHeight)
    GUICtrlSetOnEvent(-1, "_selPrinterLimitToOne")
    $iTop += $iListHeight+$iLineHeight
    _updateInstalledPrinters($mPrinterGuiData.idInstalledPrinters)

    ; connected printers
    GUICtrlCreateLabel ( "Verbundene Drucker: ", 10, 220, 120, 20 )
   GUICtrlSetFont(-1, 9, 900) ; bold
    $mPrinterGuiData.idConnectedPrinters = GUICtrlCreateList("", $iBorder, $iTop, $iWidthLeft, $iListHeight)
    GUICtrlSetOnEvent(-1, "_selPrinterLimitToOne")
    $iTop += $iListHeight
    _updateConnectedPrinters($mPrinterGuiData.idConnectedPrinters)

    ; network printers
    GUICtrlCreateLabel("Netzwerkdrucker einbinden: ", $iBorder, $iTop, $iWidthLeft, $iLineHeight)
    $iTop += $iLineHeight
    GUICtrlSetFont(-1, 9, 900) ; bold
    $mPrinterGuiData.idNoPrintServer = GUICtrlCreateLabel("Kein Druckserver", $iBorder, $iTop, $iWidthLeft, $iLineHeight)
    GUICtrlSetFont(-1, 9, 900) ; bold
    GUICtrlSetState(-1, $GUI_HIDE)

    $mPrinterGuiData.idNetworkPrinters = GUICtrlCreateCombo("", $iBorder, $iTop, $iWidthLeft, $iLineHeight)
    $iTop += 50
     GUICtrlSetOnEvent(-1, "_conPrinter")
    _updateNetworkPrinters($mPrinterGuiData.idNetworkPrinters, $mPrinterGuiData.idNoPrintServer)


    ; create right column
    Local $arButtons = [["idTestprint", "Testdruck", "_doTestPrint"],["idSettings", "Einstellungen", "_openSettings"],["idPreferences", "Eigenschaften", "_openPreferences"], _
                        ["idQueue", "Warteschlange", "_openQueue"],["idPrintfolder", "Druckerordner", "_openPrintFolder"],["idDefault", "Standard", "_setDefaultPrinter"], _
                        ["idDelete", "Delete", "_DeletePrinter"], ["idIPlist", "IP-List", "_IPList"]]
    For $i = 0 To UBound($arButtons)-1 Step 1
        ;$mPrinterGuiData[$arButtons[$i][0]] = GUICtrlCreateButton($arButtons[$i][1], $iBorder*2+$iWidthLeft, $iRightColumnTop+$iBorder+($iLineHeight+$iBorder)*$i, $iWidthRight, $iLineHeight)
        $mPrinterGuiData[$arButtons[$i][0]] = GUICtrlCreateButton($arButtons[$i][1], $iBorder*2+$iWidthLeft, $iRightColumnTop-0+($iLineHeight+$iBorder)*$i, $iWidthRight, $iLineHeight)
        GUICtrlSetOnEvent(-1, $arButtons[$i][2])
    Next

    $mPrinterGuis[$mPrinterGuiData.Gui] = $mPrinterGuiData
    GUISwitch($hParent)
    Return $mPrinterGuiData
EndFunc
;------------------------------------------------------------------------------------------------------------------------

Func _conPrinter()
  Local $sText = GUICtrlRead($mPrinterGuis[@GUI_WinHandle].idNetworkPrinters)
  Local $var1 = 'Drucker' & " " & $sText & @CRLf & 'wird verbunden'
  Local $var2 = 'Drucker wurde verbunden und auf Standard gesetzt!'
    _SPText($Var1)
       RunWait(@SystemDir & "\RUNDLL32 PRINTUI.DLL,PrintUIEntry /in /n  " & '"' & "\\" & $sPrintServer & "\" & $sText & '"')
       RunWait(@SystemDir & "\RUNDLL32 PRINTUI.DLL,PrintUIEntry /q /y /n " & '"' & "\\" & $sPrintServer & "\" & $sText & '"')
    _updatePrinters($mPrinter)
    _SPText($Var2)
EndFunc

Func _SPText($var)
  SplashTextOn('', $Var, 300, 60, -1, -1, $DLG_NOTITLE)
  Sleep(2000)
  SplashOff()
EndFunc

Func _IPList()
      If  IsArray($aList) = "" Then
       MsgBox(262144,"Title", "keine Netzerkdrucker verfügbar! ")
      else
       _ArrayDisplay($aList)
      EndIF
EndFunc

Func _selPrinterLimitToOne()
    _GUICtrlListBox_SetCurSel(@GUI_CtrlId=$mPrinterGuis[@GUI_WinHandle].idConnectedPrinters?$mPrinterGuis[@GUI_WinHandle].idInstalledPrinters:$mPrinterGuis[@GUI_WinHandle].idConnectedPrinters, -1)
EndFunc

Func _updatePrinters($mPrinterGuiData)
    _updateDefaultPrinter($mPrinterGuiData.idDefaultPrinter)
    _updateInstalledPrinters($mPrinterGuiData.idInstalledPrinters)
    _updateConnectedPrinters($mPrinterGuiData.idConnectedPrinters)
    _updateNetworkPrinters($mPrinterGuiData.idNetworkPrinters, $mPrinterGuiData.idNoPrintServer)
EndFunc

Func _closePrinterGui()
    GUISetState(@SW_HIDE, $mPrinterGuis[@GUI_WinHandle].Gui)
EndFunc

Func _networkPrinterSelection()
    Local $sPrinter = GUICtrlRead($mPrinterGuis[@GUI_WinHandle].idNetworkPrinters)
    RunWait(@SystemDir & "\RUNDLL32 PRINTUI.DLL,PrintUIEntry /in /n  \\" & $sPrintServer &"\"& $sPrinter)
    RunWait(@SystemDir & "\RUNDLL32 PRINTUI.DLL,PrintUIEntry /q /y /n \\"  & $sPrintServer &"\"& $sPrinter)
    MsgBox('262144', "Default printer", "Default printer set to: " & $sPrinter)
EndFunc

Func _doTestPrint()
    SoundPlay($sBeepFile)
    
    Local $sPrinter = _printExec("/k")
    If Not @error Then MsgBox('262144', "TestDruck", "Der TestDruck wurde an den Drucker """ & _getSelectedPrinter() & """ abgeschickt!" & @CRLF & "Bitte überprüfen Sie den Ausdruck.")
EndFunc

Func _openSettings()
    SoundPlay($sBeepFile)
    _printExec("/e")
EndFunc

Func _DeletePrinter()
    SoundPlay($sBeepFile)
    ;_printExec("/p")
    Local $sPrinter = _getSelectedPrinterAbs()
    If @error Then Return SetError(1, 0, -1)
    RunWait(@SystemDir & "\RUNDLL32 PRINTUI.DLL,PrintUIEntry /dl /n " & $sPrinter)
     If @error Then Return SetError(2, 0, -1)
    _updatePrinters($mPrinter) 
    Return $sPrinter
EndFunc

Func _openPreferences()
    SoundPlay($sBeepFile)
    _printExec("/p")
EndFunc

Func _openQueue()
    SoundPlay($sBeepFile)
    _printExec("/o")
EndFunc

Func _openPrintFolder()
    SoundPlay($sBeepFile)
    Run("rundll32.exe shell32.dll,SHHelpShortcuts_RunDLL PrintersFolder")
EndFunc

Func _setDefaultPrinter()
    SoundPlay($sBeepFile)
    Local $sPrinter = '"' & GUICtrlRead($mPrinterGuis[@GUI_WinHandle].idInstalledPrinters) & '"'
    RunWait(@SystemDir & "\RUNDLL32 PRINTUI.DLL,PrintUIEntry /q /y /n " & $sPrinter)
    _updateDefaultPrinter($mPrinterGuis[@GUI_WinHandle].idDefaultPrinter)
EndFunc

Func _printExec($sCommand)
    Local $sPrinter = _getSelectedPrinterAbs()
    MsgBox(262144,"Title", $sPrinter)
    If @error Then Return SetError(1, 0, -1)
    RunWait( "rundll32 printui.dll,PrintUIEntry /n " & $sPrinter & " "&$sCommand )
    If @error Then Return SetError(2, 0, -1)
    Return $sPrinter
EndFunc

; Returns the selected printer with the absolute path including \\ and the computer name
Func _getSelectedPrinterAbs()
    Local $sPrinter = _getSelectedPrinter()
    If @error Then Return SetError(1, 0, -1)
    If Not StringInStr($sPrinter, "\\") Then $sPrinter = '"\\' & @ComputerName & "\" & $sPrinter & '"'
    Return $sPrinter
EndFunc

Func _getSelectedPrinter()
    Local $sPrinter = GUICtrlRead($mPrinterGuis[@GUI_WinHandle].idInstalledPrinters)
    If $sPrinter = "" Then $sPrinter = GUICtrlRead($mPrinterGuis[@GUI_WinHandle].idConnectedPrinters)
    If $sPrinter = "" Then
        MsgBox(16, "Druckerauswahl", "Es wurde kein Drucker ausgewählt!")
        Return SetError(1, 0, -1)
    EndIf
    Return $sPrinter
EndFunc

Func _updateDefaultPrinter($idLabel)
    Local $sDefaultPrinter = _getDefaultPrinter()
    If @error Then Return SetError(2, @error, -1)
    GUICtrlSetData($idLabel, $sDefaultPrinter)
    Return 1
EndFunc

Func _updateInstalledPrinters($idList)
    _GUICtrlListBox_ResetContent($idList)
    Local $iCount = 1
    While True
        Local $sPrinterName = RegEnumKey("HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Print\Printers", $iCount)
        If @error = -1 Then ExitLoop
        $iCount+=1
        _GUICtrlListBox_AddString($idList, $sPrinterName)
    WEnd
    _GUICtrlListBox_SelectString($idList, _getDefaultPrinter())
    Return 1
EndFunc

Func _updateConnectedPrinters($idList)
    _GUICtrlListBox_ResetContent($idList)
    Local $iCount = 1
    While True
        Local $sPrinterName = RegEnumKey("HKEY_CURRENT_USER\Printers\Connections", $iCount)
        If @error = -1 Then ExitLoop
        $iCount+=1
         Local $arPrinter = StringSplit($sPrinterName, ",")
        If UBound($arPrinter)>1 Then _GUICtrlListBox_AddString($idList, $arPrinter[4])
    WEnd
    _GUICtrlListBox_SelectString($idList, _getDefaultPrinter())
    Return 1
EndFunc

Func _updateNetworkPrinters($idCombo, $idLabel)
    _GUICtrlComboBox_ResetContent($idCombo)
    Local $arPrinters = _getNetworkPrinters()
    If Not IsArray($arPrinters) Then
        GUICtrlSetState($idCombo, $GUI_HIDE)
        GUICtrlSetState($idLabel, $GUI_SHOW)
    Else
        GUICtrlSetState($idCombo, $GUI_SHOW)
        GUICtrlSetState($idLabel, $GUI_HIDE)
        For $i=1 To UBound($arPrinters)-1 Step 1
            If $arPrinters[$i][0] <> "" Then _GUICtrlComboBox_AddString($idCombo, $arPrinters[$i][0])
        Next
    EndIf
    Return 1
EndFunc

; Returns the name of the default printer;
; Errors:     1 - Registry entry could not be read
;             2 - Registry entry could not be parsed
Func _getDefaultPrinter()
    Local $sDefaultPrinter = RegRead( "HKEY_CURRENT_USER\Software\Microsoft\Windows NT\CurrentVersion\windows", "Device")
    If @error Then Return SetError(1, 0, -1)
    Local $arDefaultPrinter = StringSplit($sDefaultPrinter, ",")
    If UBound($arDefaultPrinter)>0 Then Return $arDefaultPrinter[1]
    Return SetError(2, 0, -1)
EndFunc

;-------------------------------------------------------------------------------------------------------------------
; Returns a 2D array with network printers: 0 name; 1 driverName; 2 portName; 3 Shared; 4 ShareName; 5 Published; 6 Local; 7 Location; 8 DeviceID; 9 DriverName
; Errors:     1 - Printserver file does not exist
;             2 - Printer query failed
;             3 - No printers found
Func _getNetworkPrinters()
    If Not FileExists("\\"&$sPrintServer&"\c$") Then Return SetError(1, 0, -1)

    Local $objWMIService = ObjGet("winmgmts:\\" & $sPrintServer & "\root\CIMV2")
    Local $colItems = $objWMIService.ExecQuery('SELECT * FROM Win32_Printer')
    If Not IsObj($colItems) Then Return SetError(2, 0, -1)
    If Not $colItems.count Then Return SetError(3, 0, -1) ; No Printer found
    Local $aPrinter[$colItems.count][10], $i = 0
    For $oItem In $colItems
        $aPrinter[$i][0] = $oItem.Name
        $aPrinter[$i][1] = $oItem.DriverName
        $aPrinter[$i][2] = $oItem.PortName
        $aPrinter[$i][3] = $oItem.Shared
        $aPrinter[$i][4] = $oItem.ShareName
        $aPrinter[$i][5] = $oItem.Published
        $aPrinter[$i][6] = $oItem.Local
        $aPrinter[$i][7] = $oItem.Location
        $aPrinter[$i][8] = $oItem.DeviceID
        $aPrinter[$i][9] = $oItem.DriverName
        $i += 1
    Next
    Return $aPrinter
     _ArrayDisplay($aPrinter)
EndFunc

Alles anzeigen

Um es noch mal konkret zu formulieren, wie kann ich hier eine IF Bedingung in der Func _printExec integrieren,um abzufragen, ob das gewähle Element aus dem oberen Fenster oder dem unteren Fenster stammt, damit ich die Exec Befehle entsprechend mit vorangestellten Localhost oder aber vorangestelltem Printserver ausgestalten kann. Gibt es da eine Möglichkeit? Im vorliegenden Code wird immer der localhost vorangestellt und das funktioniert bei Druckserver Netzwerkdruckern einfach nicht.

lg und eine schöne Restwoche noch

casi4712

ok hab jetzt eine Lösung für das Problem gefunden, wahrscheinlich wieder ne dumme Lösung, aber sie funktioniert, der String für die beiden Bedingungen muss natürlich noch gebaut werden, für die die es interessiert:

AutoIt

Func _printExec($sCommand)
   If GUICtrlRead($mPrinterGuis[@GUI_WinHandle].idInstalledPrinters) <> "" And GUICtrlRead($mPrinterGuis[@GUI_WinHandle].idConnectedPrinters) = "" Then
     MsgBox(0, "", "Selection from Local Printer: ")
     ;Variable Printserver = Lokaler PC
   ElseIf GUICtrlRead($mPrinterGuis[@GUI_WinHandle].idConnectedPrinters) <> "" And GUICtrlRead($mPrinterGuis[@GUI_WinHandle].idInstalledPrinters) = "" Then
     MsgBox(0, "", "Selection from conPrinters: ")
     ;Variable Printserver = Printserver
   Else
     MsgBox(0, "", "No selection made.")
     Return 1
   EndIf
  .
  .
  .
    Local $sPrinter = _getSelectedPrinterAbs()
    MsgBox(262144,"Title", $sPrinter)
    If @error Then Return SetError(1, 0, -1)
    RunWait( "rundll32 printui.dll,PrintUIEntry /n " & $sPrinter & " "&$sCommand )
    If @error Then Return SetError(2, 0, -1)
    Return $sPrinter
EndFunc

Alles anzeigen

Vielen Dank noch mal für alle Helfer und schönes Wocheende noch

casi4712

Hallo noch mal,

Eigentlich dachte ich ja dieses Druckermodul ist mit 100 Zeilen abgeschlossen, aber es ist wie es ist, es kommen immer noch Ideen und Wünsche dazu. Ich habe das Script jetzt noch mal entsprechend modifiziert und mit einer Combo ergänzt für "reine IP Printer" die nicht über einen Printserver vervunden sind. Da hier ein Scan zwar möglich wäre, dies aber in der Regel doch ziemlich lange dauert, habe ich mich entschlossen dies mit einer CSV EIngabe zu erledigen. Die Strunktur dieser Tabelle schaut exemplarisch so aus:

Code

Druckername,IP-Adresse,Treiberpfad,PName,Raum
Kyocera KY 301,192.168.178.50,\\drivers\PRINTERMOD\IP-Drucker\kyocera\E_WF1XZE.INF,Kyocera KY 301,2.21
XP-3150 Series,EP_192.168.178.49,\\drivers\PRINTERMOD\IP-Drucker\Epson\EPPRNUT.INF,XP-3150 Series,P1
HP-301,IP_192.168.100.44,C:\\drivers\PRINTERMOD\IP-Drucker\Epson\EPPRNUT.INF,HP-301,2.19

NUn versuche ich also eine Funktion zu bauen die dann in Abhängigkeit von der Auswahl diese Werte aus der jeweiligen Tabellenzeile ausliest, damiut ich dann entsprechend diesen Befehl zusammenbauen kann:

Code

rundll32 printui.dll,PrintUIEntry /b "Dell 3110cn" /f "\\driver\Int0101\IP-Drucker\Dell 3110cn\dlxbuzi.inf" /r "IP_192.168.100.49:" /m "PName" /if

Ich habe ja das entsprechende Array, aber wie kann ich die entsprechenden Werte zuweisen aus der Comboauswahl, geht das überhaupt? Ich hoffe meine Frage war halbwegs verständlich. Mein modifiziertes Script sieht wie folgt aus:

Zitat

AutoIt

#include-once
#include <ButtonConstants.au3>
#include <WindowsConstants.au3>
#include <Array.au3>
#include <ComboConstants.au3>
#include <MsgBoxConstants.au3>
#include <GUIConstantsEx.au3>
#include <GuiListBox.au3>
#include <GuiComboBox.au3>
#include <StringSize.au3>
#include <GuiListView.au3>
Opt("GUIOnEventMode", 1)
#NoTrayIcon



Global $SubBack = 0xFFFFFF, $sBeepFile="", $mPrinterGuis[]
Global $sPrintServer = "Druck.vwlt.antrax-berlin.de"
 $hMainGui = GUICreate("Some Window", 600, 400)
 Global $mPrinter = _Form2($hMainGui)
  If @error Then MsgBox(16, "Error", "Fehler bei der Initialisierung des Druckerfensters: "&@error&":"&@extended)

GUISetState(@SW_SHOW, $mPrinter.Gui)

While Sleep(100)
WEnd

Func _Form2($hParent)
    Local $iWidth = 430, $iHeight = 480, $iBorder = 10, $iWidthRight = 100, $iListHeight = 120, $iLineHeight = 30
    Local $iWidthLeft = $iWidth-$iWidthRight-$iBorder*3
    Local $mPrinterGuiData[]
    Global $aList = _getNetworkPrinters()
    Global $iList
    Global $str

    ; CREATE GUI
    $mPrinterGuiData.Gui = GUICreate("DRUCKER ZUWEISEN", $iWidth, $iHeight, -1, -1, -1, -1, $hParent)
    If @error Then Return SetError(1, 0, -1)
    GUISetOnEvent($GUI_EVENT_CLOSE, "_closePrinterGui", $mPrinterGuiData.Gui)
    GUISetBkColor($SubBack, $mPrinterGuiData.Gui)

    ; CREATE LEFT COLUMN
    Local $iTop = $iBorder

    ; default printer
    GUICtrlCreateLabel("Standarddrucker: ", $iBorder, $iTop, $iWidth-$iBorder*2, $iLineHeight)
    $iTop += $iLineHeight
    GUICtrlSetFont(-1, 12, 900) ; bold
    $mPrinterGuiData.idDefaultPrinter = GUICtrlCreateLabel("", $iBorder, $iTop, $iWidth-$iBorder*2, $iLineHeight)
    $iTop += $iLineHeight
    GUICtrlSetFont(-1, 9, 900) ; bold
    _updateDefaultPrinter($mPrinterGuiData.idDefaultPrinter)


; INSTALLED PRINTERS
    ;$iTop += $iLineHeight
    GUICtrlCreateLabel("Lokale Drucker: ", $iBorder, $iTop, $iWidthLeft, $iLineHeight)
    $iTop += $iLineHeight
    GUICtrlSetFont(-1, 9, 900) ; bold
    Local $iRightColumnTop = $iTop
    $mPrinterGuiData.idInstalledPrinters = GUICtrlCreateList("", $iBorder, 100, $iWidthLeft, $iListHeight)
    GUICtrlSetOnEvent(-1, "_selPrinterLimitToOne")
    $iTop += $iListHeight+$iLineHeight
    _updateInstalledPrinters($mPrinterGuiData.idInstalledPrinters)


    $idButton_Refresh = GUICtrlCreateButton("Refresh", 170, 220, 70, 30)
     GUICtrlSetOnEvent( -1, "_Refresh")
     GUICtrlSetTip( -1, "Druckelisten aktualisieren")
    $idButton_New = GUICtrlCreateButton("New", 240, 220, 70, 30)
     GUICtrlSetOnEvent( -1, "_addprt")
     GUICtrlSetTip( -1, "Neuer lokaler Drucker")

; CONNECTED PRINTERS
    GUICtrlCreateLabel ( "Verbundene Drucker: ", 10, 227, 120, 20 )
   GUICtrlSetFont(-1, 9, 900) ; bold
    $mPrinterGuiData.idConnectedPrinters = GUICtrlCreateList("", $iBorder, 260, $iWidthLeft, $iListHeight)
    GUICtrlSetOnEvent(-1, "_selPrinterLimitToOne")
    $iTop += $iListHeight
    _updateConnectedPrinters($mPrinterGuiData.idConnectedPrinters)

; NETWORK PRINTERS
    GUICtrlCreateLabel("Netzwerkdrucker einbinden: ", $iBorder, $iTop, $iWidthLeft, $iLineHeight)
    $iTop += $iLineHeight
    GUICtrlSetFont(-1, 9, 900) ; bold
    $mPrinterGuiData.idNoPrintServer = GUICtrlCreateLabel("Kein Druckserver", $iBorder, $iTop, $iWidthLeft, $iLineHeight)
    GUICtrlSetFont(-1, 9, 900) ; bold
    GUICtrlSetState(-1, $GUI_HIDE)

    $mPrinterGuiData.idNetworkPrinters = GUICtrlCreateCombo("", $iBorder, $iTop, $iWidthLeft, $iLineHeight)
    $iTop += 50
     GUICtrlSetOnEvent(-1, "_conPrinter")
    _updateNetworkPrinters($mPrinterGuiData.idNetworkPrinters, $mPrinterGuiData.idNoPrintServer)

;  IP PRINTERS
   GUICtrlCreateLabel ( "IP Drucker einbinden: ", 10, 425, 150, 20 )
  GUICtrlSetFont(-1, 9, 900) ; bold
    $mPrinterGuiData.idIPPrinters = GUICtrlCreateCombo("", $iBorder, 445, $iWidthLeft, $iLineHeight)
    $iTop += 50
    ;GUICtrlSetOnEvent(-1, "_selPrinterLimitToOne")
    $iTop += $iListHeight
             $iList = IPprt()
            For $i = 1 To UBound($iList) - 1
             If $iList[$i][0] <> "" Then $var = GUICtrlSetData($mPrinterGuiData.idIPPrinters, $iList[$i][0] & " - " & $iList[$i][1])
              GUICtrlSetOnEvent($mPrinterGuiData.idIPPrinters, "_conIPprt")
            Next

    _updateConnectedPrinters($mPrinterGuiData.idConnectedPrinters)
    
; CREATE RIGHT COLUMN
    Local $arButtons = [["idTestprint", "Testdruck", "_doTestPrint", "Testdruck auf gewählten Drucker"],["idSettings", "Einstellungen", "_openSettings", "Einstellungen öffnen loakaler/Netzwerk Drucker"],["idPreferences", "Eigenschaften", "_openPreferences", "Eigenschaften loakaler/Netzwerk Drucker"], _
                        ["idQueue", "Warteschlange", "_openQueue", "Wartenschlange anzeigen loakaler/Netzwerk Drucker"],["idPrintfolder", "Druckerordner", "_openPrintFolder", "Printerfolder anzeigen"],["idDefault", "Standard", "_setDefaultPrinter", "Standard Drucker setzen"], _
                        ["idDelete", "Delete", "_DeletePrinter", "Drucker löschen loakaler/Netzwerk Drucker"], ["idIPlist", "IP-List", "_IPList", "IP-Liste der Printserver Drucker"], ["idIPlistNon", "IP-ListNoPS", "_IPListNon", "IP-Liste sonstiger IP Drucker"] ]
    For $i = 0 To UBound($arButtons)-1 Step 1
        ;$mPrinterGuiData[$arButtons[$i][0]] = GUICtrlCreateButton($arButtons[$i][1], $iBorder*2+$iWidthLeft, $iRightColumnTop+$iBorder+($iLineHeight+$iBorder)*$i, $iWidthRight, $iLineHeight)
        $mPrinterGuiData[$arButtons[$i][0]] = GUICtrlCreateButton($arButtons[$i][1], $iBorder*2+$iWidthLeft, $iRightColumnTop-0+(32+$iBorder)*$i, $iWidthRight, $iLineHeight)
        GUICtrlSetOnEvent(-1, $arButtons[$i][2])
        GUICtrlSetTip( -1, $arButtons[$i][3])
    Next

    $mPrinterGuis[$mPrinterGuiData.Gui] = $mPrinterGuiData
    GUISwitch($hParent)
    Return $mPrinterGuiData
EndFunc



;------------------------------------------------------------------------------------------------------------------------
;OTHER FUNCTIONS
;------------------------------------------------------------------------------------------------------------------------

Func IPprt()
    Local $sFile = @ScriptDir & "\IPs.csv"
    Local $sFileData = FileRead($sFile)
    Local $sFirstLine = FileReadLine($sFile, 1)
    Local $asCSV[0][UBound(StringSplit($sFirstLine, ",", 3))]
    _ArrayAdd($asCSV, $sFileData, 0, ",")
    Return $asCSV ; Rückgabe des Arrays
EndFunc

Func _conIPprt()
  $sipPrinter = GUICtrlRead($mPrinterGuis[@GUI_WinHandle].idIPPrinters)
  MsgBox(16, "Error", $sipPrinter)
    ;$command2 = ('rundll32 printui.dll,PrintUIEntry /b "' & GUICtrlRead($typ) & '" /f "' & @scriptdir & '\' & $treiber & 'dlxbuzi.inf" /r "IP_'& GUICtrlRead($host) & ':" /m "' & GUICtrlRead($typ) & '" /if')
    ; $command2 = ('rundll32 printui.dll,PrintUIEntry /b '"EPSON XP-3150 Series"' /if /f "C:\Users\driver\Desktop\PRINTERMOD\IP-Drucker\Epson\EPPRNUT.INF" /r '"EP_192.168.178.49"' /u "')
    ;ConsoleWrite($command2)
    ;Run(@comspec & ' /c ' & $command2,'',@SW_SHOW)
EndFunc

Func _IPListNon() ;NON Printserver
If  IsArray($iList) = "" Then
       MsgBox(262144,"Title", "keine Netzerkdrucker verfügbar! ")
      else
       ;_ArrayDisplay($iList,  "sonstige IP Drucker", Default, 64)
        Local $iListModified = $iList
        _ArrayDelete($iListModified, 2) 
    _ArrayDisplay($iList,  "sonstige IP Drucker", Default, 64)    
      EndIF
EndFunc

Func _IPList()
      If  IsArray($aList) = "" Then
       MsgBox(262144,"Title", "keine Netzerkdrucker verfügbar! ")
      else
       _ArrayDisplay($aList, "IP-Liste Druckserver")
      EndIF
EndFunc


Func _conPrinter()
  Local $sText = GUICtrlRead($mPrinterGuis[@GUI_WinHandle].idNetworkPrinters)
  Local $var1 = 'Drucker' & " " & $sText & @CRLf & 'wird verbunden'
  Local $var2 = 'Drucker wurde verbunden und auf Standard gesetzt!'
    _SPText($Var1)
       RunWait(@SystemDir & "\RUNDLL32 PRINTUI.DLL,PrintUIEntry /in /n  " & '"' & "\\" & $sPrintServer & "\" & $sText & '"')
       RunWait(@SystemDir & "\RUNDLL32 PRINTUI.DLL,PrintUIEntry /q /y /n " & '"' & "\\" & $sPrintServer & "\" & $sText & '"')
    _updatePrinters($mPrinter)
    _SPText($Var2)
EndFunc

Func _SPText($var)
  SplashTextOn('', $Var, 300, 60, -1, -1, $DLG_NOTITLE)
  Sleep(2000)
  SplashOff()
EndFunc

Func _Refresh()
 _updatePrinters($mPrinter)
EndFunc


Func _addprt()
   Run(@ComSpec & " /c " & "Rundll32 shell32.dll,SHHelpShortcuts_RunDLL AddPrinter", "", @SW_HIDE)
EndFunc


Func _selPrinterLimitToOne()
    _GUICtrlListBox_SetCurSel(@GUI_CtrlId=$mPrinterGuis[@GUI_WinHandle].idConnectedPrinters?$mPrinterGuis[@GUI_WinHandle].idInstalledPrinters:$mPrinterGuis[@GUI_WinHandle].idConnectedPrinters, -1)
EndFunc

Func _updatePrinters($mPrinterGuiData)
    _updateDefaultPrinter($mPrinterGuiData.idDefaultPrinter)
    _updateInstalledPrinters($mPrinterGuiData.idInstalledPrinters)
    _updateConnectedPrinters($mPrinterGuiData.idConnectedPrinters)
    _updateNetworkPrinters($mPrinterGuiData.idNetworkPrinters, $mPrinterGuiData.idNoPrintServer)
EndFunc

Func _closePrinterGui()
    GUISetState(@SW_HIDE, $mPrinterGuis[@GUI_WinHandle].Gui)
EndFunc

Func _networkPrinterSelection()
    Local $sPrinter = GUICtrlRead($mPrinterGuis[@GUI_WinHandle].idNetworkPrinters)
    RunWait(@SystemDir & "\RUNDLL32 PRINTUI.DLL,PrintUIEntry /in /n  \\" & $sPrintServer &"\"& $sPrinter)
    RunWait(@SystemDir & "\RUNDLL32 PRINTUI.DLL,PrintUIEntry /q /y /n \\"  & $sPrintServer &"\"& $sPrinter)
    MsgBox('262144', "Default printer", "Default printer set to: " & $sPrinter)
EndFunc


Func _TestListbox(); Check which Listbox selected
    If GUICtrlRead($mPrinterGuis[@GUI_WinHandle].idInstalledPrinters) <> "" And GUICtrlRead($mPrinterGuis[@GUI_WinHandle].idConnectedPrinters) = "" Then
    If @error Then Return SetError(1, 0, -1)
        MsgBox(0, "", "Selection from Local Printer: ")
         $str = ""
    ElseIf GUICtrlRead($mPrinterGuis[@GUI_WinHandle].idConnectedPrinters) <> "" And GUICtrlRead($mPrinterGuis[@GUI_WinHandle].idInstalledPrinters) = "" Then
        MsgBox(0, "", "Selection from conPrinters: ")
          $str = $sPrintServer
          ;$sprinter=Sprintserver & mPrinter
    Else
       ; MsgBox(0, "", "No selection made.")
         If @error Then Return SetError(1, 0, -1)
     Return 1
    EndIf
EndFunc

Func _printExec($sCommand)
 _TestListbox()
    Local $sPrinter = _getSelectedPrinterAbs()
     If @error Then Return SetError(1, 0, -1)
    ConsoleWrite( "rundll32 printui.dll,PrintUIEntry /n " & $sPrinter & " "&$sCommand)
    RunWait( "rundll32 printui.dll,PrintUIEntry /n " & $sPrinter & " "&$sCommand, "", @SW_HIDE )
     If @error Then Return SetError(2, 0, -1)
    Return $sPrinter
EndFunc

Func _DeletePrinter()
    SoundPlay($sBeepFile)
      _TestListbox()
MsgBox(0, "", $str)
    ;_printExec("/p")
    Local $sPrinter = _getSelectedPrinterAbs()
  If @error Then Return SetError(1, 0, -1)
    
    if $str = "" Then
     RunWait(@SystemDir & "\RUNDLL32 PRINTUI.DLL,PrintUIEntry /dl /q /n " & $sPrinter) ;rundll32 printui.dll,PrintUIEntry /dn /q /n \\druck.xy.de\printername nur verbindung
     ConsoleWrite( "\RUNDLL32 PRINTUI.DLL,PrintUIEntry /dl /q /n " & $sPrinter)
    Else
     RunWait(@SystemDir & "\RUNDLL32 PRINTUI.DLL,PrintUIEntry /dn /q /n " & $sPrinter) ;rundll32 printui.dll,PrintUIEntry /dn /q /n \\druck.xy.de\printername nur verbindung
     ConsoleWrite( "\RUNDLL32 PRINTUI.DLL,PrintUIEntry /dn /q /n " & $sPrinter)
    EndIF
    
 If @error Then Return SetError(2, 0, -1)
    _updatePrinters($mPrinter)
    Return $sPrinter
EndFunc

Func _setDefaultPrinter()
    SoundPlay($sBeepFile)
    _TestListbox()
     Local $sPrinter = _getSelectedPrinterAbs()
      If @error Then Return SetError(1, 0, -1)
     RunWait(@SystemDir & "\RUNDLL32 PRINTUI.DLL,PrintUIEntry /q /y /n " & $sPrinter)
     ConsoleWrite("\RUNDLL32 PRINTUI.DLL,PrintUIEntry /q /y /n " & $sPrinter )
      If @error Then Return SetError(2, 0, -1)
    _updatePrinters($mPrinter)
    Return $sPrinter
EndFunc

Func _doTestPrint()
    SoundPlay($sBeepFile)
    Local $sPrinter = _printExec("/k")
     If Not @error Then MsgBox('262144', "TestDruck", "Der TestDruck wurde an den Drucker """ & _getSelectedPrinter() & """ abgeschickt!" & @CRLF & "Bitte überprüfen Sie den Ausdruck.")
EndFunc

Func DelPrintingqueue()
; net stop spooler
; del /Q /F %systemroot%\System32\spool\PRINTERS\*
; net start spooler
EndFunc

Func _openSettings()
    SoundPlay($sBeepFile)
    _printExec("/e")
EndFunc

Func _openPreferences()
    SoundPlay($sBeepFile)
    _printExec("/p")
EndFunc

Func _openQueue()
    SoundPlay($sBeepFile)
    _printExec("/o")
EndFunc

Func _openPrintFolder()
    SoundPlay($sBeepFile)
    Run("rundll32.exe shell32.dll,SHHelpShortcuts_RunDLL PrintersFolder")
EndFunc

; Returns the selected printer with the absolute path including \\ and the computer name
Func _getSelectedPrinterAbs()
    Local $sPrinter = _getSelectedPrinter()

    If @error Then Return SetError(1, 0, -1)
    ;idee: if Str0
    If $str = "" Then $sPrinter = '"\\' & @ComputerName & "\" & $sPrinter & '"'
    If $str = $sPrintServer Then $sPrinter = '"\\' & $sPrintServer & "\" & $sPrinter & '"'
     ; MsgBox(16, "Test3", $str)
    Return $sPrinter
EndFunc

Func _getSelectedPrinter()
    Local $sPrinter = GUICtrlRead($mPrinterGuis[@GUI_WinHandle].idInstalledPrinters)
    If $sPrinter = "" Then $sPrinter = GUICtrlRead($mPrinterGuis[@GUI_WinHandle].idConnectedPrinters)
    If $sPrinter = "" Then
        MsgBox(16, "Druckerauswahl", "Es wurde kein Drucker ausgewählt!")
        Return SetError(1, 0, -1)
    EndIf
    Return $sPrinter
EndFunc

Func _updateDefaultPrinter($idLabel)
    Local $sDefaultPrinter = _getDefaultPrinter()
    If @error Then Return SetError(2, @error, -1)
    GUICtrlSetData($idLabel, $sDefaultPrinter)
    Return 1
EndFunc

Func _updateInstalledPrinters($idList)
    _GUICtrlListBox_ResetContent($idList)
    Local $iCount = 1
    While True
        Local $sPrinterName = RegEnumKey("HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Print\Printers", $iCount)
        If @error = -1 Then ExitLoop
        $iCount+=1
        _GUICtrlListBox_AddString($idList, $sPrinterName)
    WEnd
    _GUICtrlListBox_SelectString($idList, _getDefaultPrinter())
    Return 1
EndFunc

Func _updateConnectedPrinters($idList)
    _GUICtrlListBox_ResetContent($idList)
    Local $iCount = 1
    While True
        Local $sPrinterName = RegEnumKey("HKEY_CURRENT_USER\Printers\Connections", $iCount)
        If @error = -1 Then ExitLoop
        $iCount+=1
         Local $arPrinter = StringSplit($sPrinterName, ",")
        If UBound($arPrinter)>1 Then _GUICtrlListBox_AddString($idList, $arPrinter[4])
    WEnd
    _GUICtrlListBox_SelectString($idList, _getDefaultPrinter())
    Return 1
EndFunc

Func _updateNetworkPrinters($idCombo, $idLabel)
    _GUICtrlComboBox_ResetContent($idCombo)
    Local $arPrinters = _getNetworkPrinters()
    If Not IsArray($arPrinters) Then
        GUICtrlSetState($idCombo, $GUI_HIDE)
        GUICtrlSetState($idLabel, $GUI_SHOW)
    Else
        GUICtrlSetState($idCombo, $GUI_SHOW)
        GUICtrlSetState($idLabel, $GUI_HIDE)
        For $i=1 To UBound($arPrinters)-1 Step 1
            If $arPrinters[$i][0] <> "" Then _GUICtrlComboBox_AddString($idCombo, $arPrinters[$i][0])
        Next
    EndIf
    Return 1
EndFunc


; Returns the name of the default printer;
; Errors:     1 - Registry entry could not be read
;             2 - Registry entry could not be parsed
Func _getDefaultPrinter()
    Local $sDefaultPrinter = RegRead( "HKEY_CURRENT_USER\Software\Microsoft\Windows NT\CurrentVersion\windows", "Device")
    If @error Then Return SetError(1, 0, -1)
    Local $arDefaultPrinter = StringSplit($sDefaultPrinter, ",")
    If UBound($arDefaultPrinter)>0 Then Return $arDefaultPrinter[1]
    Return SetError(2, 0, -1)
EndFunc

;-------------------------------------------------------------------------------------------------------------------
; Returns a 2D array with network printers: 0 name; 1 driverName; 2 portName; 3 Shared; 4 ShareName; 5 Published; 6 Local; 7 Location; 8 DeviceID; 9 DriverName
; Errors:     1 - Printserver file does not exist
;             2 - Printer query failed
;             3 - No printers found
Func _getNetworkPrinters()
    If Not FileExists("\\"&$sPrintServer&"\c$") Then Return SetError(1, 0, -1)

    Local $objWMIService = ObjGet("winmgmts:\\" & $sPrintServer & "\root\CIMV2")
    Local $colItems = $objWMIService.ExecQuery('SELECT * FROM Win32_Printer')
    If Not IsObj($colItems) Then Return SetError(2, 0, -1)
    If Not $colItems.count Then Return SetError(3, 0, -1) ; No Printer found
    Local $aPrinter[$colItems.count][10], $i = 0
    For $oItem In $colItems
        $aPrinter[$i][0] = $oItem.Name
        $aPrinter[$i][1] = $oItem.DriverName
        $aPrinter[$i][2] = $oItem.PortName
        $aPrinter[$i][3] = $oItem.Shared
        $aPrinter[$i][4] = $oItem.ShareName
        $aPrinter[$i][5] = $oItem.Published
        $aPrinter[$i][6] = $oItem.Local
        $aPrinter[$i][7] = $oItem.Location
        $aPrinter[$i][8] = $oItem.DeviceID
        $aPrinter[$i][9] = $oItem.DriverName
        $i += 1
    Next
    Return $aPrinter
     _ArrayDisplay($aPrinter)
EndFunc


EndFunc

Alles anzeigen

Ich hoffe das ist jetzt nicht das Riesenproblem, über entsprechendes Feedback würde ich mich sehr freuen.

LG und einen schönen Sonntag noch;)

casi4712

ok ich habs herausgefunden, war einfacher als ich dachte, für die die das selbe Problem haben, hier kurz das Vorgehen:

AutoIt

Func _conIPprt()
    Local $sipPrinter = GUICtrlRead($mPrinterGuis[@GUI_WinHandle].idIPPrinters)
    Local $aList = IPprt()
    Local $vbsScriptPath = "C:\Windows\SysWOW64\Printing_Admin_Scripts\de-DE\prnport.vbs"
    Local $printerPort = '9100'
    For $i = 1 To UBound($aList) - 1 ;read out TableValues
        If $aList[$i][0] & " - " & $aList[$i][1] = $sipPrinter Then
            $PrName = $aList[$i][0]
            $Port = $aList[$i][1]
            $ip = $aList[$i][2]
            $driver = $aList[$i][3]
            $pName = $aList[$i][4]
            $room = $aList[$i][5]
            $TS = $aList[$i][6]
            ExitLoop
        EndIf
    Next
  ;MsgBox(262144,"Driver", $driver)
     RunWait('cscript.exe "' & $vbsScriptPath & '" -a -r ' & $Port & ' -h ' & $IP & ' -o raw -n ' & $printerPort, "", @SW_HIDE) ;make port
     RunWait(@SystemDir & "\RUNDLL32 PRINTUI.DLL,PrintUIEntry /if /b " & '"' & $PrName & '" /f "' & $driver & '" /r "' & $Port & '" /m "' & $pName & '" /z') ; connect printer
     RunWait(@SystemDir & "\RUNDLL32 PRINTUI.DLL,PrintUIEntry /q /y /n " & '"' & $PrName & '"') ; make standard
    ; RunWait(@SystemDir & "\RUNDLL32 PRINTUI.DLL,PrintUIEntry /k /n " & '"' & $PrName & '"') ; Testdruck

EndFunc

Alles anzeigen

Frohe Pfingsten