Bildgröße laufend an GUI anpassen

#region ;************ Includes ************
#include <ScreenCapture.au3>
#include <WindowsConstants.au3>
#include <GUIConstantsEx.au3>
#endregion ;************ Includes ************

$bild = @TempDir & "\" & "bild.jpg"
_ScreenCapture_Capture($bild)

Global $hGui = GUICreate("Test", 300, 300, -1, -1, $WS_OVERLAPPEDWINDOW)
$pic = GUICtrlCreatePic("", 0, 0, 300, 300)
GUISetState()

_bild()
GUIRegisterMsg($WM_SIZE, "_bild")

While 1
Switch GUIGetMsg()
Case $GUI_EVENT_CLOSE
Exit
EndSwitch
WEnd

Func _bild()
$win = WinGetPos("Test", "")
GUICtrlSetImage($pic, $bild)
GUICtrlSetPos($pic, 0, 0, $win[2], $win[3])
EndFunc ;==>_bild

#region ;************ Includes ************
;~ #include <eigen_bilder.au3>
#include <WindowsConstants.au3>
#include <ScreenCapture.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#endregion ;************ Includes ************

Global $breite_min, $breite_max, $hoehe_min, $hoehe_max, $array_bilder_1[3], $hBitmap_quelle, $hGfxCtxt, $hHBitmap, $hImage, $breite = 800

Global $bild = @TempDir & "\" & "bild.jpg"
_ScreenCapture_Capture($bild)

_GDIPlus_Startup()
Global $hImage = _GDIPlus_ImageLoadFromFile($bild)
$array_bilder_1[1] = _GDIPlus_ImageGetWidth($hImage)
$array_bilder_1[2] = _GDIPlus_ImageGetHeight($hImage)

Global $seitenverhaeltnis = $array_bilder_1[1] / $array_bilder_1[2]

Global $hGui = GUICreate("Test", $breite, $breite / $seitenverhaeltnis, -1, -1, $WS_OVERLAPPEDWINDOW, $WS_EX_COMPOSITED)
Global $pic = GUICtrlCreatePic("", 0, 0, $breite, $breite / $seitenverhaeltnis)
GUISetState()

Global $aWS = WinGetClientSize($hGui)
Global Const $ratio = $aWS[1] / $aWS[0]
$breite_min = 0
$breite_max = 9300
$hoehe_min = 0
$hoehe_max = 9300

_bild()
GUIRegisterMsg($WM_SIZE, "_bild")
GUIRegisterMsg($WM_SIZING, "WM_SIZING")
GUIRegisterMsg($WM_GETMINMAXINFO, "WM_GETMINMAXINFO")

While 1
Switch GUIGetMsg()
Case $GUI_EVENT_CLOSE
Exit
EndSwitch
WEnd

_WinAPI_DeleteObject(GUICtrlSendMsg($pic, 0x0172, 0, $hHBitmap))
_GDIPlus_ImageDispose($hImage)
_GDIPlus_BitmapDispose($hBitmap_quelle)
_GDIPlus_GraphicsDispose($hGfxCtxt)
_GDIPlus_Shutdown()

Func _bild()
Local $win = WinGetClientSize($hGui)
Local $aResult = DllCall($ghGDIPDll, "uint", "GdipCreateBitmapFromScan0", "int", $win[0], "int", $win[1], "int", 0, "int", 0x0026200A, "ptr", 0, "int*", 0)
$hBitmap_quelle = $aResult[6]
$hGfxCtxt = _GDIPlus_ImageGetGraphicsContext($hBitmap_quelle)
DllCall($ghGDIPDll, "uint", "GdipSetInterpolationMode", "handle", $hGfxCtxt, "int", 1)
_GDIPlus_GraphicsDrawImageRect($hGfxCtxt, $hImage, 0, 0, $win[0], $win[1])
$hHBitmap = _GDIPlus_BitmapCreateDIBFromBitmap($hBitmap_quelle)
GUICtrlSetPos($pic, Default, Default, $win[0], $win[1])
_WinAPI_DeleteObject(GUICtrlSendMsg($pic, 0x0172, 0, $hHBitmap))
EndFunc ;==>_bild

Func WM_GETMINMAXINFO($hWnd, $Msg, $wParam, $lParam)
Local $minmaxinfo = DllStructCreate("int;int;int;int;int;int;int;int;int;int", $lParam)
DllStructSetData($minmaxinfo, 7, $breite_min) ; min X
DllStructSetData($minmaxinfo, 8, $hoehe_min) ; min Y
DllStructSetData($minmaxinfo, 9, $breite_max) ; max X
DllStructSetData($minmaxinfo, 10, $hoehe_max) ; max Y
Return "GUI_RUNDEFMSG"
EndFunc ;==>WM_GETMINMAXINFO

Func WM_SIZING($hWnd, $iMsg, $wParam, $lParam)
Local $sRect = DllStructCreate("Int[4]", $lParam)
Local $left = DllStructGetData($sRect, 1, 1)
Local $top = DllStructGetData($sRect, 1, 2)
Local $right = DllStructGetData($sRect, 1, 3)
Local $bottom = DllStructGetData($sRect, 1, 4)

Switch $wParam ;drag side or corner
Case 1, 2, 4, 7
Local $iNewY = Int(($right - $left) * $ratio)
DllStructSetData($sRect, 1, DllStructGetData($sRect, 1, 2) + $iNewY, 4)
Case Else
Local $iNewX = Int(($bottom - $top) / $ratio)
DllStructSetData($sRect, 1, DllStructGetData($sRect, 1, 1) + $iNewX, 3)
EndSwitch
Return "GUI_RUNDEFMSG"
EndFunc ;==>WM_SIZING

Func _GDIPlus_BitmapCreateDIBFromBitmap($hBitmap)
Local $tBIHDR, $Ret, $tData, $pBits, $hResult = 0
$Ret = DllCall($ghGDIPDll, 'uint', 'GdipGetImageDimension', 'ptr', $hBitmap, 'float*', 0, 'float*', 0)
If (@error) Or ($Ret[0]) Then Return 0
$tData = _GDIPlus_BitmapLockBits($hBitmap, 0, 0, $Ret[2], $Ret[3], $GDIP_ILMREAD, $GDIP_PXF32ARGB)
$pBits = DllStructGetData($tData, 'Scan0')
If Not $pBits Then Return 0
$tBIHDR = DllStructCreate('dword;long;long;ushort;ushort;dword;dword;long;long;dword;dword')
DllStructSetData($tBIHDR, 1, DllStructGetSize($tBIHDR))
DllStructSetData($tBIHDR, 2, $Ret[2])
DllStructSetData($tBIHDR, 3, $Ret[3])
DllStructSetData($tBIHDR, 4, 1)
DllStructSetData($tBIHDR, 5, 32)
DllStructSetData($tBIHDR, 6, 0)
$hResult = DllCall('gdi32.dll', 'ptr', 'CreateDIBSection', 'hwnd', 0, 'ptr', DllStructGetPtr($tBIHDR), 'uint', 0, 'ptr*', 0, 'ptr', 0, 'dword', 0)
If (Not @error) And ($hResult[0]) Then
DllCall('gdi32.dll', 'dword', 'SetBitmapBits', 'ptr', $hResult[0], 'dword', $Ret[2] * $Ret[3] * 4, 'ptr', DllStructGetData($tData, 'Scan0'))
$hResult = $hResult[0]
Else
$hResult = 0
EndIf
_GDIPlus_BitmapUnlockBits($hBitmap, $tData)
Return $hResult
EndFunc ;==>_GDIPlus_BitmapCreateDIBFromBitmap

#include <WindowsConstants.au3>
#include <GUIConstantsEx.au3>
#include <Constants.au3>
#include <WinAPI.au3>

; --- $BITMAP
Global Const $BITMAP = _
"LONG bmType;"& _
"LONG bmWidth;"& _
"LONG bmHeight;"& _
"LONG bmWidthBytes;"& _
"WORD bmPlanes;"& _
"WORD bmBitsPixel;"& _
"PTR bmBits;"

Global Const $HWND_DESKTOP = 0
Global $sImagePath = "C:\Windows\System32\oobe\background.bmp"
Global $hbmp, $hdcMem

; start the main procedure
Call ("_AuMain")

Func _AuMain ( )

Local $hwnd

GUIRegisterMsg ($WM_CREATE, "OnCreate")
GUIRegisterMsg ($WM_ERASEBKGND, "OnEraseBkGnd")

$hwnd = GUICreate ("Test", 300, 300, -1, -1, $WS_OVERLAPPEDWINDOW)

GUISetState (@SW_SHOW, $hwnd)

While (TRUE)
Switch GUIGetMsg (FALSE)
Case $GUI_EVENT_CLOSE
ExitLoop
EndSwitch
WEnd

; free resources
_WinAPI_DeleteObject ($hbmp)
_WinAPI_DeleteDC ($hdcMem)

Return 0

EndFunc

Func OnCreate ($hwnd, $message, $wParam, $lParam)

Local $hdc

$hbmp = _WinAPI_LoadImage (0, $sImagePath, $IMAGE_BITMAP, 0, 0, $LR_LOADFROMFILE)

If (not $hbmp) Then
; error handling here
ConsoleWrite (StringFormat ("_WinAPI_LoadImage fehlgeschlagen!\n"))
EndIf

$hdc = _WinAPI_GetDC ($HWND_DESKTOP)
$hdcMem = _WinAPI_CreateCompatibleDC ($hdc)
_WinAPI_ReleaseDC ($HWND_DESKTOP, $hdc)

If (not $hdcMem) Then
; error handling here
ConsoleWrite (StringFormat ("_WinAPI_CreateCompatibleDC fehlgeschlagen!\n"))
EndIf

Return $GUI_RUNDEFMSG

EndFunc

Func OnEraseBkGnd ($hwnd, $message, $wParam, $lParam)

Local $rcClient
Local $hObjOld
Local $rcRight, $rcBottom
Local $bmWidth , $bmHeight
Local $bm = DllStructCreate ($BITMAP)

If (not $hbmp) Then
Return 1
EndIf

; get the window's client area
$rcClient = _WinAPI_GetClientRect ($hwnd)

$rcRight = DllStructGetData ($rcClient, "Right")
$rcBottom = DllStructGetData ($rcClient, "Bottom")

; get the bitmap dimensions
_WinAPI_GetObject ($hbmp, DllStructGetSize ($bm), DllStructGetPtr ($bm))

; select the bitmap into the memory DC
$hObjOld = _WinAPI_SelectObject ($hdcMem, $hbmp)

$bmWidth = DllStructGetData ($bm, "bmWidth")
$bmHeight = DllStructGetData ($bm, "bmHeight")

StretchBlt ( _
$wParam, 0, 0, $rcRight, $rcBottom, _
$hdcMem, 0, 0, $bmWidth, $bmHeight, _
$SRCCOPY _
)

_WinAPI_SelectObject ($hdcMem, $hObjOld)

Return 1

EndFunc

Func StretchBlt ($hdcDest, $nXOriginDest, $nYOriginDest, $nWidthDest, $nHeightDest, $hdcSrc, $nXOriginSrc, $nYOriginSrc, $nWidthSrc, $nHeightSrc, $dwRop)

Local $aRes = DllCall ("gdi32.dll", "BOOL", "StretchBlt", _
"HANDLE", $hdcDest, _
"INT", $nXOriginDest, _
"INT", $nYOriginDest, _
"INT", $nWidthDest, _
"INT", $nHeightDest, _
"HANDLE", $hdcSrc, _
"INT", $nXOriginSrc, _
"INT", $nYOriginSrc, _
"INT", $nWidthSrc, _
"INT", $nHeightSrc, _
"DWORD", $dwRop)
Return $aRes[0]

EndFunc

#include <WindowsConstants.au3>
#include <GUIConstantsEx.au3>
#include <Constants.au3>
#include <WinAPI.au3>

; --- $BITMAP
Global Const $BITMAP = _
"LONG bmType;"& _
"LONG bmWidth;"& _
"LONG bmHeight;"& _
"LONG bmWidthBytes;"& _
"WORD bmPlanes;"& _
"WORD bmBitsPixel;"& _
"PTR bmBits;"

Global Const $HWND_DESKTOP = 0
Global $sImagePath = "C:\Windows\System32\oobe\background.bmp"
Global $hbmp, $hdcMem

; start the main procedure
Call ("_AuMain")

Func _AuMain ( )

Local $hwnd

GUIRegisterMsg ($WM_CREATE, "OnCreate")
GUIRegisterMsg ($WM_ERASEBKGND, "OnEraseBkGnd")

$hwnd = GUICreate ("Test", 300, 300, -1, -1, $WS_OVERLAPPEDWINDOW)

GUISetState (@SW_SHOW, $hwnd)

While (TRUE)
Switch GUIGetMsg (FALSE)
Case $GUI_EVENT_CLOSE
ExitLoop
EndSwitch
WEnd

; free resources
_WinAPI_DeleteObject ($hbmp)
_WinAPI_DeleteDC ($hdcMem)

Return 0

EndFunc

Func OnCreate ($hwnd, $message, $wParam, $lParam)

Local $hdc

$hbmp = _WinAPI_LoadImage (0, $sImagePath, $IMAGE_BITMAP, 0, 0, $LR_LOADFROMFILE)

If (not $hbmp) Then
; error handling here
ConsoleWrite (StringFormat ("_WinAPI_LoadImage fehlgeschlagen!\n"))
EndIf

$hdc = _WinAPI_GetDC ($HWND_DESKTOP)
$hdcMem = _WinAPI_CreateCompatibleDC ($hdc)

_WinAPI_ReleaseDC ($HWND_DESKTOP, $hdc)

If (not $hdcMem) Then
; error handling here
ConsoleWrite (StringFormat ("_WinAPI_CreateCompatibleDC fehlgeschlagen!\n"))
EndIf

Return $GUI_RUNDEFMSG

EndFunc

Func OnEraseBkGnd ($hwnd, $message, $wParam, $lParam)

Local $rcClient
Local $hObjOld
Local $rcRight, $rcBottom
Local $bmWidth , $bmHeight
Local $bm = DllStructCreate ($BITMAP)

If (not $hbmp) Then
Return 1
EndIf

; get the window's client area
$rcClient = _WinAPI_GetClientRect ($hwnd)

$rcRight = DllStructGetData ($rcClient, "Right")
$rcBottom = DllStructGetData ($rcClient, "Bottom")

; get the bitmap dimensions
_WinAPI_GetObject ($hbmp, DllStructGetSize ($bm), DllStructGetPtr ($bm))

; select the bitmap into the memory DC
$hObjOld = _WinAPI_SelectObject ($hdcMem, $hbmp)

$bmWidth = DllStructGetData ($bm, "bmWidth")
$bmHeight = DllStructGetData ($bm, "bmHeight")

DllCall ("gdi32.dll", "INT", "SetStretchBltMode", "HANDLE", $wParam, "INT", 4)

StretchBlt ( _
$wParam, 0, 0, $rcRight, $rcBottom, _
$hdcMem, 0, 0, $bmWidth, $bmHeight, _
$SRCCOPY _
)

_WinAPI_SelectObject ($hdcMem, $hObjOld)

Return 1

EndFunc

Func StretchBlt ($hdcDest, $nXOriginDest, $nYOriginDest, $nWidthDest, $nHeightDest, $hdcSrc, $nXOriginSrc, $nYOriginSrc, $nWidthSrc, $nHeightSrc, $dwRop)

Local $aRes = DllCall ("gdi32.dll", "BOOL", "StretchBlt", _
"HANDLE", $hdcDest, _
"INT", $nXOriginDest, _
"INT", $nYOriginDest, _
"INT", $nWidthDest, _
"INT", $nHeightDest, _
"HANDLE", $hdcSrc, _
"INT", $nXOriginSrc, _
"INT", $nYOriginSrc, _
"INT", $nWidthSrc, _
"INT", $nHeightSrc, _
"DWORD", $dwRop)
Return $aRes[0]

EndFunc

#region ;************ Includes ************
#include <ScreenCapture.au3>;~~~
#include <WinAPI.au3>;~~~
#include <WindowsConstants.au3>;~~~
#include <GUIConstantsEx.au3>;~~~
#include <Constants.au3>
#endregion ;************ Includes ************

Global $iGUI_WidthInitial = 800, $fRatio, $iMinWidth = 0, $iMinHeight = 0, $iMaxWidth = 9300, $iMaxHeight = 9300
Global $hbmp, $hdcMem

; --- $BITMAP
Global Const $BITMAP = _
"LONG bmType;" & _
"LONG bmWidth;" & _
"LONG bmHeight;" & _
"LONG bmWidthBytes;" & _
"WORD bmPlanes;" & _
"WORD bmBitsPixel;" & _
"PTR bmBits;"

Global Const $HWND_DESKTOP = _WinAPI_GetDesktopWindow()

$fRatio = _WinAPI_GetClientWidth($HWND_DESKTOP) / _WinAPI_GetClientHeight($HWND_DESKTOP)
ConsoleWrite("Original Ratio: " & $fRatio & @CRLF)

_AuMain()

Func _AuMain()
Local $hwnd

GUIRegisterMsg($WM_CREATE, "OnCreate")
GUIRegisterMsg($WM_ERASEBKGND, "OnEraseBkGnd")
GUIRegisterMsg($WM_SIZING, "WM_SIZING")
GUIRegisterMsg($WM_GETMINMAXINFO, "WM_GETMINMAXINFO")

$hwnd = GUICreate("Test", $iGUI_WidthInitial, $iGUI_WidthInitial / $fRatio, -1, -1, $WS_OVERLAPPEDWINDOW)
GUISetState()

While True
Switch GUIGetMsg()
Case $GUI_EVENT_CLOSE
ExitLoop
EndSwitch
WEnd

; free resources
_WinAPI_DeleteObject($hbmp)
_WinAPI_DeleteDC($hdcMem)

Return 0
EndFunc ;==>_AuMain

Func OnCreate($hwnd, $message, $wParam, $lParam)
Local $hdc, $bm = DllStructCreate($BITMAP)

$hbmp = _ScreenCapture_Capture()

If (Not $hbmp) Then
; error handling here
ConsoleWrite(StringFormat("_WinAPI_LoadImage fehlgeschlagen!\n"))
EndIf

$hdc = _WinAPI_GetDC($HWND_DESKTOP)
$hdcMem = _WinAPI_CreateCompatibleDC($hdc)

_WinAPI_ReleaseDC($HWND_DESKTOP, $hdc)

If (Not $hdcMem) Then
; error handling here
ConsoleWrite(StringFormat("_WinAPI_CreateCompatibleDC fehlgeschlagen!\n"))
EndIf

Return $GUI_RUNDEFMSG
EndFunc ;==>OnCreate

Func OnEraseBkGnd($hwnd, $message, $wParam, $lParam)
Local $rcClient
Local $hObjOld
Local $rcRight, $rcBottom
Local $bmWidth, $bmHeight
Local $bm = DllStructCreate($BITMAP)

If (Not $hbmp) Then
Return 1
EndIf

; get the window's client area
$rcClient = _WinAPI_GetClientRect($hwnd)

$rcRight = DllStructGetData($rcClient, "Right")
$rcBottom = DllStructGetData($rcClient, "Bottom")
ConsoleWrite("Ratio after WM_SIZING " & $rcRight / $rcBottom & @CRLF)

; get the bitmap dimensions
_WinAPI_GetObject($hbmp, DllStructGetSize($bm), DllStructGetPtr($bm))

; select the bitmap into the memory DC
$hObjOld = _WinAPI_SelectObject($hdcMem, $hbmp)

$bmWidth = DllStructGetData($bm, "bmWidth")
$bmHeight = DllStructGetData($bm, "bmHeight")

DllCall("gdi32.dll", "INT", "SetStretchBltMode", "HANDLE", $wParam, "INT", 4)

StretchBlt( _
$wParam, 0, 0, $rcRight, $rcBottom, _
$hdcMem, 0, 0, $bmWidth, $bmHeight, _
$SRCCOPY _
)

_WinAPI_SelectObject($hdcMem, $hObjOld)

Return 1
EndFunc ;==>OnEraseBkGnd

Func StretchBlt($hdcDest, $nXOriginDest, $nYOriginDest, $nWidthDest, $nHeightDest, $hdcSrc, $nXOriginSrc, $nYOriginSrc, $nWidthSrc, $nHeightSrc, $dwRop)
Local $aRes = DllCall("gdi32.dll", "BOOL", "StretchBlt", _
"HANDLE", $hdcDest, _
"INT", $nXOriginDest, _
"INT", $nYOriginDest, _
"INT", $nWidthDest, _
"INT", $nHeightDest, _
"HANDLE", $hdcSrc, _
"INT", $nXOriginSrc, _
"INT", $nYOriginSrc, _
"INT", $nWidthSrc, _
"INT", $nHeightSrc, _
"DWORD", $dwRop)
Return $aRes[0]
EndFunc ;==>StretchBlt

Func WM_GETMINMAXINFO($hwnd, $Msg, $wParam, $lParam)
Local $minmaxinfo = DllStructCreate("int;int;int;int;int;int;int;int;int;int", $lParam)
DllStructSetData($minmaxinfo, 7, $iMinWidth) ; min X
DllStructSetData($minmaxinfo, 8, $iMinHeight) ; min Y
DllStructSetData($minmaxinfo, 9, $iMaxWidth) ; max X
DllStructSetData($minmaxinfo, 10, $iMaxHeight) ; max Y
Return "GUI_RUNDEFMSG"
EndFunc ;==>WM_GETMINMAXINFO

Func WM_SIZING($hwnd, $iMsg, $wParam, $lParam)
Local $sRect = DllStructCreate("Int[4]", $lParam)
Local $left = DllStructGetData($sRect, 1, 1)
Local $top = DllStructGetData($sRect, 1, 2)
Local $right = DllStructGetData($sRect, 1, 3)
Local $bottom = DllStructGetData($sRect, 1, 4)

Switch $wParam ;drag side or corner
Case 1, 2, 4, 7
Local $iNewY = Int(($right - $left) / $fRatio)
DllStructSetData($sRect, 1, $top + $iNewY, 4)
Case Else
Local $iNewX = Int(($bottom - $top) * $fRatio)
DllStructSetData($sRect, 1, $left + $iNewX, 3)
EndSwitch

Return "GUI_RUNDEFMSG"
EndFunc ;==>WM_SIZING

#include <WindowsConstants.au3>
#include <GUIConstants.au3>
#include <Constants.au3>
#include <WinAPI.au3>
#include <ScreenCapture.au3>

Global $iGUI_WidthInitial = 800, $fRatio, $iMinWidth = 0, $iMinHeight = 0, $iMaxWidth = 9300, $iMaxHeight = 9300, $iX_Offset, $iY_Offset
Global $hbmp, $hdcMem

; --- $BITMAP
Global Const $BITMAP = _
"LONG bmType;" & _
"LONG bmWidth;" & _
"LONG bmHeight;" & _
"LONG bmWidthBytes;" & _
"WORD bmPlanes;" & _
"WORD bmBitsPixel;" & _
"PTR bmBits;"

Global Const $HWND_DESKTOP = _WinAPI_GetDesktopWindow()

$fRatio = _WinAPI_GetClientWidth($HWND_DESKTOP) / _WinAPI_GetClientHeight($HWND_DESKTOP)

_AuMain()

Func _AuMain()
Local $hwnd

GUIRegisterMsg($WM_CREATE, "OnCreate")
GUIRegisterMsg($WM_ERASEBKGND, "OnEraseBkGnd")
GUIRegisterMsg($WM_SIZING, "WM_SIZING")
GUIRegisterMsg($WM_GETMINMAXINFO, "WM_GETMINMAXINFO")

$hwnd = GUICreate("Test", $iGUI_WidthInitial, Floor($iGUI_WidthInitial / $fRatio), -1, -1, $WS_OVERLAPPEDWINDOW)
GUISetState()

$fRatio = _WinAPI_GetWindowWidth($hwnd) / _WinAPI_GetWindowHeight($hwnd)

While True
Switch GUIGetMsg()
Case $GUI_EVENT_CLOSE
ExitLoop
EndSwitch
WEnd

; free resources
_WinAPI_DeleteObject($hbmp)
_WinAPI_DeleteDC($hdcMem)

Return 0
EndFunc ;==>_AuMain

Func OnCreate($hwnd, $message, $wParam, $lParam)
Local $hdc, $bm = DllStructCreate($BITMAP)

$hbmp = _ScreenCapture_Capture()

If (Not $hbmp) Then
; error handling here
ConsoleWrite(StringFormat("_WinAPI_LoadImage fehlgeschlagen!\n"))
EndIf

$hdc = _WinAPI_GetDC($HWND_DESKTOP)
$hdcMem = _WinAPI_CreateCompatibleDC($hdc)

_WinAPI_ReleaseDC($HWND_DESKTOP, $hdc)

If (Not $hdcMem) Then
; error handling here
ConsoleWrite(StringFormat("_WinAPI_CreateCompatibleDC fehlgeschlagen!\n"))
EndIf

Return $GUI_RUNDEFMSG
EndFunc ;==>OnCreate

Func OnEraseBkGnd($hwnd, $message, $wParam, $lParam)
Local $rcClient
Local $hObjOld
Local $rcRight, $rcBottom
Local $bmWidth, $bmHeight
Local $bm = DllStructCreate($BITMAP)

If (Not $hbmp) Then
Return 1
EndIf

; get the window's client area
$rcClient = _WinAPI_GetClientRect($hwnd)

$rcRight = DllStructGetData($rcClient, "Right")
$rcBottom = DllStructGetData($rcClient, "Bottom")

; get the bitmap dimensions
_WinAPI_GetObject($hbmp, DllStructGetSize($bm), DllStructGetPtr($bm))

; select the bitmap into the memory DC
$hObjOld = _WinAPI_SelectObject($hdcMem, $hbmp)

$bmWidth = DllStructGetData($bm, "bmWidth")
$bmHeight = DllStructGetData($bm, "bmHeight")

DllCall("gdi32.dll", "INT", "SetStretchBltMode", "HANDLE", $wParam, "INT", 4)

StretchBlt( _
$wParam, 0, 0, $rcRight, $rcBottom, _
$hdcMem, 0, 0, $bmWidth, $bmHeight, _
$SRCCOPY _
)

_WinAPI_SelectObject($hdcMem, $hObjOld)

Return 1
EndFunc ;==>OnEraseBkGnd

Func StretchBlt($hdcDest, $nXOriginDest, $nYOriginDest, $nWidthDest, $nHeightDest, $hdcSrc, $nXOriginSrc, $nYOriginSrc, $nWidthSrc, $nHeightSrc, $dwRop)
Local $aRes = DllCall("gdi32.dll", "BOOL", "StretchBlt", _
"HANDLE", $hdcDest, _
"INT", $nXOriginDest, _
"INT", $nYOriginDest, _
"INT", $nWidthDest, _
"INT", $nHeightDest, _
"HANDLE", $hdcSrc, _
"INT", $nXOriginSrc, _
"INT", $nYOriginSrc, _
"INT", $nWidthSrc, _
"INT", $nHeightSrc, _
"DWORD", $dwRop)
Return $aRes[0]
EndFunc ;==>StretchBlt

Func WM_GETMINMAXINFO($hwnd, $Msg, $wParam, $lParam)
Local $minmaxinfo = DllStructCreate("int;int;int;int;int;int;int;int;int;int", $lParam)
DllStructSetData($minmaxinfo, 7, $iMinWidth) ; min X
DllStructSetData($minmaxinfo, 8, $iMinHeight) ; min Y
DllStructSetData($minmaxinfo, 9, $iMaxWidth) ; max X
DllStructSetData($minmaxinfo, 10, $iMaxHeight) ; max Y
Return "GUI_RUNDEFMSG"
EndFunc ;==>WM_GETMINMAXINFO

Func WM_SIZING($hwnd, $iMsg, $wParam, $lParam)
Local $tRect_Cur = DllStructCreate("int[4]", $lParam), $tRect_New = DllStructCreate($tagRECT)
Local $left = DllStructGetData($tRect_Cur, 1, 1)
Local $top = DllStructGetData($tRect_Cur, 1, 2)
Local $right = DllStructGetData($tRect_Cur, 1, 3)
Local $bottom = DllStructGetData($tRect_Cur, 1, 4)

Switch $wParam ;drag side or corner
Case 1, 2, 4, 7
Local $iNewY = Int(($right - $left) / $fRatio)
DllStructSetData($tRect_Cur, 1, $top + $iNewY, 4)
Case Else
Local $iNewX = Int(($bottom - $top) * $fRatio)
DllStructSetData($tRect_Cur, 1, $left + $iNewX, 3)
EndSwitch

Return "GUI_RUNDEFMSG"
EndFunc ;==>WM_SIZING

; #FUNCTION# ====================================================================================================================
; Name...........: _WinAPI_AdjustWindowRectEx
; Description....: Calculates the required size of the window rectangle, based on the desired size of the client rectangle.
; Syntax.........: _WinAPI_AdjustWindowRectEx ( ByRef $tRECT, $iStyle [, $iExStyle [, $fMenu] )
; Parameters.....: $tRECT - $tagRECT structure that contains the coordinates of the desired client area.
; $iStyle - The window style of the window whose required size is to be calculated. Note that you cannot
; specify the $WS_OVERLAPPED style.
; $iExStyle - The extended window style of the window whose required size is to be calculated.
; $fMenu - Specifies whether the window has a menu, valid values:
; |TRUE - The window has a menu, valid values:
; |FALSE - The window does not has a menu. (Default)
; Return values..: Success - 1.
; Failure - 0 and sets the @error flag to non-zero.
; Author.........: Yashied
; Modified.......:
; Remarks........: None
; Related........:
; Link...........: @@MsdnLink@@ AdjustWindowRectEx
; Example........: Yes
; ===============================================================================================================================

Func _WinAPI_AdjustWindowRectEx(ByRef $tRECT, $iStyle, $iExStyle = 0, $fMenu = 0)

Local $Ret = DllCall('user32.dll', 'int', 'AdjustWindowRectEx', 'ptr', DllStructGetPtr($tRECT), 'dword', $iStyle, 'int', $fMenu, 'dword', $iExStyle)

If (@error) Or (Not $Ret[0]) Then
Return SetError(1, 0, 0)
EndIf
Return 1
EndFunc ;==>_WinAPI_AdjustWindowRectEx

#include <Constants.au3>
#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Global Const $STM_SETIMAGE = 0x0172
Global $sPathKey = "HKLM64\SOFTWARE\AutoIt v3\AutoIt\"
If @OSArch = "x64" Then $sPathKey = "HKLM\SOFTWARE\Wow6432Node\AutoIt v3\AutoIt\"
Global $sImage = RegRead($sPathKey, "InstallDir") & "\Examples\GUI\logo4.gif"

Global $hGUI = GUICreate("Test", 235, 112, -1, -1, BitOR($GUI_SS_DEFAULT_GUI, $WS_SIZEBOX, $WS_THICKFRAME))
Global $idPic = GUICtrlCreatePic("", 32, 16, 169, 68)
GUICtrlSetResizing(-1, $GUI_DOCKVCENTER + $GUI_DOCKHCENTER)

_GDIPlus_Startup()
Global $hBmp = _GDIPlus_BitmapCreateFromFile($sImage)
Global $hHBitmap = _GDIPlus_BitmapCreateHBITMAPFromBitmap($hBmp)
Global $hB = GUICtrlSendMsg($idPic, $STM_SETIMAGE, $IMAGE_BITMAP, $hHBitmap)
If $hB Then _WinAPI_DeleteObject($hB)
GUISetState(@SW_SHOW)

While 1
Switch GUIGetMsg()
Case $GUI_EVENT_CLOSE
_GDIPlus_BitmapDispose($hBmp)
_GDIPlus_Shutdown()
GUIDelete()
Exit
EndSwitch
WEnd

#include <Constants.au3>
#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Global Const $STM_SETIMAGE = 0x0172
Global $sPathKey = "HKLM64\SOFTWARE\AutoIt v3\AutoIt\"
If @OSArch = "x64" Then $sPathKey = "HKLM\SOFTWARE\Wow6432Node\AutoIt v3\AutoIt\"
Global $sImage = RegRead($sPathKey, "InstallDir") & "\Examples\GUI\logo4.gif"

_GDIPlus_Startup()
Global $hBmp = _GDIPlus_BitmapCreateFromFile($sImage)
Global $iW = _GDIPlus_ImageGetWidth($hBmp), $iH = _GDIPlus_ImageGetHeight($hBmp)

Global $hGUI = GUICreate("Test", 235, 112, -1, -1, BitOR($GUI_SS_DEFAULT_GUI, $WS_SIZEBOX, $WS_THICKFRAME))
Global $idPic = GUICtrlCreatePic("", 32, 16, $iW, $iH)
GUICtrlSetResizing(-1, $GUI_DOCKVCENTER + $GUI_DOCKHCENTER)

Global $hHBitmap = _GDIPlus_BitmapCreateHBITMAPFromBitmap($hBmp)
Global $hB = GUICtrlSendMsg($idPic, $STM_SETIMAGE, $IMAGE_BITMAP, $hHBitmap)
If $hB Then _WinAPI_DeleteObject($hB)
GUISetState(@SW_SHOW)

GUIRegisterMsg($WM_SIZE, "WM_SIZE")

While 1
Switch GUIGetMsg()
Case $GUI_EVENT_CLOSE
_GDIPlus_BitmapDispose($hBmp)
_GDIPlus_Shutdown()
GUIDelete()
Exit
EndSwitch
WEnd

Func WM_SIZE($hWnd, $Msg, $wParam, $lParam)
#forceref $Msg, $wParam, $lParam
Local $aSize = ControlGetPos($hWnd, "", $idPic)
Local $aResult = DllCall($ghGDIPDll, "uint", "GdipCreateBitmapFromScan0", "int", $aSize[2], "int", $aSize[3], "int", 0, "int", 0x0026200A, "ptr", 0, "int*", 0)
Local $hBitmap = $aResult[6]
Local $hContext = _GDIPlus_ImageGetGraphicsContext($hBitmap)
DllCall($ghGDIPDll, "uint", "GdipSetInterpolationMode", "handle", $hContext, "int", 7)
_GDIPlus_GraphicsDrawImageRect($hContext, $hBmp, 0, 0, $aSize[2], $aSize[3])
_GDIPlus_GraphicsDispose($hContext)
Local $hHBitmap = _GDIPlus_BitmapCreateHBITMAPFromBitmap($hBitmap)
Local $hB = GUICtrlSendMsg($idPic, $STM_SETIMAGE, $IMAGE_BITMAP, $hHBitmap)
If $hB Then _WinAPI_DeleteObject($hB)
_WinAPI_DeleteObject($hHBitmap)
_GDIPlus_BitmapDispose($hBitmap)
Return "GUI_RUNDEFMSG"
EndFunc