_GUICtrlRichEdit_GetParaIndents

Beschreibung anzeigen in

Ermittelt die Zeileneinzüge des (ersten) markierten Absatzes oder, wenn keiner markiert ist, des aktuellen Absatzes

#include <GuiRichEdit.au3>
_GUICtrlRichEdit_GetParaIndents ( $hWnd )

Parameter

$hWnd

Handle des Controls

Rückgabewert

Erfolg:	Die Einstellungen - Ein aus vier Werten zusammengesetzter String, getrennt durch Semikola ";": Wert 1 - Links - Einrückung der linken Seite des Absatzes (der Zeilen nach der ersten) Wert 2 - Rechts - Einrückung der rechten Seite des Absatzes Wert 3 - Erste Zeile - Einrückung der ersten Zeile (links) relativ zu der der anderen Wert 4 - Bereich: a - Alle markierten Absätze haben diese Einstellungen b - Der erste Absatz hat diese Einstellungen, die anderen nicht c - Der aktuelle Absatz hat diese Einstellungen
Fehler:	"" und setzt das @error Flag auf ungleich null
@error:	101 - $hWnd ist kein Handle

Bemerkungen

Positive Werte von $iLeft, $iRight und $iFirstLine rücken in Richtung der Mitte des Absatzes.

Alle Werte sind in der aktuellen Maßeinheit des Controls (Standard: Inch).

- - - - - - - - Erklärung der Controls - - - - - - - -

Siehe auch

Suche nach EM_GETPARAFORMAT in der MSDN Bibliothek.

Beispiel

#include <GUIConstantsEx.au3>
#include <GuiRichEdit.au3>
#include <WindowsConstants.au3>

Global $g_idLblMsg, $g_hRichEdit

Example()

Func Example()
    Local $hGui, $iMsg, $idBtnNext, $iStep = 0
    $hGui = GUICreate("Beispiel (" & StringTrimRight(@ScriptName, 4) & ")", 320, 350, -1, -1)
    $g_hRichEdit = _GUICtrlRichEdit_Create($hGui, "Dies ist ein Test.", 10, 10, 300, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    $g_idLblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
    $idBtnNext = GUICtrlCreateButton("Weiter", 270, 310, 40, 30)
    GUISetState(@SW_SHOW)

    _GUICtrlRichEdit_SetText($g_hRichEdit, "Erster Absatz")
    Report("Absatz mit den Standardeigenschaften")

    While True
        $iMsg = GUIGetMsg()
        Select
            Case $iMsg = $GUI_EVENT_CLOSE
                _GUICtrlRichEdit_Destroy($g_hRichEdit) ; wird benötigt, da sonst das Skript abstürzt
;~              GUIDelete()     ; ist auch in Ordnung
                Exit
            Case $iMsg = $idBtnNext
                $iStep += 1
                Switch $iStep
                    Case 1
                        _GUICtrlRichEdit_AppendText($g_hRichEdit, @CR & "Zweiter Absatz")
                        Report("Füge einen weiteren Absatz hinzu")
                    Case 2
                        _GUICtrlRichEdit_SetParaIndents($g_hRichEdit, 0.25, .1)
                        Report("Ändere die Eigenschaften des zweiten Absatzes")
                    Case 3
                        _GUICtrlRichEdit_SetSel($g_hRichEdit, 10, 26)
                        _GUICtrlRichEdit_SetParaIndents($g_hRichEdit, Default, 0, .2)
                        Report("Ändere die Eigenschaften beider Absätze")
                    Case 4
                        ; Zeichnet allen Text in einer Datei auf dem Desktop auf, um dessen Eigenschaften in Word anzuzeigen
                        _GUICtrlRichEdit_Deselect($g_hRichEdit)
                        _GUICtrlRichEdit_StreamToFile($g_hRichEdit, @DesktopDir & "\gcre.rtf")
                        GUICtrlSetState($idBtnNext, $GUI_DISABLE)
                EndSwitch
        EndSelect
    WEnd
EndFunc   ;==>Example

Func Report($sMsg)
    $sMsg = $sMsg & @CR & @CR & "Die Rückgaben der Funktion " & @CR & _GUICtrlRichEdit_GetParaIndents($g_hRichEdit)
    GUICtrlSetData($g_idLblMsg, $sMsg)
EndFunc   ;==>Report