GUIRegisterMsg($WM_DRAWITEM, ...) Problem mit Map

**BugFix**

Ich habe die Problematik mal auf ein mimimales Skript runtergebrochen.
Im Original lese ich Daten aus einer INI in eine Map, habe ich hier nachgestellt.
Diese Daten sollen abhängig von dem Wert in 'access' (0/1) in rot oder Schwarz in der Combobox gelistet werden. Das funktioniert auch grundlegend.
Versuche ich jedoch innerhalb der WM_DRAWITEM-Funktion aus der Map den Wert für 'access' abzufragen, um entsprechend einzufärben, bekomme ich einen Fehler:

Code

==> Array variable has incorrect number of subscripts or subscript dimension range exceeded.:
If $mUnit[GUICtrlRead($cCombo)]['access'] = 0 Then $clrForeground = 0x0000FF
If $mUnit[GUICtrlRead($cCombo)]^ ERROR

Wie aber im Skript sichtbar ist, lasse ich zur Kontrolle die gesamte Map vorab in die Konsole ausgeben - problemlos.
Eigentlich könnte ich statt GUICtrlRead($cCombo) auf das funktionsintern gelesene $sText zugreifen. Hatte das aber mal testweise geändert, um es als Fehlerquelle auszuschließen.

Vielleicht hat ja schonmal jemand das Problem gehabt.

In Zeilen #90 / #91 mal die Kommentierung tauschen, um den Effekt zu sehen.

AutoIt

 #include <GUIComboBox.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <WinAPI.au3>


Global Const $ODT_COMBOBOX = 3
Global Const $ODA_DRAWENTIRE = 1
Global Const $ODA_SELECT = 2
Global Const $ODS_SELECTED = 1


Global $hGUI
Global $cCombo, $inPath
Global $sStr = ''

$hGUI = GUICreate('Test', 600, 400)
$cCombo = GUICtrlCreateCombo('', 100, 20, 300, 300, BitOR($WS_CHILD, $CBS_OWNERDRAWFIXED, $CBS_HASSTRINGS, $CBS_DROPDOWNLIST, $CBS_AUTOHSCROLL, $WS_VSCROLL))
$inPath = GUICtrlCreateInput('', 100, 50, 300, 20)

Global $sPathRoot = 'D:\Units'
Global $mUnit[]        ; $m['Einheit']['path']  /  $m['Einheit']['template']  / $m['Einheit']['access']
For $i = 1 To 15
    Local $m[]
    $mUnit['Einheit_' & $i] = $m
    $mUnit['Einheit_' & $i]['path'] = $sPathRoot & '\Einheit_' & $i
    $mUnit['Einheit_' & $i]['template'] = 'Template_' & Random(1,100,1)
    $mUnit['Einheit_' & $i]['access'] = Random(0,1,1)
Next

For $key in MapKeys($mUnit)
    $sStr &= '|' & $key
Next

GUICtrlSetData($cCombo, $sStr)

; ============================= Testausgabe Inhalt Map:
For $key in MapKeys($mUnit)
    ConsoleWrite($key & ': ' & $mUnit[$key]['path'] & ' | ' & $mUnit[$key]['template'] & ' | ' & $mUnit[$key]['access'] & @CRLF)
Next
; =============================================

GUIRegisterMsg($WM_DRAWITEM, '_WM_DRAWITEM')

GUISetState()

While True
    Switch GUIGetMsg()
        Case -3
            Exit
        Case $cCombo
            $sSel = GUICtrlRead($cCombo)
            GUICtrlSetData($inPath, $mUnit[$sSel]['path'])
    EndSwitch
WEnd


Func _WM_DRAWITEM($hWnd, $iMsg, $iwParam, $ilParam)
    Local Const $tagDRAWITEMSTRUCT = 'uint CtlType;' & 'uint CtlID;' & 'uint itemID;' & 'uint itemAction;' & _
                    'uint itemState;' & 'hwnd hwndItem;' & 'hwnd hDC;' & $tagRECT & ';ulong_ptr itemData;'
    Local $tDIS = DllStructCreate($tagDRAWITEMSTRUCT, $ilParam)
    Local $clrForeground = 0x000000, $clrBackground = 0xFFFFFF, $sText
    Local Static $clrPrev = $clrForeground
    $clrForeground = $clrPrev
    Local $iCtlType    = $tDIS.CtlType
    Local $iCtlID      = $tDIS.CtlID
    Local $iItemID     = $tDIS.itemID
    Local $iItemAction = $tDIS.itemAction
    Local $iItemState  = $tDIS.itemState
    Local $hWndItem    = $tDIS.hwndItem
    Local $hDC         = $tDIS.hDC
    Local $tRect       = DllStructCreate($tagRECT)


    If $iCtlType = $ODT_COMBOBOX And $iCtlID = $cCombo Then
        For $i = 1 To 4
            DllStructSetData($tRect, $i, DllStructGetData($tDIS, $i+7))
        Next
        _GUICtrlComboBox_GetLBText($hWndItem, $iItemID, $sText)

        Switch $iItemAction
            Case $ODA_DRAWENTIRE
                $clrForeground = 0x000000
                If BitAND($iItemState, $ODS_SELECTED) Then
                    $clrBackground = _WinAPI_SetBkColor($hDC, 0xD8D8D8)
                Else
                    $clrBackground = _WinAPI_SetBkColor($hDC, 0xFFFFFF)
                EndIf
; ##################################################################################################
;~                 If $mUnit[GUICtrlRead($cCombo)]['access'] = 0 Then $clrForeground = 0x0000FF
                If Random(0,1,1) = 0 Then $clrForeground = 0x0000FF
; ##################################################################################################

                $clrPrev = _WinAPI_SetTextColor($hDC, $clrForeground)
                _WinAPI_DrawText($hDC, $sText, $tRect, $DT_LEFT)
                _WinAPI_SetTextColor($hDC, $clrForeground)
                _WinAPI_SetBkColor($hDC, $clrBackground)
        EndSwitch
    EndIf
    Return $GUI_RUNDEFMSG
EndFunc

Alles anzeigen

**Kanashius**

Beim auslesen der Combobox kommt bei mir am Anfang ein leerer String (wenn noch nicht ausgewählt wurde). Dabei crasht es dann.

Wenn ich das Prüfe crasht es nicht mehr:

AutoIt

Local $sComboContent = GUICtrlRead($cCombo)
If MapExists($mUnit, $sComboContent) And $mUnit[$sComboContent].access = 0 Then $clrForeground = 0x0000FF

**UEZ**

Scheint eventuell ein Bug zu sein, denn die globale Variable $mUnit ist nicht vollständig in der Funktion _WM_DRAWITEM sichtbar, selbst wann man aus der _WM_DRAWITEM Funktion eine andere Function aufruft.

Kanashius die Farbe wird dann für alle gesetzt und nicht nach "Access".

**Kanashius**

Ja, weil in seinem Beispiel die ComboBox (für alle Einträge) ausgelesen wird.

Zitat

Eigentlich könnte ich statt GUICtrlRead($cCombo) auf das funktionsintern gelesene $sText zugreifen. Hatte das aber mal testweise geändert, um es als Fehlerquelle auszuschließen.

Wenn man das also mit $sText ersetzt sieht es so aus:

AutoIt

If MapExists($mUnit, $sText) And $mUnit[$sText]['access'] = 0 Then $clrForeground = 0x0000FF

Und das funktioniert bei mir einwandfrei. Es sind Einträge in der Liste Rot und wenn man die auswählt ist auch die Farbe in dem ComboFeld richtig.

Wenn ich mir $sText ausgeben lasse ist es halt manchmal ein leerer String und in so einem Fall existiert $mUnit[$sText] nunmal nicht und wenn man dann damit auf etwas zugreifen will schlägt das mit der Fehlermeldung fehl.
Ich hab mir mit _ToStringC($mUnit) (_toString für alle (AutoIt-) Objekte (und mehr) sowie eine Methode zum Errorhandling) das ganze auch ausgeben lassen und die Map war immer komplett definiert.

Win10, AutoIt 3.3.16.1

**BugFix**

Zitat von Kanashius

Wenn ich mir $sText ausgeben lasse ist es halt manchmal ein leerer String

Ja, ich war der (irrigen) Meinung, wenn ich die Listbox befüllt habe, ist doch da auf jeden Fall Inhalt. Der Inhalt, der in der Callbackfunktion relevant ist, entsteht ja erst beim Zeichnen desselben. Somit ist beim ersten Zeichnen der Wert von _GUICtrlComboBox_GetLBText noch leer und führt zum Crash.

Ich habe die Callbackfunktion jetzt dahingehend angepasst, dass sie bei leerem Text wieder verlassen wird.

AutoIt

Func _WM_DRAWITEM($hWnd, $iMsg, $iwParam, $ilParam)
    Local Const $tagDRAWITEMSTRUCT = 'uint CtlType;' & 'uint CtlID;' & 'uint itemID;' & 'uint itemAction;' & _
                    'uint itemState;' & 'hwnd hwndItem;' & 'hwnd hDC;' & $tagRECT & ';ulong_ptr itemData;'
    Local $tDIS = DllStructCreate($tagDRAWITEMSTRUCT, $ilParam)
    Local $clrForeground = 0x000000, $clrBackground = 0xFFFFFF, $sText
    Local Static $clrPrev = $clrForeground
    $clrForeground = $clrPrev
    Local $iCtlType    = $tDIS.CtlType
    Local $iCtlID      = $tDIS.CtlID
    Local $iItemID     = $tDIS.itemID
    Local $iItemAction = $tDIS.itemAction
    Local $iItemState  = $tDIS.itemState
    Local $hWndItem    = $tDIS.hwndItem
    Local $hDC         = $tDIS.hDC
    Local $tRect       = DllStructCreate($tagRECT)


    If $iCtlType = $ODT_COMBOBOX And $iCtlID = $cCombo Then
        For $i = 1 To 4
            DllStructSetData($tRect, $i, DllStructGetData($tDIS, $i+7))
        Next
        _GUICtrlComboBox_GetLBText($hWndItem, $iItemID, $sText)
; ################################################		
		If $sText = '' Then Return $GUI_RUNDEFMSG
; ################################################		

        Switch $iItemAction
            Case $ODA_DRAWENTIRE
                $clrForeground = 0x000000
                If BitAND($iItemState, $ODS_SELECTED) Then
                    $clrBackground = _WinAPI_SetBkColor($hDC, 0xD8D8D8)
                Else
                    $clrBackground = _WinAPI_SetBkColor($hDC, 0xFFFFFF)
                EndIf
                If $mUnit[$sText]['access'] = 0 Then $clrForeground = 0x0000FF
                $clrPrev = _WinAPI_SetTextColor($hDC, $clrForeground)
                _WinAPI_DrawText($hDC, $sText, $tRect, $DT_LEFT)
                _WinAPI_SetTextColor($hDC, $clrForeground)
                _WinAPI_SetBkColor($hDC, $clrBackground)
        EndSwitch
    EndIf
    Return $GUI_RUNDEFMSG
EndFunc

Alles anzeigen

Velted

Moin, die Ursache der Abbrüche ist wahrscheinlich:

DRAWITEMSTRUCT

Zitat

itemID
Type: UINT
The menu item identifier for a menu item or the index of the item in a list box or combo box. For an empty list box or combo box, this member can be -1. This allows the application to draw only the focus rectangle at the coordinates specified by the rcItem member even though there are no items in the control. This indicates to the user whether the list box or combo box has the focus. How the bits are set in the itemAction member determines whether the rectangle is to be drawn as though the list box or combo box has the focus.

Weil das Strukturfeld auch im Skript als UInt definiert ist, kommt als Wert 4294967295 an. Für diesen 'Index' kann man die _WM_DRAWITEM Funktion sofort verlassen.