_GUICtrlRichEdit_GetParaShading
Beschreibung anzeigen in
Ermittelt die Schattierungseinstellungen des (ersten) markierten Absatzes oder, wenn keiner markiert ist, die des aktuellen Absatzes
#include <GuiRichEdit.au3>
_GUICtrlRichEdit_GetParaShading ( $hWnd )
Parameter
| $hWnd | Handle des Controls |
Rückgabewert
| Erfolg: | Ein String, der die durch Semikola (;) getrennten Einstellungen des Absatzes enthält: Wert 1 - Gewichtung - Anteil (in %) der Vordergrundfarbe, der Rest ist Hintergrundfarbe Wert 2 - Stil - String, der einen der folgenden Werte enthält: non - keiner dhz - dunkel, horizontal dvt - dunkel, vertikal ddd - dunkel, diagonal abwärts dud - dunkel, diagonal aufwärts dgr - dunkel, netzförmig dtr - dunkel, gitterförmig lhz - hell, horizontal lvt - hell, vertikal ldd - hell, diagonal abwärts lud - hell, diagonal aufwärts lgr - hell, netzförmig ltr - hell, gitterförmig Wert 3 - Vordergrundfarbe - eine der folgenden: "blk" - schwarz "blu" - blau "cyn" - zyan "grn" - grün "mag" - magenta "red" - rot "yel" - gelb "whi" - weiß "dbl" - dunkles blau "dgn" - dunkles grün "dmg" - dunkles magenta "drd" - dunkles rot "dyl" - dunkles gelb "dgy" - dunkles grau "lgy" - helles grau Wert 4 - Hintergrundfarbe - gleiche Werte wie bei Vordergrundfarbe (Wert 3) Wert 5 - Geltungsbereich: a - Alle (oder nur die) ausgewählten Absätze haben diese Einstellungen f - Ausschließlich der erste ausgewählte Absatz hat diese Einstellungen c - Der aktuelle Absatz hat diese Einstellungen |
| Fehler: | "" und setzt das @error Flag auf ungleich null |
| @error: | 101 - $hWnd ist kein Handle |
Bemerkungen
Unter Word 2007 führen die Codes für den Schattierungsstil nicht zu den erwarteten Ergebnissen, also ggf. vorher ausprobieren!
Ein RichEdit-Control zeigt keine Schattierungen an, aber hier erstellte Schattierungen werden in Word angezeigt.
- - - - - - - - Erklärung der Controls - - - - - - - -
Verwandte Funktionen
_GUICtrlRichEdit_SetParaShading
Siehe auch
Suche nach EM_SETPARAFORMAT in der MSDN Bibliothek.
Beispiel
#include <GUIConstantsEx.au3>
#include <GuiRichEdit.au3>
#include <WindowsConstants.au3>
Global $g_idLblMsg, $g_hRichEdit
Example()
Func Example()
Local $hGui, $iMsg, $idBtnNext, $iStep = 0
$hGui = GUICreate("Beispiel (" & StringTrimRight(@ScriptName, 4) & ")", 320, 350, -1, -1)
$g_hRichEdit = _GUICtrlRichEdit_Create($hGui, "Dies ist ein Test.", 10, 10, 300, 220, _
BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
$g_idLblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
$idBtnNext = GUICtrlCreateButton("Weiter", 270, 310, 40, 30)
GUISetState(@SW_SHOW)
_GUICtrlRichEdit_SetText($g_hRichEdit, "Erster Absatz")
Report("0. Absatz mit den Standardeinstellungen")
While True
$iMsg = GUIGetMsg()
Select
Case $iMsg = $GUI_EVENT_CLOSE
_GUICtrlRichEdit_Destroy($g_hRichEdit) ; wird benötigt, da sonst das Skript abstürzt
;~ GUIDelete() ; ist auch in Ordnung
Exit
Case $iMsg = $idBtnNext
$iStep += 1
Switch $iStep
Case 1
_GUICtrlRichEdit_AppendText($g_hRichEdit, @CR & "Zweiter Absatz")
_GUICtrlRichEdit_SetParaShading($g_hRichEdit, 60, "ddd", "blu", "dmg")
Report("1. Die Schattierung des ersten Absatzes ist ")
Case 2
_GUICtrlRichEdit_SetSel($g_hRichEdit, 0, 2)
Report("2. Das Aussehen des ersten Absatzes in der Auswahl ist ")
Case 3
_GUICtrlRichEdit_SetSel($g_hRichEdit, 10, 26)
_GUICtrlRichEdit_SetParaShading($g_hRichEdit, Default, "dgr")
Report("3. Ändert die Schattierung beider Absätze")
Case 4
; Zeichnet allen Text in einer Datei auf dem Desktop auf, um dessen Eigenschaften in Word anzuzeigen
_GUICtrlRichEdit_Deselect($g_hRichEdit)
_GUICtrlRichEdit_StreamToFile($g_hRichEdit, @DesktopDir & "\gcre.rtf")
GUICtrlSetState($idBtnNext, $GUI_DISABLE)
EndSwitch
EndSelect
WEnd
EndFunc ;==>Example
Func Report($sMsg)
$sMsg = $sMsg & @CR & @CR & "Rückgaben der Funktion " & @CR & _GUICtrlRichEdit_GetParaShading($g_hRichEdit)
GUICtrlSetData($g_idLblMsg, $sMsg)
EndFunc ;==>Report