gecryptete Section aus ini-Datei wieder encrypten

  • Hallo miteinander,

    derzeit hab ich für mich und meine Arbeitskollegen ein kleines Tool geschrieben wo wir unsere Passwörter speichern können. Da wir einfach etliche Programme mit unterschiedlichen Zugangsdaten nutzen ist es nervig sich immer alles merken zu müssen ;)

    Daher habe ich mir folgendes kleines Skript gebastelt. Soweit funktioniert alles bestens - ich schaffe es auch, dass die Passwörter verschlüsselt in der ini Datei gespeichert werden, jedoch das erneute wieder einlesen und diese dann wieder als Klartext einzulesen scheiterte bisher. Aktuell ist hier das Skript mit Verschlüsselung aber ohne Entschlüsselung:

    Spoiler anzeigen
    [autoit]


    #Region ;**** Directives created by AutoIt3Wrapper_GUI ****
    #AutoIt3Wrapper_UseUpx=n
    #AutoIt3Wrapper_Res_Description=PWS
    #AutoIt3Wrapper_Res_Fileversion=1.0.0.0
    #AutoIt3Wrapper_Res_LegalCopyright="(C) Copyright CT-Team 2011"
    #EndRegion ;**** Directives created by AutoIt3Wrapper_GUI ****
    Opt("TrayIconHide", 1)
    ;------------------INCLUDES------------------------
    #include <GUIConstantsEx.au3>
    #include <WindowsConstants.au3>
    #include <StructureConstants.au3>
    #include <GUIConstants.au3>
    #include <EditConstants.au3>
    #Include <String.au3>
    ;-----------------HAUPT-GUI------------------------
    $ini = @ScriptDir & "\pws.ini"

    [/autoit] [autoit][/autoit] [autoit]

    If not FileExists(@ScriptDir & "\pws.ini") Then
    IniWrite($ini, "Programme", "Programm 1", "Testprogramm 1")
    IniWrite($ini, "Programme", "Programm 2", "")
    IniWrite($ini, "Programme", "Programm 3", "")
    IniWrite($ini, "Programme", "Programm 4", "")
    IniWrite($ini, "Programme", "Programm 5", "")
    IniWrite($ini, "Programme", "Programm 6", "")
    IniWrite($ini, "Programme", "Programm 7", "")
    IniWrite($ini, "Programme", "Programm 8", "")
    IniWrite($ini, "Programme", "Programm 9", "")
    IniWrite($ini, "Programme", "Programm 10", "")
    IniWrite($ini, "Login", "Login 1", "Testlogin 1")
    IniWrite($ini, "Login", "Login 2", "")
    IniWrite($ini, "Login", "Login 3", "")
    IniWrite($ini, "Login", "Login 4", "")
    IniWrite($ini, "Login", "Login 5", "")
    IniWrite($ini, "Login", "Login 6", "")
    IniWrite($ini, "Login", "Login 7", "")
    IniWrite($ini, "Login", "Login 8", "")
    IniWrite($ini, "Login", "Login 9", "")
    IniWrite($ini, "Login", "Login 10", "")
    IniWrite($ini, "Passwort", "Passwort 1", "Testpasswort 1")
    IniWrite($ini, "Passwort", "Passwort 2", "")
    IniWrite($ini, "Passwort", "Passwort 3", "")
    IniWrite($ini, "Passwort", "Passwort 4", "")
    IniWrite($ini, "Passwort", "Passwort 5", "")
    IniWrite($ini, "Passwort", "Passwort 6", "")
    IniWrite($ini, "Passwort", "Passwort 7", "")
    IniWrite($ini, "Passwort", "Passwort 8", "")
    IniWrite($ini, "Passwort", "Passwort 9", "")
    IniWrite($ini, "Passwort", "Passwort 10", "")
    EndIf

    [/autoit] [autoit][/autoit] [autoit]

    $mainGui = GUIcreate("PWS - Der ultimative Passwort-Safe", 500, 400)

    [/autoit] [autoit][/autoit] [autoit]

    GUICtrlCreateLabel("PWS", 225, 5, 60, 30)
    GUICtrlSetFont(-1, 15, 800, 0, "Verdana")
    GUICtrlCreateLabel("Der ultimative Passwort-Safe", 165, 30, 200, 20)
    GUICtrlSetFont(-1, 8, 800, 3, "Verdana")

    [/autoit] [autoit][/autoit] [autoit]

    GUICtrlCreateGroup("Programm:", 15, 50, 150, 320)
    GUICtrlSetFont(-1, 8, 800, 0, "Verdana")
    $Programm1 = GUICtrlCreateInput(IniRead($ini, "Programme", "Programm 1", ""), 22, 70, 135, 25)
    $Programm2 = GUICtrlCreateInput(IniRead($ini, "Programme", "Programm 2", ""), 22, 100, 135, 25)
    $Programm3 = GUICtrlCreateInput(IniRead($ini, "Programme", "Programm 3", ""), 22, 130, 135, 25)
    $Programm4 = GUICtrlCreateInput(IniRead($ini, "Programme", "Programm 4", ""), 22, 160, 135, 25)
    $Programm5 = GUICtrlCreateInput(IniRead($ini, "Programme", "Programm 5", ""), 22, 190, 135, 25)
    $Programm6 = GUICtrlCreateInput(IniRead($ini, "Programme", "Programm 6", ""), 22, 220, 135, 25)
    $Programm7 = GUICtrlCreateInput(IniRead($ini, "Programme", "Programm 7", ""), 22, 250, 135, 25)
    $Programm8 = GUICtrlCreateInput(IniRead($ini, "Programme", "Programm 8", ""), 22, 280, 135, 25)
    $Programm9 = GUICtrlCreateInput(IniRead($ini, "Programme", "Programm 9", ""), 22, 310, 135, 25)
    $Programm10 = GUICtrlCreateInput(IniRead($ini, "Programme", "Programm 10", ""), 22, 340, 135, 25)

    [/autoit] [autoit][/autoit] [autoit]

    GUICtrlCreateGroup("User/Login:", 173, 50, 150, 320)
    GUICtrlSetFont(-1, 8, 800, 0, "Verdana")
    $Login1 = GUICtrlCreateInput(IniRead($ini, "Login", "Login 1", ""), 180, 70, 135, 25)
    $Login2 = GUICtrlCreateInput(IniRead($ini, "Login", "Login 2", ""), 180, 100, 135, 25)
    $Login3 = GUICtrlCreateInput(IniRead($ini, "Login", "Login 3", ""), 180, 130, 135, 25)
    $Login4 = GUICtrlCreateInput(IniRead($ini, "Login", "Login 4", ""), 180, 160, 135, 25)
    $Login5 = GUICtrlCreateInput(IniRead($ini, "Login", "Login 5", ""), 180, 190, 135, 25)
    $Login6 = GUICtrlCreateInput(IniRead($ini, "Login", "Login 6", ""), 180, 220, 135, 25)
    $Login7 = GUICtrlCreateInput(IniRead($ini, "Login", "Login 7", ""), 180, 250, 135, 25)
    $Login8 = GUICtrlCreateInput(IniRead($ini, "Login", "Login 8", ""), 180, 280, 135, 25)
    $Login9 = GUICtrlCreateInput(IniRead($ini, "Login", "Login 9", ""), 180, 310, 135, 25)
    $Login10 = GUICtrlCreateInput(IniRead($ini, "Login", "Login 10", ""), 180, 340, 135, 25)

    [/autoit] [autoit][/autoit] [autoit][/autoit] [autoit]

    $bPassVisible = FALSE
    GUICtrlCreateGroup("Passwort:", 330, 50, 150, 320)
    GUICtrlSetFont(-1, 8, 800, 0, "Verdana")
    $Passwort1 = GUICtrlCreateInput(IniRead($ini, "Passwort", "Passwort 1", ""), 337, 70, 135, 25)
    GUICtrlSendMsg($Passwort1, $EM_SETPASSWORDCHAR, Not $bPassVisible * Asc('*'), 0)
    $hCheck1 = GUICtrlCreateCheckbox("", 485, 75, 10, 10)
    If $bPassVisible Then GUICtrlSetState(-1, $GUI_CHECKED)
    $Passwort2 = GUICtrlCreateInput(IniRead($ini, "Passwort", "Passwort 2", ""), 337, 100, 135, 25)
    GUICtrlSendMsg($Passwort2, $EM_SETPASSWORDCHAR, Not $bPassVisible * Asc('*'), 0)
    $hCheck2 = GUICtrlCreateCheckbox("", 485, 105, 10, 10)
    If $bPassVisible Then GUICtrlSetState(-1, $GUI_CHECKED)
    $Passwort3 = GUICtrlCreateInput(IniRead($ini, "Passwort", "Passwort 3", ""), 337, 130, 135, 25)
    GUICtrlSendMsg($Passwort3, $EM_SETPASSWORDCHAR, Not $bPassVisible * Asc('*'), 0)
    $hCheck3 = GUICtrlCreateCheckbox("", 485, 135, 10, 10)
    If $bPassVisible Then GUICtrlSetState(-1, $GUI_CHECKED)
    $Passwort4 = GUICtrlCreateInput(IniRead($ini, "Passwort", "Passwort 4", ""), 337, 160, 135, 25)
    GUICtrlSendMsg($Passwort4, $EM_SETPASSWORDCHAR, Not $bPassVisible * Asc('*'), 0)
    $hCheck4 = GUICtrlCreateCheckbox("", 485, 165, 10, 10)
    If $bPassVisible Then GUICtrlSetState(-1, $GUI_CHECKED)
    $Passwort5 = GUICtrlCreateInput(IniRead($ini, "Passwort", "Passwort 5", ""), 337, 190, 135, 25)
    GUICtrlSendMsg($Passwort5, $EM_SETPASSWORDCHAR, Not $bPassVisible * Asc('*'), 0)
    $hCheck5 = GUICtrlCreateCheckbox("", 485, 195, 10, 10)
    If $bPassVisible Then GUICtrlSetState(-1, $GUI_CHECKED)
    $Passwort6 = GUICtrlCreateInput(IniRead($ini, "Passwort", "Passwort 6", ""), 337, 220, 135, 25)
    GUICtrlSendMsg($Passwort6, $EM_SETPASSWORDCHAR, Not $bPassVisible * Asc('*'), 0)
    $hCheck6 = GUICtrlCreateCheckbox("", 485, 225, 10, 10)
    If $bPassVisible Then GUICtrlSetState(-1, $GUI_CHECKED)
    $Passwort7 = GUICtrlCreateInput(IniRead($ini, "Passwort", "Passwort 7", ""), 337, 250, 135, 25)
    GUICtrlSendMsg($Passwort7, $EM_SETPASSWORDCHAR, Not $bPassVisible * Asc('*'), 0)
    $hCheck7 = GUICtrlCreateCheckbox("", 485, 255, 10, 10)
    If $bPassVisible Then GUICtrlSetState(-1, $GUI_CHECKED)
    $Passwort8 = GUICtrlCreateInput(IniRead($ini, "Passwort", "Passwort 8", ""), 337, 280, 135, 25)
    GUICtrlSendMsg($Passwort8, $EM_SETPASSWORDCHAR, Not $bPassVisible * Asc('*'), 0)
    $hCheck8 = GUICtrlCreateCheckbox("", 485, 285, 10, 10)
    If $bPassVisible Then GUICtrlSetState(-1, $GUI_CHECKED)
    $Passwort9 = GUICtrlCreateInput(IniRead($ini, "Passwort", "Passwort 9", ""), 337, 310, 135, 25)
    GUICtrlSendMsg($Passwort9, $EM_SETPASSWORDCHAR, Not $bPassVisible * Asc('*'), 0)
    $hCheck9 = GUICtrlCreateCheckbox("", 485, 315, 10, 10)
    If $bPassVisible Then GUICtrlSetState(-1, $GUI_CHECKED)
    $Passwort10 = GUICtrlCreateInput(IniRead($ini, "Passwort", "Passwort 10", ""), 337, 340, 135, 25)
    GUICtrlSendMsg($Passwort10, $EM_SETPASSWORDCHAR, Not $bPassVisible * Asc('*'), 0)
    $hCheck10 = GUICtrlCreateCheckbox("", 485, 345, 10, 10)
    If $bPassVisible Then GUICtrlSetState(-1, $GUI_CHECKED)
    $SaveButton = GUICtrlCreateButton("Save", 225, 375, 50, 20)

    [/autoit] [autoit][/autoit] [autoit][/autoit] [autoit]

    GUIsetstate(@SW_SHOW,$mainGui)
    While 1
    Global $isHide
    $msg = GUIgetmsg()
    Switch $msg
    Case $GUI_EVENT_CLOSE
    Exit
    Case $SaveButton
    IniWrite($ini, "Programme", "Programm 1", GUICtrlRead($Programm1))
    IniWrite($ini, "Programme", "Programm 2", GUICtrlRead($Programm2))
    IniWrite($ini, "Programme", "Programm 3", GUICtrlRead($Programm3))
    IniWrite($ini, "Programme", "Programm 4", GUICtrlRead($Programm4))
    IniWrite($ini, "Programme", "Programm 5", GUICtrlRead($Programm5))
    IniWrite($ini, "Programme", "Programm 6", GUICtrlRead($Programm6))
    IniWrite($ini, "Programme", "Programm 7", GUICtrlRead($Programm7))
    IniWrite($ini, "Programme", "Programm 8", GUICtrlRead($Programm8))
    IniWrite($ini, "Programme", "Programm 9", GUICtrlRead($Programm9))
    IniWrite($ini, "Programme", "Programm 10", GUICtrlRead($Programm10))
    IniWrite($ini, "Login", "Login 1", GUICtrlRead($Login1))
    IniWrite($ini, "Login", "Login 2", GUICtrlRead($Login2))
    IniWrite($ini, "Login", "Login 3", GUICtrlRead($Login3))
    IniWrite($ini, "Login", "Login 4", GUICtrlRead($Login4))
    IniWrite($ini, "Login", "Login 5", GUICtrlRead($Login5))
    IniWrite($ini, "Login", "Login 6", GUICtrlRead($Login6))
    IniWrite($ini, "Login", "Login 7", GUICtrlRead($Login7))
    IniWrite($ini, "Login", "Login 8", GUICtrlRead($Login8))
    IniWrite($ini, "Login", "Login 9", GUICtrlRead($Login9))
    IniWrite($ini, "Login", "Login 10", GUICtrlRead($Login10))
    If GUICtrlRead($Passwort1) = "" then
    Else
    IniWrite($ini, "Passwort", "Passwort 1", _StringEncrypt(1,GUICtrlRead($Passwort1),GuiCtrlRead($Passwort1),"2"))
    EndIf
    If GUICtrlRead($Passwort2) = "" then
    Else
    IniWrite($ini, "Passwort", "Passwort 2", _StringEncrypt(1,GUICtrlRead($Passwort2),GuiCtrlRead($Passwort2),"2"))
    EndIf
    If GUICtrlRead($Passwort3) = "" then
    Else
    IniWrite($ini, "Passwort", "Passwort 3", _StringEncrypt(1,GUICtrlRead($Passwort3),GuiCtrlRead($Passwort3),"2"))
    EndIf
    If GUICtrlRead($Passwort4) = "" then
    Else
    IniWrite($ini, "Passwort", "Passwort 4", _StringEncrypt(1,GUICtrlRead($Passwort4),GuiCtrlRead($Passwort4),"2"))
    EndIf
    If GUICtrlRead($Passwort5) = "" then
    Else
    IniWrite($ini, "Passwort", "Passwort 5", _StringEncrypt(1,GUICtrlRead($Passwort5),GuiCtrlRead($Passwort5),"2"))
    EndIf
    If GUICtrlRead($Passwort6) = "" then
    Else
    IniWrite($ini, "Passwort", "Passwort 6", _StringEncrypt(1,GUICtrlRead($Passwort6),GuiCtrlRead($Passwort6),"2"))
    EndIf
    If GUICtrlRead($Passwort7) = "" then
    Else
    IniWrite($ini, "Passwort", "Passwort 7", _StringEncrypt(1,GUICtrlRead($Passwort7),GuiCtrlRead($Passwort7),"2"))
    EndIf
    If GUICtrlRead($Passwort8) = "" then
    Else
    IniWrite($ini, "Passwort", "Passwort 8", _StringEncrypt(1,GUICtrlRead($Passwort8),GuiCtrlRead($Passwort8),"2"))
    EndIf
    If GUICtrlRead($Passwort9) = "" then
    Else
    IniWrite($ini, "Passwort", "Passwort 9", _StringEncrypt(1,GUICtrlRead($Passwort9),GuiCtrlRead($Passwort9),"2"))
    EndIf
    If GUICtrlRead($Passwort10) = "" then
    Else
    IniWrite($ini, "Passwort", "Passwort 10", _StringEncrypt(1,GUICtrlRead($Passwort10),GuiCtrlRead($Passwort10),"2"))
    EndIf
    MsgBox(0, "", "Speichern erfolgreich!")
    Case $hCheck1
    GUICtrlSendMsg($Passwort1, $EM_SETPASSWORDCHAR, Not BitAND(GUICtrlRead($hCheck1), $GUI_CHECKED) * Asc('*'), 0)
    GUICtrlSetState($Passwort1, $GUI_FOCUS)
    Case $hCheck2
    GUICtrlSendMsg($Passwort2, $EM_SETPASSWORDCHAR, Not BitAND(GUICtrlRead($hCheck2), $GUI_CHECKED) * Asc('*'), 0)
    GUICtrlSetState($Passwort2, $GUI_FOCUS)
    Case $hCheck3
    GUICtrlSendMsg($Passwort3, $EM_SETPASSWORDCHAR, Not BitAND(GUICtrlRead($hCheck3), $GUI_CHECKED) * Asc('*'), 0)
    GUICtrlSetState($Passwort3, $GUI_FOCUS)
    Case $hCheck4
    GUICtrlSendMsg($Passwort4, $EM_SETPASSWORDCHAR, Not BitAND(GUICtrlRead($hCheck4), $GUI_CHECKED) * Asc('*'), 0)
    GUICtrlSetState($Passwort4, $GUI_FOCUS)
    Case $hCheck5
    GUICtrlSendMsg($Passwort5, $EM_SETPASSWORDCHAR, Not BitAND(GUICtrlRead($hCheck5), $GUI_CHECKED) * Asc('*'), 0)
    GUICtrlSetState($Passwort5, $GUI_FOCUS)
    Case $hCheck6
    GUICtrlSendMsg($Passwort6, $EM_SETPASSWORDCHAR, Not BitAND(GUICtrlRead($hCheck6), $GUI_CHECKED) * Asc('*'), 0)
    GUICtrlSetState($Passwort6, $GUI_FOCUS)
    Case $hCheck7
    GUICtrlSendMsg($Passwort7, $EM_SETPASSWORDCHAR, Not BitAND(GUICtrlRead($hCheck7), $GUI_CHECKED) * Asc('*'), 0)
    GUICtrlSetState($Passwort7, $GUI_FOCUS)
    Case $hCheck8
    GUICtrlSendMsg($Passwort8, $EM_SETPASSWORDCHAR, Not BitAND(GUICtrlRead($hCheck8), $GUI_CHECKED) * Asc('*'), 0)
    GUICtrlSetState($Passwort8, $GUI_FOCUS)
    Case $hCheck9
    GUICtrlSendMsg($Passwort9, $EM_SETPASSWORDCHAR, Not BitAND(GUICtrlRead($hCheck9), $GUI_CHECKED) * Asc('*'), 0)
    GUICtrlSetState($Passwort9, $GUI_FOCUS)
    Case $hCheck10
    GUICtrlSendMsg($Passwort10, $EM_SETPASSWORDCHAR, Not BitAND(GUICtrlRead($hCheck10), $GUI_CHECKED) * Asc('*'), 0)
    GUICtrlSetState($Passwort10, $GUI_FOCUS)
    EndSwitch
    WEnd

    [/autoit]

    Ich hab kein Plan wie ich das geschlüsselte PW wieder entschlüsseln kann - wer kann mir helfen?

    LG

    Mein AutoIT Smartphone GUI >>hier<<

    Der Mensch ist das einzige Tier, dass arbeiten muss.

    2 Mal editiert, zuletzt von mirko2002 (20. Oktober 2011 um 08:39)

  • hm gibts da keine einfachere lösung?

    ich mein das crypten ging ja auch mit einer Zeile code :)

    und derzeit lass ich die passwörter mit sich selbst crypten. Als Beispiel wird das Wort TEST mit dem Wort TEST gecrypted und ergibt den Wert 123456789. Starte ich nun das Tool steht jetzt natürlich nicht mehr TEST im PW Feld sondern 123456789...

    Mein AutoIT Smartphone GUI >>hier<<

    Der Mensch ist das einzige Tier, dass arbeiten muss.

  • Hi,


    Du läst das Passwort mit sich selbs verschlüsseln u. da ist auch das Problem um es wieder zu endschlüsseln, leg ein Masterschlüssel im Script an.

    Dein Script kürzer u. Funktionierend:

    Spoiler anzeigen
    [autoit]

    #Region ;**** Directives created by AutoIt3Wrapper_GUI ****
    #AutoIt3Wrapper_UseUpx=n
    #AutoIt3Wrapper_Res_Description=PWS
    #AutoIt3Wrapper_Res_Fileversion=1.0.0.0
    #AutoIt3Wrapper_Res_LegalCopyright="(C) Copyright CT-Team 2011"
    #EndRegion ;**** Directives created by AutoIt3Wrapper_GUI ****

    [/autoit] [autoit][/autoit] [autoit]

    Opt('GUIOnEventMode', 1)
    Opt("TrayIconHide", 1)
    ;------------------INCLUDES------------------------
    #include <GUIConstantsEx.au3>
    #include <WindowsConstants.au3>
    #include <StructureConstants.au3>
    #include <GUIConstants.au3>
    #include <EditConstants.au3>
    #include <String.au3>
    ;-----------------HAUPT-GUI------------------------
    Global $ini = @ScriptDir & '\pws.ini'
    Global $MasterPW = 'Master'
    Global $ABeschreibung[3] = ['Programme', 'Login', 'Passwort']
    Global $Programm[10], $Login[10], $Passwort[10], $hCheck[10]

    [/autoit] [autoit][/autoit] [autoit]

    If Not FileExists(@ScriptDir & "\pws.ini") Then
    For $i = 0 To 2
    For $e = 0 To 9
    IniWrite($ini, $ABeschreibung[$i], $ABeschreibung[$i] & $e + 1, "")
    Next
    Next

    [/autoit] [autoit][/autoit] [autoit]

    EndIf

    [/autoit] [autoit][/autoit] [autoit]

    Global $mainGui = GUICreate("PWS - Der ultimative Passwort-Safe", 500, 400)
    GUISetOnEvent(-3, 'E')
    GUICtrlCreateLabel("PWS", 225, 5, 60, 30)
    GUICtrlSetFont(-1, 15, 800, 0, "Verdana")
    GUICtrlCreateLabel("Der ultimative Passwort-Safe", 165, 30, 200, 20)
    GUICtrlSetFont(-1, 8, 800, 3, "Verdana")
    GUICtrlCreateGroup("Programm:", 15, 50, 150, 320)
    GUICtrlSetFont(-1, 8, 800, 0, "Verdana")
    Local $x = 70
    For $i = 0 To 9
    $Programm[$i] = GUICtrlCreateInput(IniRead($ini, $ABeschreibung[0], $ABeschreibung[0] & $i + 1, ""), 22, $x, 135, 25)
    $x += 30
    Next
    GUICtrlCreateGroup("User/Login:", 173, 50, 150, 320)
    GUICtrlSetFont(-1, 8, 800, 0, "Verdana")
    $x = 70
    For $i = 0 To 9
    $Login[$i] = GUICtrlCreateInput(IniRead($ini, $ABeschreibung[1], $ABeschreibung[1] & $i + 1, ""), 180, $x, 135, 25)
    $x += 30
    Next
    GUICtrlCreateGroup("Passwort:", 330, 50, 150, 320)
    GUICtrlSetFont(-1, 8, 800, 0, "Verdana")
    $x = 70
    Local $y = 75
    For $i = 0 To 9
    $Passwort[$i] = GUICtrlCreateInput(IIF(Not IniRead($ini, $ABeschreibung[2], $ABeschreibung[2] & $i + 1, ""), '', _StringEncrypt(0, IniRead($ini, $ABeschreibung[2], $ABeschreibung[2] & $i + 1, ""), $MasterPW, 2)), 337, $x, 135, 25)
    GUICtrlSendMsg($Passwort[$i], $EM_SETPASSWORDCHAR, Asc('*'), 0)
    $hCheck[$i] = GUICtrlCreateCheckbox("", 485, $y, 10, 10)
    GUICtrlSetOnEvent(-1, 'Menue')
    $x += 30
    $y = $x
    Next
    $SaveButton = GUICtrlCreateButton("Save", 225, 375, 50, 20)
    GUICtrlSetOnEvent(-1, 'Menue')
    GUISetState(@SW_SHOW, $mainGui)

    [/autoit] [autoit][/autoit] [autoit][/autoit] [autoit]

    Func Menue()
    Switch @GUI_CtrlId
    Case $SaveButton
    For $i = 0 To 9
    If GUICtrlRead($Programm[$i]) <> '' Or IniRead($ini, $ABeschreibung[0], $ABeschreibung[0] & $i + 1, "") <> GUICtrlRead($Programm[$i]) Then
    IniWrite($ini, $ABeschreibung[0], $ABeschreibung[0] & $i + 1, GUICtrlRead($Programm[$i]))
    EndIf
    If GUICtrlRead($Login[$i]) <> '' Or IniRead($ini, $ABeschreibung[1], $ABeschreibung[1] & $i + 1, "") <> GUICtrlRead($Login[$i]) Then
    IniWrite($ini, $ABeschreibung[1], $ABeschreibung[1] & $i + 1, GUICtrlRead($Login[$i]))
    EndIf
    If GUICtrlRead($Passwort[$i]) <> '' Or _StringEncrypt(0, IniRead($ini, $ABeschreibung[2], $ABeschreibung[2] & $i + 1, ""), $MasterPW, 2) <> GUICtrlRead($Passwort[$i]) Then
    IniWrite($ini, $ABeschreibung[2], $ABeschreibung[2] & $i + 1, _StringEncrypt(1, GUICtrlRead($Passwort[$i]), $MasterPW, 2))
    EndIf
    Next
    MsgBox(0, "", "Speichern erfolgreich!")
    Case Else
    For $i = 0 To 9
    If @GUI_CtrlId = $hCheck[$i] Then
    GUICtrlSendMsg($Passwort[$i], $EM_SETPASSWORDCHAR, Not BitAND(GUICtrlRead($hCheck[$i]), $GUI_CHECKED) * Asc('*'), 0)
    GUICtrlSetState($Passwort[$i], $GUI_FOCUS)
    EndIf
    Next
    EndSwitch

    [/autoit] [autoit][/autoit] [autoit]

    EndFunc ;==>Menue

    [/autoit] [autoit][/autoit] [autoit]

    ;===================================================================================================================================#
    ;Function Name....: IIF($expr, $Truepart = True, $Falsepart = False)
    ;
    ;Description......: If Abfrage
    ;$expr............: Wert zu Prüfung
    ;$Truepart........: Wenn Wert bei der Prüfung Wahr = ausgabe ( z.B True [Standart])
    ;$Falsepart.......: Wenn Wert bei der Prüfung Falsch = ausgabe ( z.B False [Standart])
    ;Return Value(s)..: Auswertung der Prüfung True/False/Benutzer(Ausgabe)
    ;
    ;Author(s)........: Kleiner (http://www.autoit.de)
    ;====================================================================================================================================#
    Func IIF($V_Expr, $F_True = True, $F_False = False)
    If $V_Expr Then Return $F_True
    Return $F_False
    EndFunc ;==>IIF

    [/autoit] [autoit][/autoit] [autoit]

    Func E()
    Exit
    EndFunc ;==>E

    [/autoit] [autoit][/autoit] [autoit]

    While 1 * Sleep(10)
    WEnd

    [/autoit]


    Lg Kleiner

  • Ah ok alles klar das war mein Denkfehler, habs eben getestet funktioniert wunderbar. Das Dein Skript kürzer ist freut mich natürlich noch umso mehr... Schleifen sind für mich noch immer eine Sache die ich nicht verstehe (auch wenn ich natürlich das Grundprinzip einer Schleife verstehe).

    Ich setz den Thread mal auf "Gelöst". Danke Kleiner!

    Mein AutoIT Smartphone GUI >>hier<<

    Der Mensch ist das einzige Tier, dass arbeiten muss.