TrayIcon Notification Counter

kaesereibe

Huhu =)

hat jemand eine Ahnung wie ich ein Notification Counter hinbekomme ählich wie im Bild unten?

[Blockierte Grafik: https://addons.cdn.mozilla.net/user-media/previews/full/130/130796.png?modified=1413303217]

Ohne das ich für jede Zahl ein eigenes Icon zur Verfügung stelle.

Danke im Voraus

kaese

**Raupi**

Mit GDIPlus das Icon modifizieren und per TraySetIcon dieses setzen.

Hier mal ein kleines Beispiel zum rumspielen:

AutoIt

#include <WindowsConstants.au3>
#include <GDIPlus.au3>
#include <WinAPI.au3>


Global Const $tagNOTIFYICONDATA = "dword Size;" & _
        "hwnd Wnd;" & _
        "uint ID;" & _
        "uint Flags;" & _
        "uint CallbackMessage;" & _
        "ptr Icon;" & _
        "wchar Tip[128];" & _
        "dword State;" & _
        "dword StateMask;" & _
        "wchar Info[256];" & _
        "uint Timeout;" & _
        "wchar InfoTitle[64];" & _
        "dword InfoFlags;" & _
        "dword Data1;word Data2;word Data3;byte Data4[8];" & _
        "ptr BalloonIcon"


Global Const $NIM_ADD = 0
Global Const $NIM_MODIFY = 1


Global Const $NIF_MESSAGE = 1
Global Const $NIF_ICON = 2


Global Const $AUT_WM_NOTIFYICON = $WM_USER + 1 ; Application.h
Global Const $AUT_NOTIFY_ICON_ID = 1 ; Application.h


AutoItWinSetTitle("this is a test 123")
Global $TRAY_ICON_GUI = WinGetHandle(AutoItWinGetTitle()) ; Internal AutoIt GUI


;;;


_GDIPlus_Startup()


Local $hBitmap, $hImage, $hGraphic, $hIcon


$hBitmap = _WinAPI_CreateSolidBitmap(0, 0xFFFFFF, 16, 16)
$hImage = _GDIPlus_BitmapCreateFromHBITMAP($hBitmap)
$hGraphic = _GDIPlus_ImageGetGraphicsContext($hImage)


For $i = 99 To 1 Step -1
    _GDIPlus_GraphicsClear($hGraphic, 0xFFFFFFFF)
    _GDIPlus_GraphicsDrawString($hGraphic, $i, (StringLen($i) - 2) * - 3, 2, "Arial", 8)


    $hIcon = _GDIPlus_BitmapCreateHICONFromBitmap($hImage)
    _Tray_SetHIcon($hIcon)
    _WinAPI_DestroyIcon($hIcon)


    Sleep(200)
Next


_GDIPlus_ImageDispose($hImage)
_GDIPlus_GraphicsDispose($hGraphic)
_WinAPI_DeleteObject($hBitmap)


_GDIPlus_Shutdown()


;;;


Func _Tray_SetHIcon($hIcon)
    Local $tNOTIFY = DllStructCreate($tagNOTIFYICONDATA)
    DllStructSetData($tNOTIFY, "Size", DllStructGetSize($tNOTIFY))
    DllStructSetData($tNOTIFY, "Wnd", $TRAY_ICON_GUI)
    DllStructSetData($tNOTIFY, "ID", $AUT_NOTIFY_ICON_ID)
    DllStructSetData($tNOTIFY, "Icon", $hIcon)
    DllStructSetData($tNOTIFY, "Flags", BitOR($NIF_ICON, $NIF_MESSAGE))
    DllStructSetData($tNOTIFY, "CallbackMessage", $AUT_WM_NOTIFYICON)


    Local $aRet = DllCall("shell32.dll", "int", "Shell_NotifyIconW", "dword", $NIM_MODIFY, "ptr", DllStructGetPtr($tNOTIFY))
    If (@error) Then Return SetError(1, 0, 0)


    Return $aRet[0] <> 0
EndFunc   ;==>_Tray_SetHIcon


Func _GDIPlus_BitmapCreateHICONFromBitmap($hBitmap)
    Local $hIcon = DllCall($__g_hGDIPDll, "int", "GdipCreateHICONFromBitmap", "hwnd", $hBitmap, "int*", 0)
    If @error Or Not $hIcon[0] Then Return SetError(@error, @extended, $hIcon[2])


    Return $hIcon[2]
EndFunc   ;==>_GDIPlus_BitmapCreateHICONFromBitmap

Alles anzeigen

**Tweaky**

Wow, sieht super aus Raupi, gleich mal gesichert.

Per Zufall habe ich entdeckt, dass es die Funktion "_WinAPI_ShellNotifyIcon" gibt.
Spricht was dagegen, statt deinem dllcall diese zu verwenden?

Außer habe ich probiert, ob ich statt dem einfachen weißen Bild ein Icon verwenden kann. Leider wird da nicht gezählt.
Siehst du was da falsch ist?

AutoIt

#Region    ;************ Includes ************
#Include <WinAPIShellEx.au3>
#include <WindowsConstants.au3>
#include <GDIPlus.au3>
#EndRegion ;************ Includes ************


Global Const $AUT_WM_NOTIFYICON = $WM_USER + 1 ; Application.h
Global Const $AUT_NOTIFY_ICON_ID = 1 ; Application.h


AutoItWinSetTitle("this is a test 123")
Global $TRAY_ICON_GUI = WinGetHandle(AutoItWinGetTitle()) ; Internal AutoIt GUI


;;;


_GDIPlus_Startup()


Local $hBitmap, $hImage, $hGraphic, $hIcon


$hBitmap = _WinAPI_CreateSolidBitmap(0, 0xFFFFFF, 16, 16)
$hImage = _GDIPlus_BitmapCreateFromHBITMAP($hBitmap)
$hGraphic = _GDIPlus_ImageGetGraphicsContext($hImage)


For $i = 99 To 1 Step -1
	_GDIPlus_GraphicsClear($hGraphic, 0xFFFFFFFF)
	_GDIPlus_GraphicsDrawString($hGraphic, $i, (StringLen($i) - 2) * -3, 2, "Arial", 8)


;~ 	$hIcon = _GDIPlus_BitmapCreateHICONFromBitmap($hImage)
	$hIcon = _WinAPI_ShellExtractIcon(@SystemDir & '\shell32.dll', 166, 16, 16)
	_Tray_SetHIcon($hIcon)
	_WinAPI_DestroyIcon($hIcon)


	Sleep(200)
Next


_GDIPlus_ImageDispose($hImage)
_GDIPlus_GraphicsDispose($hGraphic)
_WinAPI_DeleteObject($hBitmap)


_GDIPlus_Shutdown()


;;;


Func _Tray_SetHIcon($hIcon)
	Local $tNOTIFY = DllStructCreate($tagNOTIFYICONDATA)
	DllStructSetData($tNOTIFY, "Size", DllStructGetSize($tNOTIFY))
	DllStructSetData($tNOTIFY, "hWnd", $TRAY_ICON_GUI)
	DllStructSetData($tNOTIFY, "ID", $AUT_NOTIFY_ICON_ID)
	DllStructSetData($tNOTIFY, "hIcon", $hIcon)
	DllStructSetData($tNOTIFY, "Flags", BitOR($NIF_ICON, $NIF_MESSAGE))
	DllStructSetData($tNOTIFY, "CallbackMessage", $AUT_WM_NOTIFYICON)


	Local $aRet = DllCall("shell32.dll", "int", "Shell_NotifyIconW", "dword", $NIM_MODIFY, "ptr", DllStructGetPtr($tNOTIFY))
;~ 	Local $aRet = _WinAPI_ShellNotifyIcon($NIM_MODIFY, $tNOTIFY)
	If (@error) Then Return SetError(1, 0, 0)


;~ 	Return $aRet[0] <> 0
EndFunc   ;==>_Tray_SetHIcon


Func _GDIPlus_BitmapCreateHICONFromBitmap($hBitmap)
	Local $hIcon = DllCall($__g_hGDIPDll, "int", "GdipCreateHICONFromBitmap", "hwnd", $hBitmap, "int*", 0)
	If @error Or Not $hIcon[0] Then Return SetError(@error, @extended, $hIcon[2])


	Return $hIcon[2]
EndFunc   ;==>_GDIPlus_BitmapCreateHICONFromBitmap

Alles anzeigen

**Raupi**

Kann ich dir nichts dazu sagen. Das Beispiel ist ein 1 Minuten google ergebnis.
Vielleicht kann dir warter dazu was sagen, soweit ich weis stammt der Code von ihm.

**Oscar**

Das Problem hierbei ist die Unterscheidung GDI und GDI+. Einmal mit und einmal ohne Plus.
Wenn Du eine GDI+ Bitmap erstellst und darauf zeichnest, musst Du sie anschließend erst in eine GDI-Bitmap umwandeln, bevor Du sie an das Control (hier das Tray-Icon) senden kannst.
Ich habe das Beispiel mal abgewandelt und kommentiert:

AutoIt

#include <APIShellExConstants.au3>
#include <GDIPlus.au3>
#include <WinAPI.au3>
#include <WinAPIShellEx.au3>
#include <WindowsConstants.au3>


Global Const $AUT_WM_NOTIFYICON = $WM_USER + 1
Global Const $AUT_NOTIFY_ICON_ID = 1


AutoItWinSetTitle("this is a test 123")
Global $TRAY_ICON_GUI = WinGetHandle(AutoItWinGetTitle()) ; Internal AutoIt GUI


OnAutoItExitRegister('OnAutoItExit')
_GDIPlus_Startup()
Global $iSize = 16, $hNewIcon
Global $hIcon = _WinAPI_ShellExtractIcon(@SystemDir & '\shell32.dll', 2, $iSize, $iSize)
Global $hBitmapIcon = _GDIPlus_BitmapCreateFromHICON($hIcon) ; GDI+ Bitmap vom HIcon erstellen
Global $hBitmap = _GDIPlus_BitmapCreateFromScan0($iSize, $iSize) ; leere GDI+ Bitmap zum zeichnen erstellen
Global $hGraphic = _GDIPlus_ImageGetGraphicsContext($hBitmap) ; GraphicContext der Bitmap
Global $hBrush = _GDIPlus_BrushCreateSolid(0xFF000000) ; Brush (ARGB) erstellen
Global $hFormat = _GDIPlus_StringFormatCreate()
Global $hFamily = _GDIPlus_FontFamilyCreate('Verdana') ; Zeichensatz auswählen
Global $hFont = _GDIPlus_FontCreate($hFamily, 8, 1) ; Größe und Stil des Zeichensatzes
Global $tLayout = _GDIPlus_RectFCreate(2, 1, $iSize - 2, $iSize - 1) ; Rechteck: Left, Top, Width, Height


For $i = 9 To 0 Step -1
	_GDIPlus_GraphicsClear($hGraphic) ; Graphic löschen
	_GDIPlus_GraphicsDrawImage($hGraphic, $hBitmapIcon, 0, 0) ; das Icon zeichnen
	_GDIPlus_GraphicsDrawStringEx($hGraphic, $i, $hFont, $tLayout, $hFormat, $hBrush) ; den String ($i) zeichnen
	$hNewIcon = _GDIPlus_HICONCreateFromBitmap($hBitmap) ; ein HIcon (GDI ohne Plus) der Bitmap (GDI+) erstellen
	_Tray_SetHIcon($hNewIcon)
	_WinAPI_DestroyIcon($hNewIcon)
	Sleep(500)
Next




While 1
	Sleep(1000)
WEnd


Func OnAutoItExit()
	_GDIPlus_FontDispose($hFont)
	_GDIPlus_FontFamilyDispose($hFamily)
	_GDIPlus_StringFormatDispose($hFormat)
	_GDIPlus_BrushDispose($hBrush)
	_GDIPlus_GraphicsDispose($hGraphic)
	_GDIPlus_BitmapDispose($hBitmap)
	_GDIPlus_BitmapDispose($hBitmapIcon)
	_WinAPI_DestroyIcon($hIcon)
	_GDIPlus_Shutdown()
EndFunc   ;==>OnAutoItExit




Func _Tray_SetHIcon($hIcon)
	Local $tNOTIFY = DllStructCreate($tagNOTIFYICONDATA)
	DllStructSetData($tNOTIFY, "Size", DllStructGetSize($tNOTIFY))
	DllStructSetData($tNOTIFY, "hWnd", $TRAY_ICON_GUI)
	DllStructSetData($tNOTIFY, "ID", $AUT_NOTIFY_ICON_ID)
	DllStructSetData($tNOTIFY, "hIcon", $hIcon)
	DllStructSetData($tNOTIFY, "Flags", BitOR($NIF_ICON, $NIF_MESSAGE))
	DllStructSetData($tNOTIFY, "CallbackMessage", $AUT_WM_NOTIFYICON)
	Local $aRet = DllCall("shell32.dll", "int", "Shell_NotifyIconW", "dword", $NIM_MODIFY, "ptr", DllStructGetPtr($tNOTIFY))
	If @error Then Return SetError(1, 0, 0)
	Return $aRet[0] <> 0
EndFunc   ;==>_Tray_SetHIcon

Alles anzeigen

**Andy**

hier gabs vor Jahren auch schon etwas

**Tweaky**

Ok, darauf wäre ich nie gekommen.
Aber statt dem DllCall kann man auch _WinAPI_ShellNotifyIcon verwenden, oder?

Geht es auch, dass der weiße Hintergrund der Schrift transparent ist?

**Raupi**

Welchen Code meinst du? Den von Oscar? Wenn ja, der Hintergrund der Zahlen ist doch transparent. Das Weiß kommt vom Icon.

**Tweaky**

Ja den von Oscar.
Du hast recht Raupi.
Hab gar nicht darauf geachtet, welches Icon Oscar verwendet hat.
Dachte er hat meines übernommen.

Somit ist der Hintergrund transparent