Versteckt (oder zeigt) eine Markierung
#include <GuiRichEdit.au3>
_GUICtrlRichEdit_HideSelection ( $hWnd [, $bHide = True] )
$hWnd | Handle des Controls |
$bHide | [optional] True - verstecken False - zeigen Standard: verstecken |
Erfolg: | True |
Fehler: | False und setzt das @error Flag auf ungleich null |
@error: | 101 - $hWnd ist kein Handle 102 - $bHide muss True oder False sein |
- - - - - - - - Erklärung der Controls - - - - - - - -
Suche nach EM_HIDESELECTION in der MSDN Bibliothek.
#include <GUIConstantsEx.au3>
#include <GuiRichEdit.au3>
#include <WindowsConstants.au3>
Global $g_idLblMsg, $g_hRichEdit
Example()
Func Example()
Local $hGui, $iMsg, $idBtnNext, $iStep = 0
$hGui = GUICreate("Beispiel (" & StringTrimRight(@ScriptName, 4) & ")", 320, 350, -1, -1)
$g_hRichEdit = _GUICtrlRichEdit_Create($hGui, "Dies ist ein Text.", 10, 10, 300, 220, _
BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
$g_idLblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
$idBtnNext = GUICtrlCreateButton("Weiter", 270, 310, 40, 30)
GUISetState(@SW_SHOW)
_GUICtrlRichEdit_SetText($g_hRichEdit, "Erster Absatz")
While True
$iMsg = GUIGetMsg()
Select
Case $iMsg = $GUI_EVENT_CLOSE
_GUICtrlRichEdit_Destroy($g_hRichEdit) ; wird benötigt, da sonst das Skript abstürzt
;~ GUIDelete() ; ist auch in Ordnung
Exit
Case $iMsg = $idBtnNext
$iStep += 1
Switch $iStep
Case 1
_GUICtrlRichEdit_SetSel($g_hRichEdit, 2, 5)
Report("Text ist markiert")
Case 2
_GUICtrlRichEdit_HideSelection($g_hRichEdit, True)
Report("Auswahl ist versteckt")
Case 3
_GUICtrlRichEdit_HideSelection($g_hRichEdit, False)
Report("Auswahl ist nicht versteckt")
GUICtrlSetState($idBtnNext, $GUI_DISABLE)
EndSwitch
EndSelect
WEnd
EndFunc ;==>Example
Func Report($sMsg)
Local $sRet = _GUICtrlRichEdit_GetCharAttributes($g_hRichEdit)
$sMsg = $sMsg & @CR & @CR & "Zeichenattribute=" & $sRet
GUICtrlSetData($g_idLblMsg, $sMsg)
EndFunc ;==>Report