Ich erstelle ein Skript, der neue Active Directory Benutzer anlegt.
Der Benutzername soll aus dem ersten Buchstab des Vornames, ein Punkt, und dem Nachnamen bestehen.
Beispiele: Stefan Raab = s.raab
Georg Schmidt = g.schmidt
usw.
Wie kann ich Auto-IT dies machen lassen?
was genau die namen erstellen oder die Benutzer in AD anlegen? oder beides?
[autoit]$vorname = "Hans"
$nachname = "Wurst"
$name = StringLeft($vorname, 1) & "." & $nachname
MsgBox(64, "", StringLower($name))
so gehts auch.
[autoit]$vname = "Hans Wurst"
$array =StringSplit($vname, " ")
$name = StringLeft($array[1], 1) & "." & $array[2]
MsgBox(64, "", StringLower($name))
Beides, und danke erstmal.
Das Programm muss auch Umlaute umschreiben, z.B. Müller als Mueller.
Ich habe hier im Forum gesucht, und gegoolt mit Begriffen string replace usw.
Bitte helfen Sie mir weiter.
$Voller_Name = "Jörg Müller"
$Name_conv = StringLower(StringReplace(StringReplace(StringReplace($Voller_Name,"ü","ue"),"ö","oe"),"ä","ae"))
$Name_split = StringSplit($Name_conv, " ")
$Name = StringLeft($Name_split[1], 1) & "." & $Name_split[2]
MsgBox(0,"Benutzername",$Name)
[/autoit]Oder so:
[autoit]Global $CheckStr = 'Jörg Müller'
Global $oUml = ObjCreate("Scripting.Dictionary")
$oUml.Add('ä', 'ae')
$oUml.Add('Ä', 'Ae')
$oUml.Add('ö', 'oe')
$oUml.Add('Ö', 'Oe')
$oUml.Add('ü', 'ue')
$oUml.Add('Ü', 'Ue')
$oUml.Add('ß', 'ss')
$colKeys = $oUml.Keys
For $strKey In $colKeys
If StringInStr($CheckStr, $strKey, 1) Then $CheckStr = StringReplace($CheckStr, $strKey, $oUml.Item($strKey))
Next
ConsoleWrite($CheckStr & @CRLF)
Und mein Beispiel könnte eher von Dir stammen, Bugfix:
[autoit]
$sName = 'Bärbel Köhler-R0ßberg'
MsgBox(0, 0, _CreateUsername($sName))
Func _CreateUsername($sUsername)
Local $aReplace[5][2] = [['ä', 'ae'],['ö', 'oe'],['ü', 'ue'],['ß', 'ss'],['0', 'o']]
For $i = 0 To UBound($aReplace, 1) - 1
$sUsername = StringReplace($sUsername, $aReplace[$i][0], $aReplace[$i][1], 0, 0)
Next
$sUsername = StringRegExpReplace(StringLower($sUsername), '(.)(.+ )', '$1' & '.')
Return StringRegExpReplace($sUsername, '[^a-z\-._]', '')
EndFunc ;==>_CreateUsername
[OT]
'Bärbel Köhler-R0ßberg'
Die kennst du auch??!! 
[/OT]
Ich meinte weniger den Namen (kennst Du wirklich eine, die so heißt?), sondern eher die Array-Variante. 
kennst Du wirklich eine, die so heißt?
Nee, war Scherz - aber dem Namen nach könnte sie bei der SPD sein (ähnelt doch sehr "Heidemarie Wieczorek-Zeul")
habe ich einbauen und anpassen können, und auch auf ß->ss erweitern können, danke alle.
Mein neues, und hoffentlich letztes Problem;
Bei Nachnamen mit mehreren Teilen (z.B. Walther von der Vogelweide), oder welche mit Bindestrich, muss das Programm nur den letzten Teil nehmen können.
Hier müsste es rein:
[autoit]
$vorname = InputBox("Vorname des neuen Benutzers", "Geben Sie den Vornamen des neuen Benutzers ein.", "")
$nachname = InputBox("Nachname des neuen Benutzers", "Geben Sie den Nachnamen des neuen Benutzers ein.", "")
$voller_name = ($vorname & " " & $nachname)
$Name_conv = StringLower(StringReplace(StringReplace(StringReplace(StringReplace($voller_name,"ü","ue"),"ö","oe"),"ä","ae"),"ß","ss"))
$Name_split = StringSplit($Name_conv, " ")
$bname = StringLeft($Name_split[1], 1) & "." & $Name_split[2]
Im Moment komm bei 'Walther von der Vogelweide' folgendes raus:
w.von
Dann so:
[autoit]$bname = StringLeft($Name_split[1], 1) & "." & $Name_split[$Name_split[0]]
[/autoit]Ahh danke wusste garnicht dass man sie nesten kann. Das hat 100% geklappt bei Namen mit mehr Teilen, aber bei Namen mit Bindestrich nicht.
Dann frage das vorher ab und splitte ggf.
[autoit]If StringInStr($Name_split[$Name_split[0]], '-') Then
$var = StringSplit($Name_split[$Name_split[0]], '-')
$Name_split[$Name_split[0]] = $var[$var[0]]
EndIf
$bname = StringLeft($Name_split[1], 1) & "." & $Name_split[$Name_split[0]]
Danke, Sie sind alle sehr hilfreich gewesen.
Ähm...wir duzen uns hier. 
Ich habe mal meine Funktion etwas erweitert, sodass es Deine Anforderungen erfüllt:
[autoit]
$sName = 'Georg Schmidt'
MsgBox(0, 0, _CreateUsername($sName))
$sName = 'Bärbel Köhler-R0ßberg'
MsgBox(0, 0, _CreateUsername($sName))
$sName = 'Walther von-der-Vogelweide'
MsgBox(0, 0, _CreateUsername($sName))
$sName = 'Günther von der Dotterblume'
MsgBox(0, 0, _CreateUsername($sName))
Func _CreateUsername($sUsername)
Local $aReplace[5][2] = [['ä', 'ae'],['ö', 'oe'],['ü', 'ue'],['ß', 'ss'],['0', 'o']]
For $i = 0 To UBound($aReplace, 1) - 1
$sUsername = StringReplace($sUsername, $aReplace[$i][0], $aReplace[$i][1], 0, 0)
Next
$sUsername = StringRegExpReplace(StringLower($sUsername), '(.)(.+ .+\-|.+ )', '$1' & '.')
Return $sUsername
EndFunc ;==>_CreateUsername
