_GUICtrlRichEdit_SetParaSpacing

Beschreibung anzeigen in

Ändert den Zeilenabstand und Absatzabstand von markierten Absätzen oder, wenn keine markiert sind, für den Text, der nach dem Einfügungspunkt (Cursor) eingefügt wird

#include <GuiRichEdit.au3>
_GUICtrlRichEdit_SetParaSpacing ( $hWnd [, $vInter = Default [, $iBefore = Default [, $iAfter = Default]]] )

Parameter

$hWnd	Handle des Controls
$vInter	[optional] Abstand zwischen den Zeilen: Entweder: Eine Zahl - in Leerzeichen-Einheiten oder: " lines" - in Zeilen
$iBefore	[optional] Abstand über den Absätzen (in Leerzeichen-Einheiten)
$iAfter	[optional] Abstand unter den Absätzen (in Leerzeichen-Einheiten)

Rückgabewert

Erfolg:	True.
Fehler:	False und setzt das @error Flag auf ungleich null.
@error:	101 - $hWnd ist kein Handle 103 - $iBefore < 0 104 - $iAfter < 0 1021 - $vInter ist ungültig 1022 - Nur 1, 1.5 oder 2 " lines" können als Zeilenabstand gesetzt werden - " lines"

Bemerkungen

Es werden nur Werte geändert, die nicht mit 'Default' gesetzt sind.

Um die Leerzeichen-Einheit zu ändern (Standard: Inch), ist _GUICtrlRichEdit_SetSpaceUnit() zu benutzen.

- - - - - - - - Erklärung der Controls - - - - - - - -

Siehe auch

Suche nach EM_SETPARAFORMAT in der MSDN Bibliothek.

Beispiel

#include <GUIConstantsEx.au3>
#include <GuiRichEdit.au3>
#include <WindowsConstants.au3>

Global $g_idLblMsg, $g_hRichEdit

Example()

Func Example()
    Local $hGui, $iMsg, $idBtnNext, $iStep = 0
    $hGui = GUICreate("Beispiel (" & StringTrimRight(@ScriptName, 4) & ")", 320, 350, -1, -1)
    $g_hRichEdit = _GUICtrlRichEdit_Create($hGui, "Dies ist ein Test.", 10, 10, 300, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    $g_idLblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
    $idBtnNext = GUICtrlCreateButton("Weiter", 270, 310, 40, 30)
    GUISetState(@SW_SHOW)

    _GUICtrlRichEdit_SetText($g_hRichEdit, "Erster Absatz")
    Report("0. Absatz mit den Standardeinstellungen")

    While True
        $iMsg = GUIGetMsg()
        Select
            Case $iMsg = $GUI_EVENT_CLOSE
                _GUICtrlRichEdit_Destroy($g_hRichEdit) ; wird benötigt, da sonst das Skript abstürzt
;~              GUIDelete()     ; ist auch in Ordnung
                Exit
            Case $iMsg = $idBtnNext
                $iStep += 1
                Switch $iStep
                    Case 1
                        _GUICtrlRichEdit_AppendText($g_hRichEdit, @CR & "Zweiter Absatz")
                        _GUICtrlRichEdit_SetParaSpacing($g_hRichEdit, "2 lines", .2, .25)
                        Report("1. Der Abstand des zweiten Absatzes ist ")
                    Case 2
                        _GUICtrlRichEdit_SetSel($g_hRichEdit, 0, 2)
                        Report("2. Die Einstellungen des ersten Absatzes in der Auswahl sind ")
                    Case 3
                        _GUICtrlRichEdit_SetSel($g_hRichEdit, 10, 26)
                        _GUICtrlRichEdit_SetParaSpacing($g_hRichEdit, Default, .1)
                        Report("3. Ändere den Abstand beider Absätze")
                    Case 4
                        ; Streamt den Text in eine Datei auf dem Desktop, um dessen Eigenschaften in Word ansehen zu können.
                        _GUICtrlRichEdit_Deselect($g_hRichEdit)
                        _GUICtrlRichEdit_StreamToFile($g_hRichEdit, @DesktopDir & "\gcre.rtf")
                        GUICtrlSetState($idBtnNext, $GUI_DISABLE)
                EndSwitch
        EndSelect
    WEnd
EndFunc   ;==>Example

Func Report($sMsg)
    $sMsg = $sMsg & @CR & @CR & "Rückgaben der Funktion " & @CR & _GUICtrlRichEdit_GetParaSpacing($g_hRichEdit)
    GUICtrlSetData($g_idLblMsg, $sMsg)
EndFunc   ;==>Report