Funktionreferenz


_GUICtrlRichEdit_GetBkColor

Beschreibung anzeigen in

Ermittelt die Hintergrundfarbe des Controls

#include <GuiRichEdit.au3>
_GUICtrlRichEdit_GetBkColor ( $hWnd )

Parameter

$hWnd Handle des Controls

Rückgabewert

Erfolg: ein COLORREF Wert
Fehler: Setzt das @error Flag auf ungleich null
@error: 101 - $hWnd ist kein Handle

Bemerkungen

Falls ein Farbarray erstellt werden soll, so ist _ColorGetCOLORREF() anstatt _ColorGetRGB() zu verwenden.

- - - - - - - - Erklärung der Controls - - - - - - - -

Verwandte Funktionen

_GUICtrlRichEdit_SetBkColor

Siehe auch

Suche nach EM_SETBKGNDCOLOR in der MSDN Bibliothek.

Beispiel

#include <Color.au3>
#include <GUIConstantsEx.au3>
#include <GuiRichEdit.au3>
#include <WindowsConstants.au3>

Global $g_idLblMsg, $g_hRichEdit

Example()

Func Example()
    Local $hGui, $iMsg, $idBtnNext, $iStep = 0
    $hGui = GUICreate("Beispiel (" & StringTrimRight(@ScriptName, 4) & ")", 320, 350, -1, -1)
    $g_hRichEdit = _GUICtrlRichEdit_Create($hGui, "", 10, 10, 300, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    $g_idLblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
    $idBtnNext = GUICtrlCreateButton("Weiter", 270, 310, 40, 30)
    GUISetState(@SW_SHOW)

    _GUICtrlRichEdit_SetText($g_hRichEdit, "Absatz 1")
    While True
        $iMsg = GUIGetMsg()
        Select
            Case $iMsg = $GUI_EVENT_CLOSE
                _GUICtrlRichEdit_Destroy($g_hRichEdit) ; wird benötigt, da sonst das Skript abstürzt
;~              GUIDelete()     ; ist auch in Ordnung
                Exit
            Case $iMsg = $idBtnNext
                $iStep += 1
                Switch $iStep
                    Case 1
                        _GUICtrlRichEdit_SetBkColor($g_hRichEdit, 0xE8CCCC)
                        Report("1. Gefärbter Hintergrund")
                    Case 2
                        _GUICtrlRichEdit_SetBkColor($g_hRichEdit)
                        Report("2. Zurück zu Weiß")
                    Case 3
                        _GUICtrlRichEdit_SetBkColor($g_hRichEdit, 0xB3B3C7)
                        Report("3. Gefärbter Hintergrund, erneut")
                        ; Speichert den ganzen Text auf dem Desktop damit sie die Einstellungen in Word auslesen können
                        _GUICtrlRichEdit_StreamToFile($g_hRichEdit, @DesktopDir & "\gcre.rtf")
                        GUICtrlSetState($idBtnNext, $GUI_DISABLE)
                EndSwitch
        EndSelect
    WEnd
EndFunc   ;==>Example

Func Report($sMsg)
    Local $iBngColor = _GUICtrlRichEdit_GetBkColor($g_hRichEdit)
    Local $aRet = _ColorGetRGB($iBngColor)
    $sMsg = $sMsg & @CR & @CR & $aRet[0] & ";" & $aRet[1] & ";" & $aRet[2] & " BngColor=0x" & Hex($iBngColor)
    GUICtrlSetData($g_idLblMsg, $sMsg)
EndFunc   ;==>Report