Hilfe benötigt bei der Automatisierung des Dateiumbenennungsskripts in AutoIt

Elliana

Hallo zusammen,

Ich bin neu bei AutoIt und versuche, ein Skript zu erstellen, um das Umbenennen einer großen Anzahl von Dateien in einem Verzeichnis zu automatisieren. Das Ziel besteht darin, bestimmte Muster in Dateinamen durch neuen Text zu ersetzen. Ich möchte beispielsweise Dateinamen wie folgt ändern:

report_2023_final.txt → report_final_2023.txt
log_2023_backup.zip → backup_log_2023.zip

Ich habe mit String-Manipulationsfunktionen wie StringReplace() und StringSplit() experimentiert, aber ich habe Probleme, die Dateien in einem Ordner zu durchlaufen und diese Transformationen konsistent anzuwenden.

Das habe ich bisher erreicht:

AutoIt

#include <File.au3>

Local $folder = "C:\TestFiles"
Local $fileList = _FileListToArray($folder)

If @error Then
	MsgBox(0, "Error", "Failed to retrieve file list.")
	Exit
EndIf

For $i = 1 To $fileList[0]
	Local $oldName = $fileList[$i]
	; Logic to manipulate $oldName here
	; Replace placeholders with actual transformation
	Local $newName = StringReplace($oldName, "_2023_", "_") ; Attempt to rename file
	FileMove($folder & "\" & $oldName, $folder & "\" & $newName)
Next

Alles anzeigen

Das Skript scheint die Dateien korrekt abzurufen, aber meine Transformationen schlagen entweder fehl oder führen beim Umbenennen zu Fehlern. Ich wäre für jede Anleitung dankbar zu:

1. Strukturierung der Logik für komplexere Namenstransformationen.
2. Behandlung von Fehlern während des Umbenennungsprozesses (z. B. doppelte Namen).
3. Best Practices zum Testen solcher Skripte ohne Risiko eines Dateiverlusts.

Vielen Dank im Voraus für Ihre Hilfe! Ich freue mich darauf, von Ihrem Fachwissen zu lernen.

Grüße

Elli

Peter S. Taler · *Ab 19-10-22 ergänzt um:*

Du solltest zuerst die einzelnen Dateibezeichnungen bis zu den _ extrahieren und in Hilfsvariablen speichern, danach diese "Teile" nach Bedarf zusammensetzen. Als "Schutz" vor Dupletten, einen Zähler mitlaufen lassen und in den Dateinamen einbauen.

Peter

**Schnuffel**

Also,

erstmal:

Wenn ein Script eingestellt wird, dann bitte als Script in Code Tags und nict als Bild.

Und in der Signatur auf eine Marketingseite verlinken ist ein "no go"

Da das auch noch dein erster Post ist, gehe ich nicht davon aus dass du hier Hilfe suchst.

Peter S. Taler · *Ab 19-10-22 ergänzt um:*

Aber Schnuffel...Du solttest, noch dazu in der Weihnachtszeit, nicht immer nur das schlechte unterstellen...

Frohe Weihnachten

Peter

Ps: Zumal der TE ja schon reagiert hat...

**Kanashius**

Auch wenn reguläre Ausdrücke gerade für Anfänger schwerer sind, würde ich sie hier verwenden. Sie sind meiner Meinung nach die beste/einfachste Möglichkeit, sicherzustellen, dass ein Input genauso aussieht, wie man das will und im Zweifel ein Fehler geworfen wird.

AutoIt

; #include <Array.au3>

Local $arData = ["report_2023_final.txt", "log_2023_backup.zip", "log_2023_final_backup.zip", "log_2023_unknown.zip", "log_2023.zip", "log.zip", "log", "final", "other.txt"]
Local $mData[]

For $i=0 to UBound($arData)-1 Step 1
	; Array => 0: Full match, 1: type (report/log) (required), 2: year (or empty), 3+: other additions (e.g. final/backup), last: file extension
	Local $arSplit = StringRegExp($arData[$i], "(?|(report)|(log))(?:_(\d{4}))?(?:_)?((?:(?:_)?[a-zA-Z0-9]+)*)?\.(\S+)", 2)
	If @error Then
		ConsoleWrite("Error matching: "&$arData[$i]&@crlf)
		ContinueLoop
	EndIf
	; _ArrayDisplay($arSplit)
	Local $mEntry[]
	$mEntry["path"] = $arSplit[0]
	$mEntry["type"] = $arSplit[1]
	If $arSplit[2]<>"" Then $mEntry["year"] = $arSplit[2]
	If $arSplit[3]<>"" Then
		Local $arAddSplit = StringSplit($arSplit[3], "_", 1+2)
		For $j=0 to UBound($arAddSplit)-1 Step 1
			Switch $arAddSplit[$j]
				Case "final"
					$mEntry["final"] = True
				Case "backup"
					$mEntry["backup"] = True
				Case Else
					ConsoleWrite("Error with addition: "&$arAddSplit[$j]&" >> found in "&$arData[$i]&@crlf)
					ContinueLoop 2
			EndSwitch
		Next
	EndIf
	$mEntry["ext"] = $arSplit[UBound($arSplit)-1]
	MapAppend($mData, $mEntry)
Next

#cs
; Output for debugging
For $sKey in MapKeys($mData)
	Local $mTmp = $mData[$sKey]
	ConsoleWrite($sKey&": "&$mTmp.path&@crlf)
	ConsoleWrite(@TAB&"Type: "&$mTmp.type&@crlf)
	If MapExists($mTmp, "year") Then ConsoleWrite(@TAB&"Year: "&$mTmp.year&@crlf)
	If MapExists($mTmp, "final") Then ConsoleWrite(@TAB&"Final: "&$mTmp.final&@crlf)
	If MapExists($mTmp, "backup") Then ConsoleWrite(@TAB&"Backup: "&$mTmp.backup&@crlf)
	If MapExists($mTmp, "ext") Then ConsoleWrite(@TAB&"Extension: "&$mTmp.ext&@crlf)
Next
#ce

For $sKey in MapKeys($mData)
	Local $mEntry = $mData[$sKey]
	Local $sFilenameNew = ""
	If MapExists($mEntry, "backup") Then $sFilenameNew &= "backup_"
	$sFilenameNew &= $mEntry.type
	If MapExists($mEntry, "final") Then $sFilenameNew &= "_final"
	If MapExists($mEntry, "year") Then $sFilenameNew &= "_"&$mEntry.year
	$sFilenameNew &= "."&$mEntry.ext
	ConsoleWrite("Copy: "&$mEntry.path&" >> "&$sFilenameNew&@crlf)
	; FileMove($mEntry.path, $sFilenameNew, BitOR(0,8))
	; If @error Then ConsoleWrite("Copy failed: "&$mEntry.path&" >> "&$sFilenameNew&" >> "&@error&":"&@extended&@crlf)
Next

Alles anzeigen

Hier bin ich bei dem Ausdruck (?|(report)|(log))(?:_(\d{4}))?(?:_)?((?:(?:_)?[a-zA-Z0-9]+)*)?\.(\S+) davon ausgegangen, dass am Anfang immer der Typ der Datei steht (report/log/...); (optional) gefolgt von einem Jahr; (optional) gefolgt von Zusätzen, wie backup/final/... (mit _ getrennt) und am Ende der Dateiendung.
Wenn irgendetwas anderes auftaucht, wird ein Fehler ausgegeben und die Datei ignoriert (nicht kopiert/verschoben/gelöscht/...).

Gerade bei wichtigen Dateien würde ich aber immer auf einer Kopie arbeiten. Sind es zu viele Dateien um alle zu kopieren würde ich erst mit Teilen davon arbeiten und Testen und sicherstellen, dass alle Möglichkeiten abgedeckt sind.

Falls du noch Fragen hast, stell sie gerne

**Schnuffel**

ich will ja nicht nur negativ denken, also auch ein Vorschlag von mir ohne RegEx, die ja einen Anfänger doch ein wenig überfordern können.

AutoIt

#include <File.au3>

Global $folder = "C:\TestFiles"
Global $fileList = _FileListToArray($folder)

If @error Then
	MsgBox(0, "Error", "Failed to retrieve file list.")
	Exit
EndIf

Global $a1stString[3] = ['', 'backup', 'report'] ; Strings die an erster Stelle gefunden und eingesetzt werden sollen
Global $a2ndString[3] = ['', 'log', 'final'] ; Strings die an zweiter Stelle gefunden und eingesetzt werden sollen
Global $a3rdString[3] = ['', '2023', '2024'] ; Strings die an dritter Stelle gefunden und eingesetzt werden sollen
Global $NewName, $aoldName, $nCheck

For $i = 1 To $fileList[0]
	$NewName = ""
	; Logic to manipulate $oldName here
	; Replace placeholders with actual transformation
	$aoldName = StringSplit($fileList[$i], '_')
	If @error = 0 Then
		If $aoldName[0] > 2 Then ; mind. 2 "_" vorhanden
			;Nach dem ersten Teil des künftigen Dateinamens suchen
			For $j = 0 To UBound($a1stString) - 1
				If _ArraySearch($aoldName, $a1stString[$j], 0, 0, 0, 1) <> -1 Then
					$NewName = $a1stString[$j] & '_'
					$nCheck = 1
				EndIf
			Next
			If $NewName = "" Then ContinueLoop
			;Nach dem zweiten Teil des künftigen Dateinamens suchen
			For $j = 0 To UBound($a2ndString) - 1
				If _ArraySearch($aoldName, $a2ndString[$j], 0, 0, 0, 1) <> -1 Then
					$NewName &= $a2ndString[$j] & '_'
					$nCheck &= 2
				EndIf
			Next
			;Nach dem dritten Teil des künftigen Dateinamens suchen
			For $j = 0 To UBound($a3rdString) - 1
				If _ArraySearch($aoldName, $a3rdString[$j], 0, 0, 0, 1) <> -1 Then
					$NewName &= $a3rdString[$j]
					$nCheck &= 3
				EndIf
			Next
			If $nCheck = '123' Then
				$aExt = StringSplit($aoldName[$aoldName[0]], '.')
				$NewName &= "." & $aExt[2]
			Else
				ContinueLoop
			EndIf
		EndIf
		ConsoleWrite($NewName & @CRLF)
		;FileMove($folder & "\" & $oldName, $folder & "\" & $newName)
	EndIf
Next

Alles anzeigen

Peter S. Taler · *Ab 19-10-22 ergänzt um:*

Ich verstehe das Problem ein wenig anders. Aber das muss der TE entscheiden.

Er schreibt.. als Beispiel....

report_2023_final.txt → report_final_2023.txt
log_2023_backup.zip → backup_log_2023.zip

das bedeutet nicht dass nicht auch xyz_2023_abc.doc existieren könnte.

Wie ich das verstehe sind nur die _ beständig. Daher würde ich die Position der Unterstriche feststellen und die "Namensteile" davor, dazwischen und danach extrahieren. Diese kann man dann ersetzen umstellen usw.

Um das Prog flexibel zu halten ---> Trenner in die *.ini dann kann man das anpassen.

Frohe Weihnachten

Peter

**Moombas**

Hmm,

ich finde Kanashius Lösung zwar schön von der herangehensweise, jedoch wären dort aus meiner Sicht 2 Sachen nicht erfüllt:

1. Die Reihenfolge der Dateinamensbestandteile (Log, backup,...) ändert sich, das lässt sich aber recht leicht im letzen Block neu anordnen.
2. Eine Prüfung ob der neue Dateiname bereits existiert (und ggf. ergänzen durch fortlaufende Nummer, das wurde nicht weiter erläutert in der Anfrage was gemacht werden soll).
Hierfür müsste eine weitere Schleife in den letzten Block eingefügt werden, die das entsprechend prüft und hoch zählt und den entsprechenden counter dann im Dateinamen einfügt.

Oscar 24. Dezember 2024 um 12:56