Active Directory Funktionen - Neue Version 1.5.0.0 freigegeben!

; #FUNCTION# ====================================================================================================================
; Name...........: _AD_ListDomainControllers
; Description ...: Enumerates all Domain Controllers (returns information about: Domain Controller, site, subnet and Global Catalog).
; Syntax.........: _AD_ListDomainControllers([$bAD_ListRO = False[, $bAD_ListGC = False]])
; Parameters ....: $bAD_ListRO - Optional: If set to True only returns RODC (read only domain controllers) (default = False)
; $bAD_ListGC - Optional: If set to True queries the DC for a Global Catalog. Disabled for performance reasons (default = False)
; Return values .: Success - One-based two dimensional array with the following information:
; |0 - Domain Controller: Name
; |1 - Domain Controller: Distinguished Name (FQDN)
; |2 - Domain Controller: DNS host name
; |3 - Site: Name
; |4 - Site: Distinguished Name (FQDN)
; |5 - Site: List of subnets that can connect to the site using this DC in the format x.x.x.x/mask - multiple subnets are separated by comma
; |6 - Global Catalog: Set to True if the DC is a Global Catalog (only if flag $bAD_ListGC = True. If False then "" is returned)
; Failure - "", sets @error to:
; |1 - No Domain Controllers found
; Author ........: water (based on VB functions by Richard L. Mueller)
; Modified.......:
; Remarks .......: This function only lists writeable DCs (default). To list RODC (read only DCs) use parameter $bAD_ListRO
; Related .......:
; Link ..........: http://www.rlmueller.net/Enumerate%20DCs.htm
; Example .......: Yes
; ===============================================================================================================================
Func _AD_ListDomainControllers($bAD_ListRO = False, $bAD_ListGC = False)

Local $oAD_DC, $oAD_Site, $oAD_Result
Local Const $NTDSDSA_OPT_IS_GC = 1
$oAD_Command.CommandText = "<LDAP://" & $sAD_HostServer & "/" & $sAD_Configuration & ">;(objectClass=nTDSDSA);ADsPath;subtree"
If $bAD_ListRO Then $oAD_Command.CommandText = "<LDAP://" & $sAD_HostServer & "/" & $sAD_Configuration & ">;(objectClass=nTDSDSARO);ADsPath;subtree"
Local $oAD_RecordSet = $oAD_Command.Execute
If Not IsObj($oAD_RecordSet) Or $oAD_RecordSet.RecordCount = 0 Then Return SetError(1, 0, "")
; The parent object of each object with objectClass=nTDSDSA is a Domain
; Controller. The parent of each Domain Controller is a "Servers"
; container, and the parent of this container is the "Site" container.
$oAD_RecordSet.MoveFirst
Local $aAD_Result[1][7], $iCount1 = 1, $aAD_SubNet, $aAD_Temp, $sAD_Temp
Do
ReDim $aAD_Result[$iCount1 + 1][7]
$oAD_Result = _AD_ObjGet($oAD_RecordSet.Fields("AdsPath").Value)
$oAD_DC = _AD_ObjGet($oAD_Result.Parent)
$aAD_Result[$iCount1][0] = $oAD_DC.Get("Name")
$aAD_Result[$iCount1][1] = $oAD_DC.serverReference
$aAD_Result[$iCount1][2] = $oAD_DC.DNSHostName
$oAD_Result = _AD_ObjGet($oAD_DC.Parent)
$oAD_Site = _AD_ObjGet($oAD_Result.Parent)
$aAD_Result[$iCount1][3] = StringMid($oAD_Site.Name, 4)
$aAD_Result[$iCount1][4] = $oAD_Site.distinguishedName
$aAD_SubNet = $oAD_Site.GetEx("siteObjectBL")
For $iCount2 = 0 To UBound($aAD_SubNet) - 1
$aAD_Temp = StringSplit($aAD_SubNet[$iCount2], ",")
$sAD_Temp = StringMid($aAD_Temp[1], 4)
If $iCount2 = 0 Then
$aAD_Result[$iCount1][5] = $sAD_Temp
Else
$aAD_Result[$iCount1][5] = $aAD_Result[$iCount1][5] & "," & $sAD_Temp
EndIf
Next
If $bAD_ListGC Then
; Is the DC a GC? Taken from: http://www.activexperts.com/activmonitor/w…rmanagement/ad/
Local $oAD_DCRootDSE = _AD_ObjGet("LDAP://" & $oAD_DC.DNSHostName & "/rootDSE")
Local $sAD_DsServiceDN = $oAD_DCRootDSE.Get("dsServiceName")
Local $oAD_DsRoot = _AD_ObjGet("LDAP://" & $oAD_DC.DNSHostName & "/" & $sAD_DsServiceDN)
Local $iAD_DCOptions = $oAD_DsRoot.Get("options")
If BitAND($iAD_DCOptions, $NTDSDSA_OPT_IS_GC) = 1 Then
$aAD_Result[$iCount1][6] = True
Else
$aAD_Result[$iCount1][6] = False
EndIf
EndIf
$oAD_RecordSet.MoveNext
$iCount1 += 1
Until $oAD_RecordSet.EOF
$oAD_RecordSet.Close
$aAD_Result[0][0] = UBound($aAD_Result, 1) - 1
$aAD_Result[0][1] = UBound($aAD_Result, 2)
Return $aAD_Result

EndFunc ;==>_AD_ListDomainControllers