If verzweigung treibt mich in den Wahnsinn

hipfzwirgel

Hallo Gemeinde,

mit der nachfolgenden Funktion versuche ich auszulesen ob ein WWAN-Modul verbaut ist oder nicht:

Code

Func _CI_GetNetwork()

	$wbemFlagReturnImmediately = 0x10
	$wbemFlagForwardOnly = 0x20
	$colItems = ""
	$strComputer = "localhost"

	$objWMIService = ObjGet("winmgmts:\\.\root\StandardCimv2")
	Local $colItems = $objWMIService.ExecQuery("SELECT * FROM MSFT_NetAdapter")

	If IsObj($colItems) Then
		For $objItem In $colItems

			If $objItem.InterfaceType = 243 Then ; InterfaceType 243 ist für WWAN-Adapter
				
				Local $s_OutputWWAN = "WWAN Yes"

			Else

				Local $s_OutputWWAN = "WWAN No"

			EndIf

		Next
	Else

		MsgBox(0, "Error", "No network adapters found or query failed.")

	EndIf

	Return $s_OutputWWAN


EndFunc   ;==>_CI_GetNetwork

Alles anzeigen

Kann mir jemand den Fehler aufzeigen warum Die If-Verzweigung immer "WWAN No" zurückgibt obwohl ein WWAN-Modul verbeut ist. Debug von $objItem.InterfaceType ergibt 243

**BugFix**

Probier doch mal:

If $objItem.InterfaceType = "243"

hipfzwirgel

Hallo Bugfix,

hatte ich schon weil ich vermutete. dass die If den Datentyp nicht erkennt. Leider erfolglos.

hipfzwirgel

FEHLER GEFUNDEN:

Die Abfrage geht durch alle im Namespace aufgeführten Netzwerkadapter durch und der letzte Adapter ist eben KEIN WWAN-Modul.
Daher ergibt die If in letzter iteration immer false = else = "WWAN No"

Lösung(Exitloop):

Code

If $objItem.InterfaceType = 243 Then ; InterfaceType 243 ist für WWAN-Adapter
				
				Local $s_OutputWWAN = "WWAN Yes"
				Exitloop
			Else

				Local $s_OutputWWAN = "WWAN No"

			EndIf

**Kanashius**

Wenn du eh nur wissen willst, ob ein WWAN adapter vorhanden willst, würde ich es als Funktion mit Bool-Rückgabe implementieren. Macht das ganze kleiner und übersichtlicher.
Du kannst dabei auch stattdessen das erste gefundene WWAN adapter zurückgeben und damit weiterarbeiten.

AutoIt

If Not _CI_HasWWAN() Then MsgBox(0, "Error", "No network adapters found or query failed.")

Func _CI_HasWWAN()
	Local $objWMIService = ObjGet("winmgmts:\\.\root\StandardCimv2")
	Local $colItems = $objWMIService.ExecQuery("SELECT * FROM MSFT_NetAdapter")
	If IsObj($colItems) Then
		For $objItem In $colItems
			; InterfaceType 243 ist für WWAN-Adapter
			If $objItem.InterfaceType = 243 Then Return True ; maybe return $objItem, if you want the object itself
		Next
	EndIf
	Return False
EndFunc

Alles anzeigen

hipfzwirgel

Hallo Kanashius,

vielen lieben Dank für deinen Denkanstoß...

**Andy**

Hi,

eben gerade bei Hackaday drübergestolpert....https://hackaday.com/2024/08/07/com…-if-statements/

Und hier treibt eine einzige IF-Verzweigung in den Wahnsinn