UNIX Timestamp in Millisekunden

' DateToInteger8.vbs
' VBScript program demonstrating how to convert a datetime value to
' the corresponding Integer8 (64-bit) value. The Integer8 value is the
' number of 100-nanosecond intervals since 12:00 AM January 1, 1601,
' in Coordinated Universal Time (UTC). The conversion is only accurate
' to the nearest second, so the Integer8 value will always end in at
' least 7 zeros.


' beispiel: "C:\test.vbs" "5/5/2010 0:00:00 PM"
'
' ----------------------------------------------------------------------
' Copyright (c) 2004 Richard L. Mueller
' Hilltop Lab web site - http://www.rlmueller.net
' Version 1.0 - June 11, 2004
'
' You have a royalty-free right to use, modify, reproduce, and
' distribute this script file in any way you find useful, provided that
' you agree that the copyright owner above has no warranty, obligations,
' or liability for such use.


Option Explicit


Dim dtmDateValue, dtmAdjusted, lngSeconds, str64Bit, objShell, lngBiasKey, lngBias, k, fso, file
Dim WshShell
dtmDateValue = InputBox("   Enter Date to convert" & vbcrlf & vbcrlf &"    5/5/2010 0:00:00 PM","Integer8 Converter", " 5/5/2010 0:00:00 PM")


' Evaluate the user input.
If dtmDateValue = "" Then    ' Canceled by the user
    WScript.Echo "Canceled by the user"
	WScript.Quit
Else 
    'WScript.Echo dtmDateValue
End If


' Obtain local Time Zone bias from machine registry.
Set objShell = CreateObject("Wscript.Shell")
lngBiasKey = objShell.RegRead("HKLM\System\CurrentControlSet\Control\" _
& "TimeZoneInformation\ActiveTimeBias")
If UCase(TypeName(lngBiasKey)) = "LONG" Then
lngBias = lngBiasKey
ElseIf UCase(TypeName(lngBiasKey)) = "VARIANT()" Then
lngBias = 0
For k = 0 To UBound(lngBiasKey)
lngBias = lngBias + (lngBiasKey(k) * 256^k)
Next
End If


' Convert datetime value to UTC.
dtmAdjusted = DateAdd("n", lngBias, dtmDateValue)


' Find number of seconds since 1/1/1601.
lngSeconds = DateDiff("s", #1/1/1601#, dtmAdjusted)


' Convert the number of seconds to a string
' and convert to 100-nanosecond intervals.
str64Bit = CStr(lngSeconds) & "0000000"
'Wscript.Echo "Integer8 value: " & str64Bit


'Set fso = Wscript.CreateObject("Scripting.FileSystemObject")
Set fso = CreateObject("Scripting.FileSystemObject")
Set file = fso.CreateTextFile("C:\ScriptLog.txt")


'Set File = fso.OpenTextFile("C:\log.txt",8,true)
file.WriteLine "Integer8 value: " & str64Bit
file.close


Set WshShell = WScript.CreateObject("WScript.Shell")
WshShell.Run "%windir%\notepad C:\ScriptLog.txt"
'WScript.Sleep 2000