_IsPressed in Inputbox

Silvermoon

Hallo Forum
Habe wieder mal ein Problem.
Ich möchte die Eingabe bestimmter Zeichen in einer Inputbox unterbinden.
Func _test() sollte die Eingabe Beistrich (,) nicht zulassen.
Leider klappt das nicht was ist daran falsch?
Danke für eure Tipp’s

C

include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <Misc.au3>
#include <GuiEdit.au3>
#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("Form1", 270, 43, 380, 136)
$Input1 = GUICtrlCreateInput("", 16, 8, 245, 21)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###
$hdll =""
While 1
	$nMsg = GUIGetMsg()
	Switch $nMsg
		Case $GUI_EVENT_CLOSE
			Exit
		Case $Input1
			_test()
	EndSwitch
WEnd


;-----------------------
Func _test()
	Local $dll = DllOpen("user32.dll")
While 1


    If  _IsPressed("BC", $hDLL) Then


       MsgBox(0,"Fehler","Befehle dürfen keinen '','' haben",3)
	   _GUICtrlEdit_SetText($Input1,"")
    EndIf
    Sleep(250)
WEnd
DllClose($hDLL)
EndFunc

Alles anzeigen

**alpines**

Letztens gabs eine UDF dafür: Gefilterte Eingabe: InputFilter.au3 (1.1)

Du könntest aber auch einfach bei jeder Eingabe (wird ja eine WM Nachricht geschickt) die , entfernen, oder wenn du den Inhalt des Feldes weiterverarbeitest einfach mit StringReplace das , entfernen.

4ern

geht auch alles ohne _IsPressed...

AutoIt

#include <GUIConstantsEx.au3>


$Form1 = GUICreate("Form1", 270, 43, 380, 136)
$Input1 = GUICtrlCreateInput("", 16, 8, 245, 21)
GUISetState(@SW_SHOW)


While 1
	$nMsg = GUIGetMsg()
	Switch $nMsg
		case 0
			if _captureSymbol($Input1, ',') = true then 
				MsgBox(0,'Fehler','Befehle dürfen keinen "," haben',3)
				GUICtrlSetData($Input1, StringReplace(GUICtrlRead($Input1), ',', ''))
			endif

		Case $GUI_EVENT_CLOSE
			Exit

	EndSwitch
WEnd


func _captureSymbol($input, $symbol)
	If StringInStr(GUICtrlRead($input), $symbol) = 0 Then return False
	return True
endfunc

Alles anzeigen

Silvermoon

Hallo Alpines
Danke für deinen Tipp
Bei Deinem Link für die UDF fand ich leider nichts zum downloaden.
Was meinst du mit:

Zitat

Du könntest aber auch einfach bei jeder Eingabe (wird ja eine WM Nachricht geschickt)

Im Moment versuche ich, sobald input1 den Fokus hat wird die Function „_Test()“ aufgerufen und dort der Tastendruck mit _IsPressed abgefragt.
Er springt zwar in die besagte Funktion aber _IsPressed erkennt scheinbar nicht wenn ich die Taste Beistrich drücke.

**BugFix**

WM-Messages wertest du aus, durch registrieren einer Funktion dazu:

AutoIt

#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
Opt("GUIOnEventMode", 1)


$hGui = GUICreate("Test")
GUISetOnEvent($GUI_EVENT_CLOSE, '_ende')
$cInput = GUICtrlCreateInput('', 50, 20, 100, 20)
GUISetState(@SW_SHOW)


GUIRegisterMsg($WM_COMMAND, "WM_COMMAND")


While True
    Sleep(100)
WEnd


Func _ende()
    Exit
EndFunc


Func WM_COMMAND($hWnd, $iMsg, $iwParam, $ilParam)
    Local $hWndFrom, $iIDFrom, $iCode, $hWndEdit = GUICtrlGetHandle($cInput)
    $hWndFrom = $ilParam
    $iCode = BitShift($iwParam, 16) ; Hi Word
    Switch $hWndFrom
		Case $hWndEdit
            Switch $iCode
				Case $EN_CHANGE  ; Sent when the user has taken an action that may have altered text in an edit control
					Local $sRead = ControlGetText($hWnd, '', $iIDFrom)
					If StringRegExp($sRead, ',\Z') Then ; last Input = ','
						ControlSetText($hWnd, '', $iIDFrom, StringTrimRight($sRead, 1)) ; Komma abschneiden
						ControlSend($hWnd, '', $iIDFrom, '{END}') ; Cursor ans Ende setzen
					EndIf
			EndSwitch
	EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_COMMAND

Alles anzeigen

Silvermoon

Ich danke Euch allen Dreien für eure Hilfe.
Aber nur wegen einem einzelnen Zeichen erscheint mir der Aufwand doch etwas viel.
Ich dachte es geht einfacher.
Deshalb habe ich eine andere Lösung gefunden, nicht gerade professionell aber es erfüllt seinen Zweck

Die Profis mögen mir für solchen Skript verzeihen.

Code

HotKeySet(",", "_Beistrich")
;----------
Func _Beistrich()
	MsgBox(0,"Fehler","Befehle dürfen keinen '','' haben",3)
		_GUICtrlEdit_SetText($Input5,"")
EndFunc

Das Thema kann geschlossen werden
Danke euch noch mal.
Silvemoon

**alpines**

Wenn du einen HotKey setzt dann mach das bitte anständig. Sollte die Anwendung laufen und man will in einem Chat ein , tippen, dann wird das geblockt.

Deshalb schau nach ob dein Fenster aktiv ist, ansonsten soll er , dennoch senden (aber HotKey nicht noch einmal auslösen).

Silvermoon

Alpines:
Danke das ist mir klar, muss ich noch einbauen.

4ern

Hm du baust somit ein Kreisverkehr auf der Autobahn... Am Ende wird deine Funktion größer als die Beispiele. Wie Alpines schon gesagt hat musst du Fenster erkennen, wenn deine gui weitere inputs hat musst du diese ebenfalls abgreifen... Du erschaffst somit eigene Probleme die du wiederum lösen musst.

Tipp: Nimm dir die Zeit und Versuch das anhand den Beispielen zulösen. Damit hast du eine anständige Lösung und zudem lernst du was dabei.

Ok Bugfix sein Beispiel ist etwas für Fortgeschrittene, dies solltest du dir anschauen wenn du etwas weiter bist.

**BugFix**

Nochwas zu HotKeys. Diese sollte man nicht mit einer GUI verwenden, da sind GuiSetAccelerator wesentlich besser geeignet, da diese von Haus aus nur für die jeweilige GUI gelten.
HotKeys sind nur sinnvoll für systemweite Anwendungen.