Taskleiste automatisch ausblenden

matthias87

Hallo,

ich würde gerne die Funktion "Taskleiste automatisch ausblenden" mit einer Autoit Funktion aktivieren/deaktivieren.
Ich bin bereits soweit:

AutoIt

#cs ----------------------------------------------------------------------------


 AutoIt Version: 3.3.14.1
 Author:         myName


 Script Function:
	Template AutoIt script.


#ce ----------------------------------------------------------------------------


; Script Start - Add your code below here
Run("rundll32.exe shell32.dll,Options_RunDLL 1")
sleep (500)
send("{TAB}")
If GUICtrlRead(1102) = 0 Then
	send("{+}")


else


	send("{-}")
EndIf
send("{TAB 8}")
send("{ENTER}")

Alles anzeigen

Das Problem ist, dass die if else Funktion nicht funktioniert.

Ich weiß das geht bestimmt um einiges eleganter aber so war es nun einmal am einfachsten

Vielen Dank!

Matthias

**BugFix**

Zitat von matthias87

Ich weiß das geht bestimmt um einiges eleganter

Ja, und das sollte man dann auch versuchen, statt irgendwelche Send-Konstrukte zu nehmen.

AutoIt

#include <WinAPI.au3>


Func _TrayVisible($_fVisible) ; True/False
	Local Const $SWP_SHOWWINDOW = 0x40
	Local Const $SWP_HIDEWINDOW = 0x80
	Local $hTray = _WinAPI_FindWindow("Shell_TrayWnd", "")
	Local $iFlag = $_fVisible ? $SWP_SHOWWINDOW : $SWP_HIDEWINDOW
	_WinAPI_SetWindowPos($hTray, 0, 0, 0, 0, 0, $iFlag)
EndFunc

matthias87

Danke für deine Antwort. Wie du an meinen Versuchen gesehen hast, habe ich nicht viel Ahnung von der Programmierung mit Autoit, ich habe es aber versucht...

Den von dir geschrieben Code kann ich überhaupt nicht zuordnen. Das Googeln von TrayVisible brachte auch keine wirklichen Ergebnisse. Ein einfach ausführen des Codes bewirkt bei mir nichts.
Könntest du das bitte noch ein wenig erklären?

**BugFix**

Zitat

Das Googeln von TrayVisible brachte auch keine wirklichen Ergebnisse

Die Funktion habe ich auch gerade erst erstellt.
Das ist eine Funktion, die du mit _TrayVisible(True) oder _TrayVisible(False) aufrufen musst.

**Bitnugger**

@matthias87
In AutoIt integrierte Funktionen beginnen immer ohne einen initialen Unterstrich. Von Usern selbst definierte Funktionen (UDF = User Defined Function) sollten zur besseren Unterscheidung mit einem Unterstrich beginnen. Hilfsfunktionen in UDFs, die nur zur internen Verwendung gedacht sind, fangen meist mit zwei Unterstrichen an.

Damit auch der Start-Button verschwindet, wenn die Taskleiste ausgeblendet wird, habe ich noch ein paar Zeilen hinzugefügt... ich verstehe nur nicht, wieso das Fenster des Start-Button erst nach einem MouseMove wieder sichbar wird.

AutoIt

#include-once
#include <WinAPI.au3>






_TrayVisible(False)
Sleep(2000)
_TrayVisible(True)






Func _TrayVisible($_fVisible) ; True/False
    Local Const $SWP_SHOWWINDOW = 0x40
    Local Const $SWP_HIDEWINDOW = 0x80
    Local $hTray = _WinAPI_FindWindow("Shell_TrayWnd", "")
    Local $hStart = _WinAPI_FindWindow("Button", "Start")
    Local $iFlag = $_fVisible ? $SWP_SHOWWINDOW : $SWP_HIDEWINDOW
    _WinAPI_SetWindowPos($hTray, 0, 0, 0, 0, 0, $iFlag)
    _WinAPI_SetWindowPos($hStart, 0, 0, 0, 0, 0, $iFlag)
    Switch $iFlag
        Case $SWP_SHOWWINDOW
            Local $aPos = MouseGetPos()
            Local $aWinPos = WinGetPos($hStart)
            MouseMove($aWinPos[0], $aWinPos[1], 1)
            MouseMove($aPos[0], $aPos[1], 1)
    EndSwitch
EndFunc

Alles anzeigen

**BugFix**

Zitat von Bitnugger

Damit auch der Start-Button verschwindet, wenn die Taskleiste ausgeblendet wird, habe ich noch ein paar Zeilen hinzugefügt... ich verstehe nur nicht, wieso das Fenster des Start-Button erst nach einem MouseMove wieder sichbar wird.

Weil der Startbutton nicht die Position 0,0 besitzt.
Hier mal die Funktion, bei der es dann auch egal ist, wo die Taskbar angedockt ist:

AutoIt

Func _TrayVisible($_fVisible) ; True/False
	Local Const $SWP_SHOWWINDOW = 0x40
	Local Const $SWP_HIDEWINDOW = 0x80
	Local $hTray = _WinAPI_FindWindow("Shell_TrayWnd", "")
;~ 	Local $hStart = _WinAPI_FindWindow("ClassicShell.CStartButton", "")  ; bei Benutzung Classic.Shell
	Local $hStart = _WinAPI_FindWindow("Button", "Start")
	Local $aTray = WinGetPos($hTray), $aStart = WinGetPos($hStart)
	Local $iFlag = $_fVisible ? $SWP_SHOWWINDOW : $SWP_HIDEWINDOW
	_WinAPI_SetWindowPos($hTray, 0, $aTray[0], $aTray[1], $aTray[2], $aTray[3], $iFlag)
	_WinAPI_SetWindowPos($hStart, 0, $aStart[0], $aStart[1], $aStart[2], $aStart[3], $iFlag)
EndFunc

Alles anzeigen

Edit:
Oder vielleicht besser allgemeingültig mit Vorbelegung Standard-Windows-Button

AutoIt

; Classic Shell:
;~ _TrayVisible(False, "ClassicShell.CStartButton", "")
;~ Sleep(2000)
;~ _TrayVisible(True, "ClassicShell.CStartButton", "")


; Standard:
_TrayVisible(False)
Sleep(2000)
_TrayVisible(True)


Func _TrayVisible($_fVisible, $_sDefButtonClass='Button', $_sDefButtonText='Start') ; True/False
	Local Const $SWP_SHOWWINDOW = 0x40
	Local Const $SWP_HIDEWINDOW = 0x80
	Local $hStart = _WinAPI_FindWindow($_sDefButtonClass, $_sDefButtonText)
	Local $aTray = WinGetPos($hTray), $aStart = WinGetPos($hStart)
	Local $iFlag = $_fVisible ? $SWP_SHOWWINDOW : $SWP_HIDEWINDOW
	_WinAPI_SetWindowPos($hTray, 0, $aTray[0], $aTray[1], $aTray[2], $aTray[3], $iFlag)
	_WinAPI_SetWindowPos($hStart, 0, $aStart[0], $aStart[1], $aStart[2], $aStart[3], $iFlag)
EndFunc

Alles anzeigen

Racer

Hallo!

Meine Lösung sieht so aus:

Hidetask:

AutoIt

WinSetState("[Class:Shell_TrayWnd]","",@SW_HIDE)
WinSetState("Start","",@SW_HIDE)

Showtask:

AutoIt

WinSetState("[Class:Shell_TrayWnd]","",@SW_SHOW)
WinSetState("Start","",@SW_SHOW)

lg
Racer

**BugFix**

@Racer
DAS ist doch viel zu einfach.

Aber wenn schon kurz, dann will ich auch Einzeiler

AutoIt

; Hide
BitOR(WinSetState("[Class:Shell_TrayWnd]","",@SW_HIDE),WinSetState("Start","",@SW_HIDE))
; Show
BitOR(WinSetState("[Class:Shell_TrayWnd]","",@SW_SHOW),WinSetState("Start","",@SW_SHOW))

**Bitnugger**

Sehr schön... beide... wobei mir der Einzeiler - obwohl ein wenig lahmer - besser gefällt.

Dann sieht das Ganze nun so bei mir aus:

AutoIt

;-- TIME_STAMP   2015-09-29 14:29:34   v 1.1




_TrayVisible(False)
Sleep(2000)
_TrayVisible(True)




Func _TrayVisible($_fVisible) ; True/False
    Switch $_fVisible
        Case True
            ; Show
            BitOR(WinSetState("[Class:Shell_TrayWnd]","",@SW_SHOW),WinSetState("[TITLE:Start; CLASS:Button]","",@SW_SHOW))
        Case False
            ; Hide
            BitOR(WinSetState("[Class:Shell_TrayWnd]","",@SW_HIDE),WinSetState("[TITLE:Start; CLASS:Button]","",@SW_HIDE))
    EndSwitch
EndFunc

Alles anzeigen

**Oscar**

Na dann aber als Einzeiler:

AutoIt

Func _TrayVisible($_fVisible) ; True/False
	BitOR(WinSetState("[Class:Shell_TrayWnd]", "", $_fVisible ? @SW_SHOW : @SW_HIDE), WinSetState("[TITLE:Start; CLASS:Button]","",$_fVisible ? @SW_SHOW : @SW_HIDE))
EndFunc