PING mit Mailversand (Server Überwachen)

Prekuz

Huhu,

ich hab mal wieder ein Problem. Was ich möchte ist das ich alle ca. 3 Minuten einen Ping auf meine Server mache und wenn diese/r nicht verfügbar ist eine Mail rausgeschickt wird.
Im Prinzip funktioniert der Mail versand ohne Probleme (Andere Scripte laufen sehr gut z.B. Backupbenachrichtigungen etc.)

C

#include <MsgBoxConstants.au3>


;##################################
; Global Variablen
;##################################
Global $oMyRet[2]
Global $oMyError = ObjEvent("AutoIt.Error", "MyErrFunc")
Global $pc = @ComputerName												; Auslesen des PC Namen
Global $Domain = @LogonDNSDomain										; Auselesen der Domain
Global $IPDC = "192.168.2.1"											; IP Adresse vom Domain Controller
Global $IPWSM = "192.168.3.1	"										; IP Adresse vom WSM Server
Global $NameDC = "DC"													; IP Adresse vom Domain Controller
Global $NameWSM = "WSM"




#include <_INetSmtpMailCom.au3>
#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>




;##################################
; Variablen
;##################################
$SmtpServer = "mail.gmx.net" 												; SMPT Server vom Provider (Ist Erforderlich)
$FromName = "Überwachung Ping Server" & $Domain			 					; Von wem kommt die Mail
$FromAddress = "mail@absender.de" 										; Email Adresse von (Ist Erforderlich)
$ToAddress = "mail@empfänger.de" 									; Email Adresse an (Ist Erforderlich)
;$Subject = "Server nicht Verfügbar in der  " & " " & $Domain 				; Betreff für die Email (Kann Variabel vergeben werden)
$Body = "Server nicht erreichbar in der:  " & $Domain 						; WIRD HIER IN DER SCHLEIFE VERGEBEN Text inhalt (kann auch leer bleiben)
$Importance = "Hight" ; 													; Priorität der Email: "High", "Normal", "Low"
$Username = "Benutzer" 											; Loginname der Email Adresse (Ist Erforderlich)
$Password = "Passwort" 													; Passwort der Email Adresse (Ist Erforderlich)
$IPPort = 465 																; Genutzter Port(Ist Erforderlich)
$ssl = 1 																	; SSL an (1) oder aus (0)(Ist Erforderlich)






While True
Sleep(180000)
																				 ; Warte 3 min bis zum erneuten Ausführen


; 1. Abfrage Domain Controler


       Local $PingDc = Ping($IPDC, 250) 										 ; Ping auf Server max Antwortzeit toleranz 250 ms


    If $PingDC Then 															 ; Wenn ein Ping erfolgreich ist tue nichts

		; wenn PING innerhalb von 250 ms gehe zur 2. Abfrage
		; MsgBox($MB_SYSTEMMODAL, "", "Antwortzeit von   " & $IPDC & ":   "& $PingDC & " ms" & "  Alles OK  ")


	Else																		 ; Wenn ein Ping nicht erfolgreich ist sende mail


		 ; wenn Ping nicht innerhalb von 250 ms dann verschicke Email
        $Subject = "Server nicht Verfügbar in der:  " & $Domain & " " & $NameDc  ; Betreff für die Email, muss hier gesetzt werden da der Servername gesetzt werden muss
		$rc = _INetSmtpMailCom($SmtpServer, $FromName, $FromAddress, $ToAddress, $Subject, $Body, $Importance, $Username, $Password, $IPPort, $ssl)


		 ;MsgBox($MB_SYSTEMMODAL, "", "Ein Fehler ist aufgetretten bei  " & $IPDC)


	 EndIf




; 2. Abfrage WSM Server


	 Local $PingWSM = Ping($IPWSM, 250) 										  ; Ping auf Server max Antwortzeit toleranz 250 ms


    If $PingWSM Then 


																				  ; Wenn ein Ping erfolgreich ist tue nichts


		 ; wenn PING innerhalb von 250 ms gehe zum Anfang der Schleife
		 ;MsgBox($MB_SYSTEMMODAL, "", "Antwortzeit von   " & $IPWSM & ":   "& $PingWSM & " ms" & "  Alles OK  ")


	 Else																		  ; Wenn ein Ping nicht erfolgreich ist sende mail


		 ; wenn Ping nicht innerhalb von 250 ms dann verschicke Email

		$Subject = "Server nicht Verfügbar in der:  " & $Domain & " " & $NameWSM  ; Betreff für die Email, muss hier gesetzt werden da der Servername gesetzt werden muss
		$rc = _INetSmtpMailCom($SmtpServer, $FromName, $FromAddress, $ToAddress, $Subject, $Body, $Importance, $Username, $Password, $IPPort, $ssl)


		 ;MsgBox($MB_SYSTEMMODAL, "", "Ein Fehler ist aufgetretten bei  " & $IPWSM)


	 EndIf
WEnd

Alles anzeigen

IP Adressen und Benutzer daten sind im Orginal Script richtig.

Jetzt steh ich da und finde keine Lösung. Mit denn MSGBoxen klappt es aber der Versand der Mail nicht. Habt ihr eine Idee? Von mir aus auch was ganz anderes. Danke schon mal im Voraus.

LG
Pre

**AspirinJunkie**

Wo ist denn dein Error-Handling für die _INetSmtpMailCom?
Einmal @error direkt danach abfragen bzw. da es sich um ein COM-Objekt handelt folgendes noch an den Anfang des Skriptes:

AutoIt

ObjEvent("AutoIt.Error", "_ErrFunc")

und dann folgende Funktion noch irgendwo im Skript unterbringen:

AutoIt

; User's COM error function. Will be called if COM error occurs
Func _ErrFunc($oError)
    ; Do anything here.
    ConsoleWrite(@ScriptName & " (" & $oError.scriptline & ") : ==> COM Error intercepted !" & @CRLF & _
            @TAB & "err.number is: " & @TAB & @TAB & "0x" & Hex($oError.number) & @CRLF & _
            @TAB & "err.windescription:" & @TAB & $oError.windescription & @CRLF & _
            @TAB & "err.description is: " & @TAB & $oError.description & @CRLF & _
            @TAB & "err.source is: " & @TAB & @TAB & $oError.source & @CRLF & _
            @TAB & "err.helpfile is: " & @TAB & $oError.helpfile & @CRLF & _
            @TAB & "err.helpcontext is: " & @TAB & $oError.helpcontext & @CRLF & _
            @TAB & "err.lastdllerror is: " & @TAB & $oError.lastdllerror & @CRLF & _
            @TAB & "err.scriptline is: " & @TAB & $oError.scriptline & @CRLF & _
            @TAB & "err.retcode is: " & @TAB & "0x" & Hex($oError.retcode) & @CRLF & @CRLF)
EndFunc   ;==>_ErrFunc

Alles anzeigen

Dann solltest du verwertbare Informationen bekommen wenn die _INetSmtpMailCom() fehl schlägt.

Edit: Sehe gerade, dass du eine eigene MyErrFunc schon registriert hast.
Was schmeißt die für Fehlermeldungen?

**bernd670**

Hallo,

3 Fehler sind mir aufgefallen.

$Importance = "Hight" gibt es nicht, sondern $Importance = "High"
~~der Port für mail.gmx.net ist 587~~ Edit: geht doch mit Port 465
Bei dem Aufruf von _INetSmtpMailCom fehlen 3 Parameter, muss so aufgerufen werden
_INetSmtpMailCom($SmtpServer, $FromName, $FromAddress, $ToAddress, $Subject, $Body, $AttachFiles, $CcAddress, $BccAddress, $Importance, $Username, $Password, $IPPort, $ssl)

Noch ein paar Tipps!

Ich würde mich nie auf ein einzelnen Ping verlassen. Es kann nämlich passieren das der erste Ping fehlschlägt, das hängt mit dem ARP Cache zusammen!
Besser ist ein Ping in einer Schleife mit Timeout z.B. so

AutoIt

Const $TimeOut = 250


$TimeoutTimer = TimerInit()
Do
	$PingDc = Ping($IPDC, 50)
Until TimerDiff($TimeoutTimer >= $TimeOut) Or $PingDc > 0

Für einen ersten Check ist Ping in Ordnung, aber wenn der Rechner per Ping erreichbar ist heißt das noch lange nicht das die Dienste auch laufen.
Man sollte evtl. zusätzlich noch eine Überprüfung der Dienste z. B. via WMI-Abfrage einbauen.

**Andy**

Hi,

Ping nützt dir nur etwas, wenn du herausfinden willst, ob der Rechner läuft.
Das hat NICHTS damit zu tun herauszufinden, ob dort auch die benötigten Dienste, bspw. Mail/FTP/File-blablubServer-Dienste, erreichbar sind!

vgl. HIER und HIER, die Antwortzeiten werden von M$-Betriebssystemen (und anderen btw. auch) dynamisch berechnet und können bis zu 15 Sekunden im Fall eines nicht laufenden Dienstes betragen!

Prekuz

Huhu,

danke für die Hilfe.
@Andy hier gehts es darum zu schauen ob Server da wenn nein dann mail an mich. Damit ich nicht erst reagieren kann wenn ich einen Anruf vom Anwender bekomme.
@bernd670 danke die fehlenden Parameter haben es gerichtet.

Die Dienstabfrage wird anderes geregelt intern mit einem anderen Script.

Vielen Dank für die Hilfe

Runa

Zitat von Prekuz

Huhu,

danke für die Hilfe.
@Andy hier gehts es darum zu schauen ob Server da wenn nein dann mail an mich. Damit ich nicht erst reagieren kann wenn ich einen Anruf vom Anwender bekomme.
@bernd670 danke die fehlenden Parameter haben es gerichtet.

Die Dienstabfrage wird anderes geregelt intern mit einem anderen Script.

Vielen Dank für die Hilfe

Ich empfehle das Tool "BLAT". Der hat ein eigenes Error-Log, ist Kommandozeile(n) basiert, portable und sehr klein. Nutzen wir zum selben Zweck.

gmmg

für ein mailreporting + attachments habe ich hier folgendes script.
die beiden Dateien body.txt & config.ini (muss in config.ini umbenannt werden) müssen im script verzeichnis liegen.

AutoIt

#include <File.au3>
#include <String.au3>
#Include <Array.au3>
#include <Date.au3>


Dim $oMyRet, $oMyError, $to, $cc, $bcc, $subject, $body, $attachment, $aRecords, $body_txt, $allfilesok


Local $ADMINUSER = "user")
Local $DOMAIN = @LogonDomain
Local $ADMINPASS = "passwort")


;----ini---
$ini = @scriptdir & "\config.ini"


$from = IniRead($ini, "Variablen", "from", "NotFound")
$to = IniRead($ini, "Variablen", "to", "NotFound")
$cc = IniRead($ini, "Variablen", "cc", "NotFound")
$bcc = IniRead($ini, "Variablen", "bcc", "NotFound")
$subject = IniRead($ini, "Variablen", "subject", "NotFound")
$body = IniRead($ini, "Variablen", "body", "NotFound")
$attachment = IniRead($ini, "Variablen", "attachment", "NotFound")
;MsgBox(0,"",$attachment)
;----------
If Not _FileReadToArray(@ScriptDir & "\" & $body, $aRecords) Then
   MsgBox(0,"Error1", " Error reading log to Array     error:" & @error,2)
   Exit
EndIf
For $x = 1 to $aRecords[0]


	$body_txt &= $aRecords[$x] & @CRLF


	 ;Msgbox(0,'Record:' & $x, $body02)
Next


;Msgbox(0,'Record:' & $x, $body_txt)


If $attachment = "" Then
	;Sendmail()
Else
	$attachment_files = StringSplit($attachment,";")
	$allfilesok = 1
	For $i = 1 To $attachment_files[0]
        ;MsgBox(0, $attachment_files[0], $attachment_files[$i])
		;ConsoleWrite($attachment_files[$i] & @CRLF)
		$iFileExists = FileExists($attachment_files[$i])
		IF $iFileExists = 0 Then $allfilesok = 0
    Next
	;MsgBox(0,"allfilesok",$allfilesok)


	;MsgBox(0,"",$file01[0])
;~ 	IF FileExists($file01[1]) Then
	If $allfilesok = 1 Then
		Sendmail()
	Else
		$to = "support@test.de"
		$subject = "ReportFile nicht vorhanden"
		$body_txt = $attachment
		$attachment = ""
		Sendmail()
	EndIf
EndIf


;MsgBox(0,"test",$body_txt)


sleep (2000)


Func Sendmail()


	;MsgBox(0,"", $strData2)  ;mailadresse prüfen


	Global $oMyError = ObjEvent("AutoIt.Error", "MyErrFunc")
	;##################################
	; Variables
	;##################################
	$s_SmtpServer = "server" 	; address for the smtp-server to use - REQUIRED
	$s_FromName = $from 						; name from who the email was sent
	$s_FromAddress = $from 						; address from where the mail should come
	$s_ToAddress = $to							; destination address of the email - REQUIRED
	$s_Subject = $subject						; subject from the email - can be anything you want it to be
	$as_Body = $body_txt						; the messagebody from the mail - can be left blank but then you get a blank mail
	$s_AttachFiles = $attachment				; the file you want to attach- leave blank if not needed
	$s_CcAddress = $cc 							; address for cc - leave blank if not needed
	$s_BccAddress = $bcc 						; address for bcc - leave blank if not needed
	$s_Username = $ADMINUSER						; username for the account used from where the mail gets sent  - Optional (Needed for eg GMail)
	$s_Password = $ADMINPASS					; password for the account used from where the mail gets sent  - Optional (Needed for eg GMail)
	$IPPort = 25 								; port used for sending the mail
	$ssl = 0 									; enables/disables secure socket layer sending - put to 1 if using httpS
	;~ $IPPort=465                            	; GMAIL port used for sending the mail
	;~ $ssl=1                                 	; GMAILenables/disables secure socket layer sending - put to 1 if using httpS


	;##################################
	; Script
	;##################################
	Global $oMyRet[2]
	;MsgBox(0,"", $s_SmtpServer& $s_FromName& $s_FromAddress& $s_ToAddress& $s_Subject& $as_Body& $s_AttachFiles& $s_CcAddress& $s_BccAddress& $s_Username& $s_Password& $IPPort& $ssl)
	$rc = _INetSmtpMailCom($s_SmtpServer, $s_FromName, $s_FromAddress, $s_ToAddress, $s_Subject, $as_Body, $s_AttachFiles, $s_CcAddress, $s_BccAddress, $s_Username, $s_Password, $IPPort, $ssl)
	If @error Then
		MsgBox(0, "Error sending message", "Error code:" & @error & "  Description:" & $rc,1)
	EndIf


EndFunc   ;==>Sendmail




Func _INetSmtpMailCom($s_SmtpServer, $s_FromName, $s_FromAddress, $s_ToAddress, $s_Subject = "", $as_Body = "", $s_AttachFiles = "", $s_CcAddress = "", $s_BccAddress = "", $s_Username = "", $s_Password = "", $IPPort = 25, $ssl = 0)
	$objEmail = ObjCreate("CDO.Message")
	$objEmail.From = '"' & $s_FromName & '" <' & $s_FromAddress & '>'
	$objEmail.To = $s_ToAddress
	Local $i_Error = 0
	Local $i_Error_desciption = ""
	If $s_CcAddress <> "" Then $objEmail.Cc = $s_CcAddress
	If $s_BccAddress <> "" Then $objEmail.Bcc = $s_BccAddress
	$objEmail.Subject = $s_Subject
	If StringInStr($as_Body, "<") And StringInStr($as_Body, ">") Then
		$objEmail.HTMLBody = $as_Body
	Else
		$objEmail.Textbody = $as_Body & @CRLF
	EndIf
	If $s_AttachFiles <> "" Then
		Local $S_Files2Attach = StringSplit($s_AttachFiles, ";")
		For $x = 1 To $S_Files2Attach[0]
			$S_Files2Attach[$x] = _PathFull($S_Files2Attach[$x])
			If FileExists($S_Files2Attach[$x]) Then
				$objEmail.AddAttachment($S_Files2Attach[$x])
			Else
				$i_Error_desciption = $i_Error_desciption & @LF & 'File not found to attach: ' & $S_Files2Attach[$x]
				SetError(1)
				Return 0
			EndIf
		Next
	EndIf
	$objEmail.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2
	$objEmail.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpserver") = $s_SmtpServer
	$objEmail.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = $IPPort
	;Authenticated SMTP
	If $s_Username <> "" Then
		$objEmail.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpauthenticate") = 1
		$objEmail.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/sendusername") = $s_Username
		$objEmail.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/sendpassword") = $s_Password
	EndIf
	If $ssl Then
		$objEmail.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpusessl") = True
	EndIf
	;Update settings
	$objEmail.Configuration.Fields.Update
	; Sent the Message
	$objEmail.Send
	If @error Then
		SetError(2)
		Return $oMyRet[1]
	EndIf
EndFunc   ;==>_INetSmtpMailCom


Func MyErrFunc()
	$HexNumber = Hex($oMyError.number, 8)
	$oMyRet[0] = $HexNumber
	$oMyRet[1] = StringStripWS($oMyError.description, 3)
	ConsoleWrite("### COM Error !  Number: " & $HexNumber & "   ScriptLine: " & $oMyError.scriptline & "   Description:" & $oMyRet[1] & @LF)
	SetError(1); something to check for when this function returns
	Return
EndFunc   ;==>MyErrFunc

Alles anzeigen

gruß gmmg

Peter S. Taler · *Ab 19-10-22 ergänzt um:*

@ bernd670
Du schreibst .....

Ich würde mich nie auf ein einzelnen Ping verlassen. Es kann nämlich passieren das der erste Ping fehlschlägt, das hängt mit dem ARP Cache zusammen!

Ich habe in einem Sript tatsächlich, das Problem dass genau das, alle paar Wochen mal passiert . Kannst Du mir erklären was es sich mit dem ARP Code auf sich hat. Unbenommen davon, dass ich das in eine Schleife umbaue ... ich habe aber an der Stelle nicht so ewig Zeit, was ist die sichere Mindestanforderung an die Schleife?

Danke für Antwort

Peter