_GUICtrlRichEdit_SetUndoLimit
Beschreibung anzeigen in
Setzt die maximale Anzahl von Befehlen die in der Undo-Reihe gespeichert werden können
#include <GuiRichEdit.au3>
_GUICtrlRichEdit_SetUndoLimit ( $hWnd, $iLimit )
Parameter
| $hWnd | Handle des Controls |
| $iLimit | Die maximale Anzahl von Befehlen die in der Undo-Rehe gespeichert werden können |
Rückgabewert
| Erfolg: | True. |
| Fehler: | False und setzt das @error Flag auf ungleich null. |
| @error: | 101 - $hWnd ist kein Handle 102 - $iLimit ist weder eine positive Zahl noch Null |
Bemerkungen
Um das Undo-Feature zu deaktivieren ist $iLimit auf Null zu setzen
Der Standardwert von $iLimit ist 100.
- - - - - - - - Erklärung der Controls - - - - - - - -
Verwandte Funktionen
_GUICtrlRichEdit_CanRedo, _GUICtrlRichEdit_CanUndo, _GUICtrlRichEdit_GetNextRedo, _GUICtrlRichEdit_Redo, _GUICtrlRichEdit_Undo
Siehe auch
Suche nach EM_SETUNDOLIMIT in der MSDN Bibliothek.
Beispiel
#include <GUIConstantsEx.au3>
#include <GuiRichEdit.au3>
#include <WindowsConstants.au3>
Example()
Func Example()
Local $hGui, $iMsg, $idBtnNext, $iStep = 0, $idLblMsg, $hRichEdit
$hGui = GUICreate("Beispiel (" & StringTrimRight(@ScriptName, 4) & ")", 320, 350, -1, -1)
$hRichEdit = _GUICtrlRichEdit_Create($hGui, "Dies ist ein Test.", 10, 10, 300, 220, _
BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
$idLblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
$idBtnNext = GUICtrlCreateButton("Weiter", 270, 310, 40, 30)
GUISetState(@SW_SHOW)
_GUICtrlRichEdit_SetText($hRichEdit, "Erster Absatz")
While True
$iMsg = GUIGetMsg()
Select
Case $iMsg = $GUI_EVENT_CLOSE
_GUICtrlRichEdit_Destroy($hRichEdit) ; wird benötigt, da sonst das Skript abstürzt
;~ GUIDelete() ; ist auch in Ordnung
Exit
Case $iMsg = $idBtnNext
$iStep += 1
Switch $iStep
Case 1
_GUICtrlRichEdit_SetUndoLimit($hRichEdit, 200)
GUICtrlSetData($idLblMsg, 'Anzahl der Aktionen, die in der Rückgängig-Schlange gespeichert werden können, von 100 auf 200 erhöht')
Case 2
_GUICtrlRichEdit_SetUndoLimit($hRichEdit, 0)
GUICtrlSetData($idLblMsg, "Rückgängig ist deaktiviert")
GUICtrlSetState($idBtnNext, $GUI_DISABLE)
EndSwitch
EndSelect
WEnd
EndFunc ;==>Example