Probleme mit GUISetAccelerators()

DasIch

Hallo zusammen,

ich habe in meinem Programm die Entertaste zum Bestätigen einer Funktion im Einsatz, allerdings soll er dies natürlich nicht in Editboxen ausführen, weil man so nicht darin schreiben kann.

Wie stelle ich es an, dass das Programm beim schreiben in Editboxen die Entertaste vorübergehend "deaktiviert" und erst nachdem man wieder aus der Editbox raus ist wieder aktiviert?

Hier der Code:

[autoit]

Global $aAccelKeys[1][2] = [["{ENTER}", $frmRefreshButton]]
GUISetAccelerators($aAccelKeys)

[/autoit]

Vielen Dank vorab und LG,
der Robert

**Mars**

Aus der AutoIt Hilfe zu GuiCtrlCreateEdit: Defines the style of the control. See [url='../appendix/GUIStyles.htm#Edit']GUI Control Styles Appendix[/url]. default ( -1) : $ES_WANTRETURN, $WS_VSCROLL, $WS_HSCROLL, $ES_AUTOVSCROLL, $ES_AUTOHSCROLL forced styles : $ES_MULTILINE, $WS_TABSTOP only if not $ES_READONLY.
Der Standardstyle beinhaltet alle diese Komponenten. Wenn man einen Teil davon nicht braucht kann man manuell eigene Styles beim erstellen des GuiCtrlEdit angeben. In deinem Fall müsstest du jeden Style außer $ES_WANTRETURN benutzen damit die EditBox gleich bleibt aber kein Return mehr akzeptiert.

DasIch

Okay, da reden wir gerade aneinander vorbei

Ich möchte ja, dass ich in der Editbox Enter verwenden kann, nur außerhalb dieser Editbox soll Enter halt wie gewünscht $frmRefreshButton auslösen.

**Raupi**

Ist ganz einfach, hier mal eine mögliche Lösung:

AutoIt

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <EditConstants.au3>


Global $oMyError


Example()


Func Example()
	Local $myedit, $msg


	Local $GUI = GUICreate("My GUI edit") ; will create a dialog box that when displayed is centered


	$myedit = GUICtrlCreateEdit("First line" & @CRLF, 176, 32, 121, 97, $ES_AUTOVSCROLL + $WS_VSCROLL)
	Local $test = GUICtrlCreateButton("Test", 10, 150, 100, 21)
	Local $test2 = GUICtrlCreateButton("Test1", 10, 180, 100, 21)
	Local $aAccelKeys[1][2] = [["{ENTER}", $test]]
	GUISetAccelerators($aAccelKeys)
	GUISetState(@SW_SHOW)


	Send("{END}")


	; will be append dont' forget 3rd parameter
	GUICtrlSetData($myedit, "Second line", 1)


	; Loop until the user exits.
	While 1
		Switch GUIGetMsg()
			Case $GUI_EVENT_CLOSE
				ExitLoop
			Case $test
				If ControlGetFocus($GUI) <> "Edit1" Then
					MsgBox(0, "Test", ControlGetFocus($GUI), 1)
				EndIf
		EndSwitch
	WEnd
	GUIDelete()
EndFunc   ;==>Example

Alles anzeigen

DasIch

Hiho Raupi,

danke erstmal für deine Antwort. Leider komme ich damit irgendwie nicht weiter...

So wird die Editbox erstellt, und gefüllt wird sie mit Daten aus einer Datei die ausgelesen wird:

[autoit]

$Log_edtBot = GUICtrlCreateEdit("", 421, 360, 340, 170, BitOR($ES_AUTOVSCROLL, $ES_AUTOHSCROLL, $ES_WANTRETURN, $ws_hscroll, $ws_vscroll), $WS_EX_CLIENTEDGE) ;untere Detailansicht

[/autoit]

Das Hauptfenster heißt

[autoit]

$frmMain

[/autoit]

Würde es so funktionieren? Leider tut es das nicht

[autoit]

If ControlGetFocus($frmMain) <> $Log_edtBot Then ;$Log_edtBot ist die untere von zwei Editboxen
...
EndIf

[/autoit]

**Mars**

Eigentlich müsste das funktionieren (wenn es an die richtige Stelle gepackt wird). Du musst an die Stelle wo $frmRefreshButton abgefragt wird und dort eine Abfrage zum Fokus einbauen, sodass das Event (oder wie auch immer du das gemacht hast) nur ausgelöst wird wenn der Fokus stimmt.

Wenn das nicht läuft müssten wir einen Blick in den Code werfen.

(PS: Sry, wegen dem ersten Post, aus "dass das Programm beim schreiben in Editboxen die Entertaste vorübergehend "deaktiviert"" hab ich geschlossen das die Entertaste im Edit nicht funktionieren soll^^)

DasIch

Heyho Mars, auch dir danke für die Hilfe

Ich habe den Code jetzt mal zurechtgeschnitten, weil ich nicht alle 1500 Zeilen hier reinkopieren mag Aber die Funktionen, um die es geht, habe ich trotzdem im Groben beibehalten.

schau es dir mal bitte an, ob irgendetwas nicht passt.

Zur Erklärung wie es gedacht war:
Dadurch, dass ich einige Textfelder habe, nach deren Begriffen in Dateien, Berechtigungen usw. gesucht werden können, war es sehr unangenehm, immer den Button anklicken zu müssen. Also habe ich mir einen Workaround einfallen lassen, wie man die Suche auch mit Enter starten kann.

Hierzu setze ich mit GUISetAccelerators() einen entsprechenden Hotkey, der einen anderen, versteckten Button auslöst, der wiederum eine Funktion startet. In dieser Funktion wird geschaut, aus welchem Textfeld die Eingaben kamen und entsprechend wird die jeweilige Funktion ausgeführt.

Allerdings ist das Problem, dass ich, wenn ich in der besagten Editbox den Text bearbeiten möchte und Enter drücke, immer die zuletzt ausgeführte Suche ausgeführt wird, was natürlich nicht Sinn der Sache ist. Ich möchte in der Editbox sobald sie aktiv ist auch mit Enter arbeiten können und den Hotkey während dieser Bearbeitung deaktivieren können.

Ich hoffe ihr versteht das Problem nun besser und könnt mir helfen

LG und Danke,
der Robert

P.S.: Hier noch der Sourcecode:

Spoiler anzeigen

AutoIt

#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <GUIListBox.au3>
#include <StaticConstants.au3>
#include <TabConstants.au3>
#include <WindowsConstants.au3>
#RequireAdmin


$frmMain = GUICreate("", 170, 200)
$Log_edtBot = GUICtrlCreateEdit("", 8, 35, 150, 150, BitOR($ES_AUTOVSCROLL, $ES_AUTOHSCROLL, $ES_WANTRETURN, $ws_hscroll, $ws_vscroll), $WS_EX_CLIENTEDGE) ;untere Detailansicht
GUICtrlSetBkColor(-1, "0xffffff")
GUICtrlSetFont(-1, 10, 500, 0, "Arial")
$Log_txtSkript = GUICtrlCreateInput("", 8, 8, 150, 25)
$frmRefreshButton = GUICtrlCreateButton("", 8, 8, 20, 25)
GUICtrlSetState($frmRefreshButton, $GUI_HIDE)
GUISetState(@SW_SHOW)


Global $Log_sUser, $iLog, $iEnter, $hPwrShell


#Region Hotkeys
	Global $aAccelKeys[1][2] = [["{ENTER}", $frmRefreshButton]]
	GUISetAccelerators($aAccelKeys)
#EndRegion




While 1
	$nMsg = GUIGetMsg(1)
	Switch $nMsg[0]
		Case $GUI_EVENT_CLOSE
			Switch $nMsg[1]
				Case $frmMain
					If $hPwrShell = True Then
						WinClose($hPwrShell)
					EndIf
					Exit
				Case Else
					GUISetState(@SW_SHOW, $frmMain)
					GUISetState(@SW_HIDE, $nMsg[1])
					GUISetState(@SW_DISABLE, $nMsg[1])
					GUISwitch($frmMain)
			EndSwitch


		Case $frmRefreshButton
			_Enter()


		Case $Log_txtSkript
			$iEnter = 1


	EndSwitch
WEnd


#Region Enter Taste
Func _Enter()
	;1 = Details anzeigen


	Switch $iEnter


		Case 1
			If ControlGetFocus($frmMain) <> "EDIT1" Then
;~ 			MsgBox(0, "", "Details anzeigen")
			_TestFunc()
			Else
				MsgBox(0, "", "Details anzeigen")
			EndIf


	EndSwitch
EndFunc
#EndRegion


Func _TestFunc()
	MsgBox(0, "", "TestFunc")
EndFunc

Alles anzeigen

**Raupi**

Was hält dich davon ab mal die Hilfe zu ControlGetFocus zu lesen?
Die Rückgabe ist nicht ein ControlId wie $Log_edtBot sondern ein String mit z.B. "EDIT1", "BUTTON1" usw und danach solltest du abfragen.

AutoIt

if ControlGetFocus($frmMain) <> "EDIT1" Then

Warum ich das in meinem Bespiel wohl benutzt habe?

DasIch

Oh, na klar. Wusste ich doch! Not...

Okay, damit kann ich zumindest verhindern, dass die Funktion erneut ausgeführt wird. Allerdings kann ich immer noch keine Entertaste für den Zeilenumbruch in der Editbox verwenden

**Mars**

Ich rate von versteckten Buttons ab. Ein einfacher Trick wäre die nutzung von _IsPressed.
Nachteil: Muss im Main Loop auftauchen -> verbraucht etwas Rechenzeit
Vorteil: Absolut Ctrl-Unabhängig, da einfach nur gecheckt wird ob eine Taste gedrückt wurde.

AutoIt

#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <GUIListBox.au3>
#include <StaticConstants.au3>
#include <TabConstants.au3>
#include <WindowsConstants.au3>
#include <Misc.au3>
;~ #RequireAdmin


$frmMain = GUICreate("", 170, 200)
$Log_edtBot = GUICtrlCreateEdit("", 8, 35, 150, 150, BitOR($ES_AUTOVSCROLL, $ES_AUTOHSCROLL, $ES_WANTRETURN, $ws_hscroll, $ws_vscroll), $WS_EX_CLIENTEDGE) ;untere Detailansicht
GUICtrlSetBkColor(-1, "0xffffff")
GUICtrlSetFont(-1, 10, 500, 0, "Arial")
$Log_txtSkript = GUICtrlCreateInput("", 8, 8, 150, 25)
;~ $frmRefreshButton = GUICtrlCreateButton("", 8, 8, 20, 25)
;~ GUICtrlSetState($frmRefreshButton, $GUI_HIDE)
GUISetState(@SW_SHOW)


Global $Log_sUser, $iLog, $iEnter, $hPwrShell


;~ #Region Hotkeys
;~ 	Global $aAccelKeys[1][2] = [["{ENTER}", $frmRefreshButton]]
;~ 	GUISetAccelerators($aAccelKeys)
;~ #EndRegion




While 1
	$nMsg = GUIGetMsg(1)
	Switch $nMsg[0]
		Case $GUI_EVENT_CLOSE
			Switch $nMsg[1]
				Case $frmMain
					If $hPwrShell = True Then
						WinClose($hPwrShell)
					EndIf
					Exit
				Case Else
					GUISetState(@SW_SHOW, $frmMain)
					GUISetState(@SW_HIDE, $nMsg[1])
					GUISetState(@SW_DISABLE, $nMsg[1])
					GUISwitch($frmMain)
			EndSwitch


;~ 		Case $frmRefreshButton
;~ 			_Enter()


		Case $Log_txtSkript
			$iEnter = 1


	EndSwitch


	If _IsPressed('0D') And ControlGetFocus($frmMain) <> 'Edit1' Then _Enter()
WEnd


#Region Enter Taste
Func _Enter()
	;1 = Details anzeigen
	_TestFunc()


;~ 	Switch $iEnter


;~ 		Case 1
;~ 			If ControlGetFocus($frmMain) <> 'Edit1' Then
;~ 			MsgBox(0, "", "Details anzeigen")
;~ 			_TestFunc()
;~ 			Else
;~ 				MsgBox(0, "", "Details anzeigen")
;~ 			EndIf


;~ 	EndSwitch
EndFunc
#EndRegion


Func _TestFunc()
	MsgBox(0, "", "TestFunc")
EndFunc

Alles anzeigen

lg
M

DasIch

Das hat mir sehr geholfen Mars Daran sieht man, dass du schon länger hier bist und die Wege kennst die man gehen kann und sie dir nicht noch mühevoll herleiten musst

Gibt es eine Möglichkeit nach dem Enter Drücken, den Fokus aus dem Inputfeld zu lösen, sodass man das Popup mit Enter wieder schließen kann?

**Mars**

Das erste was mir eingefallen ist ist ein Workaround mit einem Local Static Timer.
Die Funktion kann also nur 0.5s (natürlich beliebig veränderbar) nachdem sie zuletzt beendet wurde wieder aufgerufen werden. Ist glaube ich keine besonderst elegante Lösung, so bleibt aber der Fokus auf dem Inputfeld erhalten und trotzdem kann das Popup mit Return beendet werden.

AutoIt

#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <GUIListBox.au3>
#include <StaticConstants.au3>
#include <TabConstants.au3>
#include <WindowsConstants.au3>
#include <Misc.au3>
;~ #RequireAdmin


$frmMain = GUICreate("", 170, 200)
$Log_edtBot = GUICtrlCreateEdit("", 8, 35, 150, 150, BitOR($ES_AUTOVSCROLL, $ES_AUTOHSCROLL, $ES_WANTRETURN, $ws_hscroll, $ws_vscroll), $WS_EX_CLIENTEDGE) ;untere Detailansicht
GUICtrlSetBkColor(-1, "0xffffff")
GUICtrlSetFont(-1, 10, 500, 0, "Arial")
$Log_txtSkript = GUICtrlCreateInput("", 8, 8, 150, 25)
;~ $frmRefreshButton = GUICtrlCreateButton("", 8, 8, 20, 25)
;~ GUICtrlSetState($frmRefreshButton, $GUI_HIDE)
GUISetState(@SW_SHOW)


Global $Log_sUser, $iLog, $iEnter, $hPwrShell


;~ #Region Hotkeys
;~ 	Global $aAccelKeys[1][2] = [["{ENTER}", $frmRefreshButton]]
;~ 	GUISetAccelerators($aAccelKeys)
;~ #EndRegion




While 1
	$nMsg = GUIGetMsg(1)
	Switch $nMsg[0]
		Case $GUI_EVENT_CLOSE
			Switch $nMsg[1]
				Case $frmMain
					If $hPwrShell = True Then
						WinClose($hPwrShell)
					EndIf
					Exit
				Case Else
					GUISetState(@SW_SHOW, $frmMain)
					GUISetState(@SW_HIDE, $nMsg[1])
					GUISetState(@SW_DISABLE, $nMsg[1])
					GUISwitch($frmMain)
			EndSwitch


;~ 		Case $frmRefreshButton
;~ 			_Enter()


		Case $Log_txtSkript
			$iEnter = 1


	EndSwitch


	If _IsPressed('0D') And ControlGetFocus($frmMain) <> 'Edit1' Then _Enter()
WEnd


#Region Enter Taste
Func _Enter()
	Local Static $iTimer = TimerInit(), $bFirstrun = True
	If TimerDiff($iTimer) < 500 And Not $bFirstrun Then Return
	$bFirstrun = False


	;1 = Details anzeigen
	_TestFunc()


;~ 	Switch $iEnter


;~ 		Case 1
;~ 			If ControlGetFocus($frmMain) <> 'Edit1' Then
;~ 			MsgBox(0, "", "Details anzeigen")
;~ 			_TestFunc()
;~ 			Else
;~ 				MsgBox(0, "", "Details anzeigen")
;~ 			EndIf


;~ 	EndSwitch
	$iTimer = TimerInit()
EndFunc
#EndRegion


Func _TestFunc()
	MsgBox(0, "", "TestFunc")
EndFunc

Alles anzeigen

**Raupi**

_IsPressed genau wie HotKeySet ist aber eine beschissen Lösung. Die Entertaste ist Global umbelegt und nicht nur auf die GUI bezogen.
Angenommen du hast das Prog am laufen und du willst was im Browser schreiben, dann hast du gelitten. Bei Enter wird auch im Browser die Funktion ausgeführt.

DasIch

Also würdest du GUISetAccelerators() nutzen, Raupi? Wenn ja, erklär mir doch bitte, wie ich die Zeilenumbrüche mit Enter in der Editbox verwirklichen kann

**Kanashius**

In deine ENTER-Funktion einfügen, dass, wenn Das EDIT den Fokus hat, das ENTER an das EDIT gegeben wird.
guictrlgetfocus() gabs doch glaub ich dafür.
Gegebenenfalls einfach ein @crlf in das edit schreiben.

DasIch

Es kann so einfach sein:

AutoIt

If ControlGetFocus($frmMain) = 'Edit1' Then
_GUICtrlEdit_InsertText($Log_edtBot, @CRLF)
Else
_TestFunc()
EndIf

Danke euch!