Outlookex Schriftgröße ändern

Windi

Moin zusammen,

Erst einmal ein Dankeschön an water für die tolle Umsetzung der Outlookex.

Jetzt zu meiner Frage?

Gibt es eine Möglichkeit die Schriftgröße im Body zu ändern.

Ich schreibe das Script für einen Kollegen der schwer Sehbehindert ist.

C

#include <Array.au3>
#include <MsgBoxConstants.au3>
#include <String.au3>
#include <OutlookEX.au3>

; Zum Testen bitte Mailadresse und den Outlook Ordner "*\\Paketversand\" ändern

Local   $arr  [6] [4]
 $arr  [0] [0]  =   "Artikel Nr."
 $arr  [0] [1]  =   "Stückzahl"
 $arr  [0] [2]  =   "Text"
 $arr  [0] [3]  =   "Größe"

For $i = 1 to 5
 $arr  [$i] [0]  =   "1"
 $arr  [$i] [1]  =   "10"
 $arr  [$i] [2]  =   "Schrauben"
 $arr  [$i] [3]  =   "M10"
Next

Local $AlleArtikel = _ArrayToString($arr, "  " )


; Outlook öffnen
Local $oOutlook = _OL_Open()
If @error <> 0 Then Exit MsgBox(16, "OutlookEX UDF", "Error creating a connection to Outlook. @error = " & @error & ", @extended = " & @extended)

; Ordner wählen (hier den Mailordner einfügen) "Paketversand"
Global $aFolder = _OL_FolderAccess($oOutlook, "*\\Paketversand\", $olFolderInbox)
If @error <> 0 Then Exit MsgBox(16, "OutlookEX UDF", "Error accessing PST. @error = " & @error & ", @extended = " & @extended)

; hier "[UnRead]=False" = alle gelesene Mails im Ordner - "[UnRead]=True" = alle ungelesene
Local $aItems = _OL_ItemFind($oOutlook, $aFolder[1], $olMail, "[UnRead]=True", "", "", "EntryID,Subject,Body", "", 1)

; Erstellen  das E-Mail-Element
Local $oItem = _OL_ItemCreate($oOutlook, $olMailItem, "*\\Paketversand\", "", _
 "Subject=Betreff", "BodyFormat=" & $olFormatHTML, "HTMLBody= <font size=7>" &$AlleArtikel &"</font>", "To=abc@gmx.de")

; Sende die Mail
_OL_ItemSend($oOutlook, $oItem)
If @extended = -2147352567 Then _
 MsgBox(16, "OutlookEX UDF - Example Script", "You don't have permission to send the mail on behalf of the specified person!")

; Outlookverbindung beenden
_OL_Close($oOutlook)

Alles anzeigen

Ich würde mich freuen wenn sich jemand meldet und mir hilft.

Viele Grüße

Werner

**Moombas**

Hallo Werner,

zunächst mal, außerhalb einer Funktion wird nicht "Local" definiert, sondern "Global", das empfehle ich schon mal zu ändern (oder das ganze in eine Funktion zu packen).

Zu deiner Frage: In Zeile 37 steht "font size", den Wert schon mal angepasst (von 7 auf z.B. 12)?

Windi

Hallo Moombas

Danke für deine schnelle Meldung.

Ich habe schon verschiedene Größen ausprobiert, es tut sich leider nichts.

Windi

Das Script ist auch nur zum Testen. (Global / Local)

Zum Ablauf folgendes:

Der Kollege bekommt aus seinem Shop eine Mail mit einer neuen Bestellung.

Ich soll jetzt die Mail auslesen und die Artikelnummern der Bestellung sortieren.

Eine neue Mail senden mit der geänderten Textgröße.

Der Shopinstaller kann es nicht, oder ist nicht bereit das zu ändern.

Die Mail ist nicht nur klein geschrieben, sondern auch noch ganz dünn, das ich schon Schwierigkeiten habe sie zu lesen.

Die Mail ist deshalb mit seiner Sehbehinderung nicht zu lesen.

Ich kann leider keine Original Daten einstellen.

Gruß Werner

**Moombas**

Also bei mir funktionierts.

Habe es zum Testen und für mehr Flexibilität aber in eine Funktion gepackt (Font Size 7 resultierte bei mir in Schriftgröße 36, font size 2 in Schriftgröße 10):

AutoIt

Opt('MustDeclareVars', 1)

#include <Array.au3>
#include <MsgBoxConstants.au3>
#include <String.au3>
#include <OutlookEX.au3>

; Zum Testen bitte Mailadresse und den Outlook Ordner "*\\Paketversand\" ändern

Global $AlleArtikel
Global $arr[6][4] = [["Artikel Nr.", "Stückzahl", "Text", "Größe"]]

For $i = 1 to 5
	$arr[$i][0]  =   "1"
	$arr[$i][1]  =   "10"
	$arr[$i][2]  =   "Schrauben"
	$arr[$i][3]  =   "M10"
Next
$AlleArtikel = _ArrayToString($arr, "  " )

_SendMail('anything@anything.com', 'Dein Betreff', 'Ordner', True, 2)


Func _SendMail(Const $To, Const $Subject, Const $MailFolder, Const $ReadMail = True, Const $FontSize = 7)
	; Outlook öffnen
Local $oOutlook = _OL_Open()
	If @error <> 0 Then Return MsgBox(16, "OutlookEX UDF", "Error creating a connection to Outlook. @error = " & @error & ", @extended = " & @extended)
	; Ordner wählen (hier den Mailordner einfügen) "Paketversand"
Local $aFolder = _OL_FolderAccess($oOutlook, "*\\" & $MailFolder & "\", $olFolderInbox)
	If @error <> 0 Then Return MsgBox(16, "OutlookEX UDF", "Error accessing PST. @error = " & @error & ", @extended = " & @extended)

	; hier "[UnRead]=False" = alle gelesene Mails im Ordner - "[UnRead]=True" = alle ungelesene
Local $aItems = _OL_ItemFind($oOutlook, $aFolder[1], $olMail, "[UnRead]=" & $ReadMail, "", "", "EntryID,Subject,Body", "", 1)

	; Erstelle das E-Mail-Element
Local $oItem = _OL_ItemCreate($oOutlook, $olMailItem, "*\\" & $MailFolder & "\", "", _
	"Subject=" & $Subject, "BodyFormat=" & $olFormatHTML, "HTMLBody= <font size=" & $FontSize & ">" & $AlleArtikel & "</font>", "To=" & $To)

	; Sende die Mail
	_OL_ItemSend($oOutlook, $oItem)
	If @extended = -2147352567 Then _
	Return MsgBox(16, "OutlookEX UDF - Example Script", "You don't have permission to send the mail on behalf of the specified person!")

	; Outlookverbindung beenden
	_OL_Close($oOutlook)
	Return True
EndFunc

Alles anzeigen

Edit:

Falls du die Schriftgröße in meinem Beispielcode lieber in px oder em angeben magst, Zeile 37 wie folgt ändern (als Beispiel):
"Subject=" & $Subject, "BodyFormat=" & $olFormatHTML, 'HTMLBody= ' & $AlleArtikel & "", "To=" & $To)
"Subject=" & $Subject, "BodyFormat=" & $olFormatHTML, 'HTMLBody= ' & $AlleArtikel & "", "To=" & $To)

Ich würde em nutzen, da dies dann auf der Default Schriftgröße basiert, sprich 1em = (in meinem Fall) Schriftgröße 11 in Outlook, wobei 2em dann natürlich Größe 22 ist und 1.5 in 16,5 resultiert. Das wäre somit berechenbar.

Hier daher ein abgewandeltes Beispiel mit Angabe der realen Schriftgröße (funktioniert nur wenn man die Defaultschriftgröße kennt und angibt!):

AutoIt

Opt('MustDeclareVars', 1)

#include <Array.au3>
#include <MsgBoxConstants.au3>
#include <String.au3>
#include <OutlookEX.au3>

; Zum Testen bitte Mailadresse und den Outlook Ordner "*\\Paketversand\" ändern

Global $AlleArtikel
Global $arr[6][4] = [["Artikel Nr.", "Stückzahl", "Text", "Größe"]]

For $i = 1 to 5
	$arr[$i][0]  =   "1"
	$arr[$i][1]  =   "10"
	$arr[$i][2]  =   "Schrauben"
	$arr[$i][3]  =   "M10"
Next
$AlleArtikel = _ArrayToString($arr, "  " )

_SendMail('anything@anything.com', 'Dein Betreff', 'Ordner', True, 15, 11)


Func _SendMail(Const $To, Const $Subject, Const $MailFolder, Const $ReadMail = True, $FontSize = 7, Const $DefaultFontsize = 11)
	; Outlook öffnen
Local $oOutlook = _OL_Open()
	If @error <> 0 Then Return MsgBox(16, "OutlookEX UDF", "Error creating a connection to Outlook. @error = " & @error & ", @extended = " & @extended)
	; Ordner wählen (hier den Mailordner einfügen) "Paketversand"
Local $aFolder = _OL_FolderAccess($oOutlook, "*\\" & $MailFolder & "\", $olFolderInbox)
	If @error <> 0 Then Return MsgBox(16, "OutlookEX UDF", "Error accessing PST. @error = " & @error & ", @extended = " & @extended)

	; hier "[UnRead]=False" = alle gelesene Mails im Ordner - "[UnRead]=True" = alle ungelesene
Local $aItems = _OL_ItemFind($oOutlook, $aFolder[1], $olMail, "[UnRead]=" & $ReadMail, "", "", "EntryID,Subject,Body", "", 1)

	; Erstelle das E-Mail-Element
	$FontSize = $FontSize / $DefaultFontsize
Local $oItem = _OL_ItemCreate($oOutlook, $olMailItem, "*\\" & $MailFolder & "\", "", _
	"Subject=" & $Subject, "BodyFormat=" & $olFormatHTML, 'HTMLBody= <p style="font-size:' & $FontSize & 'em">' & $AlleArtikel & "</p>", "To=" & $To)

	; Sende die Mail
	_OL_ItemSend($oOutlook, $oItem)
	If @extended = -2147352567 Then _
	Return MsgBox(16, "OutlookEX UDF - Example Script", "You don't have permission to send the mail on behalf of the specified person!")

	; Outlookverbindung beenden
	_OL_Close($oOutlook)
	Return True
EndFunc

Alles anzeigen

**water**

Probier mal:

"HTMLBody=" (ohne Leerzeichen)

oder

'HTMLBody=' die Schriftgröße in Anführungszeichen

**Moombas**

Nebenbei festgestellt beim Testen: Wenn Werte übergeben werden, womit Outlook nix anfangen kann wird immer die Default Schriftgröße genommen.

Windi

Habe gerade festgestellt auf Outlook 2007 funktioniert es nicht.

Auf Laptop mit Outlook 2021 geht beides.

Super vielen Dank euch beiden.

Nur aus Interesse

Code

Func _BoolToStr($bBool)

was bedeutet das?

Muss ich das Array zeilenweise auslesen um es tabellarisch zu gestalten.

Gruß Werner

**Moombas**

~~Weiß ich nicht, dafür ist die Funktion nicht da~~

Die Funktion ist im Beipiel mit drin und macht nur aus einem True (als Bool) ein True als Text/String bzw. aus einem False (Bool) ein False (String). Sonst würde das 1 bzw. 0 im String ergeben und somit nicht das was man braucht.
Braucht man in AutoIt nicht XD

Um eine Tabelle darzustellen, musst du dich html bedienen denke ich.

Ich schaue kurz ob ich da was bauen kann, ich nehme an anstatt des Textes?

Windi

Super Jetzt weiß ich genau so viel wie vorher

als Anfänger im hohen Alter.

Aber wir belassen es so, die Hauptsache es läuft so.

Zitat

Falls du die Schriftgröße in meinem Beispielcode lieber in px oder em angeben magst, Zeile 37 wie folgt ändern (als Beispiel):
"Subject=" & $Subject, "BodyFormat=" & $olFormatHTML, 'HTMLBody= ' & $AlleArtikel & "", "To=" & $To)
"Subject=" & $Subject, "BodyFormat=" & $olFormatHTML, 'HTMLBody= ' & $AlleArtikel & "", "To=" & $To)

Ich wollte eine Gui machen, wo er sich es selbst die Größe einstellen kann.

**Moombas**

Das geht auch mit der Funktion dann am einfachsten.

Hier mal das Beispiel mit der korrekten Tabelle:

AutoIt

Opt('MustDeclareVars', 1)

#include <Array.au3>
#include <MsgBoxConstants.au3>
#include <String.au3>
#include <OutlookEX.au3>

; Zum Testen bitte Mailadresse und den Outlook Ordner "*\\Paketversand\" ändern

Global $AlleArtikel
Global Const $Cols = 4, $Rows = 6
Global $arr[$Rows][$Cols] = [["Artikel Nr.", "Stückzahl", "Text", "Größe"]]

For $i = 1 to $Rows - 1
	$arr[$i][0]  =   "1"
	$arr[$i][1]  =   "10"
	$arr[$i][2]  =   "Schrauben"
	$arr[$i][3]  =   "M10"
Next
;~ $AlleArtikel = _ArrayToString($arr, "  " )

$AlleArtikel = '<table><tr>'
For $Col = 0 to $Cols - 1
	$AlleArtikel &= '<th>' & $arr[0][$Col] & '</th>'
Next
	$AlleArtikel &= '</tr>'

For $Row = 1 to $Rows - 1
	$AlleArtikel &= '<tr>'
	For $Col = 0 to $Cols - 1
		$AlleArtikel &= '<td>' & $arr[$Row][$Col] & '</td>'
	Next
	$AlleArtikel &= '</tr>'
Next
	$AlleArtikel &= '</table>'


_SendMail('anything@anything.com', 'Test', 'Ordner', True, 15, 11)


Func _SendMail(Const $To, Const $Subject, Const $MailFolder, Const $ReadMail = True, $FontSize = 7, Const $DefaultFontsize = 11)
	; Outlook öffnen
Local $oOutlook = _OL_Open()
	If @error <> 0 Then Return MsgBox(16, "OutlookEX UDF", "Error creating a connection to Outlook. @error = " & @error & ", @extended = " & @extended)
	; Ordner wählen (hier den Mailordner einfügen) "Paketversand"
Local $aFolder = _OL_FolderAccess($oOutlook, "*\\" & $MailFolder & "\", $olFolderInbox)
	If @error <> 0 Then Return MsgBox(16, "OutlookEX UDF", "Error accessing PST. @error = " & @error & ", @extended = " & @extended)

	; hier "[UnRead]=False" = alle gelesene Mails im Ordner - "[UnRead]=True" = alle ungelesene
Local $aItems = _OL_ItemFind($oOutlook, $aFolder[1], $olMail, "[UnRead]=" & $ReadMail, "", "", "EntryID,Subject,Body", "", 1)

	; Erstelle das E-Mail-Element
	$FontSize = $FontSize / $DefaultFontsize
Local $oItem = _OL_ItemCreate($oOutlook, $olMailItem, "*\\" & $MailFolder & "\", "", _
	"Subject=" & $Subject, "BodyFormat=" & $olFormatHTML, 'HTMLBody= <p style="font-size:' & $FontSize & 'em">' & $AlleArtikel & "</p>", "To=" & $To)

	; Sende die Mail
	_OL_ItemSend($oOutlook, $oItem)
	If @extended = -2147352567 Then _
	Return MsgBox(16, "OutlookEX UDF - Example Script", "You don't have permission to send the mail on behalf of the specified person!")

	; Outlookverbindung beenden
	_OL_Close($oOutlook)
	Return True
EndFunc

Alles anzeigen

Du musst halt ihm die Schriftgröße über die GUI auswählen lassen und den Wert hier anstelle der 15 übergeben: _SendMail('anything@anything.com', 'Test', 'Ordner', True, 15, 11)
Ersetze hierbei die 11 mit der Default Schriftgröße (fix im Script). An die Funktion Übergibst du 1. Den EMpfänger, 2. Den Betreff, 3. Der Mailordner, 4. gelesene/ungelesene Mails per True/False, 5. gewünschte Schriftgröße (lt. Outlook) 6. die Defaultschriftgröße in Outlook

Ergebnis:
:

Vergess die Funktion BoolToStr, AutoIt macht das von selbst XD Ich hatte das von einer anderen Programmiersprache noch so drin das selber machen zu müssen. Hab es daher mal überall raus genommen um Verwirrung zu vermeiden.

Windi

Muss jetzt erstmal wieder alles zusammen bauen.

Vielen Dank ich melde mich nochmal!

Gruß Werner

**Moombas**

Ich weiß nicht ob man die Defaultschriftgröße ggf. über Outlook ermitteln lassen kann. water weißt du das ggf.?

Bei mir passt das halt zu meiner Recherche mit Schriftgröße 11:

Windi

Ich habe hier große Probleme mit:

Wie kann ich die Spalten verschieben?

$AlleArtikel = '<table><tr>'
For $Col = 0 to $Cols - 1
$AlleArtikel &= '<th>' & $arr[0][$Col] & '</th>'
Next
$AlleArtikel &= '</tr>'

For $Row = 1 to $Rows - 1
$AlleArtikel &= '<tr>'
For $Col = 0 to $Cols - 1
$AlleArtikel &= '<td>' & $arr[$Row][$Col] & '</td>'
Next
$AlleArtikel &= '</tr>'
Next
$AlleArtikel &= '</table>'

**Moombas**

Was meinst du mit verschieben?

Das erstellt eine einfache HTML Tabelle (https://www.w3schools.com/html/html_tables.asp) dynamisch je nachdem wieviele Spalten/Zeilen vorhanden sind.
Für weitere Anpassungen (an welcher Position sie auftauchen soll etc.) musst du HTML code hinzufügen/ändern.

Ich bin aber wirklich kein Experte dafür daher weiß ich nicht ob ich dir dabei helfen kann, würde es aber versuchen.

Wie wäre es mit einem Bild oder Beispiel hier im Forum mit der Anordnung, wie du es haben willst.
Das muss dann halt in HTML umgesetzt werden.

Windi

Hallo Moombas

habs jetzt geschnallt das es HTML ist.

In meinem Alter brauch man ein bisschen länger.

Ich habe ein neues Problem!

War gestern bei meinem Kollegen, er hat noch Office 2003.

Wahrscheinlich wird es damit nicht funktionieren (glaube mal sowas gelesen zu haben).

Ich mache eine Testscript und probiere es damit.

Ich melde mich wieder sobald ich mehr weiß.

Vorerst vielen Dank für deine Mühe.

Gruß Werner

**Moombas**

Schau dir ggf. mal die Funktion _OL_Wrapper_SendMail an, die ist Bestandteil von der UDF und kann glaube ich mehr als das was ich dir bisher zusammengeschustert habe ()muss dann nur anders verpackt werden).
Wäre dann in etwa so:

AutoIt

Opt('MustDeclareVars', 1)

#include <Array.au3>
#include <MsgBoxConstants.au3>
#include <String.au3>
#include <OutlookEX.au3>

; Zum Testen bitte Mailadresse und den Outlook Ordner "*\\Paketversand\" ändern

Global $AlleArtikel, $FontSize = 15
Global Const $Cols = 4, $Rows = 6
Global $arr[$Rows][$Cols] = [["Artikel Nr.", "Stückzahl", "Text", "Größe"]]

For $i = 1 to $Rows - 1
	$arr[$i][0]  =   "1"
	$arr[$i][1]  =   "10"
	$arr[$i][2]  =   "Schrauben"
	$arr[$i][3]  =   "M10"
Next
;~ $AlleArtikel = _ArrayToString($arr, "  " )

$FontSize = $FontSize / 11
$AlleArtikel = '<table style="font-size:' & $FontSize & 'em"><tr>'
For $Col = 0 to $Cols - 1
	$AlleArtikel &= '<th>' & $arr[0][$Col] & '</th>'
Next
	$AlleArtikel &= '</tr>'

For $Row = 1 to $Rows - 1
	$AlleArtikel &= '<tr>'
	For $Col = 0 to $Cols - 1
		$AlleArtikel &= '<td>' & $arr[$Row][$Col] & '</td>'
	Next
	$AlleArtikel &= '</tr>'
Next
	$AlleArtikel &= '</table>'


Global $oOutlook = _OL_Open()
	If @error <> 0 Then Exit MsgBox(16, "OutlookEX UDF", "Error creating a connection to Outlook. @error = " & @error & ", @extended = " & @extended)
	_OL_Wrapper_SendMail($oOutlook, 'anything@anything.com', '', '', 'Dein Betreff', $AlleArtikel, '', $olFormatHTML, Default)
	_OL_Close($oOutlook)

Alles anzeigen

**water**

Die Wrapper-Funktionen meiner UDFs können meist weniger, da sie ja dazu gedacht sind, die einfachsten Anwendungsfälle mit einem einfachen Befehl abzudecken.

**Moombas**

In diesem Fall nicht unbedingt, da sie alles liefert was er braucht (soweit ich sehe). Der Rest passiert ja im HTML, der so oder so komplett generiert werden muss.

Windi

Ich danke Euch beiden.