Erstellt ein ListView-Control
#include <GuiListView.au3>
_GUICtrlListView_Create ( $hWnd, $sHeaderText, $iX, $iY [, $iWidth = 150 [, $iHeight = 150 [, $iStyle = 0x0000000D [, $iExStyle = 0x00000000 [, $bCoInit = False]]]]] )
$hWnd | Handle zum Eltern- oder Besitzerfenster |
$sHeaderText | Text in der Kopfzeile. Getrennt durch "|". |
$iX | Horizontale Position im Control |
$iY | Vertikale Position im Control |
$iWidth | [optional] Breite des Controls |
$iHeight | [optional] Höhe des Controls |
$iStyle | [optional] Stile des Controls: $LVS_ALIGNLEFT - Items werden in der "Icon" Ansicht und "kleine Icons" Ansicht links ausgerichtet $LVS_ALIGNTOP - Items werden in der "Icon" Ansicht und "kleine Icons" Ansicht oben ausgerichtet $LVS_AUTOARRANGE - Icons werden in der "Icon" Ansicht und "kleine Icons" Ansicht automatisch am Gitter eingerastet $LVS_EDITLABELS - Der Itemtext kann vor Ort geändert werden $LVS_ICON - Dieser Stil bestimmt die Iconansicht $LVS_LIST - Dieser Stil bestimmt die Listenansicht $LVS_NOCOLUMNHEADER - Die Spaltenüberschriften werden in der Report Ansicht nicht dargestellt $LVS_NOLABELWRAP - Der Itemtext wird in der "Icon" Ansicht in einer einzelnen Zeile dargestellt $LVS_NOSCROLL - Scrollen ist deaktiviert $LVS_NOSORTHEADER - Die Spaltenüberschriften funktionieren nicht wie Buttons $LVS_OWNERDATA - Dieser Stil bestimmt ein virtuelles Control $LVS_OWNERDRAWFIXED - Das eigene Fenster kann Items in der Report Ansicht darstellen $LVS_REPORT - Dieser Stil bestimmt die Report Ansicht $LVS_SHAREIMAGELISTS - Die Imagelist wird nicht gelöscht $LVS_SHOWSELALWAYS - Falls eine Markierung besteht, wird diese immer angezeigt $LVS_SINGLESEL - Es kann nur ein Item ausgewählt werden $LVS_SMALLICON - Dieser Stil bestimmt die "kleine Icons" Ansicht $LVS_SORTASCENDING - Itemindizes werden aufsteigend (ascending) sortiert $LVS_SORTDESCENDING - Itemindizes werden absteigend (descending) sortiert Standard: $LVS_REPORT, $LVS_SINGLESEL, $LVS_SHOWSELALWAYS erzwungen: $WS_CHILD, $WS_VISIBLE |
$iExStyle | [optional] Erweiterte Stile. Kann eine Kombination der folgenden sein: $LVS_EX_BORDERSELECT - Wenn ein Item markiert ist, ändert sich die Randfarbe des Items $LVS_EX_CHECKBOXES - Aktiviert Checkboxen für Items in einem ListView-Control $LVS_EX_DOUBLEBUFFER - Zeichnet mit double-buffering, welches das Flimmern reduziert $LVS_EX_FLATSB - Aktiviert flache Scrollbalken in dem ListView $LVS_EX_FULLROWSELECT - Wenn ein Item markiert ist, werden alle Items und all seine Subitems hervorgehoben $LVS_EX_GRIDLINES - Zeigt Gitternetzlinien rund um die Items und Subitems an $LVS_EX_HEADERDRAGDROP - Aktiviert die drag-and-drop Anordnung der Spalten $LVS_EX_INFOTIP - Die $LVN_GETINFOTIP Nachricht wird gesendet, bevor ein Tooltip angezeigt wird $LVS_EX_LABELTIP - Falls nicht gesetzt, werden teilweise versteckte Labels nur für die "große Icons" Ansicht angezeigt $LVS_EX_MULTIWORKAREAS - Das Control wird seine Icons nicht automatisch einrasten bis ein oder mehrere Arbeitsflächen definiert wurden $LVS_EX_ONECLICKACTIVATE - Das Control sendet eine $LVN_ITEMACTIVATE Nachricht wenn der Benutzer ein Item anklickt $LVS_EX_REGIONAL - Setzt den Bereich des Controls um nur die Icons und den Text der Item einzubeziehen $LVS_EX_SIMPLESELECT - In der "Icons" Ansicht wandert das Statusbild des Controls nach rechts oben $LVS_EX_SUBITEMIMAGES - Erlaubt es Bilder für Subitems darzustellen $LVS_EX_TRACKSELECT - Aktiviert "hot-track" Auswahl in dem Control $LVS_EX_TWOCLICKACTIVATE - Das Control sendet eine $LVN_ITEMACTIVATE Nachricht wenn der Benutzer ein Item mit einem Doppelklick angeklickt hat $LVS_EX_UNDERLINECOLD - "non-hot" Items werden aktiviert und der Text wird unterstrichen dargestellt $LVS_EX_UNDERLINEHOT - "Hot" Items werden aktiviert und mit unterstrichenem Text dargestellt |
$bCoInit | [optional] Initialisiert die COM Library zur Benutzung durch den aufrufenden Thread |
Erfolg: | das Handle des ListView-Controls |
Fehler: | 0 und setzt das @error Flag auf ungleich null |
@error: | 1 - ungültiges Fensterhandle 2 - Header-Text ist kein String |
Diese Funktion ist für erfahrene Benutzer und zum erlernen der Funktion von Controls.
- - - - - - - - Erklärung der Controls - - - - - - - -
_GUICtrlListView_Destroy, _GUICtrlListView_SetBkImage
#include <Extras\WM_NOTIFY.au3>
#include <GUIConstantsEx.au3>
#include <GuiImageList.au3>
#include <GuiListView.au3>
#include <WindowsConstants.au3>
Global $g_hListView
Example()
Func Example()
Local $hGUI, $hImage
$hGUI = GUICreate("ListView: Erstellen (v" & @AutoItVersion & ")", 400, 300)
$g_hListView = _GUICtrlListView_Create($hGUI, "", 2, 2, 394, 268)
_GUICtrlListView_SetExtendedListViewStyle($g_hListView, BitOR($LVS_EX_GRIDLINES, $LVS_EX_FULLROWSELECT, $LVS_EX_SUBITEMIMAGES))
GUISetState(@SW_SHOW)
_WM_NOTIFY_Register()
; Lädt die Bilder
$hImage = _GUIImageList_Create()
_GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($g_hListView, 0xFF0000, 16, 16))
_GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($g_hListView, 0x00FF00, 16, 16))
_GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($g_hListView, 0x0000FF, 16, 16))
_GUICtrlListView_SetImageList($g_hListView, $hImage, 1)
; Fügt die Spalten hinzu
_GUICtrlListView_InsertColumn($g_hListView, 0, "Spalte 1", 120)
_GUICtrlListView_InsertColumn($g_hListView, 1, "Spalte 2", 120)
_GUICtrlListView_InsertColumn($g_hListView, 2, "Spalte 3", 120)
; Fügt die Items hinzu
_GUICtrlListView_AddItem($g_hListView, "Zeile 1: Spalte 1", 0)
_GUICtrlListView_AddSubItem($g_hListView, 0, "Zeile 1: Spalte 2", 1)
_GUICtrlListView_AddSubItem($g_hListView, 0, "Zeile 1: Spalte 3", 2)
_GUICtrlListView_AddItem($g_hListView, "Zeile 2: Spalte 1", 1)
_GUICtrlListView_AddSubItem($g_hListView, 1, "Zeile 2: Spalte 2", 1)
_GUICtrlListView_AddItem($g_hListView, "Zeile 3: Spalte 1", 2)
; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
GUIDelete()
EndFunc ;==>Example
Func WM_NOTIFY($hWnd, $iMsg, $wParam, $lParam)
#forceref $hWnd, $iMsg, $wParam
Local $hWndListView = $g_hListView
If Not IsHWnd($g_hListView) Then $hWndListView = GUICtrlGetHandle($g_hListView)
Local $tNMHDR = DllStructCreate($tagNMHDR, $lParam)
Local $hWndFrom = HWnd(DllStructGetData($tNMHDR, "hWndFrom"))
Local $iCode = DllStructGetData($tNMHDR, "Code")
Switch $hWndFrom
Case $hWndListView
Switch $iCode
;~ Case $LVN_BEGINDRAG ; Eine "Ziehen und Ablegen"-Operation wurde ausgelöst, an der die linke Maustaste beteiligt ist
;~ _WM_NOTIFY_DebugEvent("$LVN_BEGINDRAG", $tagNMLISTVIEW, $lParam, "IDFrom,,Item,SubItem,NewState,OldState,Changed,ActionX,ActionY,Param")
;~ ; Kein Rückgabewert
;~ Case $LVN_BEGINLABELEDIT ; Beginn der Änderung der Itembezeichnung
;~ _WM_NOTIFY_DebugEvent("$LVN_BEGINLABELEDIT", $tagNMLVDISPINFO, $lParam, "IDFrom,,Mask,Item,SubItem,State,StateMask,Image,Param,Indent,,GroupID,Columns,pColumns")
;~ Return False ; Erlaubt dem Benutzer, die Bezeichnung zu ändern
;~ ;Return True ; Verbietet dem Benutzer, die Bezeichnung zu ändern
;~ Case $LVN_BEGINRDRAG ; Eine "Ziehen und Ablegen"-Operation wurde ausgelöst, an der die rechte Maustaste beteiligt ist
;~ _WM_NOTIFY_DebugEvent("$LVN_BEGINRDRAG", $tagNMLISTVIEW, $lParam, "IDFrom,,Item,SubItem,NewState,OldState,Changed,ActionX,ActionY,Param")
;~ ; Kein Rückgabewert
;~ Case $LVN_BEGINSCROLL ; Eine Scroll-Operation beginnt (Minimum WinXP)
;~ _WM_NOTIFY_DebugEvent("$LVN_BEGINSCROLL", $tagNMLVSCROLL, $lParam, "IDFrom,,DX,DY")
;~ ; Kein Rückgabewert
Case $LVN_COLUMNCLICK ; Eine Spalte wurde angeklickt
_WM_NOTIFY_DebugEvent("$LVN_COLUMNCLICK", $tagNMLISTVIEW, $lParam, "IDFrom,,Item,SubItem,NewState,OldState,Changed,ActionX,ActionY,Param")
; Kein Rückgabewert
;~ Case $LVN_DELETEALLITEMS ; Alle Items des Controls sollen gelöscht werden
;~ _WM_NOTIFY_DebugEvent("$LVN_DELETEALLITEMS", $tagNMLISTVIEW, $lParam, "IDFrom,,Item,SubItem,NewState,OldState,Changed,ActionX,ActionY,Param")
;~ Return True ; Unterdrückt die folgenden $LVN_DELETEITEM-Nachrichten
;~ ;Return False ; Empfängt die folgenden $LVN_DELETEITEM-Nachrichten
;~ Case $LVN_DELETEITEM ; Ein Item soll gelöscht werden
;~ _WM_NOTIFY_DebugEvent("$LVN_DELETEITEM", $tagNMLISTVIEW, $lParam, "IDFrom,,Item,SubItem,NewState,OldState,Changed,ActionX,ActionY,Param")
;~ ; Kein Rückgabewert
;~ Case $LVN_ENDLABELEDIT ; Ende der Änderung der Bezeichnung eines Items
;~ _WM_NOTIFY_DebugEvent("$LVN_ENDLABELEDIT", $tagNMLVDISPINFO, $lParam, "IDFrom,,Mask,Item,SubItem,State,StateMask,Image,Param,Indent,,GroupID,Columns,pColumns,,TextMax,*Text")
;~ ; Wenn das Input-Control nicht leer ist, führt der Rückgabewert True zum Übernehmen des Textes als Itembezeichnung, False verwirft den eingegebenen Text.
;~ ; Wenn das Input-Control leer ist, wird der Rückgabewert ignoriert
;~ Return True
;~ Case $LVN_ENDSCROLL ; Eine Scroll-Operation endet (Minimum WinXP)
;~ _WM_NOTIFY_DebugEvent("$LVN_ENDSCROLL", $tagNMLVSCROLL, $lParam, "IDFrom,,DX,DY")
;~ ; Kein Rückgabewert
;~ Case $LVN_GETDISPINFO ; Liefert Informationen, die für die Anzeige oder Sortierung eines ListView-Items benötigt werden
;~ _WM_NOTIFY_DebugEvent("$LVN_GETDISPINFO", $tagNMLVDISPINFO, $lParam, "IDFrom,,Mask,Item,SubItem,State,StateMask,Image,Param,Indent,,GroupID,Columns,pColumns,,TextMax,*Text")
;~ ; Kein Rückgabewert
;~ Case $LVN_GETINFOTIP ; Wird von einem ListView mit großen Icons gesendet, das den erweiterten Stil $LVS_EX_INFOTIP besitzt
;~ _WM_NOTIFY_DebugEvent("$LVN_GETINFOTIP", $tagNMLVGETINFOTIP, $lParam, "IDFrom,,Flags,Item,SubItem,lParam,,TextMax, *Text")
;~ ; Kein Rückgabewert
;~ Case $LVN_HOTTRACK ; Wird von einem ListView gesendet, wenn der Benutzer die Maus über ein Item bewegt
;~ _WM_NOTIFY_DebugEvent("$LVN_HOTTRACK", $tagNMLISTVIEW, $lParam, "IDFrom,,Item,SubItem,NewState,OldState,Changed,ActionX,ActionY,Param")
;~ Return 0 ; Erlaubt dem ListView, seine normale "Verfolgen und Auswählen"-Operation durchzuführen.
;~ ;Return 1 ; Das Item wird nicht ausgewählt.
;~ Case $LVN_INSERTITEM ; Ein neues Item wurde eingefügt
;~ _WM_NOTIFY_DebugEvent("$LVN_INSERTITEM", $tagNMLISTVIEW, $lParam, "IDFrom,,Item,SubItem,NewState,OldState,Changed,ActionX,ActionY,Param")
;~ ; Kein Rückgabewert
;~ Case $LVN_ITEMACTIVATE ; Wird von einem ListView gesendet, wenn der Benutzer ein Item aktiviert
;~ _WM_NOTIFY_DebugEvent("$LVN_ITEMACTIVATE", $tagNMITEMACTIVATE, $lParam, "IDFrom,,Index,SubItem,NewState,OldState,Changed,ActionX,ActionY,lParam,KeyFlags")
;~ Return 0
;~ Case $LVN_ITEMCHANGED ; Ein Item hat sich geändert
;~ _WM_NOTIFY_DebugEvent("$LVN_ITEMCHANGED", $tagNMLISTVIEW, $lParam, "IDFrom,,Item,SubItem,NewState,OldState,Changed,ActionX,ActionY,Param")
;~ ; Kein Rückgabewert
;~ Case $LVN_ITEMCHANGING ; Ein Item wird geändert
;~ _WM_NOTIFY_DebugEvent("$LVN_ITEMCHANGING", $tagNMLISTVIEW, $lParam, "IDFrom,,Item,SubItem,NewState,OldState,Changed,ActionX,ActionY,Param")
;~ Return True ; Verhindert das Ändern
;~ ;Return False ; Erlaubt das Ändern
Case $LVN_KEYDOWN ; Eine Taste wurde gedrückt
_WM_NOTIFY_DebugEvent("$LVN_KEYDOWN", $tagNMLVKEYDOWN, $lParam, "IDFrom,,VKey,Flags")
; Kein Rückgabewert
;~ Case $LVN_MARQUEEBEGIN ; Ein Auswahlrahmen (Marquee) wurde begonnen
;~ _WM_NOTIFY_DebugEvent("$LVN_MARQUEEBEGIN", $tagNMHDR, $lParam, "hWndFrom,IDFrom")
;~ Return 0 ; Akzeptiert die Nachricht
;~ ;Return 1 ; Bricht die Auswahlbox ab
;~ Case $LVN_SETDISPINFO ; Aktualisiert die enthaltenen Informationen über ein Item
;~ _WM_NOTIFY_DebugEvent("$LVN_SETDISPINFO", $tagNMLVDISPINFO, $lParam, "IDFrom,,Mask,Item,SubItem,State,StateMask,Image,Param,Indent,,GroupID,Columns,pColumns,,TextMax,*Text")
;~ ; Kein Rückgabewert
Case $NM_CLICK ; Wird vom ListView gesendet, wenn der Benutzer ein Item mit der linken Maustaste anklickt
_WM_NOTIFY_DebugEvent("$NM_CLICK", $tagNMITEMACTIVATE, $lParam, "IDFrom,,Index,SubItem,NewState,OldState,Changed,ActionX,ActionY,lParam,KeyFlags")
; Kein Rückgabewert
Case $NM_DBLCLK ; Wird vom ListView gesendet, wenn der Benutzer ein Item mit der linken Maustaste doppelklickt
_WM_NOTIFY_DebugEvent("$NM_DBLCLK", $tagNMITEMACTIVATE, $lParam, "IDFrom,,Index,SubItem,NewState,OldState,Changed,ActionX,ActionY,lParam,KeyFlags")
; Kein Rückgabewert
;~ Case $NM_HOVER ; Wird vom ListView gesendet, wenn die Maus über einem Item schwebt
;~ _WM_NOTIFY_DebugEvent("$NM_HOVER", $tagNMHDR, $lParam, "hWndFrom,IDFrom")
;~ Return 0 ; Normale Bearbeitung der Schwebe-Nachricht
;~ ;Return 1 ; Verbietet die Abarbeitung der Schwebe-Nachricht
Case $NM_KILLFOCUS ; Das Control hat den Eingabefokus verloren
_WM_NOTIFY_DebugEvent("$NM_KILLFOCUS", $tagNMHDR, $lParam, "hWndFrom,IDFrom")
; Kein Rückgabewert
Case $NM_RCLICK ; Wird vom ListView gesendet, wenn der Benutzer ein Item mit der rechten Maustaste anklickt
$tInfo = DllStructCreate($tagNMITEMACTIVATE, $lParam)
_WM_NOTIFY_DebugEvent("$NM_RCLICK", $tagNMITEMACTIVATE, $lParam, "IDFrom,,Index,SubItem,NewState,OldState,Changed,ActionX,ActionY,lParam,KeyFlags")
;Return 1 ; Verhindert die weitere Standard-Nachrichtenbehandlung
Return 0 ; Erlaubt die weitere Standard-Nachrichtenbehandlung
Case $NM_RDBLCLK ; Wird vom ListView gesendet, wenn der Benutzer ein Item mit der rechten Maustaste doppelklickt
$tInfo = DllStructCreate($tagNMITEMACTIVATE, $lParam)
_WM_NOTIFY_DebugEvent("$NM_RDBLCLK", $tagNMITEMACTIVATE, $lParam, "IDFrom,,Index,SubItem,NewState,OldState,Changed,ActionX,ActionY,lParam,KeyFlags")
; Kein Rückgabewert
Case $NM_RETURN ; Das Control hat den Eingabefokus und der Benutzer hat die ENTER-Taste gedrückt
_WM_NOTIFY_DebugEvent("$NM_RETURN", $tagNMHDR, $lParam, "hWndFrom,IDFrom")
; Kein Rückgabewert
Case $NM_SETFOCUS ; Das Control hat den Eingabefokus erhalten
_WM_NOTIFY_DebugEvent("$NM_SETFOCUS", $tagNMHDR, $lParam, "hWndFrom,IDFrom")
; Kein Rückgabewert
EndSwitch
EndSwitch
Return $GUI_RUNDEFMSG
EndFunc ;==>WM_NOTIFY