Ermittelt die Scrollposition in dem Control
#include <GuiRichEdit.au3>
_GUICtrlRichEdit_GetScrollPos ( $hWnd )
$hWnd | Handle des Controls |
Erfolg: | Ein Array welches [x, y] enthält |
Fehler: | Setzt das @error Flag auf ungleich null |
@error: | 101 - $hWnd ist kein Handle |
Die Scrollposition ist die obere linke Ecke des Controls
- - - - - - - - Erklärung der Controls - - - - - - - -
_GUICtrlRichEdit_GetSelAA, _GUICtrlRichEdit_SetScrollPos
Suche nach EM_GETSCROLLPOS in der MSDN Bibliothek.
#include <GUIConstantsEx.au3>
#include <GuiRichEdit.au3>
#include <WindowsConstants.au3>
Global $g_idLblMsg, $g_hRichEdit
Example()
Func Example()
Local $hGui = GUICreate("RichEdit: Setzt und ermittelt ide Scrollposition (v" & @AutoItVersion & ")", 460, 350, -1, -1)
$g_hRichEdit = _GUICtrlRichEdit_Create($hGui, "", 10, 10, 340, 220, _
BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
$g_idLblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
Local $idBtnNext = GUICtrlCreateButton("Weiter", 270, 310, 40, 30)
GUISetState(@SW_SHOW)
_GUICtrlRichEdit_SetText($g_hRichEdit, "Absatz 1")
For $i = 2 To 20
_GUICtrlRichEdit_AppendText($g_hRichEdit, @CRLF & "Absatz " & $i)
Next
Report("0. Zuerst ans Ende verschoben, um den Einfügepunkt zu zeigen")
Local $iMsg, $iStep = 0
While True
$iMsg = GUIGetMsg()
Select
Case $iMsg = $GUI_EVENT_CLOSE
_GUICtrlRichEdit_Destroy($g_hRichEdit) ; wird benötigt, da sonst das Skript abstürzt
;~ GUIDelete() ; ist auch in Ordnung
Exit
Case $iMsg = $idBtnNext
$iStep += 1
Switch $iStep
Case 1
_GUICtrlRichEdit_SetScrollPos($g_hRichEdit, 0, 0)
Report("1. Zum Anfang verschoben")
Case 2
_GUICtrlRichEdit_SetScrollPos($g_hRichEdit, 7, 22)
Report("2. Nach rechts unten verschoben")
GUICtrlSetState($idBtnNext, $GUI_DISABLE)
EndSwitch
EndSelect
WEnd
EndFunc ;==>Example
Func Report($sMsg)
Local $aPos = _GUICtrlRichEdit_GetScrollPos($g_hRichEdit)
$sMsg = $sMsg & @CR & @CR & "Die Position ist " & $aPos[0] & ";" & $aPos[1]
GUICtrlSetData($g_idLblMsg, $sMsg)
EndFunc ;==>Report