Kameraüberwachung möglich?

**chip**

Hi,

hab mir grade überlegt ob es eigentlich möglich wäre mit Autoit eine automatisch Kameraüberwachung zu realisieren. Stelle mir das so vor, das eine Kamera jede Sekunde ein Bild erzeugt. Von diesem Bild wird eine PixelChecksum erstellt immer mit PixelChecksum des eine Sekunde vorher entstandenen Bildes vergleicht. Um zu verhindern, dass bei der kleinsten Änderung schon "Alarm" kommt müsste man denke ich einfach die Anzahl der step in der PixeklChecksum erhöhen. Wäre das so wie ich mir das denke möglich?

mfg

**Andy**

Hallo,
das Problem bei der ganzen Geschichte ist, daß die Sensoren der Kameras ein eingebautes "Rauschen" haben. Dieses Verfahren wird mittlerweile zur Erzeugung von Zufallszahlen verwendet, kein Scherz!
Somit bekommst du sicherlich nicht 2 komplett gleiche Bilder, aber das hast du ja schon gemerkt.

[autoit]

pixelchecksum()

[/autoit]

ist leider auch nicht die Lösung, die Steps hochzusetzen verändert das Problem nicht.
Ggf. würde es funktionieren, das Bild in Sektoren zu unterteilen und für jeden Sektor eine "geglättete" Prüfsumme zu erstellen.
Bsp.: Scanne einen 50x50 Pixelblock (ggf auch nur jedes 4. Pixel), schreibe die Farben in eine Liste und Sortiere diese Liste aufsteigend nach den Grundfarben RGB. Man erhält dadurch "vorherrschende" Farben, mal angenommen X-mal Rot, Y-mal Grün, Z-mal Blau. Angenommen das Bild ist ein überwiegend grüner Fußballrasen.
Wenn sich im nächsten Bild (ich phantasiere jetzt^^ ) ein roter Ball in diesen Bildausschnitt bewegt, dann werden die X-Werte (Rot) wesentlich zunehmen, und die y-Werte (Grün) wesentlich abnehmen.
Keine Ahnung, ob Pixelgetcolor() und Autoit allgemein schnell genug für deine Zwecke wäre, aber ich habe vor kurzem einen sehr interessanten Ansatz gefunden (engl Forum) um Assemblercode in Autoit einzubinden. Dort war auch ein Beispiel, um GUI´s extrem schnell mit zufälligen Pixeln zu füllen. Finde aber leider den Link nicht, Progandy war aber m.E. involviert.....
ciao
Andy

Unicom

Ich hab sowas ähnliches mal gemacht.

Um das Rauschen herauszufiltern kann man einfach die Änderung aller Pixel miteinander vergleichen, daraus erhält man ein Grundrauschen.
Dieses Grundrauschen nimmt man als Referenz gegen aktuelle Änderungen.

Die Schwierigkeit ist dann wie empfindlich soll sowas sein.

Spoiler anzeigen

PS das Programm geht nur solange es im Vordergrund läuft, da die Pixel direkt vom Desktop genommen werden, falls wer das besser lösen kann dann bitte nur zu

C

;by Unicom for www.Autoit.de
;tested for AutoIT 3.3.0.0
;Demonstrations of Movement Detection via Webcam
;First displayed number value represents degree of change between two succeeding images
;Second value is maximum change of a single pixel in the image between two succeeding images 
;Quit by pressing "End" - Button




$cam_xlength=300	;Breite
$cam_ylength=300	;Höhe
$Gridstep=50		;Abstand zwischen den Pixeln zum Abtasten


$sensitivity = 15	;Empfindlichkeit 


$gui_x=400
$gui_y=500


HotKeySet("{END}", "Quit"); 
HotKeySet("{INSERT}", "SnapShot")


$snapfile1 = @ScriptDir & "\scrshot1.bmp"


#cs ----------------------------------------------------------------------------


 AutoIt Version: 3.2.11.7 (beta)
 thnx to rysiora with his great example!
 Author:         Ludocus


 Script Function:
    Webcam Udf


#ce ----------------------------------------------------------------------------
#include-once
$WM_CAP_START = 0x400
$WM_CAP_UNICODE_START = $WM_CAP_START +100
$WM_CAP_PAL_SAVEA = $WM_CAP_START + 81
$WM_CAP_PAL_SAVEW = $WM_CAP_UNICODE_START + 81
$WM_CAP_UNICODE_END = $WM_CAP_PAL_SAVEW
$WM_CAP_ABORT = $WM_CAP_START + 69
$WM_CAP_DLG_VIDEOCOMPRESSION = $WM_CAP_START + 46
$WM_CAP_DLG_VIDEODISPLAY = $WM_CAP_START + 43
$WM_CAP_DLG_VIDEOFORMAT = $WM_CAP_START + 41
$WM_CAP_DLG_VIDEOSOURCE = $WM_CAP_START + 42
$WM_CAP_DRIVER_CONNECT = $WM_CAP_START + 10
$WM_CAP_DRIVER_DISCONNECT = $WM_CAP_START + 11
$WM_CAP_DRIVER_GET_CAPS = $WM_CAP_START + 14
$WM_CAP_DRIVER_GET_NAMEA = $WM_CAP_START + 12
$WM_CAP_DRIVER_GET_NAMEW = $WM_CAP_UNICODE_START + 12
$WM_CAP_DRIVER_GET_VERSIONA = $WM_CAP_START + 13
$WM_CAP_DRIVER_GET_VERSIONW = $WM_CAP_UNICODE_START + 13
$WM_CAP_EDIT_COPY = $WM_CAP_START + 30
$WM_CAP_END = $WM_CAP_UNICODE_END
$WM_CAP_FILE_ALLOCATE = $WM_CAP_START + 22
$WM_CAP_FILE_GET_CAPTURE_FILEA = $WM_CAP_START + 21
$WM_CAP_FILE_GET_CAPTURE_FILEW = $WM_CAP_UNICODE_START + 21
$WM_CAP_FILE_SAVEASA = $WM_CAP_START + 23
$WM_CAP_FILE_SAVEASW = $WM_CAP_UNICODE_START + 23
$WM_CAP_FILE_SAVEDIBA = $WM_CAP_START + 25
$WM_CAP_FILE_SAVEDIBW = $WM_CAP_UNICODE_START + 25
$WM_CAP_FILE_SET_CAPTURE_FILEA = $WM_CAP_START + 20
$WM_CAP_FILE_SET_CAPTURE_FILEW = $WM_CAP_UNICODE_START + 20
$WM_CAP_FILE_SET_INFOCHUNK = $WM_CAP_START + 24
$WM_CAP_GET_AUDIOFORMAT = $WM_CAP_START + 36
$WM_CAP_GET_CAPSTREAMPTR = $WM_CAP_START + 1
$WM_CAP_GET_MCI_DEVICEA = $WM_CAP_START + 67
$WM_CAP_GET_MCI_DEVICEW = $WM_CAP_UNICODE_START + 67
$WM_CAP_GET_SEQUENCE_SETUP = $WM_CAP_START + 65
$WM_CAP_GET_STATUS = $WM_CAP_START + 54
$WM_CAP_GET_USER_DATA = $WM_CAP_START + 8
$WM_CAP_GET_VIDEOFORMAT = $WM_CAP_START + 44
$WM_CAP_GRAB_FRAME = $WM_CAP_START + 60
$WM_CAP_GRAB_FRAME_NOSTOP = $WM_CAP_START + 61
$WM_CAP_PAL_AUTOCREATE = $WM_CAP_START + 83
$WM_CAP_PAL_MANUALCREATE = $WM_CAP_START + 84
$WM_CAP_PAL_OPENA = $WM_CAP_START + 80
$WM_CAP_PAL_OPENW = $WM_CAP_UNICODE_START + 80
$WM_CAP_PAL_PASTE = $WM_CAP_START + 82
$WM_CAP_SEQUENCE = $WM_CAP_START + 62
$WM_CAP_SEQUENCE_NOFILE = $WM_CAP_START + 63
$WM_CAP_SET_AUDIOFORMAT = $WM_CAP_START + 35
$WM_CAP_SET_CALLBACK_CAPCONTROL = $WM_CAP_START + 85
$WM_CAP_SET_CALLBACK_ERRORA = $WM_CAP_START + 2
$WM_CAP_SET_CALLBACK_ERRORW = $WM_CAP_UNICODE_START + 2
$WM_CAP_SET_CALLBACK_FRAME = $WM_CAP_START + 5
$WM_CAP_SET_CALLBACK_STATUSA = $WM_CAP_START + 3
$WM_CAP_SET_CALLBACK_STATUSW = $WM_CAP_UNICODE_START + 3
$WM_CAP_SET_CALLBACK_VIDEOSTREAM = $WM_CAP_START + 6
$WM_CAP_SET_CALLBACK_WAVESTREAM = $WM_CAP_START + 7
$WM_CAP_SET_CALLBACK_YIELD = $WM_CAP_START + 4
$WM_CAP_SET_MCI_DEVICEA = $WM_CAP_START + 66
$WM_CAP_SET_MCI_DEVICEW = $WM_CAP_UNICODE_START + 66
$WM_CAP_SET_OVERLAY = $WM_CAP_START + 51
$WM_CAP_SET_PREVIEW = $WM_CAP_START + 50
$WM_CAP_SET_PREVIEWRATE = $WM_CAP_START + 52
$WM_CAP_SET_SCALE = $WM_CAP_START + 53
$WM_CAP_SET_SCROLL = $WM_CAP_START + 55
$WM_CAP_SET_SEQUENCE_SETUP = $WM_CAP_START + 64
$WM_CAP_SET_USER_DATA = $WM_CAP_START + 9
$WM_CAP_SET_VIDEOFORMAT = $WM_CAP_START + 45
$WM_CAP_SINGLE_FRAME = $WM_CAP_START + 72
$WM_CAP_SINGLE_FRAME_CLOSE = $WM_CAP_START + 71
$WM_CAP_SINGLE_FRAME_OPEN = $WM_CAP_START + 70
$WM_CAP_STOP = $WM_CAP_START + 68


#include <GUIConstants.au3>
#include <WindowsConstants.au3>


$avi = DllOpen("avicap32.dll")
$user = DllOpen("user32.dll")




$gui_name="Webcam UDF Test"


$gui = GUICreate($gui_name,$gui_x,$gui_y)


$label1=GUICtrlCreateLabel("Delta",50,400,150,420)
$label2=GUICtrlCreateLabel("Max",150,400)
$label3=GUICtrlCreateLabel("Max",75,420,250)




Dim $red[$cam_xlength/$Gridstep*$cam_ylength/$Gridstep+1]
Dim $green[$cam_xlength/$Gridstep*$cam_ylength/$Gridstep+1]
Dim $blue[$cam_xlength/$Gridstep*$cam_ylength/$Gridstep+1]


$WebcamID = _WebcamOpen($gui, 0, 0, $cam_xlength, $cam_ylength)




GUISetState(@SW_SHOW)


$changeold=0


While 1
 
$pos=WinGetPos ( $gui_name )	;Farbwerte der Cam werden direkt vom Screen ausgelesen
$xpos=$pos[0]					;dazu wird das direkt angezeigte Bild
$ypos=$pos[1]					;abgefragt
$count=0


$change=0
$tempchange=0
$changemax=0




For $x_scan = 1 to $cam_xlength Step $Gridstep
For $y_scan = 1 to $cam_ylength Step $Gridstep


$count=$count+1			;Counter für abgetastete Pixel


$farbe=PixelGetColor(2+$x_scan+$xpos,21+$y_scan+$ypos)
$redc=BitAND($farbe, 0xFF0000) / 16^4
$greenc=BitAND($farbe, 0x00FF00) / 16^2
$bluec=BitAND($farbe, 0x0000FF)


$change_red=$red[$count]-$redc
$change_green=$green[$count]-$greenc
$change_blue=$blue[$count]-$bluec


$tempchange=Abs($change_red)+Abs($change_green)+Abs($change_blue)


$change+=$tempchange
If $changemax<$tempchange Then $changemax=$tempchange


$red[$count]=$redc
$green[$count]=$greenc
$blue[$count]=$bluec


 $msg = GUIGetMsg()
    If $msg = $GUI_EVENT_CLOSE Then
  _WebcamClose($WebcamID)
  Exit
 EndIf
Next
Next


$change=$change/$count


GUICtrlSetData($label1,int($change))
GUICtrlSetData($label2,$changemax)










$diff=abs($change-$changeold)


;Hier können Anweisungen kommen wie "if $diff>50 then snapshot" folgen
;
;z.B.:


Select
Case $diff <$sensitivity 
	GUICtrlSetData($label3,"none")


Case $diff > $sensitivity AND $diff<=$sensitivity*2  
	GUICtrlSetData($label3,"slight")
Case $diff > 2*$sensitivity AND $diff<=$sensitivity*4  
	GUICtrlSetData($label3,"medium")
Case $diff > 4*$sensitivity 
	GUICtrlSetData($label3,"high")
EndSelect








$changeold=$change
 Sleep(100)
WEnd


Func SnapShot()
	MsgBox(0,"Snapshot","press ok")
  _WebcamSnap($WebcamID, $snapfile1)




EndFunc


Func Quit()
	    _WebcamClose($WebcamID)
        Exit
		EndFunc








;===============================================================================
;
; Description:      Open's a webcam preview screen in your gui
; Syntax:           _WebcamOpen($sHwnd, $sLeft, $sTop, $sWidth, $sHeight)
; Parameter(s):     $sHwnd     - The handle of the gui
;                   $sLeft     - Left coord. of the preview screen
;                   $sTop      - Top coord. of the preview screen
;                   $sWidth    - Width of the preview screen
;                   $sHeight   - Height of the preview screen
; Requirement(s):   A webcam
; Return Value(s):  On Success - Returns id needed for other controls
;                   On Failure - Returns -1
; Author(s):        Ludocus
; Note(s):          None
;
;===============================================================================
func _WebcamOpen($sHwnd, $sLeft, $sTop, $sWidth, $sHeight)
$cap = DllCall($avi, "int", "capCreateCaptureWindow", "str", "cap", "int", BitOR($WS_CHILD,$WS_VISIBLE), "int", $sLeft, "int", $sTop, "int", $sWidth, "int", $sHeight, "hwnd", $sHwnd, "int", 1)
DllCall($user, "int", "SendMessage", "hWnd", $cap[0], "int", $WM_CAP_DRIVER_CONNECT, "int", 0, "int", 0)
DllCall($user, "int", "SendMessage", "hWnd", $cap[0], "int", $WM_CAP_SET_SCALE, "int", 1, "int", 0)
DllCall($user, "int", "SendMessage", "hWnd", $cap[0], "int", $WM_CAP_SET_OVERLAY, "int", 1, "int", 0)
DllCall($user, "int", "SendMessage", "hWnd", $cap[0], "int", $WM_CAP_SET_PREVIEW, "int", 1, "int", 0)
DllCall($user, "int", "SendMessage", "hWnd", $cap[0], "int", $WM_CAP_SET_PREVIEWRATE, "int", 1, "int", 0)
if @error then return -1
return $cap[0]
EndFunc


;===============================================================================
;
; Description:      Creates a Snapshot from a webcam
; Syntax:           _WebcamSnap($sId, $sFile)
; Parameter(s):     $sId       - Id (returned from _WebcamOpen)
;                   $sFile     - File to save the snapshot to (*.bmp)
; Requirement(s):   A webcam
; Return Value(s):  On Success - Returns 1
;                   On Failure - Returns 0
; Author(s):        Ludocus
; Note(s):          None
;
;===============================================================================
Func _WebcamSnap($sId, $sFile)
    DllCall($user, "int", "SendMessage", "hWnd", $sId, "int", $WM_CAP_GRAB_FRAME_NOSTOP, "int", 0, "int", 0)
    DllCall($user, "int", "SendMessage", "hWnd", $sId, "int", $WM_CAP_FILE_SAVEDIBA, "int", 0, "str", $sFile)
    if @error Then
        return 0
    Else
        return 1
    EndIf
EndFunc


;===============================================================================
;
; Description:      Closes the preview screen created with _WebcamOpen
; Syntax:           _WebcamClose($sId)
; Parameter(s):     $sId       - Id (returned from _WebcamOpen)
; Requirement(s):   A webcam
; Return Value(s):  On Success - Returns 1
;                   On Failure - Returns 0
; Author(s):        Ludocus
; Note(s):          None
;
;===============================================================================
Func _WebcamClose($sId)
    DllCall($user, "int", "SendMessage", "hWnd", $sId, "int", $WM_CAP_END, "int", 0, "int", 0)
    DllCall($user, "int", "SendMessage", "hWnd", $sId, "int", $WM_CAP_DRIVER_DISCONNECT, "int", 0, "int", 0)
    DllClose($user)
    if @error Then
        return 0
    Else
        return 1
    EndIf
EndFunc


;===============================================================================
;
; Description:      Starts recording the webcam to a file
; Syntax:           _WebcamRecordStart($sFile, $sId)
; Parameter(s):     $sId       - Id (returned from _WebcamOpen)
;                   $sFile     - File to save the movie to (*.avi)
; Requirement(s):   A webcam
; Return Value(s):  On Success - Returns 1
;                   On Failure - Returns 0
; Author(s):        Ludocus
; Note(s):          Stop recording by: _WebcamRecordStop($Id)
;
;===============================================================================
Func _WebcamRecordStart($sFile, $sId)
    DllCall($user, "int", "SendMessage", "hWnd", $sId, "int", $WM_CAP_FILE_SET_CAPTURE_FILEA, "int", 0, "str", $sFile)
    DllCall($user, "int", "SendMessage", "hWnd", $sId, "int", $WM_CAP_SEQUENCE, "int", 0, "int", 0)
    if @error Then
        return 0
    Else
        return 1
    EndIf

EndFunc


;===============================================================================
;
; Description:      Stops recording.
; Syntax:           _WebcamRecordStop($sId)
; Parameter(s):     $sId       - Id (returned from _WebcamOpen)
; Requirement(s):   A webcam
; Return Value(s):  On Success - Returns 1
;                   On Failure - Returns 0
; Author(s):        Ludocus
; Note(s):          None
;
;===============================================================================
Func _WebcamRecordStop($sId)
    DllCall($user, "int", "SendMessage", "hWnd", $sId, "int", $WM_CAP_STOP, "int", 0, "int", 0)
    if @error Then
        return 0
    Else
        return 1
    EndIf
EndFunc ;==> _WebcamRecordStop

Alles anzeigen

vivus

wird in dem script jetzt das webcam bild mit dem desctop hintergrund verglichen ?!

oder wie soll ich das verstehen ...

thx

PokerFace

Habe das Skript zwar noch nicht gestartet, jedoch glaube ich, das eine GUI kommt, wo der Snapshot ausgewertet wird
Also, wenn es nicht im Vordergrund ist, dann kann AutoIT auf dem Bildschirm nur deinen Hintergrund "sehen" und nicht das GUI =D

Unicom

Ja bei dem Programm werden die Pixel direkt vom Desktop ausgelesen.
Wenn man ein anderes Fenster davorschiebt gehts nicht mehr.

Wer Lust hat kann es ja umschreiben,
z.B. Bilder aufnehmen (Funktion ist im Programm enthalten um images zu speichern)
und dort dann die Pixel vergleichen.