Tauscht das Bild zwischen dem Quell- und Zielindex aus
#include <GuiImageList.au3>
_GUIImageList_Swap ( $hWnd, $iSource, $iDestination )
$hWnd | Handle der Imagelist |
$iSource | Der 0-basierende Index des Quellbildes für die Tauschoperation |
$iDestination | Der 0-basierende Index des Zielbildes für die Tauschoperation |
Erfolg: | True |
Fehler: | False |
- - - - - - - - Erklärung der Controls - - - - - - - -
#include <GUIConstantsEx.au3>
#include <GuiImageList.au3>
#include <GuiListView.au3>
#include <MsgBoxConstants.au3>
#include <WindowsConstants.au3>
Example()
Func Example()
Local $idListview, $hImage
Local $iStylesEx = BitOR($LVS_EX_GRIDLINES, $LVS_EX_FULLROWSELECT, $LVS_EX_SUBITEMIMAGES)
GUICreate("ImageList: Quellbild auf den Index des Zielbildes kopieren", 400, 300)
$idListview = GUICtrlCreateListView("", 2, 2, 394, 268, BitOR($LVS_SHOWSELALWAYS, $LVS_NOSORTHEADER, $LVS_REPORT))
_GUICtrlListView_SetExtendedListViewStyle($idListview, $iStylesEx)
GUISetState(@SW_SHOW)
; Lädt die Bilder
$hImage = _GUIImageList_Create(16, 16, 5, 3)
_GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 110)
_GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 131)
_GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 165)
_GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 168)
_GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 137)
_GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 146)
_GUICtrlListView_SetImageList($idListview, $hImage, 1)
; Fügt die Spalten hinzu
_GUICtrlListView_AddColumn($idListview, "Spalte 1", 120)
_GUICtrlListView_AddColumn($idListview, "Spalte 2", 120)
_GUICtrlListView_AddColumn($idListview, "Spalte 3", 120)
; Fügt die Items hinzu
_GUICtrlListView_AddItem($idListview, "Zeile 1: Spalte 1", 0)
_GUICtrlListView_AddSubItem($idListview, 0, "Zeile 1: Spalte 2", 1, 1)
_GUICtrlListView_AddSubItem($idListview, 0, "Zeile 1: Spalte 3", 2, 2)
_GUICtrlListView_AddItem($idListview, "Zeile 2: Spalte 1", 1)
_GUICtrlListView_AddSubItem($idListview, 1, "Zeile 2: Spalte 2", 1, 2)
_GUICtrlListView_AddItem($idListview, "Zeile 3: Spalte 1", 2)
_GUICtrlListView_AddItem($idListview, "Zeile 4: Spalte 1", 3)
_GUICtrlListView_AddItem($idListview, "Zeile 5: Spalte 1", 4)
_GUICtrlListView_AddSubItem($idListview, 4, "Zeile 5: Spalte 2", 1, 3)
_GUICtrlListView_AddItem($idListview, "Zeile 6: Spalte 1", 5)
_GUICtrlListView_AddSubItem($idListview, 5, "Zeile 6: Spalte 2", 1, 4)
_GUICtrlListView_AddSubItem($idListview, 5, "Zeile 6: Spalte 3", 2, 3)
GUISetState(@SW_LOCK)
MsgBox($MB_SYSTEMMODAL, "Information", "Es wird das erste mit dem letzten Bild getauscht")
_GUIImageList_Swap($hImage, 0, 5)
GUISetState(@SW_UNLOCK)
; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
GUIDelete()
EndFunc ;==>Example