_GUICtrlListView_DeleteAllItems
Beschreibung anzeigen in
Löscht alle Items eines ListView-Controls
#include <GuiListView.au3>
_GUICtrlListView_DeleteAllItems ( $hWnd )
Parameter
| $hWnd | Control-ID / Handle des Controls |
Rückgabewert
| Erfolg: | True |
| Fehler: | False |
Bemerkungen
Das löschen aller Items von einem native erstellen ListView kann einige Zeit dauern. Falls dies der Fall ist, ist es sinnvoll zusätzlich _GUICtrlListView_Begin/EndUpdate zu verwenden.
- - - - - - - - Erklärung der Controls - - - - - - - -
Verwandte Funktionen
_GUICtrlListView_DeleteItem, _GUICtrlListView_DeleteItemsSelected
Beispiel
Beispiel 1
#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <MsgBoxConstants.au3>
Example1()
Func Example1()
GUICreate("ListView: Löscht alle Items", 400, 500)
Local $idListView = GUICtrlCreateListView("Spalte 1 |Spalte 2 |Spalte 3 ", 10, 10, 380, 480, $LVS_SHOWSELALWAYS)
; Zeigt die GUI
GUISetState(@SW_SHOW)
; 3 Spalten laden
For $iI = 0 To 9
GUICtrlCreateListViewItem("Item " & $iI & "|Item " & $iI & "-1|Item " & $iI & "-2", $idListView)
Next
For $i = 10 To 20
_GUICtrlListView_AddItem($idListView, "UDF Item " & $i, -1, 1000 + $i)
_GUICtrlListView_AddSubItem($idListView, $i, "Item " & $i & "-1", 1)
_GUICtrlListView_AddSubItem($idListView, $i, "Item " & $i & "-2", 2)
Next
MsgBox($MB_SYSTEMMODAL, "Information", "Löscht alle Items")
; Verwendet die ControlID des erstellten ListViews
_GUICtrlListView_DeleteAllItems($idListView)
; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
; Löscht die obige GUI und alle Controls
GUIDelete()
EndFunc ;==>Example1
Beispiel 2
#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <MsgBoxConstants.au3>
Example() ; Ein ListView Control erstellt mit der ListView UDF.
Func Example()
Local $aItems[10][3]
Local $hGUI = GUICreate("(UDF) ListView: Löscht alle Items (v" & @AutoItVersion & ")", 400, 300)
Local $hListView = _GUICtrlListView_Create($hGUI, "Spalte1|Spalte2|Spalte3", 2, 2, 394, 268)
; Zeigt die GUI
GUISetState(@SW_SHOW)
; Setzt das ANSI Format
;~ _GUICtrlListView_SetUnicodeFormat($hListView, False)
; 3 Spalten laden
For $iI = 0 To UBound($aItems) - 1
$aItems[$iI][0] = "Item " & $iI
$aItems[$iI][1] = "Item " & $iI & "-1"
$aItems[$iI][2] = "Item " & $iI & "-2"
Next
_GUICtrlListView_AddArray($hListView, $aItems)
MsgBox($MB_SYSTEMMODAL, "Information", "Löscht alle Items")
; Verwendet das Handle eines mit der UDF erstellen ListViews
_GUICtrlListView_DeleteAllItems($hListView)
; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
; Löscht die GUI und alle Controls
GUIDelete()
EndFunc ;==>Example