Klassische Progressbar (2 Beispiele)

**Oscar**

Es tauchen hier ja immer wieder mal Fragen zu einer Progressbar mit Prozentanzeige innerhalb des Progressbalkens auf.
Dazu habe ich mal ein Beispielskript erstellt. Außerdem gibt es noch ein Beispiel für eine Progressbar (mit Slider), deren Wert sich während der Sliderbewegung aktualisiert:

Spoiler anzeigen

[autoit]

#include<SliderConstants.au3>
#include<StaticConstants.au3>
#include<GUIConstantsEx.au3>
#include<ProgressConstants.au3>

[/autoit] [autoit][/autoit] [autoit]

Global $hGui = GUICreate('Klassische Progressbar', 420, 280, -1, -1)

[/autoit] [autoit][/autoit] [autoit]

DllCall('uxtheme.dll', 'none', 'SetThemeAppProperties', 'int', 0) ; auf den klassischen Style umschalten
Global $hProgress1 = GUICtrlCreateProgress(15, 20, 384, 20, $PBS_SMOOTH) ; obere Progressbar erstellen
GUICtrlSetColor(-1, 0x22FF22)
GUICtrlSetBkColor(-1, 0xEEEEEE)
GUICtrlCreateLabel('|', 18, 40, 20, 16) ; Anzeige von 0%
GUICtrlCreateLabel('0%', 11, 56, 25, 16, $SS_CENTER)
GUICtrlCreateLabel('|', 396, 40, 20, 16) ; Anzeige von 100%
GUICtrlCreateLabel('100%', 389, 56, 25, 16, $SS_CENTER)

[/autoit] [autoit][/autoit] [autoit]

Global $hLabel1 = GUICtrlCreateLabel('0%', 190, 24, 30, 14, $SS_CENTER) ; Prozentanzeige innerhalb der Progressbar
GUICtrlSetBkColor(-1, $GUI_BKCOLOR_TRANSPARENT) ; Transparenter Hintergrund für das Label

[/autoit] [autoit][/autoit] [autoit]

Global $hProgress2 = GUICtrlCreateProgress(15, 160, 384, 20, $PBS_SMOOTH) ; untere Progressbar erstellen
GUICtrlSetColor(-1, 0xC83131)
GUICtrlSetBkColor(-1, 0xEEEEEE)
DllCall('uxtheme.dll', 'none', 'SetThemeAppProperties', 'int', 7) ; zurück zum Standard-Windowsstyle

[/autoit] [autoit][/autoit] [autoit]

For $i = 0 To 100 Step 10 ; die Anzeige für die Prozentwerte der unteren Progressbar erstellen
GUICtrlCreateLabel('|', 16 + $i * 3.8, 180, 20, 16)
GUICtrlCreateLabel($i & '%', 9 + $i * 3.8, 196, 25, 16, $SS_CENTER)
Next

[/autoit] [autoit][/autoit] [autoit]

Global $hSlider = GUICtrlCreateSlider(5, 130, 404, 28, BitOR($TBS_TOOLTIPS, $TBS_AUTOTICKS))
GUICtrlSetData(-1, 33) ; Sliderwert auf 33% setzen (als Beispiel)

[/autoit] [autoit][/autoit] [autoit]

Global $hClose = GUICtrlCreateButton('Close', 180, 240, 60, 24)
GUISetState(@SW_SHOW)

[/autoit] [autoit][/autoit] [autoit]

Global $iAddend = 1 ; globale Variable (dient als Summand für _SetProgress)
AdlibEnable('_SetProgress', 30)

[/autoit] [autoit][/autoit] [autoit]

While True
Switch GUIGetMsg()
Case $GUI_EVENT_CLOSE, $hClose
Exit
EndSwitch
WEnd

[/autoit] [autoit][/autoit] [autoit]

Func _SetProgress()
Local $iPercent = GUICtrlRead($hProgress1) ; Prozentwert der oberen Progressbar auslesen
If $iPercent = 100 Or $iPercent = 0 Then $iAddend = -$iAddend ; wenn 100 oder Null, dann den Summand negieren
GUICtrlSetData($hProgress1, $iPercent + $iAddend) ; neuen Wert der oberen Progressbar schreiben
GUICtrlSetData($hLabel1, $iPercent + $iAddend & '%') ; neuen Wert für das Label schreiben
GUICtrlSetData($hProgress2, GUICtrlRead($hSlider)) ; und den Wert vom Slider in die untere Progressbar schreiben
EndFunc ;==>_SetProgress

[/autoit]

Raupi

Super Beispiel Oscar, wie immer Wenn man Zeile 8 und 23 auskommentiert , funzt das unter Vista sogar im 3D Style

**GtaSpider**

Hallo

Etwas schicker vom Source geht es vielleicht mit SetWindowTheme. So kann man nämlich einzelne Controls ansteuern, und muss nicht immer das ganze AutoIt Script auf Alt Trimmen:

Spoiler anzeigen

[autoit]

#include<SliderConstants.au3>
#include<StaticConstants.au3>
#include<GUIConstantsEx.au3>
#include<ProgressConstants.au3>

[/autoit] [autoit][/autoit] [autoit]

Global $hGui = GUICreate('Klassische Progressbar', 420, 280, -1, -1)

[/autoit] [autoit][/autoit] [autoit]

Global $hProgress1 = GUICtrlCreateProgress(15, 20, 384, 20, $PBS_SMOOTH) ; obere Progressbar erstellen
DllCall("UxTheme.dll", "int", "SetWindowTheme", "hwnd", GUICtrlGetHandle(-1), "wstr", "", "wstr", "");Nur das obere Control in old Style machen
GUICtrlSetColor(-1, 0x22FF22)
GUICtrlSetBkColor(-1, 0xEEEEEE)
GUICtrlCreateLabel('|', 18, 40, 20, 16) ; Anzeige von 0%
GUICtrlCreateLabel('0%', 11, 56, 25, 16, $SS_CENTER)
GUICtrlCreateLabel('|', 396, 40, 20, 16) ; Anzeige von 100%
GUICtrlCreateLabel('100%', 389, 56, 25, 16, $SS_CENTER)

[/autoit] [autoit][/autoit] [autoit]

Global $hLabel1 = GUICtrlCreateLabel('0%', 190, 24, 30, 14, $SS_CENTER) ; Prozentanzeige innerhalb der Progressbar
GUICtrlSetBkColor(-1, $GUI_BKCOLOR_TRANSPARENT) ; Transparenter Hintergrund für das Label

[/autoit] [autoit][/autoit] [autoit]

Global $hProgress2 = GUICtrlCreateProgress(15, 160, 384, 20, $PBS_SMOOTH) ; untere Progressbar erstellen
DllCall("UxTheme.dll", "int", "SetWindowTheme", "hwnd", GUICtrlGetHandle(-1), "wstr", "", "wstr", "");Nur das obere Control in old Style machen
GUICtrlSetColor(-1, 0xC83131)
GUICtrlSetBkColor(-1, 0xEEEEEE)

[/autoit] [autoit][/autoit] [autoit]

For $i = 0 To 100 Step 10 ; die Anzeige für die Prozentwerte der unteren Progressbar erstellen
GUICtrlCreateLabel('|', 16 + $i * 3.8, 180, 20, 16)
GUICtrlCreateLabel($i & '%', 9 + $i * 3.8, 196, 25, 16, $SS_CENTER)
Next

[/autoit] [autoit][/autoit] [autoit]

Global $hSlider = GUICtrlCreateSlider(5, 130, 404, 28, BitOR($TBS_TOOLTIPS, $TBS_AUTOTICKS))
GUICtrlSetData(-1, 33) ; Sliderwert auf 33% setzen (als Beispiel)

[/autoit] [autoit][/autoit] [autoit]

Global $hClose = GUICtrlCreateButton('Close', 180, 240, 60, 24)
GUISetState(@SW_SHOW)

[/autoit] [autoit][/autoit] [autoit]

Global $iAddend = 1 ; globale Variable (dient als Summand für _SetProgress)
AdlibEnable('_SetProgress', 30)

[/autoit] [autoit][/autoit] [autoit]

While True
Switch GUIGetMsg()
Case $GUI_EVENT_CLOSE, $hClose
Exit
EndSwitch
WEnd

[/autoit] [autoit][/autoit] [autoit]

Func _SetProgress()
Local $iPercent = GUICtrlRead($hProgress1) ; Prozentwert der oberen Progressbar auslesen
If $iPercent = 100 Or $iPercent = 0 Then $iAddend = -$iAddend ; wenn 100 oder Null, dann den Summand negieren
GUICtrlSetData($hProgress1, $iPercent + $iAddend) ; neuen Wert der oberen Progressbar schreiben
GUICtrlSetData($hLabel1, $iPercent + $iAddend & '%') ; neuen Wert für das Label schreiben
GUICtrlSetData($hProgress2, GUICtrlRead($hSlider)) ; und den Wert vom Slider in die untere Progressbar schreiben
EndFunc ;==>_SetProgress

[/autoit]

Mfg Spider

Jam00

Gibt es das auch, wenn die Progressbars zusammensin ($PBS_SMOOTH) in 3D Stayle?

Raupi

Drück dich mal klarer aus, mein Dolmetscher hat gerade Urlaub .

Jam00

Oh man, pasiert mir als , tschuldigung
Ich meinte Gibt es das auch, wenn die Progressbars zusammensin ($PBS_SMOOTH) in 3D Stayle, also das es aussieht wie bei XP, nur eben zusammen und nicht einzelne balken?

L3viathan

Raupi

Zitat von Jam00

Oh man, pasiert mir als , tschuldigung
Ich meinte Gibt es das auch, wenn die Progressbars zusammensin ($PBS_SMOOTH) in 3D Stayle, also das es aussieht wie bei XP, nur eben zusammen und nicht einzelne balken?

Das hast du schonmal gefragt. 3D Style Balken gibt´s nur bei Vista mit Aero . Und da spielt es überhault keine Rolle ob der Style $PBS_SMOOTH gesetzt ist oder nicht .

Jam00

ja, ih meine das es ausieht wie bei XP, nur benen zusammen! Und das hab ich uac schon bei XP gesehen! Gibt es da nich auch irgendein DLL für?

**GtaSpider**

Hallo

Nein gibt es nicht! Jedenfalls nicht direkt. Firefox hat es irgendwie geschafft (siehe unten Rechts, wenn eine Seite geladen wird), frag mich aber nicht wie.
Vielleicht mit GDI+ und dann selbst gezeichnet.

Mfg Spider

**peethebee**

Firefox macht seine Controls selbst (XUL). Daher geht es auch "schöner" als Windows (und die Linuxer mit eigenen Stilen haben es verflucht :D).

peethebee

Jam00

ich hab das aber auch schon gesehen, wenn man z.B. ein Pogramm instaliert, das der Balken auch wie bei XP war, nur zusammen! Wie macht man denn seine Steuerelemente selber?

**Oscar**

progandy hat da mal was erstellt: Progressbar mit GDIplus

Du darfst die Suche übrigens auch gern selbst mal benutzen.

Jam00

Hey, das sist cool ! Aber ganz einfach mit einem DLL geht es nicht? Es ist nähmlich serh viel arbeit! Aber geil

**Oscar**

Nein, einfach mit einer DLL geht es nicht!
Und wenn es nicht viel Arbeit wäre, hättest Du ja gar kein Erfolgsgefühl, wenn Du es geschafft hast.

Bit

Hallo!

Bei mir funktioniert Zeile 37 nicht.

AutoIt v3 Script (neu).au3 (37) : ==> Unknown function name.:
AdlibEnable('_SetProgress', 30)
^ ERROR

Habe sie durch
AdlibRegister('_SetProgress', 30)

ersetzt. Dann funktioniert es wie gewünscht.

Tolle Sache. Genau was ich brauche. Danke für den Code.

Gruß,
Bit.

m-obi

~~Gibts ja auch nicht mehr. Jetzt heißt es AdLib(Un-)Register.~~
Hast es ja schon gefunden.