_GUICtrlListView_DeleteItemsSelected

Beschreibung anzeigen in

Löscht das/die markierte(n) Item(s)

#include <GuiListView.au3>
_GUICtrlListView_DeleteItemsSelected ( $hWnd )

Parameter

$hWnd

ID/Handle des Controls

Rückgabewert

Erfolg:	True
Fehler:	False

Bemerkungen

Das löschen aller Items von einem nativ erstellten ListView kann einige Zeit dauern. Falls dies der Fall ist, ist es sinnvoll zusätzlich _GUICtrlListView_Begin/EndUpdate zu verwenden.

- - - - - - - - Erklärung der Controls - - - - - - - -

Beispiel

Beispiel 1

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    GUICreate("ListView markierte Items löschen", 400, 500)
    Local $idListView = GUICtrlCreateListView("Spalte 1               |Spalte 2      |Spalte 3      ", 10, 10, 380, 480, BitOR($LVS_SHOWSELALWAYS, $LVS_NOSORTHEADER, $LVS_REPORT))
    _GUICtrlListView_SetExtendedListViewStyle($idListView, BitOR($LVS_EX_GRIDLINES, $LVS_EX_FULLROWSELECT))
    GUISetState(@SW_SHOW)

    For $i = 0 To 9
        GUICtrlCreateListViewItem("Native Item " & $i & "|Item " & $i & "-1|Item " & $i & "-2", $idListView)
    Next
    For $i = 10 To 20
        _GUICtrlListView_AddItem($idListView, "UDF Item " & $i, -1, 1000 + $i)
        _GUICtrlListView_AddSubItem($idListView, $i, "Item " & $i & "-1", 1)
        _GUICtrlListView_AddSubItem($idListView, $i, "Item " & $i & "-2", 2)
    Next

    MsgBox($MB_SYSTEMMODAL, "Ausgewählt", "Eines oder mehrere Items auswählen" & @CRLF & "Dann 'OK' drücken")

    ; Übergibt die Control-ID eines nativ erstellten ListViews um beide nativ- und UDF-erstellten Items zu löschen
    _GUICtrlListView_DeleteItemsSelected($idListView)

    ; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                ExitLoop

        EndSwitch
    WEnd

    ; Löscht die vorherige GUI und alle Controls.
    GUIDelete()
EndFunc   ;==>Example

Beispiel 2

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <MsgBoxConstants.au3>

Example_UDF_Created()

Func Example_UDF_Created()
    Local $aItems[10][3]

    Local $hGUI = GUICreate("ListView: Löscht die ausgewählten Items (UDF)", 400, 300)
    Local $hListView = _GUICtrlListView_Create($hGUI, "Spalte1|Spalte2|Spalte3", 2, 2, 394, 268, BitOR($LVS_SHOWSELALWAYS, $LVS_NOSORTHEADER, $LVS_REPORT))
    _GUICtrlListView_SetExtendedListViewStyle($idListView, BitOR($LVS_EX_GRIDLINES, $LVS_EX_FULLROWSELECT))
    GUISetState(@SW_SHOW)

    ; 3 Spalten laden
    For $iI = 0 To UBound($aItems) - 1
        $aItems[$iI][0] = "Item " & $iI
        $aItems[$iI][1] = "Item " & $iI & "-1"
        $aItems[$iI][2] = "Item " & $iI & "-2"
    Next

    _GUICtrlListView_AddArray($idListView, $aItems)

    MsgBox($MB_SYSTEMMODAL, "Ausgewählt", "Es sind ein oder mehrere Items auszuwählen" & @CRLF & "Dann 'OK' drücken")

    ; Verwendet das Handle eines mit der UDF erstellen ListViews
    _GUICtrlListView_DeleteItemsSelected($idListView)

    ; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    ; Löscht die GUI und alle Controls
    GUIDelete()
EndFunc   ;==>Example_UDF_Created

Funktionreferenz