Splashscreen-Gui mit Terminate Button / GuiEvents richtig abfangen

hipfzwirgel

Hallo Gemeinde,

ich habe ein kleines Programm entwickelt, das mir aus einer Excelliste Rechnernamen ausliest, und diese in eine Website einträgt.
Das Ergebnis wird dann wieder in die Excelliste eingetragen. Da dieser Vorgang lange dauern kann, habe ich einen Splashscreen erstellt.
Auf der Gui des Splashscreen befindet sich ein "Terminate-Button" um den Vorgang abzubrechen. Wie fange ich diesen Buttonklick richtig ab?
Ein Case in der Schleife der Haupt-GUI funzt nicht, logischer Weise...

AutoIt

; HauptGui:

; === GUI erstellen ===
GUICreate("UBL-Reader", 300, 250)
GUICtrlCreateLabel("Wähle einen KVM:", 20, 20)

Global $idRadio[4]
$idRadio[0] = GUICtrlCreateRadio("DeskRegal", 20, 50)
$idRadio[1] = GUICtrlCreateRadio("LapRegal", 20, 75)
$idRadio[2] = GUICtrlCreateRadio("RaritanBla", 20, 100)
$idRadio[3] = GUICtrlCreateRadio("RaritanBlupp", 20, 125)
GUICtrlSetState($idRadio[0], $GUI_CHECKED)

Global $idButtonReadSelected = GUICtrlCreateButton("Read Selected", 150, 60, 120, 30)
Global $idButtonReadAll = GUICtrlCreateButton("Read All", 150, 100, 120, 30)

GUISetState()

; === GUI Event-Loop ===
While 1
	Switch GUIGetMsg()
		Case $GUI_EVENT_CLOSE
			Exit

		Case $idButtonReadSelected
			For $i = 0 To 3
				If GUICtrlRead($idRadio[$i]) = $GUI_CHECKED Then
					_Fetch_UBL_BySheet($aSheets[$i])
					ExitLoop
				EndIf
			Next

		Case $idButtonReadAll
			For $i = 0 To 3
				_Fetch_UBL_BySheet($aSheets[$i])
			Next

	EndSwitch

WEnd
.
.
.

; === Splashscreen ===
Func _SplashStart($sText)

#Region ### START Koda GUI section ### Form=
$hGuiSp = GUICreate("sFileVersion", 542, 314, -1, -1)
GUISetFont(8, 800, 0, "Bosch Sans Bold")
GUISetBkColor(0xFFFFFF)
$SPPic2 = GUICtrlCreatePic("@ScriptDir\Band.jpg", 0, 0, 804, 11)
$SPPlease = GUICtrlCreateLabel("Please be patient", 45, 224, 450, 41, $SS_CENTER)
GUICtrlSetFont(-1, 22, 800, 0, "Sans Bold")
GUICtrlSetColor(-1, 0x000080)
$Label1 = GUICtrlCreateLabel("Searching UBL...", 154, 32, 233, 36)
GUICtrlSetFont(-1, 22, 800, 0, "Office Sans")
GUICtrlSetColor(-1, 0x000080)
$Button1 = GUICtrlCreateButton("terminate", 230, 285, 81, 25)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###


	;XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX
	Global $sFile9 = "./loading.gif"

	Global $hGIF = _GUICtrlCreateGIF($sFile9, "", 190, 122)
	GUICtrlSetTip($hGIF, "Loading...")
	;XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX

	GUIRegisterMsg(15, "_ValidateGIFs") ; WM_PAINT'
	GUISetState()
EndFunc


Func _ValidateGIFs($hWnd, $iMsg, $wParam, $lParam)

	#forceref $hWnd, $iMsg, $wParam, $lParam
	_GIF_ValidateGIF($hGIF)

EndFunc   ;==>_ValidateGIFs

Func _SplashStop()
	 If IsHWnd($hGuiSp) Then
        GUISetState(@SW_HIDE, $hGuiSp)
        Sleep(200)
        GUIDelete($hGuiSp)
        Sleep(300)
    EndIf
EndFunc

Alles anzeigen

**Moombas**

Case $Button1 in der While schleife oder soll er dann wirklich aus allen schleifen durchläufen zurückspringen?

hipfzwirgel

Hallo Moombas,

Das war mein erster Versuch aber da der Splashscreen ja auch auf einer GUI basiert, reagiert GuiGetMsg nicht darauf.
Ich teste gerade folgendes: der Splashscreen wird ja in der Func _Fetch_UBL_BySheet($aSheets[$i]) aufgerufen. Ich deaktiviere also zunächst die Hauptgui

Code

; Beispiel:
Case $idButtonReadSelected
			GUISetState(@SW_DISABLE, $Hauptform) ; Hauptform deaktiveren wg Form in _SplashStart() / alle Gui-Variablen müssen dort anders heissen!!
			For $i = 0 To 3
				If GUICtrlRead($idRadio[$i]) = $GUI_CHECKED Then
					_Fetch_UBL_BySheet($aSheets[$i])
					ExitLoop
				EndIf
			Next
			GUISetState(@SW_ENABLE, $Hauptform) ; Hauptform wieder aktivieren

und aktiviere sie im Nachgang wieder. Durch eine eigene While für die Splashscreen-Gui, kann ich nun den Button1 des Splashscreens abfangen:

Code

; While in der Func _SplashStart($sText)
While 1 
		$nMsg = GUIGetMsg()
		Switch $nMsg
			Case $GUI_EVENT_CLOSE
				_SplashStop()

			Case $Button1
				_SplashStop()
		EndSwitch
	WEnd

Alles anzeigen

soweit so gut. So kann ich den Button des Splashscreens abfangen. Die Func Splashstop() ist die vorhandene Funktion um den Splashscreen zu beenden, wenn die Func _Fetch_UBL_BySheet($aSheets[$i])
fertig ist und steht hier nur zum Testen. Jetzt muss ich nur noch heraus finden, wie ich beim Auslösen des Splash-Buttons den Excelprozess in der Func _Fetch_UBL_BySheet($aSheets[$i]) beenden kann, sowie die Func selbst und die Haupt-GUI wieder aktivere...
Hätte da jemand evtl. eine Idee?

**Kanashius**

In dem folgenden Code, wird die _mainLoop durch "AdlibRegister" auch während des Prozesses (mit sleep,...) aufgerufen. Du musst nur vorsichtig sein, dass du in _mainLoop keine länger dauernden Funktionen aufrufst, wenn es von AdlibRegister aufgerufen wurde. Das würde dann alles blockieren. Stattdessen wird dort nur kurz $bStopProgress auf True gesetzt und das Splashfenster gelöscht, bevor es weitergeht.

Der Prozess wird durch das If $bStopProgress Then ExitLoop unterbrochen. Dadurch wird sichergestellt, dass eine Aufgabe immer erfolgreich durchläuft und nur zwischen der Aufgabe und der nächsten unterbrochen wird. Bis zum wirklichen unterbrechen dauert es also maximal solange, wie eine einzelne Aufgabe (Ein For-Schleifendurchgang) benötigt. Wenn dir das zu lange dauert, müsstest du die Aufgabe wieder in Abschnitte unterteilen, zwischen denen (mit $bStopProgress) unterbrochen werden kann.

Ich hoffe, das Beispiel hilft dir weiter:

AutoIt

#include <GUIConstantsEx.au3>
Global $hGuiMain = -1, $hGuiSplash = -1, $bStopProgress = False, $iProgressMax = 0, $idCtrlProgress, $idCtrlProgressStart

_mainGuiCreate()

While True
	_mainLoop()
WEnd

Func _mainLoop()
	Local $arMsg = GUIGetMsg(1)
	Switch $arMsg[1]
		Case $hGuiMain
			Switch $arMsg[0]
				Case $GUI_EVENT_CLOSE
					Exit
				Case $idCtrlProgressStart
					_startProgress()
			EndSwitch
		Case $hGuiSplash
			Switch $arMsg[0]
				Case $GUI_EVENT_CLOSE
					_splashGuiDestroy()
			EndSwitch
	EndSwitch
EndFunc

Func _onMainClose()
	Exit
EndFunc

Func _mainGuiCreate()
	Global $iWidth = 800, $iHeight = 600
	$hGuiMain = GUICreate("", $iWidth, $iHeight)
	$idCtrlProgressStart = GUICtrlCreateButton("Start splash", 10, 10, $iWidth-20, 25)
	GUISetState(@SW_SHOW, $hGuiMain)
EndFunc

Func _startProgress()
	$bStopProgress = False
	_splashGuiCreate()
	$iProgressMax = 10
	AdlibRegister("_mainLoop", 10)
	For $i=0 to $iProgressMax
		Sleep(1000) ; your task to do ("Aufgabe")
		GUICtrlSetData($idCtrlProgress, Int((100/$iProgressMax)*$i))
		
		_mainLoop()
		If $bStopProgress Then ExitLoop
	Next
	AdlibUnRegister("_mainLoop")
	GUICtrlSetData($idCtrlProgress, 100)
	$bStopProgress = False
	_splashGuiDestroy()
EndFunc

Func _splashGuiCreate()
	If $hGuiSplash=-1 Then
		GUISetState(@SW_DISABLE, $hGuiMain)
		Local $iWidth = 400, $iHeight = 200
		$hGuiSplash = GUICreate("Splash", $iWidth, $iHeight, -1, -1, -1, -1, $hGuiMain)
		$idCtrlProgress = GUICtrlCreateProgress(10, 10, $iWidth-20, 20)
		GUISetState(@SW_SHOW, $hGuiSplash)
	EndIf
EndFunc

Func _splashGuiDestroy()
	If $hGuiSplash<>-1 Then
		$bStopProgress = True
		GuiDelete($hGuiSplash)
		GUISetState(@SW_ENABLE, $hGuiMain)
		$hGuiSplash = -1
	EndIf
EndFunc

Alles anzeigen

**Moombas**

Ganz abgesehen von Kanashius ansatz, und nur wegen meiner Anmerkung musst du natürlich die Variable $Button1 (+alle anderen angesteuerten GUI Elemente der anderen GUI) Global haben, nicht lokal. Sprich Global leer definieren und in der Funktion dann füllen oder von der Funktion füllen lassen.

Denn klar kann guigetmsg nicht drauf reagieren wenn es diese Variable nicht kennt/gefüllt ist.

hipfzwirgel

Hallole Zusammen,

zunächst einmal danke für die Beiträge

Ich glaube das Prob ist doch größer. Wenn ich in der Hauptfunktion die Splashscreen-Funktion aufrufe blockiert diese mir die Hauptfunktion und da die Hauptfunktion aber mind. 32 Rechnernamen in eine Website einträgt und dann einen String ermittelt, den ich dann wieder in das Excel-File eintrage dauert der Vorgang mit ziemlicher Sicherheit zu lang für Adlibregister (Kanashuis ' Ansatz).

Code

; das ist der Aufruf in der Hauptfunktion:

; === Hauptfunktion pro Sheet ===
Func _Fetch_UBL_BySheet($sSheetName)

    LogWrite(@ScriptLineNumber, "_Fetch_UBL_BySheet() Start Sheet: " & $sSheetName)
   
     ; ==> dieser Aufruf blockiert die Func: 
    Local $hSplash = _SplashStart("Lese: " & $sSheetName)

    ; --- Excel öffnen ---
    Local $oExcel = _Excel_Open(True)
	ConsoleWrite('@@ Debug(' & @ScriptLineNumber & ') : $oExcel = ' & $oExcel & @CRLF & '>Error code: ' & @error & @CRLF) ;### Debug Console
    If @error Or Not IsObj($oExcel) Then
        _SplashStop()
        LogWrite(@ScriptLineNumber, "_Fetch_UBL_BySheet() Fehler: Excel konnte nicht gestartet werden.")
        Return MsgBox(16, "Fehler", "Excel konnte nicht gestartet werden.")
    EndIf
    .
    .
    .
    EndFunc

Alles anzeigen

Also wenn jemand eine Idee hätte wie ich den Splashscreen realisiert bekomme ohne die Hauptfunktion zu blockieren und mit einem Abbruch-Button, dann bitte her damit

**Kanashius**

Zitat von hipfzwirgel

dauert der Vorgang mit ziemlicher Sicherheit zu lang für Adlibregister

AdlibRegister arbeitet mit interrupts, es würde also das, was gerade in dem Programm läuft unterbrechen um AdlibRegister auszuführen und dann mit dem Programm weiterzumachen.

Alles was in der von "AdlibRegister" aufgerufenen Funktion passiert, sollte nur nicht zu lang sein, da es das "Programm" pausiert und wenn die Funktion nicht beendet wird, würde es das "Programm" blockieren.
Das Programm darf aber länger dauernde Aufgaben ausführen, da das für den AdlibRegister aufruf unterbrochen wird.

AdlibRegister ist also genau das, was du willst. Es gibt dir die Möglichkeit das "Programm" kurz zu unterbrechen, zu schauen, ob ein Button o.ä. geklickt wurde und führt dann weiter das "Programm" aus.
In dieser Unterbrechung kann dann zum Beispiel eine Variable wie "$bStopProgress" geändert werden, wie ich es in meinem Beispiel gemacht habe, und das "Programm" kann darauf reagieren, indem es z.B. die aktuelle For-Schleife verlässt.

hipfzwirgel

Hallo Kanashius,

vielen lieben Dank für deine Erklärung. Offenbar hatte ich das falsch verstanden. Dann mache ich mich mal an die Umsetzung
könnte aber dauern , weil ich in ca. einer Stunde in den Urlaub aufbreche...

hipfzwirgel

Hallole,

das ging jetzt tatsächlich schneller als gedacht. ich habe das mit Adlibregister umgesetzt,. Was soll ich Sagen:

ES LÄUFT SUPER!!!

Einen fetten Applaus für Kanashius

Vorgang erledigt...

Code

; ich habe folgenden Codeschnipsel in die Splashscreen Func eingefügt und damit klappt es:

  ; Adlib aktivieren
    AdlibRegister("_CheckAbort", 200)
EndFunc

Func _CheckAbort()
    If Not IsHWnd($hGuiSp) Then Return
    Local $msg = GUIGetMsg()
    If $msg = $Button1 Then
        $g_bAbort = True
        LogWrite(@ScriptLineNumber, "Prozess vom Benutzer abgebrochen")
        _SplashStop()
    EndIf
EndFunc

Alles anzeigen

**BugFix**

Mal noch als Tipp:

Um nicht zu Überschneidungen im zeitlichen Ablauf der Adlib-Funktion zu kommen habe ich mir angewöhnt, beim Eintritt in die Adlib-Funktion diese zuerst mit AdlibUnregister vor einem erneuten Aufruf während der Abarbeitung zu schützen. Am Ende der Funktion aktiviere ich dann wieder AdlibRegister .