GUI - dynamische Button mit Daten aus DB erstellen

gmmg

Hallo Zusammen,

ich sitze aktuell an einem Projekt, in dem es darum geht, unsere einzelnen Autologin Scripte (per Webdriver) in eine GUI zu bündeln.

Nun habe ich aus vorherigen Scripten folgenden Quellcode erstellt. Die Daten dazu kommen aktuell aus einer DB, im Beispiel mal eine MS Access.

Lässt sich der Bereich der Erstellung der dyn. Button schöner umsetzen?

Ein Besonderheit gibt es noch, wenn in Col3 (GUI) = 1 steht, soll vorher noch eine zweite GUI erstellt werden mit einem Dropdown Menü, da es bei verschiedenen Webseiten mehr wie 1 Zugang, also pro Agenturnummer gibt, aber das wäre erst der nächste Schritt.

AutoIt

#AutoIt3Wrapper_UseX64=y


#include <GUIConstantsEx.au3>
#include <GUIConstants.au3>
#include <Array.au3>
#include <D:\Scripte\MS_AccessCom\Access UDF\Access_UDF.au3>

local $URL_Array_pos

;--------- MSAccess DB ------------
$dbname = @ScriptDir & "\Data.accdb"

$tblname001 = "Websites"

Local $Connection = _Start_Connection($dbname & ";")

Local $URL_Array = _Get_Records("SELECT * FROM " & $tblname001 & " ;")

_Close_Connection()

IF _ArrayMax($URL_Array, 0, 1) = "" Then

	Exit
Else
	;MsgBox(0,"1",$DB_Array[1][0])
EndIf

_ArrayDisplay($URL_Array)

;~ For $i = 1 To UBound($URL_Array) -1
;~ 	MsgBox(0,"",$URL_Array[$i][1])
;~ Next

$GUI = GUICreate("Website AutoLogin  " & FileGetVersion(@ScriptName), 474, 257)

GUISetState(@SW_SHOW)

#Region ### Create Button dynamisch

$iCols = UBound($URL_Array)
;definiere dyn. Button
Local $Button[$iCols]

$Btn_Start = GUICtrlCreateDummy()
;MsgBox(0,"",$Btn_Start)

For $t = 1 to UBound($URL_Array) -1
	;-----------------------------------------------------------------
	; Button1
	IF $t = 1 Then
		$Button[$t] = GUICtrlCreateButton($URL_Array[$t][1], 30, 30, 130, 25)
		GUICtrlSetCursor($Button[$t], 0)
		$B1 = 1
	EndIf
	; Button2
	IF $t = 2 Then
		$Button[$t] = GUICtrlCreateButton($URL_Array[$t][1], 170, 30, 130, 25)
		GUICtrlSetCursor($Button[$t], 0)
		$B2 = 1
	EndIf
	; Button3
	IF $t = 3 Then
		$Button[$t] = GUICtrlCreateButton($URL_Array[$t][1], 310, 30, 130, 25)
		GUICtrlSetCursor($Button[$t], 0)
		$B3 = 1
	EndIf
	;-----------------------------------------------------------------
	; Button4
	IF $t = 4 Then
		$Button[$t] = GUICtrlCreateButton($URL_Array[$t][1], 30, 70, 130, 25)
		GUICtrlSetCursor($Button[$t], 0)
		$B4 = 1
	EndIf
	; Button5
	IF $t = 5 Then
		$Button[$t] = GUICtrlCreateButton($URL_Array[$t][1], 170, 70, 130, 25)
		GUICtrlSetCursor($Button[$t], 0)
		$B5 = 1
	EndIf
	; Button6
	IF $t = 6 Then
		$Button[$t] = GUICtrlCreateButton($URL_Array[$t][1], 310, 70, 130, 25)
		GUICtrlSetCursor($Button[$t], 0)
		$B6 = 1
	EndIf
	;-----------------------------------------------------------------
	; Button7
	IF $t = 7 Then
		$Button[$t] = GUICtrlCreateButton($URL_Array[$t][1], 30, 110, 130, 25)
		GUICtrlSetCursor($Button[$t], 0)
		$B7 = 1
	EndIf
	; Button8
	IF $t = 8 Then
		$Button[$t] = GUICtrlCreateButton($URL_Array[$t][1], 170, 110, 130, 25)
		GUICtrlSetCursor($Button[$t], 0)
		$B8 = 1
	EndIf
	; Button9
	IF $t = 9 Then
		$Button[$t] = GUICtrlCreateButton($URL_Array[$t][1], 310, 110, 130, 25)
		GUICtrlSetCursor($Button[$t], 0)
		$B9 = 1
	EndIf
	;-----------------------------------------------------------------
	; Button10
	IF $t = 10 Then
		$Button[$t] = GUICtrlCreateButton($URL_Array[$t][1], 30, 150, 130, 25)
		GUICtrlSetCursor($Button[$t], 0)
		$B10 = 1
	EndIf
	; Button11
	IF $t = 11 Then
		$Button[$t] = GUICtrlCreateButton($URL_Array[$t][1], 170, 150, 130, 25)
		GUICtrlSetCursor($Button[$t], 0)
		$B11 = 1
	EndIf
	; Button12
	IF $t = 12 Then
		$Button[$t] = GUICtrlCreateButton($URL_Array[$t][1], 310, 150, 130, 25)
		GUICtrlSetCursor($Button[$t], 0)
		$B12 = 1
	EndIf
	;-----------------------------------------------------------------
Next
;_ArrayDisplay($Button)

$Btn_End = GUICtrlCreateDummy()
;MsgBox(0,"",$Btn_End)
#EndRegion ### Create Button
GUISetState(@SW_SHOW)

While 1
	$msg = GUIGetMsg()
	Switch $msg

		Case $GUI_EVENT_MINIMIZE

		Case $GUI_EVENT_CLOSE
			Exit
			Case $Btn_Start To $Btn_End
				;MsgBox(0, "Test", GUICtrlRead($Msg))
				IF GUICtrlRead($Msg) = "Autoit" Then
					_search()
					;MsgBox(0,"Array Position",$URL_Array_pos)
					MsgBox(0,"URL",$URL_Array[$URL_Array_pos][2])

				EndIf

				IF GUICtrlRead($Msg) = "Heise" Then
					_search()
					;MsgBox(0,"Array Position",$URL_Array_pos)
					MsgBox(0,"URL",$URL_Array[$URL_Array_pos][2])

				EndIf

				IF GUICtrlRead($Msg) = "Test1" Then _search()

				IF GUICtrlRead($Msg) = "Test2" Then _search()

				IF GUICtrlRead($Msg) = "Test3" Then _search()

				IF GUICtrlRead($Msg) = "Test4" Then _search()

				IF GUICtrlRead($Msg) = "Test5" Then _search()

				IF GUICtrlRead($Msg) = "Test6" Then _search()

				IF GUICtrlRead($Msg) = "Test7" Then _search()

	EndSwitch
WEnd

Func _search()

	$URL_Array_pos = _ArraySearch($URL_Array, GUICtrlRead($Msg),  0, 0, 0, 0, 1, 1)
	;MsgBox(0,"Array Position",$URL_Array_pos)

EndFunc

Alles anzeigen

Danke und viele Grüße

Marcel

**Moombas**

Naja, du könntest mit Arrays arbeiten, das ist zwar Anfangs etwas Aufwändiger, final aber etwas schöner.

**Moombas**

Ich habe dir mal ein QuD Beispiel zusammengezimmert.

Du musst "nur" die Daten für die Buttons entsprechend in den Arrays pflegen: 1 für den angezeigten Text, 1 für den Link

AutoIt

Opt('MustDeclareVars', 1)
#AutoIt3Wrapper_UseX64=y


#include <GUIConstantsEx.au3>
#include <GUIConstants.au3>
#include <Array.au3>
;~ #include <D:\Scripte\MS_AccessCom\Access UDF\Access_UDF.au3>

Global $URL_Array_pos
Global $msg, $GUI1, $Button1[1] = [0]
Global Const $2DArrayWithButtonData[3][3] = [['R1B1','R1B2','R1B3'],['R2B1','R2B2','R2B3'], ['R3B1','R3B2','R3B3']] ; Texte
Global Const $1DArrayWithButtonLink[9]    = ['www.autoit.de','www.heise.de','www.Google.de','www.Google.de','www.Google.de','www.Google.de', 'www.Google.de','www.Google.de','www.Google.de']

_GUI_1_Create()

While 1
	$msg = GUIGetMsg()
	Switch $msg

		Case $GUI_EVENT_MINIMIZE

		Case $GUI_EVENT_CLOSE
			Exit
		Case 1 To $Button1[$Button1[0]]
			ShellExecute($1DArrayWithButtonLink[$msg + (1 - $Button1[1]) -1])
	EndSwitch
WEnd


Func _GUI_1_Create()
Local $ID
Local Const $BWidth  = 130
Local Const $BHeight = 25
Local Const $iCols = Ubound($2DArrayWithButtonData, $UBOUND_COLUMNS)
Local Const $iRows = Ubound($2DArrayWithButtonData, $UBOUND_ROWS)
Local Const $aCols = [2, 30, 140]
Local Const $aRows = [2, 30,  40]
	$GUI1 = GUICreate("Website AutoLogin  " & FileGetVersion(@ScriptName), 474, 257)
	#Region ### Create Button dynamisch

	For $Col = 1 to $iCols
		For $Row = 1 to $iRows
			$ID = GUICtrlCreateButton($2DArrayWithButtonData[$Row - 1][$Col - 1], $aCols[1] + (($Col-1)*$aCols[2]), $aRows[1] + (($Row-1)*$aRows[2]), $BWidth, $BHeight)
			_ArrayAdd($Button1, $ID, $Button1[0])
		Next
	Next
	$Button1[0] = UBound($Button1) - 1
	_ArrayDisplay($Button1)

	#EndRegion ### Create Button
	GUISetState(@SW_SHOW)
EndFunc

Alles anzeigen

gmmg

Danke, schau ich mir später mal an

**Moombas**

Hier nochmal eine leicht andere Variante um die Links zu speichern/erhalten:

AutoIt

Opt('MustDeclareVars', 1)
#AutoIt3Wrapper_UseX64=y


#include <GUIConstantsEx.au3>
#include <GUIConstants.au3>
#include <Array.au3>
;~ #include <D:\Scripte\MS_AccessCom\Access UDF\Access_UDF.au3>

Global $URL_Array_pos
Global $msg, $GUI1, $Button1[1] = [0]
Global Const $2DArrayWithButtonData[3][3] = [['R1B1','R1B2','R1B3'],['R2B1','R2B2','R2B3'], ['R3B1','R3B2','R3B3']] ; Texte
Global $2DArrayWithButtonLink[9][2]    = [['', 'www.autoit.de'], ['', 'www.heise.de'], ['', 'www.Google.de'], ['', 'www.Google.de'], ['', 'www.Google.de'], ['', 'www.Google.de'], ['', 'www.Google.de'], ['', 'www.Google.de'], ['', 'www.Google.de']]

_GUI_1_Create()

While 1
	$msg = GUIGetMsg()
	Switch $msg

		Case $GUI_EVENT_MINIMIZE

		Case $GUI_EVENT_CLOSE
			Exit
		Case 1 To $Button1[$Button1[0]]
			Shellexecute($2DArrayWithButtonLink[_ArraySearch($2DArrayWithButtonLink, $msg)][1])
	EndSwitch
WEnd


Func _GUI_1_Create()
Local $ID, $Counter = 0
Local Const $BWidth  = 130
Local Const $BHeight = 25
Local Const $iCols = Ubound($2DArrayWithButtonData, $UBOUND_COLUMNS)
Local Const $iRows = Ubound($2DArrayWithButtonData, $UBOUND_ROWS)
Local Const $aCols = [2, 30, 140]
Local Const $aRows = [2, 30,  40]
	$GUI1 = GUICreate("Website AutoLogin  " & FileGetVersion(@ScriptName), 474, 257)
	#Region ### Create Button dynamisch

	For $Col = 1 to $iCols
		For $Row = 1 to $iRows
			$ID = GUICtrlCreateButton($2DArrayWithButtonData[$Row - 1][$Col - 1], $aCols[1] + (($Col-1)*$aCols[2]), $aRows[1] + (($Row-1)*$aRows[2]), $BWidth, $BHeight)
			_ArrayAdd($Button1, $ID, $Button1[0])
			$2DArrayWithButtonLink[$Counter][0] = $ID
			$Counter += 1
		Next
	Next
	$Button1[0] = UBound($Button1) - 1
;~ 	_ArrayDisplay($Button1)
;~ 	_ArrayDisplay($2DArrayWithButtonLink)

	#EndRegion ### Create Button
	GUISetState(@SW_SHOW)
EndFunc

Alles anzeigen

gmmg

Moombas sieht nicht schlecht aus, die Links sollen nicht direkt geöffnet werden, sondern an den Webdriver für einen Autologin übergeben werden.

Die Texte und URL + Zugangsdaten sollen aus einer DB kommen. Das sollte sich aber dementsprechend anpassen lassen.

Danke

Gruß Marcel

**Moombas**

Das Shellexecute war nur zum Testen/veranschaulichen.

Auch musst du eine Access DB wieder einbinden und entsprechend die beiden Arrays (für die Namen bzw. Links) damit erstellen.

gmmg

Hab noch das Problem, dass das Script mit Row 0 anfängt die Button zu erzeugen und auch mit der Spalte ID, die ich nicht möchte.

AutoIt

Opt('MustDeclareVars', 1)
#AutoIt3Wrapper_UseX64=y

#include <GUIConstantsEx.au3>
#include <GUIConstants.au3>
#include <Array.au3>
#include <D:\Scripte\MS_AccessCom\Access UDF\Access_UDF.au3>

Global $URL_Array_pos, $dbname, $tblname001
Global $msg, $GUI1, $Button1[1] = [0]
Global Const $2DArrayWithButtonData[3][3] = [['R1B1','R1B2','R1B3'],['R2B1','R2B2','R2B3'], ['R3B1','R3B2','R3B3']] ; Texte
Global $2DArrayWithButtonLink[9][2]    = [['', 'www.autoit.de'], ['', 'www.heise.de'], ['', 'www.Google.de'], ['', 'www.Google.de'], ['', 'www.Google.de'], ['', 'www.Google.de'], ['', 'www.Google.de'], ['', 'www.Google.de'], ['', 'www.Google.de']]

;--------- MSAccess DB ------------
$dbname = @ScriptDir & "\Data.accdb"

$tblname001 = "Websites"

Local $Connection = _Start_Connection($dbname & ";")

Local $URL_Array = _Get_Records("SELECT * FROM " & $tblname001 & " ;")

_Close_Connection()

IF _ArrayMax($URL_Array, 0, 1) = "" Then

	Exit
Else
	;MsgBox(0,"1",$URL_Array[1][0])
EndIf

_ArrayDisplay($URL_Array)


_GUI_1_Create()

While 1
	$msg = GUIGetMsg()
	Switch $msg

		Case $GUI_EVENT_MINIMIZE

		Case $GUI_EVENT_CLOSE
			Exit
		Case 1 To $Button1[$Button1[0]]
			;Shellexecute($2DArrayWithButtonLink[_ArraySearch($2DArrayWithButtonLink, $msg)][1])
	EndSwitch
WEnd


Func _GUI_1_Create()

	Local $ID, $Counter = 0
	Local Const $BWidth  = 130
	Local Const $BHeight = 25
	;Local Const $iCols = Ubound($2DArrayWithButtonData, $UBOUND_COLUMNS)
	Local Const $iCols = Ubound($URL_Array, $UBOUND_COLUMNS)
	MsgBox(0,"",$iCols)
	;Local Const $iRows = Ubound($2DArrayWithButtonData, $UBOUND_ROWS)
	Local Const $iRows = Ubound($URL_Array, $UBOUND_ROWS)
	MsgBox(0,"",$iRows)
	Local Const $aCols = [2, 30, 140]
	Local Const $aRows = [2, 30,  40]
	$GUI1 = GUICreate("Website AutoLogin  " & FileGetVersion(@ScriptName), 474, 257)
	#Region ### Create Button dynamisch

	For $Col = 1 to $iCols
		For $Row = 1 to $iRows
			;$ID = GUICtrlCreateButton($2DArrayWithButtonData[$Row - 1][$Col - 1], $aCols[1] + (($Col-1)*$aCols[2]), $aRows[1] + (($Row-1)*$aRows[2]), $BWidth, $BHeight)
			$ID = GUICtrlCreateButton($URL_Array[$Row - 1][$Col - 1], $aCols[1] + (($Col-1)*$aCols[2]), $aRows[1] + (($Row-1)*$aRows[2]), $BWidth, $BHeight)
			_ArrayAdd($Button1, $ID, $Button1[0])
			;$2DArrayWithButtonLink[$Counter][0] = $ID
			$Counter += 1
		Next
	Next
	$Button1[1] = UBound($Button1) - 1
	;_ArrayDisplay($Button1)
	;_ArrayDisplay($2DArrayWithButtonLink)

	#EndRegion ### Create Button
	GUISetState(@SW_SHOW)

EndFunc

Alles anzeigen

Danke

Gruß Marcel

gmmg

wenn ich col und row bei 2 beginnen lasse stimmt in der GUI die xy Einteilung der Button nicht mehr. Sollte man eventuell die Daten aus dem Array in ein zweites schreiben, was dann nur die Spalte Name enthält?

**Moombas**

Im Prinzip könntest du sogar auf den Anzeige Text verzichten und nur den Link angeben in dem 2D Array.
Den Anzeigetext, würde ich dann per StringSplit() extrahieren und somit nur 1 zu pflegendes Array ergeben:

AutoIt

Opt('MustDeclareVars', 1)
#AutoIt3Wrapper_UseX64=y


#include <GUIConstantsEx.au3>
#include <GUIConstants.au3>
#include <Array.au3>
;~ #include <D:\Scripte\MS_AccessCom\Access UDF\Access_UDF.au3>

Global $URL_Array_pos
Global $msg, $GUI1, $Button1[1] = [0]
Global Const $2DArrayWithButtonData[3][3] = [['www.AutoIt.de','www.Heise.de','www.test1.de'],['www.test2.de','www.test3.de','www.test4.de'], ['www.test5.de','www.test6.de','www.test7.de']] ; Texte

_GUI_1_Create()

While 1
	$msg = GUIGetMsg()
	Switch $msg

		Case $GUI_EVENT_MINIMIZE

		Case $GUI_EVENT_CLOSE
			Exit
		Case 1 To $Button1[$Button1[0]]
			Shellexecute(_Search($msg))
	EndSwitch
WEnd


Func _GUI_1_Create()
Local $ID
Local Const $Offset = 0
Local Const $BWidth  = 130
Local Const $BHeight = 25
Local Const $iCols = Ubound($2DArrayWithButtonData, $UBOUND_COLUMNS)
Local Const $iRows = Ubound($2DArrayWithButtonData, $UBOUND_ROWS)
Local Const $aCols = [2, 30, 140]
Local Const $aRows = [2, 30,  40]
	$GUI1 = GUICreate("Website AutoLogin  " & FileGetVersion(@ScriptName), 474, 257)
	#Region ### Create Button dynamisch

	For $Col = 1 to $iCols
		For $Row = 1 to $iRows
			If $2DArrayWithButtonData[$Row - 1][$Col - 1] <> '' then
				$ID = GUICtrlCreateButton(StringSplit($2DArrayWithButtonData[$Row - 1][$Col - 1], '.')[2], $aCols[1] + (($Col-1)*$aCols[2]), $aRows[1] + (($Row-1)*$aRows[2]), $BWidth, $BHeight)
				_ArrayAdd($Button1, $ID, $Button1[0])
			EndIf
		Next
	Next
	$Button1[0] = UBound($Button1) - 1
;~ 	_ArrayDisplay($Button1)
;~ 	_ArrayDisplay($2DArrayWithButtonLink)

	#EndRegion ### Create Button
	GUISetState(@SW_SHOW)
EndFunc

Func _search($ID)
Local Const $Col = _ArraySearch($2DArrayWithButtonData, GUICtrlRead($msg), 0, 0, 0, 1, 0, Default, True)
Local Const $Row = _ArraySearch($2DArrayWithButtonData, GUICtrlRead($msg), 0, 0, 0, 1, 0, Default, False)
	Return $2DArrayWithButtonData[$Row][$Col]
EndFunc

Alles anzeigen

**Moombas**

Das liegt daran, das dies nicht vorgesehen ist.

Ich habe es so gemacht, das der erste Button auf 30, 30 gesetzt wird und dann immer 140 dazu addiert werden, halt dynamisch die Positionen gesetzt werden. Warum solltest du auf einmal bei 2 Anfangen?

Wenn das so ist (also immer), muss ein Offset eingetragen werden.

Also soll das immer bei 2 anfangen? oder gar variabel sein?
Ich denke das das bei meiner Variant nicht möglich wäre.

Ich denke eher das du dann die entsprechenden Daten im $2DArrayWithButtonData beim Befüllen behandeln musst.

gmmg

schau mal bitte den Screenshot vom Array #Post8 an.

Die Werte stehen da aus der DB im Array drin.

Hier möchte ich bei Col1 und Row 1 beginnen.

Da ich anhand der ID dann weitere Werte aus einer 2 Tabelle benötige, wäre die Frage ob man für die Buttons einfach ein bereinigtes Array erstellt.

**Moombas**

Das Problem ist das du dein Array mit den Daten aus der DB erst in das andere Umschreiben musst und nicht direkt verwenden kannst.

gmmg

Moombas ich war zu langsam, hatte meinen obigen Post nochmal editiert.

Also eigentlich müsste ich einmal das $URL_Array in ein zweites mit den Feldern bereinigt wegschreiben und dieses dann für die Button nutzen.

**AspirinJunkie**

Zitat von gmmg

Lässt sich der Bereich der Erstellung der dyn. Button schöner umsetzen?

Du kannst dir ja die Positionen und Größen des GUI anhand der Indizes der Elemente im Array berechnen:

AutoIt

#include <Array.au3>
#include <GUIConstantsEx.au3>

; zum leichteren Zugriff auf die Attribute im URL-Array
Global Enum $eID, $eName, $eURL, $eGUI

; Das Eingabearray
Global $aURLArray[][4] = [["ID", "Name", "URL", "GUI"], [1,"AutoIt","www.autoit.de", 0], [2,"Heise","www.heise.de", 1], [3,"Test1","www.test1.de", 0], [4,"Test2","www.test2.de", 0], [5,"Test3","www.test3.de", 0], [6,"Test4","www.test4.de", 0], [7,"Test5","www.test5.de", 1], [8,"Test6","www.test6.de", 0], [9,"Test7","www.test7.de", 0]]

; aus dem Array abgeleitete Parameter
Global $nEntries = UBound($aURLArray, 1) - 1

; Layout-Parameter (Größen und Abstände der Buttons)
Global $iCols  = 3, _                           ; Anzahl der Spalten der Buttons
$iRows         = Ceiling($nEntries / $iCols), _ ; Anzahl der Zeilen der Buttons
$iButtonWidth  = 80, _                         ; Breite eines Buttons
$iButtonHeight = 25, _                          ; Höhe eines Buttons
$iButtonXStep  = 20, _                          ; horizontaler Abstand der Buttons
$iButtonYStep  = 20, _                          ; vertikaler Abstand der Buttons
$iGUIWidth     = $iButtonXStep + $iCols * ($iButtonWidth + $iButtonXStep), _ ; Breite des GUI
$iGUIHeight    = $iButtonYStep + $iRows * ($iButtonHeight + $iButtonYStep)   ; Höhe des GUI

; das GUI erstellen
Opt("GUIOnEventMode", 1)
$GUI = GUICreate("Website AutoLogin  " & FileGetVersion(@ScriptName), $iGUIWidth, $iGUIHeight)
GUISetOnEvent($GUI_EVENT_CLOSE, _raus)

; Das Array durchgehen und die Buttons erstellen
Global $iPosX, $iPosY, $iButtonX, $iButtonY
For $i = 1 To $nEntries

	; die Koordinaten des Buttons in der Button-Matrix
	$iPosX = Mod($i - 1, $iCols)
	$iPosY = Ceiling($i / $iCols) - 1

	; die GUI-Koordinaten des Buttons
	$iButtonX = $iButtonXStep + $iPosX * ($iButtonWidth + $iButtonXStep)
	$iButtonY = $iButtonYStep + $iPosY * ($iButtonHeight + $iButtonYStep)

	; Den Button selbst erstellen
	GUICtrlCreateButton($aURLArray[$i][$eName], $iButtonX, $iButtonY, $iButtonWidth, $iButtonHeight)

	; Verknüpfe Button mit Funktion _search
	GUICtrlSetOnEvent(-1, _search)

Next

; GUI anzeigen
GUISetState(@SW_SHOW)

; Endlosschleife um GUI am Leben zu halten
Do
	Sleep(100)
Until 0

; eigene Funktion, welche beim Klick auf einen Button ausgelöst wird
Func _search()
	Local $sName = GUICtrlRead(@GUI_CtrlId)
	Local $iPos = _ArraySearch($aURLArray, $sName, 1, 0, 1, 0, 0, $eName)
	Local $sURL = $aURLArray[$iPos][$eURL]

	MsgBox(0,"Array Position", "Element: " & $sName & @CRLF & "Position: " & $iPos & @CRLF & "URL: " & $sURL)
EndFunc

; Funktion zum Beenden des GUI
Func _raus()
	Exit
EndFunc

Alles anzeigen

**Moombas**

Auch wenn AspirinJunkie hier die wohl bessere Variante gepostet hat, möchte ich meine angepasste (mit der Test DB als Array) hier nochmal kurz anbringen :

AutoIt

Opt('MustDeclareVars', 1)
#AutoIt3Wrapper_UseX64=y


#include <GUIConstantsEx.au3>
#include <GUIConstants.au3>
#include <Array.au3>
;~ #include <D:\Scripte\MS_AccessCom\Access UDF\Access_UDF.au3>

Global $URL_Array_pos
Global $msg, $GUI1, $Button1[1] = [0]
Global Const $ButtonCols = 3
Global $DBTESTARRAY[10][4] = [['ID',   'Name',           'URL', 'GUI'], _
							  [   1, 'Autoit', 'www.Autoit.de',     0], _
							  [	  2, 'Heise' , 'www.Heise.de' ,     1], _
							  [	  3, 'Test 1', 'www.test1.de' ,     0], _
							  [	  4, 'Test 2', 'www.test2.de' ,     0], _
							  [	  5, 'Test 3', 'www.test3.de' ,     0], _
							  [	  6, 'Test 4', 'www.test4.de' ,     0], _
							  [	  7, 'Test 5', 'www.test5.de' ,     1], _
							  [	  8, 'Test 6', 'www.test6.de' ,     0], _
							  [	  9, 'Test 7', 'www.test7.de' ,     0]]
Global $ButtonRows = Ceiling((Ubound($DBTESTARRAY) -1)/ $ButtonCols)
Global $2DArrayWithButtonData[$ButtonRows][$ButtonCols] ;= [['www.AutoIt.de','www.Heise.de','www.test1.de'],['www.test2.de','www.test3.de','www.test4.de'], ['www.test5.de','www.test6.de','www.test7.de']] ; Texte

_Data2Array($DBTESTARRAY)
_GUI_1_Create()

While 1
	$msg = GUIGetMsg()
	Switch $msg

		Case $GUI_EVENT_MINIMIZE

		Case $GUI_EVENT_CLOSE
			Exit
		Case 1 To $Button1[$Button1[0]]
			Shellexecute(_Search($2DArrayWithButtonData, $msg))
	EndSwitch
WEnd


Func _GUI_1_Create()
Local $ID
Local Const $BWidth  = 130
Local Const $BHeight = 25
Local Const $iCols = Ubound($2DArrayWithButtonData, $UBOUND_COLUMNS)
Local Const $iRows = Ubound($2DArrayWithButtonData, $UBOUND_ROWS)
Local Const $aCols = [2, 30, 140]
Local Const $aRows = [2, 30,  40]
	$GUI1 = GUICreate("Website AutoLogin  " & FileGetVersion(@ScriptName), 474, 257)
	#Region ### Create Button dynamisch

	For $Col = 1 to $iCols
		For $Row = 1 to $iRows
			If $2DArrayWithButtonData[$Row - 1][$Col - 1] <> '' then
				$ID = GUICtrlCreateButton(StringSplit($2DArrayWithButtonData[$Row - 1][$Col - 1], '.')[2], $aCols[1] + (($Col-1)*$aCols[2]), $aRows[1] + (($Row-1)*$aRows[2]), $BWidth, $BHeight)
				_ArrayAdd($Button1, $ID, $Button1[0])
			EndIf
		Next
	Next
	$Button1[0] = UBound($Button1) - 1
;~ 	_ArrayDisplay($Button1)
;~ 	_ArrayDisplay($2DArrayWithButtonLink)

	#EndRegion ### Create Button
	GUISetState(@SW_SHOW)
EndFunc

Func _Data2Array($aData)
Local $Colcounter = 0, $RowCounter = 0
Local Const $Col  = _ArraySearch($aData, 'URL', Default, Default, Default, Default, Default, Default, True)
Local Const $Rows = Ubound($aData) - 1
	_ArrayDisplay($aData)

	For $Row = 1 to $Rows
		$2DArrayWithButtonData[$RowCounter][$Colcounter] = $aData[$Row][$Col]
		$Colcounter += 1
		If $Colcounter >= $ButtonCols Then
			$Colcounter = 0
			$RowCounter += 1
		Endif
	Next
EndFunc

Func _search($aArray, $ID)
Local Const $Col = _ArraySearch($aArray, GUICtrlRead($ID), 0, 0, 0, 1, 0, Default, True)
Local Const $Row = _ArraySearch($aArray, GUICtrlRead($ID), 0, 0, 0, 1, 0, Default, False)
	Return $aArray[$Row][$Col]
EndFunc

Alles anzeigen

gmmg

AspirinJunkie und Moombas ,

danke für eure Beispiele. Beide Versionen gefallen mir gut.

Praktisch muss ich mich jetzt entscheiden

Mir fehlt jetzt noch die Umsetzung, wenn ich auf den Button drücke, soll abgefragt werden, ob bei GUI ein 0 oder 1 steht.

Wenn 1 dann soll eine 2 Gui erstellt werden mit einem Dropdown und weiteren Daten aus der DB.

Das erstellen der 2. GUI sollte aber nicht das Problem sein, das habe ich ja in den bestehen Scripten.

Beispiel:

**Moombas**

Im Prinzip müsstest du das so können (konzentriere mich nur auf den Search):

AutoIt

Case 1 To $Button1[$Button1[0]]
			If _Search2($DBTESTARRAY, $msg, 3) = 1 then _Create_GUI_2()
			Shellexecute(_Search($2DArrayWithButtonData, $msg))
;....
Func _search2($aArray, $ID, $Col)
Local Const $Row = _ArraySearch($aArray, GUICtrlRead($ID), 0, 0, 0, 1, 0, Default, False)
	Return $aArray[$Row][$Col]
EndFunc

GUI - dynamische Button mit Daten aus DB erstellen

Beitrag von Moombas (29. April 2024 um 13:30)

Beitrag von Alina (29. April 2024 um 15:03)