_GUICtrlRichEdit_GetCharPosFromXY

Beschreibung anzeigen in

Ermittelt die Zeichenposition, die am nächsten an einem bestimmten Punkt im Control ist

#include <GuiRichEdit.au3>
_GUICtrlRichEdit_GetCharPosFromXY ( $hWnd, $iX, $iY )

Parameter

$hWnd	Handle des Controls
$iX	Die horizontale Koordinate relativ zum linken Rand des Controls (X-Koordinate)
$iY	Die vertikale Koordinate relativ zum oberen Rand des Controls (Y-Koordinate)

Rückgabewert

Erfolg:	die 0-basierende Zeichenposition, die am nächsten an dem Punkt ist (Index des letzten Zeichens im Control, wenn der Punkt über den Text hinaus geht.)
Fehler:	0 und setzt das @error Flag auf ungleich null
@error:	101 - $hWnd ist kein Handle 102 - $iX ist keine Zahl 103 - $iY ist keine Zahl -1 - ($iX,$iY) ist außerhalb des Controls

Bemerkungen

- - - - - - - - Erklärung der Controls - - - - - - - -

Siehe auch

Suche nach EM_CHARFROMPOS in der MSDN Bibliothek.

Beispiel

#include <GUIConstantsEx.au3>
#include <GuiRichEdit.au3>
#include <WindowsConstants.au3>

Global $g_idLblMsg

Example()

Func Example()
    Local $hGui, $iMsg, $aiPos, $idBtnNext, $hRichEdit, $iStep = 0
    $hGui = GUICreate("Beispiel (" & StringTrimRight(@ScriptName, 4) & ")", 320, 350, -1, -1)
    $hRichEdit = _GUICtrlRichEdit_Create($hGui, "Dies ist ein Test.", 10, 10, 300, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    $g_idLblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
    $idBtnNext = GUICtrlCreateButton("Weiter", 270, 310, 40, 30)
    GUISetState(@SW_SHOW)

    _GUICtrlRichEdit_AppendText($hRichEdit, @CR & "Dies ist ein angehängter Text.")

    While True
        $iMsg = GUIGetMsg()
        Select
            Case $iMsg = $GUI_EVENT_CLOSE
                _GUICtrlRichEdit_Destroy($hRichEdit) ; wird benötigt, da sonst das Skript abstürzt
;~              GUIDelete()     ; ist auch in Ordnung
                Exit
            Case $iMsg = $idBtnNext
                $iStep += 1
                Switch $iStep
                    Case 1
                        $aiPos = _GUICtrlRichEdit_GetXYFromCharPos($hRichEdit, 20)
                        Report("1. Die Koordinaten der Zeichenposition 20 sind (" & $aiPos[0] & "," & $aiPos[1] & ")")
                    Case 2
                        Report("2. Die Zeichenposition bei oder nahe den Koordinaten (" & $aiPos[0] & "," & $aiPos[1] & ")" & @CR & _
                                "ist " & _GUICtrlRichEdit_GetCharPosFromXY($hRichEdit, $aiPos[0], $aiPos[1]))
                        GUICtrlSetState($idBtnNext, $GUI_DISABLE)
                EndSwitch
        EndSelect
    WEnd
EndFunc   ;==>Example

Func Report($sMsg)
    GUICtrlSetData($g_idLblMsg, $sMsg)
EndFunc   ;==>Report