_GUICtrlRichEdit_GetXYFromCharPos

Beschreibung anzeigen in

Ermittelt die XY Koordinaten einer Zeichenposition

#include <GuiRichEdit.au3>
_GUICtrlRichEdit_GetXYFromCharPos ( $hWnd, $iCharPos )

Parameter

$hWnd	Handle des Controls
$iCharPos	Zeichenposition

Rückgabewert

Erfolg:	Ein Array [$iX, $iY] - Koordinaten der Zeichenposition relativ zum linken oberen Ende des Controls
Fehler:	Setzt das @error Flag auf ungleich null
@error:	101 - $hWnd ist kein Handle 1021 - $iCharPos ist < 0 1022 - $iCharPos überschreitet die Anzahl der Zeichen im Control

Bemerkungen

Die erste Zeichenposition ist 0.

Mit einem Control, das mehrere Zeilen hat, werden auch die Zeichenpositionen zurückgegeben, die unsichtbar sind.

- - - - - - - - Erklärung der Controls - - - - - - - -

Siehe auch

Suche nach EM_POSFROMCHAR in der MSDN Bibliothek.

Beispiel

#include <GUIConstantsEx.au3>
#include <GuiRichEdit.au3>
#include <WindowsConstants.au3>

Global $g_idLblMsg

Example()

Func Example()
    Local $hGui, $iMsg, $hRichEdit, $aiPos, $idBtnNext, $iStep = 0
    $hGui = GUICreate("Beispiel (" & StringTrimRight(@ScriptName, 4) & ")", 320, 350, -1, -1)
    $hRichEdit = _GUICtrlRichEdit_Create($hGui, "Dies ist ein Test.", 10, 10, 300, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    $g_idLblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
    $idBtnNext = GUICtrlCreateButton("Weiter", 270, 310, 40, 30)
    GUISetState(@SW_SHOW)

    _GUICtrlRichEdit_AppendText($hRichEdit, @CR & "Dies ist ein angehängter Text.")

    While True
        $iMsg = GUIGetMsg()
        Select
            Case $iMsg = $GUI_EVENT_CLOSE
                _GUICtrlRichEdit_Destroy($hRichEdit) ; wird benötigt, da sonst das Skript abstürzt
;~              GUIDelete()     ; ist auch in Ordnung
                Exit
            Case $iMsg = $idBtnNext
                $iStep += 1
                Switch $iStep
                    Case 1
                        $aiPos = _GUICtrlRichEdit_GetXYFromCharPos($hRichEdit, 20)
                        Report("1. Die Koordinaten der Zeichenposition 20 sind (" & $aiPos[0] & "," & $aiPos[1] & ")")
                    Case 2
                        Report("2. Die Zeichenposition bei oder nahe den Koordinaten (" & $aiPos[0] & "," & $aiPos[1] & ")" & @CR & _
                                "ist " & _GUICtrlRichEdit_GetCharPosFromXY($hRichEdit, $aiPos[0], $aiPos[1]))
                        GUICtrlSetState($idBtnNext, $GUI_DISABLE)
                EndSwitch
        EndSelect
    WEnd
EndFunc   ;==>Example

Func Report($sMsg)
    GUICtrlSetData($g_idLblMsg, $sMsg)
EndFunc   ;==>Report