zeit berechnung zwischen zwei zeiten aber inklusive millisekunden

bankesbusters

hallo zusammen,

ich hatte diesen thread hier gesehen: AutoIt.de Thread und als ich dazu noch eine frage stellen wollte, wurde ich mit diesen worten begruesst:

Zitat

Die letzte Antwort auf dieses Thema liegt mehr als 365 Tage zurück. Das Thema ist womöglich bereits veraltet. Bitte erstelle ggf. ein neues Thema.

also gut, dann erstelle ich eben ein neues thema dazu:

ich bastel an einem script wo ich zwei mal eine zeitberechnung benoetige. zum einen habe ich eine checkbox wo ich einen anfangspunkt setzen moechte und eine zweite checkbox wo ich einen endpunkt setzen moechte und dann soll in einem label die zeitdifferenz hierzu ausgegeben werden. allerdings inklusive millisekunden!

die zweite stelle im script macht quasi das selbe, aber man hat dropdowns fuer stunden, minuten, sekunden und millisekunden als start zeit und das selbe nochmals als endzeit.

jetzt geht es um die berechnung der differenz zwischen den zeiten. so wie ich erkennen kann bieten mir die meisten funktionen nur eine berechnung von bis zu sekunden an, aber nicht fuer den millisekunden bereich. kann mich da einer ggf. in die richtige richtung lenken?

_Now() und _NowTime() und auch _NowCalc() bieten mir alle nur bis sekunden an aber eben keine millisekunden.

gibt es da noch sinnige alternativen zu?

gruss

**AspirinJunkie**

Zitat

zum einen habe ich eine checkbox wo ich einen anfangspunkt setzen moechte und eine zweite checkbox wo ich einen endpunkt setzen moechte und dann soll in einem label die zeitdifferenz hierzu ausgegeben werden.

Mit TimerInit() die Anfangszeit setzen und mit TimerDiff() die Differenz zu diesem Zeitpunkt bestimmen.

Zum Zweiten Vorhaben mit der selbstdefinierten Startzeit müsste man sich wohl was schreiben hierfür.
Ich hätte da spontan gesagt mit _Date_Time_EncodeSystemTime() zwei Zeitstempel zu erstellen (geht auch eine eigene Struktur wie z.B. ein Array) und dann eine eigene Funktion, welche die Differenz in Millisekunden berechnet.

Edit: Mal umgesetzt was ich gerade meinte:

AutoIt

#include <Date.au3>

; Aktueller Zeitstempel:
$tNow = _Date_Time_EncodeSystemTime(@MON, @MDAY, @YEAR, @HOUR, @MIN, @SEC, @MSEC)

; Beliebiger Vergleichszeitstempel:
$tThen = _Date_Time_EncodeSystemTime(@MON, @MDAY, @YEAR, @HOUR, @MIN - 1, @SEC, @MSEC)

; Zeitdifferenz berechnen und ausgeben
ConsoleWrite("Zeitdifferenz: " & _SystemTimeDiff($tNow, $tThen) & " ms" & @CRLF)






; Berechnet die Differenz zweier Zeitstempel in Millisekunden (tTime1 - tTime2)
Func _SystemTimeDiff($tTime1, $tTime2)
	If Not IsDllStruct($tTime1) Then Return SetError(1,0, Null)
	If Not IsDllStruct($tTime2) Then Return SetError(2,0, Null)

	Return _SystemTime2JulianMSecs($tTime1) - _SystemTime2JulianMSecs($tTime2)
EndFunc

; konvertiert eine SYSTEMTIME-Struktur in ein julianisches Datum mit Millisekundenauflösung
Func _SystemTime2JulianMSecs($tSystemTime)
	If Not IsDllStruct($tSystemTime) Then Return SetError(1,0, Null)

	Local $dYear =   DllStructGetData($tSystemTime, "Year"), _
	      $dMonth =  DllStructGetData($tSystemTime, "Month"), _
          $dDay =    DllStructGetData($tSystemTime, "Day"), _
          $dHour =   DllStructGetData($tSystemTime, "Hour"), _
          $dMinute = DllStructGetData($tSystemTime, "Minute"), _
          $dSecond = DllStructGetData($tSystemTime, "Second"), _
          $dMs =     DllStructGetData($tSystemTime, "MSeconds")

	Local $fMsecs = Int(_DateToDayValue($dYear, $dMonth, $dDay) * 86400000, 2) _ ; julianisches Datum aus Jahr, Monat, Tag berechnen
		  + $dHour   * 3600000 _
		  + $dMinute * 60000 _
		  + $dSecond * 1000 _
		  + $dMs

	Return $fMsecs
EndFunc

Alles anzeigen

bankesbusters

hi,

okay, also ich fange mal mit den checkboxen an:

Code

Case $StartCheckBox
            If GUICtrlRead($StartCheckBox) = $GUI_CHECKED Then
                GUICtrlSetData($StartCheckBox, 'Checked')
				$StartCBTime = TimerInit()
            Else
                GUICtrlSetData($StartCheckBox, 'Unchecked')
            EndIf
            
[ ... more code here ... ]

Case $StopCheckBox
            If GUICtrlRead($StopCheckBox) = $GUI_CHECKED Then
                GUICtrlSetData($StopCheckBox, 'Checked')
				$AutomaticTimeCalc = TimerDiff($StartCBTime)
				; $AutomaticTimeCalc = StringFormat("%02d:%02d:%02d.%02d0", @HOUR, @MIN, @SEC, @MSEC) ; klappt nicht!
				GUICtrlSetData($Autocalculation, $AutomaticTimeCalc)
            Else
                GUICtrlSetData($StopCheckBox, 'Unchecked')
            EndIf

Alles anzeigen

also: mit dieser zeile $AutomaticTimeCalc = StringFormat("%02d:%02d:%02d.%02d0", @HOUR, @MIN, @SEC, @MSEC) bekomme ich zwar eine korrekt formatierte zahlenangabe aber keine berechnungen die richtig oder brauchbar sind. ... also testweise 3 sekunden laufen lassen zwischen checkbox start aktivieren und checkbox stop aktivieren ... ergebnis dann:

11:07:02.310 (das war die startzeit und keine berechnung zwischen den zwei zeiten)

mit der anderen zeile GUICtrlSetData($Autocalculation, $AutomaticTimeCalc) bekomme ich ein ergebnis wie zum beispiel dieses: 4958.9203 welches ja falsch ist. es sollte in etwa so aussehen:

00:00:04.203

was ubersehe ich da?

**Moombas**

bankesbusters was funktioniert denn an dem Beispiel von AspirinJunkie nicht, dies einzubauen?
Das gibt doch bereits die ms aus, wobei $tNow = Startzeit und $tThen = Endzeit wäre.

Diese ms musst du dann natürlich noch in hh, mm, ss , ms umrechnen und entsprechend ausgeben.

Achtung: Ich würde in Zeile 22 time1 von time2 abziehen (aktuell andersherum), sonst bekommst du immer negative Werte.

**Moombas**

Um mal das Beispiel von AspirinJunkie zu nehmen, Zeile ab Zeile 10 folgendes eingetragen:

Code

Global Const $ms = _SystemTimeDiff($tNow, $tThen)
ConsoleWrite("Zeitdifferenz: " & $ms & " ms" & @CRLF)
ConsoleWrite("Zeitdifferenz: " & StringFormat("%.2d:%.2d:%06.3f", (Floor($ms / 3600000)), (Floor(Mod($ms,3600000) / 60000)), (Mod(Mod($ms,3600000),60000) / 1000)) & @CRLF)

Und Zeile 22 wie erwähnt verändert: Return _SystemTime2JulianMSecs($tTime2) - _SystemTime2JulianMSecs($tTime1)

Ergibt dann als Ausgabe (z.B. bei 35456000ms):

Zeitdifferenz: 35456123 ms
Zeitdifferenz: 09:50:56.123

Hier ein kleines sample mit GUI aber Augabe nur in der Konsole:

AutoIt

Opt('MustDeclareVars', 1)
#include <Date.au3>
#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
Local $tNow, $tThen, $ms
        ; Create a GUI with various controls.
        Local $hGUI = GUICreate("Example", 300, 200)

        ; Create a checkbox control.
        Local $idCheckbox = GUICtrlCreateCheckbox("Standard Checkbox", 10, 10, 185, 25)
        Local $idButton_Close = GUICtrlCreateButton("Close", 210, 170, 85, 25)

        ; Display the GUI.
        GUISetState(@SW_SHOW, $hGUI)

        ; Loop until the user exits.
        While 1
                Switch GUIGetMsg()
                        Case $GUI_EVENT_CLOSE, $idButton_Close
                                ExitLoop

                        Case $idCheckbox
                                If GUICtrlRead($idCheckbox) = $GUI_CHECKED Then
									$tNow = _Date_Time_EncodeSystemTime(@MON, @MDAY, @YEAR, @HOUR, @MIN, @SEC, @MSEC)
                                Else
									$tThen = _Date_Time_EncodeSystemTime(@MON, @MDAY, @YEAR, @HOUR, @MIN, @SEC, @MSEC)
									$ms = _SystemTimeDiff($tNow, $tThen)
									ConsoleWrite("Zeitdifferenz: " & $ms & " ms" & @CRLF)
									ConsoleWrite("Zeitdifferenz: " & StringFormat("%.2d:%.2d:%06.3f", (Floor($ms / 3600000)), (Floor(Mod($ms,3600000) / 60000)), (Mod(Mod($ms,3600000),60000) / 1000)) & @CRLF)
									$tNow = ''
									$tThen = ''
									$ms = ''
                                EndIf

                EndSwitch
        WEnd

        ; Delete the previous GUI and all controls.
        GUIDelete($hGUI)
EndFunc   ;==>Example

; Berechnet die Differenz zweier Zeitstempel in Millisekunden (tTime1 - tTime2)
Func _SystemTimeDiff($tTime1, $tTime2)
	If Not IsDllStruct($tTime1) Then Return SetError(1,0, Null)
	If Not IsDllStruct($tTime2) Then Return SetError(2,0, Null)

	Return _SystemTime2JulianMSecs($tTime2) - _SystemTime2JulianMSecs($tTime1)
EndFunc

; konvertiert eine SYSTEMTIME-Struktur in ein julianisches Datum mit Millisekundenauflösung
Func _SystemTime2JulianMSecs($tSystemTime)
	If Not IsDllStruct($tSystemTime) Then Return SetError(1,0, Null)

	Local $dYear =   DllStructGetData($tSystemTime, "Year"), _
	      $dMonth =  DllStructGetData($tSystemTime, "Month"), _
          $dDay =    DllStructGetData($tSystemTime, "Day"), _
          $dHour =   DllStructGetData($tSystemTime, "Hour"), _
          $dMinute = DllStructGetData($tSystemTime, "Minute"), _
          $dSecond = DllStructGetData($tSystemTime, "Second"), _
          $dMs =     DllStructGetData($tSystemTime, "MSeconds")

	Local $fMsecs = Int(_DateToDayValue($dYear, $dMonth, $dDay) * 86400000, 2) _ ; julianisches Datum aus Jahr, Monat, Tag berechnen
		  + $dHour   * 3600000 _
		  + $dMinute * 60000 _
		  + $dSecond * 1000 _
		  + $dMs

	Return $fMsecs
EndFunc

Alles anzeigen

Credits to AspirinJunkie and zaNergal habs nur zusammen gefügt

bankesbusters

Moombas : vorhin war das beispiel von aspirinjunkie noch NICHT da. deswegen auch meine frage. das ist genau das, was ich in einem anderen beitrag bemaengelt habe: nicht einfach draufhauen ohne nachzudenken, das jenes beispiel spaeter hinzugefuegt wurde sieh man ja auch am einwand von aspirinjunkie:

Zitat

Edit: Mal umgesetzt was ich gerade meinte:

trotzdem danke. ich glaube ich kann damit auf jeden fall etwas anfangen.

**Moombas**

Hier hat keiner "drauf gehauen" und ich habe jetzt nicht auf die beiden Zeitstempel geschaut, muss ich zugeben aber für mich (Stand jetzt) auch nicht zu 100% ersichtlich:

Der Inhalt kann nicht angezeigt werden, da du keine Berechtigung hast, diesen Inhalt zu sehen.

Würde ich hier irgendwo "drauf hauen" wäre der Ton weitaus anders.

argumentum

AutoIt

ConsoleWrite('>>> ' & _DateDiffMs('2021/08/16 13:25:08.727', '2021/08/16 13:25:08.729') & @CRLF)
Func _DateDiffMs($sDate1st, $sDate2nd)
    Local $iDate1st, $aDate1st = StringSplit($sDate1st, ".")
    ReDim $aDate1st[3]
    Local $iDate2nd, $aDate2nd = StringSplit($sDate2nd, ".")
    ReDim $aDate2nd[3]
    Local $iDate1st = _DateDiff('s', '1970/01/01 00:00:00', $aDate1st[1])
    Local $iDate2nd = _DateDiff('s', '1970/01/01 00:00:00', $aDate2nd[1])
    $iDate1st &= "000"
    $iDate2nd &= "000"
    $iDate1st += Int($aDate1st[2])
    $iDate2nd += Int($aDate2nd[2])
    Return  ( $iDate2nd - $iDate1st ) / 1000
EndFunc

Alles anzeigen

Ich brauchte _DateDiff(), um Millisekunden einzuschließen.

argumentum

Zitat von bankesbusters

Moombas : vorhin war das beispiel von aspirinjunkie noch NICHT da.

Dies hätte der Beitrag ohne das Drama sein können. Mein Penny der Weisheit

**Schnuffel**

ein kleines Beispiel für die Berechnung:

AutoIt

;~ #Region
;~ #pragma compile(FileVersion, 1.0.0.0)
;~ #pragma compile(LegalCopyright, © (Schnuffel))
;~ #pragma compile(ProductVersion, 1.0.0.0)
;~ ;#AutoIt3Wrapper_AU3Check_Parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6 -w 7
;~ #AutoIt3Wrapper_AU3Check_Stop_OnWarning=y
;~ #AutoIt3Wrapper_Outfile=%scriptfile%.exe
;~ #AutoIt3Wrapper_Res_Language=1031
;~ #AutoIt3Wrapper_Res_requestedExecutionLevel=asInvoker
;~ #AutoIt3Wrapper_Run_Au3Stripper=y
;~ #AutoIt3Wrapper_UseUpx=n
;~ #AutoIt3Wrapper_UseX64=y
;~ #Au3Stripper_Parameters=/sf /sv /mo /rm /rsln
;~ #EndRegion
#cs===============================================================================
AutoIt Version:		3.3.16.1

Description:

Author(s):      	Oliver Zimmermann (Schnuffel@autoit.de / Schnuffel@autoit.com)

Changelog:
-------------------------------------------------------------------------
! = Bugfix, + = Feature added, - = Feature removed, ~ = Behaviour changed
-------------------------------------------------------------------------
1.0.0.0 -

#ce===============================================================================
#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>

Global $s1000
For $i = 0 To 999
	$s1000 &= $i & "|"
Next
StringTrimRight($s1000, 1)
Global $s60
For $i = 0 To 59
	$s60 &= $i & "|"
Next
StringTrimRight($s60, 1)
Global $s24
For $i = 0 To 23
	$s24 &= $i & "|"
Next
StringTrimRight($s24, 1)

Global $nMs1, $nMs2, $nMsDiff, $nErgHour, $nErgMin, $ErgSec, $nrgMsec, $nErgRest
Global $hGUI = GUICreate("", 500, 400, -1, -1)
GUISetFont(10)
GUICtrlCreateLabel("Start:", 10, 10)
GUICtrlCreateLabel("Hour:", 10, 30, 40, 20)
Global $hHourStart = GUICtrlCreateCombo("", 50, 27, 50, 20)
GUICtrlSetData(-1, $s24, 0)
GUICtrlCreateLabel("Min:", 10, 60, 60, 20)
Global $hMinStart = GUICtrlCreateCombo("", 50, 57, 50, 20)
GUICtrlSetData(-1, $s60, 0)
GUICtrlCreateLabel("Sek:", 10, 90, 60, 20)
Global $hSecStart = GUICtrlCreateCombo("", 50, 87, 50, 20)
GUICtrlSetData(-1, $s60, 0)
GUICtrlCreateLabel("MSek:", 10, 120, 60, 20)
Global $hMSecStart = GUICtrlCreateCombo("", 50, 117, 50, 20)
GUICtrlSetData(-1, $s1000, 0)

GUICtrlCreateLabel("Ende:", 200, 10)
GUICtrlCreateLabel("Hour:", 200, 30, 40, 20)
Global $hHourEnde = GUICtrlCreateCombo("", 250, 27, 50, 20)
GUICtrlSetData(-1, $s24, 0)
GUICtrlCreateLabel("Min:", 200, 60, 60, 20)
Global $hMinEnde = GUICtrlCreateCombo("", 250, 57, 50, 20)
GUICtrlSetData(-1, $s60, 0)
GUICtrlCreateLabel("Sek:", 200, 90, 60, 20)
Global $hSecEnde = GUICtrlCreateCombo("", 250, 87, 50, 20)
GUICtrlSetData(-1, $s60, 0)
GUICtrlCreateLabel("MSek:", 200, 120, 60, 20)
Global $hMSecEnde = GUICtrlCreateCombo("", 250, 117, 50, 20)
GUICtrlSetData(-1, $s1000, 0)
GUISetFont(12)
Global $hButton = GUICtrlCreateButton("calculate", 10, 170, 120, 40)
GUICtrlCreateLabel("Ergebnis:", 140, 180, 80, 40)
Global $hErgebnis = GUICtrlCreateLabel("", 220, 180, 120, 40)


GUISetFont(10)
Global $nMsg = GUIGetMsg()
GUISetState()

While 1
	$nMsg = GUIGetMsg()
	Switch $nMsg
		Case -3
			Exit
		Case $hButton
			$nMs1 = GUICtrlRead($hHourStart) * 3600000 + GUICtrlRead($hMinStart) * 60000 + GUICtrlRead($hSecStart) * 1000 + GUICtrlRead($hMSecStart)
			$nMs2 = GUICtrlRead($hHourEnde) * 3600000 + GUICtrlRead($hMinEnde) * 60000 + GUICtrlRead($hSecEnde) * 1000 + GUICtrlRead($hMSecEnde)

			$nMsDiff = $nMs2 - $nMs1
			If $nMsDiff < 0 Then
				MsgBox(0, "Error", "die zweite Zeit ist 'kleiner' als die erste Zeit!")
			Else
				$nErgHour = Floor($nMsDiff / 3600000)
				$nErgRest = $nMsDiff - $nErgHour * 3600000
				$nErgMin = Floor($nErgRest / 60000)
				$nErgRest = $nErgRest - $nErgMin * 60000
				$nErgSec = Floor($nErgRest / 1000)
				$nErgMSec = $nErgRest - $nErgSec * 1000
				GUICtrlSetData($hErgebnis, StringRight("0" & $nErgHour, 2) & ":" & StringRight("0" & $nErgMin, 2) & ":" & StringRight("0" & $nErgSec, 2) & ":" & StringRight("000" & $nErgMSec, 4))
			EndIf
	EndSwitch
WEnd

Alles anzeigen