Zeiten subtrahieren

wuff100

Moin,

diese Funktion addiert Zeiten in beliebiger Menge.

Ich möchte aber gern eine beliebige Menge Zeiten subtrahieren.

Könnt ihr mir helfen?

AutoIt

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <Array.au3>

Local $aInput[3] = ["01:30:00", "01:00:00", "01:00:00" ]
;~ _ArrayDisplay($aInput)

Local $Summe = _Timeradd($aInput)
Msgbox(1,"",$Summe)

Func _Timeradd($aInput)
    Local $aTemp
    Local $aTime[4]
    Local $sData, $iSec, $iMinCarry, $iMin, $iHrsCarry, $iHrs, $iDayCarry, $aTemp, $Sum
        For $i = 0 To UBound($aInput) - 1
        $sData = $aInput[$i]
        If $sData <> "" Then
;~             MsgBox(1, "", $sData)
            ;$aTemp = StringRegExp($sData, "(?:(\d*)\h)?(\d*):(\d*):(\d*)", 3); <- Alternative to StringSplit & _ArrayInsert below.
            $aTemp = StringSplit($sData, " :", 2)         ;   $STR_CHRSPLIT (0)  + $STR_NOCOUNT (2)
            If UBound($aTemp) = 3 Then _ArrayInsert($aTemp, 0, 0)
;~             _ArrayDisplay($aTemp)
            For $j = 0 To 3
                $aTime[$j] += Int($aTemp[$j])         ; Add all days, all hours, all mins, and, all secs.
            Next
        EndIf
    Next
;~     _ArrayDisplay($aTime)
    $iSec = Mod($aTime[3], 60)
    $iMinCarry = Int($aTime[3] / 60)
    $iMin = Mod($aTime[2] + $iMinCarry, 60)
    $iHrsCarry = Int(($aTime[2] + $iMinCarry) / 60)
    $iHrs = Mod(($aTime[1] + $iHrsCarry), 24)
;~     MsgBox(0, "Sum = ", StringFormat("%02i:%02i:%02i", $iHrs, $iMin, $iSec))
    $Sum = StringFormat("%02i:%02i:%02i", $iHrs, $iMin, $iSec)
    Return $Sum
EndFunc   ;==>_Timeradd

Alles anzeigen

Gruß

**water**

Sowas? Fehlerprüfungen fehlen noch.

C

#include <Array.au3>
#include <MsgBoxConstants.au3>

Local $aInput[] = ["01:30:00", "-01:15:00", "03:17:00"]
Local $Summe = _Timeradd($aInput)
MsgBox($MB_ICONINFORMATION, "Ergebnis", $Summe)

Func _Timeradd($aInput)
    Local $aTemp, $aTime[3], $sData, $iSec, $iMinCarry, $iMin, $iHrsCarry, $iHrs, $iDayCarry, $aTemp, $sSum, $iSign
    For $i = 0 To UBound($aInput) - 1
        $sData = $aInput[$i]
        If $sData <> "" Then
            $aTemp = StringSplit($sData, " :", 2)
            $iSign = 1
            If StringLeft($aTemp[0], 1) = "-" Then
                $iSign = -1
                $aTemp[0] = StringMid($aTemp[0], 2)
            EndIf
            For $j = 0 To 2
                $aTime[$j] += (Int($aTemp[$j]) * $iSign)         ; Add all days, all hours, all mins, and, all secs.
            Next
        EndIf
    Next
    $iSec = Mod($aTime[2], 60)
    $iMinCarry = Int($aTime[2] / 60)
    $iMin = Mod($aTime[1] + $iMinCarry, 60)
    $iHrsCarry = Int(($aTime[1] + $iMinCarry) / 60)
    $iHrs = Mod(($aTime[0] + $iHrsCarry), 24)
    $sSum = StringFormat("%02i:%02i:%02i", $iHrs, $iMin, $iSec)
    Return $sSum
EndFunc   ;==>_Timeradd

Alles anzeigen

wuff100

water, erstmal vielen Dank.

Versuche das mal.

Local $aInput[2] = ["02:30:00", "-01:30:00"]

MsgBox(1, "", _TimeAdd($aInput))

Der Wert müsste 01:00:00 ergeben.

**water**

Hab den Code in meinem vorigen Post angepasst.

Frage:

Was soll rauskommen, wenn die Stunden über 99 gehen?
Was soll rauskommen, wenn der Gesamtwert negativ wird?

wuff100

water, vielen Dank. Funktioniert super!

Zitat von water

Was soll rauskommen, wenn die Stunden über 99 gehen?
Was soll rauskommen, wenn der Gesamtwert negativ wird?

Das wird in meiner Anwendung nicht vorkommen.

wuff100

water, mir fiel noch ein Fehler auf.

Gebe bitte mal " $aInput[] = ["01:00:00", "-00:30:00"]" ein.

**Oscar**

Ich würde es so machen:

AutoIt

#include <Array.au3>

Local $aInput[] = ["01:30:00", "-00:30:00", "02:00:00", "-01:00:00"]
;~ _ArrayDisplay($aInput)

Local $Summe = _Timeradd($aInput)
Msgbox(1,"",$Summe)

Func _Timeradd(ByRef $aInput)
    Local $iSec
    For $i = 0 To UBound($aInput) - 1
        $iSec += _TimeToSec($aInput[$i])
    Next
    Return _SecToTime($iSec)
EndFunc

Func _TimeToSec(ByRef $sTime)
    Local $aTmp, $iSign, $iSec
    $iSign = (StringLeft($sTime, 1) == '-') ? -1 : 1
    $aTmp = StringSplit(StringRight($sTime, 8), ':', 2)
    $iSec = $aTmp[0] * 3600 + $aTmp[1] * 60 + $aTmp[2]
    Return $iSec * $iSign
EndFunc

Func _SecToTime($iSec)
    Local $iHour, $iMin, $iSign = $iSec < 0 ? '-' : ''
    $iHour = Int($iSec / 3600)
    $iSec = Mod($iSec, 3600)
    $iMin = Int($iSec / 60)
    $iSec = Mod($iSec, 60)
    Return $iSign & StringFormat('%02i:%02i:%02i', Abs($iHour), Abs($iMin), Abs($iSec))
EndFunc

Alles anzeigen

**water**

wuff100

Wirf meine Lösung weg - die von Oscar funktioniert perfekt

wuff100

Oscar , water, viele lieben Dank euch beiden.

Funktioniert hervorragend!