_WinAPI_ShellChangeNotifyRegister 64bit - Absturz

**Tweaky**

Hi,
ich möchte mit "_WinAPI_ShellChangeNotifyRegister" feststellen, ob ein Ordner existiert oder nicht.

C

#Region    ;************ Includes ************
#include <WinAPISysWin.au3>
#include <WinAPIShellEx.au3>
#EndRegion ;************ Includes ************
#AutoIt3Wrapper_UseX64=Y ;32bit funktioniert / 64bit funktioniert nicht

Global $aTest[2] = ["C:\_test\", "C:\_test2\"]

DirCreate($aTest[0])
DirCreate($aTest[1])

OnAutoItExitRegister('OnAutoItExit')

Local $hWnd = GUICreate('')
Local $iMsg = _WinAPI_RegisterWindowMessage('SHELLCHANGENOTIFY')
GUIRegisterMsg($iMsg, 'WM_SHELLCHANGENOTIFY')
Global $g_iID = _WinAPI_ShellChangeNotifyRegister($hWnd, $iMsg, $SHCNE_ALLEVENTS, BitOR($SHCNRF_INTERRUPTLEVEL, $SHCNRF_SHELLLEVEL, $SHCNRF_RECURSIVEINTERRUPT), $aTest, 1)
If @error Then
	MsgBox(($MB_ICONERROR + $MB_SYSTEMMODAL), 'Fehler', 'Das Fenster wurde nicht registriert.')
	Exit
EndIf

While 1
	Sleep(1000)
WEnd

Func WM_SHELLCHANGENOTIFY($hWnd, $iMsg, $wParam, $lParam)
	#forceref $hWnd, $iMsg

	Local $sPath = _WinAPI_ShellGetPathFromIDList(DllStructGetData(DllStructCreate('dword Item1; dword Item2', $wParam), 'Item1'))
	If $sPath Then
		ConsoleWrite('Event: 0x' & Hex($lParam) & ' | Pfad: ' & $sPath & @CRLF)
	Else
		ConsoleWrite('Event: 0x' & Hex($lParam) & @CRLF)
	EndIf
EndFunc   ;==>WM_SHELLCHANGENOTIFY

Func OnAutoItExit()
	If $g_iID Then
		_WinAPI_ShellChangeNotifyDeregister($g_iID)
	EndIf
EndFunc   ;==>OnAutoItExit

Alles anzeigen

Code

!>14:34:01 AutoIt3.exe ended.rc:-1073741819

Mit #AutoIt3Wrapper_UseX64=N startet das Skript und registriert auch Änderungen, wenn der Ordner umbenannt wird.
Mit #AutoIt3Wrapper_UseX64=Y stürzt das Skript direkt ab.

**Oscar**

Ich habe das mal auf 64 Bit angepasst:

AutoIt

#Region    ;************ Includes ************
#include <WinAPISysWin.au3>
#include <WinAPIShellEx.au3>
#EndRegion ;************ Includes ************
#AutoIt3Wrapper_UseX64=y ;32bit funktioniert / 64bit funktioniert

Global $aTest[2] = ["C:\_test\", "C:\_test2\"]

DirCreate($aTest[0])
DirCreate($aTest[1])

OnAutoItExitRegister('OnAutoItExit')
ConsoleWrite((@AutoItX64 ? 4 : 2) & @CRLF)

Local $hWnd = GUICreate('')
Local $iMsg = _WinAPI_RegisterWindowMessage('SHELLCHANGENOTIFY')
GUIRegisterMsg($iMsg, 'WM_SHELLCHANGENOTIFY')
Global $g_iID = _WinAPI_ShellChangeNotifyRegister64($hWnd, $iMsg, $SHCNE_ALLEVENTS, BitOR($SHCNRF_INTERRUPTLEVEL, $SHCNRF_SHELLLEVEL, $SHCNRF_RECURSIVEINTERRUPT), $aTest, 1)
If @error Then
	MsgBox(($MB_ICONERROR + $MB_SYSTEMMODAL), 'Fehler', 'Das Fenster wurde nicht registriert.')
	Exit
EndIf

While 1
	Sleep(1000)
WEnd

Func WM_SHELLCHANGENOTIFY($hWnd, $iMsg, $wParam, $lParam)
	#forceref $hWnd, $iMsg
	Local $tIDL = DllStructCreate((@AutoItX64 ? 'uint64 Item1; uint64 Item2' : 'dword Item1; dword Item2'), $wParam) ; bei 64 Bit ist das ein QWord (4 Byte)
	Local $sPath = _WinAPI_ShellGetPathFromIDList(DllStructGetData($tIDL, 'Item1'))
	If $sPath Then
		ConsoleWrite('Event: 0x' & Hex($lParam) & ' | Pfad: ' & $sPath & @CRLF)
	Else
		ConsoleWrite('Event: 0x' & Hex($lParam) & @CRLF)
	EndIf
EndFunc   ;==>WM_SHELLCHANGENOTIFY

Func OnAutoItExit()
	If $g_iID Then
		_WinAPI_ShellChangeNotifyDeregister($g_iID)
	EndIf
EndFunc   ;==>OnAutoItExit

Func _WinAPI_ShellChangeNotifyRegister64($hWnd, $iMsg, $iEvents, $iSources, $aPaths, $bRecursive = False)
	Local $iPath = $aPaths, $tagStruct = ''

	If IsArray($aPaths) Then
		If UBound($aPaths, $UBOUND_COLUMNS) Then Return SetError(1, 0, 0)
	Else
		Dim $aPaths[1] = [$iPath]
	EndIf
	For $i = 0 To UBound($aPaths) - 1
		If Not _WinAPI_PathIsDirectory($aPaths[$i]) Then Return SetError(2, 0, 0)
	Next
	For $i = 0 To UBound($aPaths) - 1
		$tagStruct &= 'ptr;int;'
	Next
	Local $tEntry = DllStructCreate($tagStruct)
	For $i = 0 To UBound($aPaths) - 1
		$aPaths[$i] = _WinAPI_ShellILCreateFromPath(_WinAPI_PathSearchAndQualify($aPaths[$i]))
		DllStructSetData($tEntry, (@AutoItX64 ? 4 : 2) * $i + 1, $aPaths[$i]) ; bei 64Bit ist PIDLIST_ABSOLUTE = 64 Bit (4 Byte)
		DllStructSetData($tEntry, (@AutoItX64 ? 4 : 2) * $i + 2, $bRecursive)
	Next

	Local $iError = 0
	Local $aCall = DllCall('shell32.dll', 'ulong', 'SHChangeNotifyRegister', 'hwnd', $hWnd, 'int', $iSources, 'long', $iEvents, _
			'uint', $iMsg, 'int', UBound($aPaths), 'struct*', $tEntry)
	If @error Or Not $aCall[0] Then $iError = @error + 10

	For $i = 0 To UBound($aPaths) - 1
		_WinAPI_CoTaskMemFree($aPaths[$i])
	Next

	Return SetError($iError, 0, $aCall[0])
EndFunc   ;==>_WinAPI_ShellChangeNotifyRegister

Alles anzeigen

**Tweaky**

Wow danke sieht sehr gut aus.
Allerdings stürzt es bei 4 und mehr Ordnern ab.

C

#Region    ;************ Includes ************
#include <Array.au3>
#include <WinAPISysWin.au3>
#include <WinAPIShellEx.au3>
#EndRegion ;************ Includes ************
#AutoIt3Wrapper_UseX64=y

;~ Global $aTest[3] = ["C:\test\", "C:\_test2\", "C:\_test3\"] ;funktioniert
Global $aTest[4] = ["C:\test\", "C:\_test2\", "C:\_test3\", "C:\_test4\"] ;funktioniert nicht

For $i = 0 To UBound($aTest) - 1
	DirCreate($aTest[$i])
Next

OnAutoItExitRegister('OnAutoItExit')
ConsoleWrite((@AutoItX64 ? 4 : 2) & @CRLF)

Local $hWnd = GUICreate('')
Local $iMsg = _WinAPI_RegisterWindowMessage('SHELLCHANGENOTIFY')
GUIRegisterMsg($iMsg, 'WM_SHELLCHANGENOTIFY')
Global $g_iID = _WinAPI_ShellChangeNotifyRegister64($hWnd, $iMsg, $SHCNE_ALLEVENTS, BitOR($SHCNRF_INTERRUPTLEVEL, $SHCNRF_SHELLLEVEL, $SHCNRF_RECURSIVEINTERRUPT), $aTest, 1)
If @error Then
	MsgBox(($MB_ICONERROR + $MB_SYSTEMMODAL), 'Fehler', 'Das Fenster wurde nicht registriert.')
	Exit
EndIf

While 1
	Sleep(1000)
WEnd

Func WM_SHELLCHANGENOTIFY($hWnd, $iMsg, $wParam, $lParam)
	#forceref $hWnd, $iMsg
	Local $tIDL = DllStructCreate((@AutoItX64 ? 'uint64 Item1; uint64 Item2' : 'dword Item1; dword Item2'), $wParam) ; bei 64 Bit ist das ein QWord (4 Byte)
	Local $sPath = _WinAPI_ShellGetPathFromIDList(DllStructGetData($tIDL, 'Item1'))
	If $sPath Then
		ConsoleWrite('Event: 0x' & Hex($lParam) & ' | Pfad: ' & $sPath & @CRLF)
	Else
		ConsoleWrite('Event: 0x' & Hex($lParam) & @CRLF)
	EndIf
EndFunc   ;==>WM_SHELLCHANGENOTIFY

Func OnAutoItExit()
	If $g_iID Then
		_WinAPI_ShellChangeNotifyDeregister($g_iID)
	EndIf
EndFunc   ;==>OnAutoItExit

Func _WinAPI_ShellChangeNotifyRegister64($hWnd, $iMsg, $iEvents, $iSources, $aPaths, $bRecursive = False)
	Local $iPath = $aPaths, $tagStruct = ''

	If IsArray($aPaths) Then
		If UBound($aPaths, $UBOUND_COLUMNS) Then Return SetError(1, 0, 0)
	Else
		Dim $aPaths[1] = [$iPath]
	EndIf
	For $i = 0 To UBound($aPaths) - 1
		If Not _WinAPI_PathIsDirectory($aPaths[$i]) Then Return SetError(2, 0, 0)
	Next
	For $i = 0 To UBound($aPaths) - 1
		$tagStruct &= 'ptr;int;'
	Next
	Local $tEntry = DllStructCreate($tagStruct)
	For $i = 0 To UBound($aPaths) - 1
		$aPaths[$i] = _WinAPI_ShellILCreateFromPath(_WinAPI_PathSearchAndQualify($aPaths[$i]))
		DllStructSetData($tEntry, (@AutoItX64 ? 4 : 2) * $i + 1, $aPaths[$i]) ; bei 64Bit ist PIDLIST_ABSOLUTE = 64 Bit (4 Byte)
		DllStructSetData($tEntry, (@AutoItX64 ? 4 : 2) * $i + 2, $bRecursive)
	Next

	Local $iError = 0
	Local $aCall = DllCall('shell32.dll', 'ulong', 'SHChangeNotifyRegister', 'hwnd', $hWnd, 'int', $iSources, 'long', $iEvents, _
			'uint', $iMsg, 'int', UBound($aPaths), 'struct*', $tEntry)
	If @error Or Not $aCall[0] Then $iError = @error + 10

	For $i = 0 To UBound($aPaths) - 1
		_WinAPI_CoTaskMemFree($aPaths[$i])
	Next

	Return SetError($iError, 0, $aCall[0])
EndFunc   ;==>_WinAPI_ShellChangeNotifyRegister64

Alles anzeigen

Velted

Moin,

frohes neues Jahr! Hoffen wir mal, dass sich der Temperaturanstieg in 2025 gegenüber 2023 und 2024 wieder umkehrt und weniger Flächen überflutet werden.

Zum Thema:

Code

For $i = 0 To UBound($aPaths) - 1
		$aPaths[$i] = _WinAPI_ShellILCreateFromPath(_WinAPI_PathSearchAndQualify($aPaths[$i]))
		DllStructSetData($tEntry, (@AutoItX64 ? 4 : 2) * $i + 1, $aPaths[$i]) ; bei 64Bit ist PIDLIST_ABSOLUTE = 64 Bit (4 Byte)
		DllStructSetData($tEntry, (@AutoItX64 ? 4 : 2) * $i + 2, $bRecursive)
Next

Ich denke, dass sich der Feldindex (@AutoItX64 ? 4 : 2) * $i + 1 von 32- zu 64-Bit nicht ändert.

**Oscar**

Zitat von Velted

Ich denke, dass sich der Feldindex (@AutoItX64 ? 4 : 2) * $i + 1 von 32- zu 64-Bit nicht ändert.

Ja, das war falsch!

Der Feldindex bleibt gleich, auch wenn das damit funktioniert hat (warum versuche ich gerade rauszukriegen).

Velted

Hallo Oscar ,

das ist eine von den 'Shell-Ausrichtungsfallen'. Die Struktur SHChangeNotifyEntry ist in ShlObj_core.h definiert. Da steht am Anfang ein
#include <pshpack1.h> /* Assume byte packing throughout */,
das auch für die Struktur gilt und ein 'Byte-Packing' erzwingt.

Deshalb:

Code

Func _WinAPI_ShellChangeNotifyRegister64($hWnd, $iMsg, $iEvents, $iSources, $aPaths, $bRecursive = False)
    Local $iPath = $aPaths, $tagStruct = 'align 1;' ; <<<<<<<<<<

**Oscar**

Zitat von Velted

das ist eine von den 'Shell-Ausrichtungsfallen'. Die Struktur SHChangeNotifyEntry ist in ShlObj_core.h definiert. Da steht am Anfang ein
#include <pshpack1.h> /* Assume byte packing throughout */,
das auch für die Struktur gilt und ein 'Byte-Packing' erzwingt.

Ah! Vielen Dank!

So funktioniert es dann:

AutoIt

#Region    ;************ Includes ************
#include <WinAPISysWin.au3>
#include <WinAPIShellEx.au3>
#EndRegion ;************ Includes ************
#AutoIt3Wrapper_UseX64=y ;32bit funktioniert / 64bit funktioniert

Global $aTest[] = ["C:\_test\", "C:\_test2\", "C:\_test3\", "C:\_test4\"]

For $i = 0 To UBound($aTest) - 1
	DirCreate($aTest[$i])
Next

OnAutoItExitRegister('OnAutoItExit')
HotKeySet('{ESC}', '_End')

Global $hWnd = GUICreate('')
Global $iMsg = _WinAPI_RegisterWindowMessage('SHELLCHANGENOTIFY')
GUIRegisterMsg($iMsg, 'WM_SHELLCHANGENOTIFY')
Global $g_iID = _WinAPI_ShellChangeNotifyRegister64($hWnd, $iMsg, $SHCNE_ALLEVENTS, BitOR($SHCNRF_INTERRUPTLEVEL, $SHCNRF_SHELLLEVEL, $SHCNRF_RECURSIVEINTERRUPT), $aTest, 1)
If @error Then
	MsgBox(($MB_ICONERROR + $MB_SYSTEMMODAL), 'Fehler', 'Das Fenster wurde nicht registriert.')
	Exit
EndIf

While 1
	Sleep(1000)
WEnd

Func _End()
	Exit
EndFunc   ;==>_End

Func OnAutoItExit()
	If $g_iID Then
		_WinAPI_ShellChangeNotifyDeregister($g_iID)
	EndIf
EndFunc   ;==>OnAutoItExit

Func WM_SHELLCHANGENOTIFY($hWnd, $iMsg, $wParam, $lParam)
	#forceref $hWnd, $iMsg
	Local $tIDL = DllStructCreate((@AutoItX64 ? 'uint64 Item1;uint64 Item2;' : 'dword Item1;dword Item2;'), $wParam) ; bei 64 Bit ist das ein QWord (8 Byte)
	Local $sPath = _WinAPI_ShellGetPathFromIDList(DllStructGetData($tIDL, 'Item1'))
	If $sPath Then
		ConsoleWrite('Event: 0x' & Hex($lParam) & ' | Pfad: ' & $sPath & @CRLF)
	Else
		ConsoleWrite('Event: 0x' & Hex($lParam) & @CRLF)
	EndIf
EndFunc   ;==>WM_SHELLCHANGENOTIFY

Func _WinAPI_ShellChangeNotifyRegister64($hWnd, $iMsg, $iEvents, $iSources, $aPaths, $bRecursive = False)
	Local $iPath = $aPaths, $tagStruct = 'align 1;'

	If IsArray($aPaths) Then
		If UBound($aPaths, $UBOUND_COLUMNS) Then Return SetError(1, 0, 0)
	Else
		Dim $aPaths[1] = [$iPath]
	EndIf
	For $i = 0 To UBound($aPaths) - 1
		If Not _WinAPI_PathIsDirectory($aPaths[$i]) Then Return SetError(2, 0, 0)
	Next
	For $i = 0 To UBound($aPaths) - 1
		$tagStruct &= 'ptr;int;'
	Next
	Local $tEntry = DllStructCreate($tagStruct)
	For $i = 0 To UBound($aPaths) - 1
		$aPaths[$i] = _WinAPI_ShellILCreateFromPath(_WinAPI_PathSearchAndQualify($aPaths[$i]))
		DllStructSetData($tEntry, 2 * $i + 1, $aPaths[$i])
		DllStructSetData($tEntry, 2 * $i + 2, $bRecursive)
	Next
	Local $iError = 0
	Local $aCall = DllCall('shell32.dll', 'ulong', 'SHChangeNotifyRegister', 'hwnd', $hWnd, 'int', $iSources, 'long', $iEvents, _
			'uint', $iMsg, 'int', UBound($aPaths), 'struct*', $tEntry)
	If @error Or Not $aCall[0] Then $iError = @error + 10

	For $i = 0 To UBound($aPaths) - 1
		_WinAPI_CoTaskMemFree($aPaths[$i])
	Next
	Return SetError($iError, 0, $aCall[0])
EndFunc   ;==>_WinAPI_ShellChangeNotifyRegister64

Alles anzeigen

**Tweaky**

Euch beiden auch ein gesundes neue Jahr.

Danke für eure Hilfe. Nun funktioniert es perfekt