GUICtrlCreateTab() TopRight Background

philipp

Hi,

ich bräuchte eure Hilfe, und zwar geht es um den Hintergrund einer TabControl, jedoch nicht den Hintergrund in einem Tab sondern den Hintergrund oben rechts, bzw in der Zeile, in der man die Tabs switchen kann.
Gibt es eine Möglichkeit diesen an die Backgroundcolor der GUI anzupassen?
Bild zeigt nochmal genauer mein Problem.

Für die, die es nochmal Testen wollen:

Spoiler anzeigen

AutoIt

GUICreate("Test")
GUISetBkColor(0x005588)
GUICtrlCreateTab(50, 50, 200, 200)
GUICtrlCreateTabItem("Test1")
GUICtrlCreateTabItem("Test2")
GUISetState()
Do


Until GUIGetMsg() = -3

Unbenannt.png

Lg Phil

**Oscar**

Die Hilfe sagt dazu:

Zitat

The tabitem control cannot be colored (too much code ...).

Ich fürchte, außer mit irgendwelchen Basteleien (überlagernde Labels oder ähnliches) wirst Du das nicht hinbekommen.

philipp

Ok, wäre es da vielleicht sinnvoller eine "eigene" TabView zu bauen?

Bzw, kann man nicht irgendwie mit WinAPI die Farben ändern?

**autoBert**

Probiere das gewünschte Ergebnis durch andere GUI-Elemente nachzustellen, z.B. so:

C

#include <StaticConstants.au3>
#include <GUIConstantsEx.au3>


Example()


Func Example()
	GUICreate("My GUI Tab", 250, 150); will create a dialog box that when displayed is centered


	GUISetBkColor(0x00E0FFFF)
	GUISetFont(9, 300)
	GUICtrlCreateGraphic(10,30,200,80,$SS_GRAYRECT)
	Local $idTab = GUICtrlCreateTab(10, 10, 150, 20)
	GUICtrlCreateTabItem("tab0")
	GUICtrlCreateLabel("label0", 30, 80, 50, 20)
	GUICtrlCreateButton("OK0", 20, 50, 50, 20)
	GUICtrlCreateInput("default", 80, 50, 70, 20)


	GUICtrlCreateTabItem("tab----1")
	GUICtrlCreateLabel("label1", 30, 80, 50, 20)
	GUICtrlCreateCombo("", 20, 50, 60, 120)
	GUICtrlSetData(-1, "Trids|CyberSlug|Larry|Jon|Tylo|guinness", "Jon"); default Jon
	GUICtrlCreateButton("OK1", 80, 50, 50, 20)


	GUICtrlCreateTabItem("tab2")
	GUICtrlSetState(-1, $GUI_SHOW); will be display first
	GUICtrlCreateLabel("label2", 30, 80, 50, 20)
	GUICtrlCreateButton("OK2", 140, 50, 50)


	GUICtrlCreateTabItem(""); end tabitem definition


	GUICtrlCreateLabel("Click on tab and see the title", 20, 130, 250, 20)


	GUISetState(@SW_SHOW)


	Local $idMsg
	; Loop until the user exits.
	While 1
		$idMsg = GUIGetMsg()


		If $idMsg = $GUI_EVENT_CLOSE Then ExitLoop
		If $idMsg = $idTab Then
			; display the clicked tab
			WinSetTitle("My GUI Tab", "", "My GUI Tab" & GUICtrlRead($idTab))
		EndIf
	WEnd
EndFunc   ;==>Example

Alles anzeigen

oder mit einem eingefärbtem Label ohne Text

**Oscar**

Was einem Tab am nächsten kommt, ist eine Gui mit mehreren Child-Guis und Checkboxen mit besonderen Style. Damit lässt sich dann schon etwas ähnliches hinkriegen:

AutoIt

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>


Opt('GUIOnEventMode', 1)


Global $hMainGui = GUICreate('Test', 800, 600)
GUISetBkColor(0x005588)
GUISetOnEvent($GUI_EVENT_CLOSE, '_CloseMainGui')


Global $aidTab[3], $ahTab[3], $aColor[3] = [0xFFAAAA, 0xAAFFAA, 0xAAAAFF], $iOld = -1
For $i = 0 To UBound($aidTab) - 1
	$aidTab[$i] = GUICtrlCreateCheckbox('Tab' & $i + 1, 50 + $i * 100, 48, 100, 28, BitOR($BS_AUTORADIOBUTTON, $BS_PUSHLIKE))
	GUICtrlSetFont(-1, 10, 400, 0, 'Arial')
	GUICtrlSetOnEvent(-1, '_TabClick')
Next
Global $aPos = WinGetPos($hMainGui)
For $i = 0 To UBound($aidTab) - 1
	$ahTab[$i] = GUICreate('', 700, 500, 50, 78, $WS_POPUP, $WS_EX_MDICHILD, $hMainGui)
	GUISetBkColor($aColor[$i], $ahTab[$i])
Next


GUISwitch($ahTab[0])
GUICtrlCreateLabel('Das hier steht auf Tab 1', 10, 50, 200, 20)


GUISwitch($ahTab[1])
GUICtrlCreateLabel('Das hier steht auf Tab 2', 10, 50, 200, 20)


GUISwitch($ahTab[2])
GUICtrlCreateLabel('Das hier steht auf Tab 3', 10, 50, 200, 20)


GUISetState(@SW_SHOW, $hMainGui)
ControlClick($hMainGui, '', $aidTab[0])
WinWaitClose($hMainGui)
Exit


Func _CloseMainGui()
	GUIDelete($hMainGui)
EndFunc   ;==>_CloseMainGui


Func _TabClick()
	Local $iNew = @GUI_CtrlId - $aidTab[0]
	If $iNew = $iOld Then Return
	If $iOld = -1 Then $iOld = 0
	GUISetState(@SW_HIDE, $ahTab[$iOld])
	$iOld = $iNew
	GUISetState(@SW_SHOWNOACTIVATE, $ahTab[$iNew])
EndFunc   ;==>_TabClick

Alles anzeigen

**BugFix**

Zitat von Phil-IT

Ok, wäre es da vielleicht sinnvoller eine "eigene" TabView zu bauen?

Gibt es hier im Forum. Such mal nach Funkey's OwnTab-UDF.

philipp

Danke an euch alle! Ich denke ich werde es erstmal mit der unschönen Variante machen, da es in meinem Script nicht sooooo wichtig ist wie es aussieht.
BugFix ich werde es mir später noch anschauen.