Times Table, Mandelbrot und Symmetrie

#include <GDIPlus.au3>
#include <Color.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>


Opt("MustDeclareVars", 1)
Opt("GUIOnEventMode", 1)


Global $iWidth = 600
Global $iHeight = 600


_GDIPlus_Startup()
Global $hGui = GUICreate("Test", $iWidth, $iHeight + 70)
GUISetOnEvent($GUI_EVENT_CLOSE, "_Exit")
Global $cSL_Mul = GUICtrlCreateSlider(10, $iHeight + 5, $iWidth - 20, 30)
Global $cSL_MulF = GUICtrlCreateSlider(10, $iHeight + 35, $iWidth - 20, 30)
Global $hGraphics = _GDIPlus_GraphicsCreateFromHWND($hGui)
Global $hBmp_Buffer = _GDIPlus_BitmapCreateFromGraphics($iWidth, $iHeight, $hGraphics)
Global $hGfx_Buffer = _GDIPlus_ImageGetGraphicsContext($hBmp_Buffer)
_GDIPlus_GraphicsSetSmoothingMode($hGfx_Buffer, 2)
GUIRegisterMsg($WM_PAINT, "WM_PAINT")
GUIRegisterMsg($WM_HSCROLL, "WM_HSCROLL")
GUISetState()


For $i = 0 To 101 Step 0.05
	If GUIGetCursorInfo($hGui)[2] Then ExitLoop
	GUICtrlSetData($cSL_Mul, Floor($i))
	GUICtrlSetData($cSL_MulF, ($i-Floor($i)) * 100)
	_Draw($i, 200, $iWidth * 0.5, $iHeight * 0.5, $iHeight * 0.4, $i / 25 * 240)
	Sleep(10)
Next


While Sleep(10)
WEnd






Func _Draw($fMultiplier, $iSegments, $fX, $fY, $fR, $iHue)
	WinSetTitle($hGui, "", StringFormat("%.2f", $fMultiplier))


	Local $fAngle = 360 / $iSegments * ATan(1) / 45


	Local $hPath = _GDIPlus_PathCreate()
	For $i = 0 To $iSegments - 1
		_GDIPlus_PathAddLine($hPath, $fX + Cos($i * $fAngle) * $fR, $fY + Sin($i * $fAngle) * $fR, $fX + Cos($i * $fAngle * $fMultiplier) * $fR, $fY + Sin($i * $fAngle * $fMultiplier) * $fR)
		_GDIPlus_PathCloseFigure($hPath)
	Next


	Local $aHSL[3] = [Mod($iHue, 240), 240, 120]
	Local $aRGB = _ColorConvertHSLtoRGB($aHSL)
	Local $hPen = _GDIPlus_PenCreate(BitOR(0xFF000000, BitShift($aRGB[0], -16), BitShift($aRGB[1], -8), $aRGB[2]))
	_GDIPlus_GraphicsClear($hGfx_Buffer, 0xFF000000)
	_GDIPlus_GraphicsDrawPath($hGfx_Buffer, $hPath, $hPen)
	_GDIPlus_GraphicsDrawEllipse($hGfx_Buffer, $fX - $fR, $fY - $fR, $fR + $fR, $fR + $fR, $hPen)
	_GDIPlus_PathDispose($hPath)
	_GDIPlus_PenDispose($hPen)
	_GDIPlus_GraphicsDrawImage($hGraphics, $hBmp_Buffer, 0, 0)
EndFunc   ;==>_Draw




Func WM_HSCROLL($hWnd, $iMsg, $wParam, $lParam)
	#forceref $hWnd, $iMsg, $wParam, $lParam
	Switch $hWnd
		Case $hGui
			If BitAND($wParam, 0x0000FFFF) = 5 Then
				Switch $lParam
					Case GUICtrlGetHandle($cSL_Mul)
						Local $fMul = BitShift($wParam, 16) + GUICtrlRead($cSL_MulF) / 100
						_Draw($fMul, 200, $iWidth * 0.5, $iHeight * 0.5, $iHeight * 0.4, $fMul / 25 * 240)
					Case GUICtrlGetHandle($cSL_MulF)
						Local $fMul = BitShift($wParam, 16) / 100 + GUICtrlRead($cSL_Mul)
						_Draw($fMul, 200, $iWidth * 0.5, $iHeight * 0.5, $iHeight * 0.4, $fMul / 25 * 240)
				EndSwitch
			EndIf
	EndSwitch
	Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_HSCROLL




Func WM_PAINT($hWnd, $iMsg, $wParam, $lParam)
	_GDIPlus_GraphicsDrawImage($hGraphics, $hBmp_Buffer, 0, 0)
	Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_PAINT




Func _Exit()
	_GDIPlus_GraphicsDispose($hGfx_Buffer)
	_GDIPlus_BitmapDispose($hBmp_Buffer)
	_GDIPlus_GraphicsDispose($hGraphics)
	_GDIPlus_Shutdown()
	GUIDelete($hGui)
	Exit
EndFunc   ;==>_Exit