Script für barcodescanner

shakoon

Hallo,

Ich suche und probiere schon seit langem ein Script zu schreiben, mit dem ich die Zahlen vom Barcode Scanner abfangen kann, und bei bestimmten werten soll das script eine andere .au3 Datei öffnen.

Ich habe schon die Adresse mittels RawInputDevice rausgefunden:
[1]| 0x00F00275 |1|\\?\HID#VID_080C&PID_0300#7&264f7ec1&0&0000#{884b96c3-56ef-11d1-bc8c-00a0c91405dd}

Aber ich weiß gerade nicht weiter wie ich ein Script schreiben soll, wenn ich mit dem Scanner einen barcode Scanne der die zahl "30" ausgibt, dann soll das Script die Datei 30.au3 öffnen. Wenn er die Zahl "40" Scannt, dann soll er 40.au3 öffnen.

Zum Scannen habe ich ausschließlich die Zahlen, 10,20,30,40,50,60,70,80 und 90.

Der Scanner liefert mit beim Scan "Zahl+(Enter)"

Könnt ihr mir da irgendwie weiterhelfen?

**Xorianator**

Heyho - Inkludiere doch einfach die Funktionen von Anfang an und rufe sie dann mit Execute() auf.

Das sähe folgendermaßen aus:

AutoIt

Call("_Funktion" & StringReplace($barcodeWert, @CRLF, ""), $Param1, $Param2, $ParamN)

Gruß

shakoon

Danke schonmal für die schnelle hilfe

Aber irgendwie kann ich dir gerade nicht folgen

ich habe momentan eine leere Datei. ( weiß einfach nicht wie ich das angehen soll )

Woher weiß die Datei denn was mein Scanner ist?

**Xorianator**

Hallo Shakoon,
ich habe das so verstanden:
Du hast es bereits geschafft den Wert deines Barcode Scanners auszulesen. Oder hast du das noch nicht implementiert?

Zu dem "öffnen einer au3 Datei" - Du schreibst den Inhalt der Au3 Datei in eine Funktion, sodass du diese nur noch aufrufen musst, wenn du den Rückgabewert deines Scanners hast.

shakoon

Das auslesen habe ich auch noch nicht geschafft.
Bin auf dem Gebiet neuling.
Ich habe nur das hier:

AutoIt

#include <APISysConstants.au3>
#include <Array.au3>
#include <WinAPISys.au3>


Local $tText, $aData = _WinAPI_EnumRawInputDevices()


If IsArray($aData) Then
    ReDim $aData[$aData[0][0] + 1][3]
    $tText = DllStructCreate('wchar[256]')
    For $i = 1 To $aData[0][0]
        If _WinAPI_GetRawInputDeviceInfo($aData[$i][0], $tText, 256, $RIDI_DEVICENAME) Then
            $aData[$i][2] = DllStructGetData($tText, 1)
        Else
            $aData[$i][2] = ''
        EndIf
    Next


EndIf


_ArrayDisplay($aData, '_WinAPI_EnumRawInputDevices')

Alles anzeigen

**Alina**

Moin Moin.

Welche Marke ist der Scanner? Wir nutzen Handscanner und da kann man den Scanner via Barcodes konfigurieren.
Ich habe im Büro das so eingestellt, das ich einmal den Button auf dem Handscanner aktiviere, damit er lesebereit ist und dann lege ich z. B. eine Akte unter den Scanner und er öffnet mir dazu die Unterlagen. Aber "erkennen" mußte das Skript nie etwas, denn der Handscanner wurde automatisch erkannt.

Folgendes sollte doch reichen:

AutoIt

$Input = InputBox("Barcode", "Bitte scanne den Zehner-Barcode", "10", "", -1, -1, 0, 0)
		 ;$_read = GUICtrlRead($Input)


    If $Input = 10 Then MsgBox(0, "", "Tue was 10 sagt.")
    If $Input = 20 Then MsgBox(0, "", "Tue was 20 sagt.")
    If $Input = 30 Then MsgBox(0, "", "Tue was 30 sagt.")
    If $Input = 40 Then MsgBox(0, "", "Tue was 40 sagt.")
    If $Input = 50 Then MsgBox(0, "", "Tue was 50 sagt.")
    If $Input = 60 Then MsgBox(0, "", "Tue was 60 sagt.")
    If $Input = 70 Then MsgBox(0, "", "Tue was 70 sagt.")
    If $Input = 80 Then MsgBox(0, "", "Tue was 80 sagt.")
    If $Input = 90 Then MsgBox(0, "", "Tue was 90 sagt.")
    If $Input = 100 Then MsgBox(0, "", "Tue was 100 sagt.")

Alles anzeigen

shakoon

Ich habe einen datalogic d130.

Ich werde es morgen früh mal ausprobieren und sage dir dann bescheid.

**Alina**

Das ist okay.
Bin da dann auch sicherlich im Büro und kann sonst mal schauen wie da das Script genau ausschaut.

shakoon

Achso, was ich vergessen habe zu sagen.
das Script soll im Hintergrund laufen.

Ich will es für SAP nutzen.

Also ich habe das SAP Fenster offen, und habe mir jetzt bisher 9 Dateien programmiert, die mir Automatisch im SAP alles nacheinander anklicken was ich für die schritte brauche. Das funktioniert soweit ganz gut und ohne Fehler.

jetzt habe ich mir gedacht, es muss doch irgendwie möglich sein ein Script zu schreiben, was irgendwie erkennt wenn über den Scanner ( ist ja quasi wie eine tastatur ) der Wert ( 10 und danach Enter [Enter sendet der Scanner danach Automatisch mit] ) gescannt wird. Und dieses Script soll mir dann einfach meine Datei "Script1.au3" öffnen, damit der Ablauf startet und meinen Vorgang im SAP automatisch startet.

**Alina**

Ich meine das SAP das zur Verfügung stellt.

Ich kenne andere Firmen, da läuft SAP und die scannen auch Barcodes ein und dann öffnet sich ein Vorgang.
Kannst dort bei SAP doch einfach mal unverbindlich anrufen unter (+49) 8005343424.

shakoon

Leider bei unserem nicht
Wir haben nur die abgespeckte billige Version. Habe schon nachgefragt

shakoon

So eine Idee von mir, weiß aber nicht ob das irgendwie geht

Kann man die Eingabe vom Scanner z.B. "10undEnter" nicht als Hotkey einbauen?

Wenn 10undEnter eingegeben wird, dann starte funktion 10. Funktion 10 startet dann datei 10.au3

irgendwie so?

Der barcode Scanner sendet halt erst die 10 und dann Enter, also nicht gleichzeitig.

**Alina**

Dann frag die zahl doch ab und häng "undEnter" hinten dran und arbeite dann damit weiter.
Und wenn er $Zahl & "undEnter", das Problem ist, und Du nur die "10" brauchst, dann

AutoIt

; Eingabelänge ermitteln
$Eingabe_und_Enter = "100undEnter" ; 10
Local $len = StringLen($Eingabe_und_Enter)


If $Eingabe_und_Enter = 10 then _zehn()
If $Eingabe_und_Enter > 10 Then _elf()




Func _zehn()
$result = StringLeft($Eingabe_und_Enter,2)
MsgBox(0,"","Die ersten beiden Stellen von li. sind: " & $result)
EndFunc


Func _elf()
$result = StringLeft($Eingabe_und_Enter,3)
MsgBox(0,"","Die ersten drei Stellen von li. sind: " & $result)
EndFunc

Alles anzeigen

wenn ich Dich nun richtig verstanden habe.

shakoon

das weiß ich gerade auch nicht
Also der Barcodescanner scannt nicht nur den barcode und gibt mir dann die zahl 10 aus, sondern der sendet die 10 und direkt dabei im anschluss einen enter befehl.

Vielleicht kann ich das auch irgendwie umstellen das er nur die zahl scannt. Muss ich mal gucken.

**Alina**

Ja, kannst Du. In dem Dokument im Anhang, es nennt sich Handbuch, wird es so ab Seite 128 wichtig. Wenn ich das richtig gelesen habe, dann sind das 3 Scanns.

shakoon

Guten morgen

Also ich habe jetzt diesen Code hier mal richtig ausprobiert:

AutoIt

$Input = InputBox("Barcode", "Bitte scanne den Zehner-Barcode", "10", "", -1, -1, 0, 0)
		 ;$_read = GUICtrlRead($Input)
    If $Input = 10 Then MsgBox(0, "", "Tue was 10 sagt.")
    If $Input = 20 Then MsgBox(0, "", "Tue was 20 sagt.")
    If $Input = 30 Then MsgBox(0, "", "Tue was 30 sagt.")
    If $Input = 40 Then MsgBox(0, "", "Tue was 40 sagt.")
    If $Input = 50 Then MsgBox(0, "", "Tue was 50 sagt.")
    If $Input = 60 Then MsgBox(0, "", "Tue was 60 sagt.")
    If $Input = 70 Then MsgBox(0, "", "Tue was 70 sagt.")
    If $Input = 80 Then MsgBox(0, "", "Tue was 80 sagt.")
    If $Input = 90 Then MsgBox(0, "", "Tue was 90 sagt.")
    If $Input = 100 Then MsgBox(0, "", "Tue was 100 sagt.")

Alles anzeigen

Das funktioniert alles einwandfrei, nur müssten wir es hinbekommen, das die Inputbox weg ist, und das Programm einfach im Hintergrund mitläuft, und wenn eine eingabe gemacht wird z.B. "10" dann startet das was "10" will.

Das müsste doch eigentlich irgendwie leicht machbar sein, habe heute nacht mal gegoogelt, aber nicht so richtig über das Thema gefunden. Wir müssten doch eigentlich nur so ne art eingabescanner im script in schleife laufen lassen, und wenn was passiert, dann macht der was, und danach geht er wieder in diese Scan-Schleife

**Alina**

@shakoon
Du mußte das Input ja nicht anzeigen lassen, aber ohne dem kenne ich keine Lsg.

**Oscar**

Doch das geht schon:

AutoIt

#include <WinAPI.au3>
#include <WindowsConstants.au3>
#include <StructureConstants.au3>


OnAutoItExitRegister('OnAutoItExit')


Global $hmod, $hHook, $hStub_KeyProc, $buffer = ''


$hStub_KeyProc = DllCallbackRegister('_KeyProc', 'long', 'int;wparam;lparam')
$hmod = _WinAPI_GetModuleHandle(0)
$hHook = _WinAPI_SetWindowsHookEx($WH_KEYBOARD_LL, DllCallbackGetPtr($hStub_KeyProc), $hmod)
While Sleep(100)
WEnd


Func _EvaluateKey($keycode)
	Switch $keycode
		Case 48 To 57 ; 0 - 9
			$buffer &= Chr($keycode)
		Case 13 ; RETURN
			ConsoleWrite('@@ Debug(' & @ScriptLineNumber & ') : $buffer = ' & $buffer & @CRLF & '>Error code: ' & @error & @CRLF) ;### Debug Console
			Switch $buffer
				Case '10'
					ToolTip('10')
				Case '20'
					ToolTip('20')
			EndSwitch
			$buffer = ''
		Case 27 ; ESC
			Exit
		Case Else
			$buffer = ''
	EndSwitch
EndFunc   ;==>_EvaluateKey


Func _KeyProc($nCode, $wParam, $lParam)
	Local $tKEYHOOKS = DllStructCreate($tagKBDLLHOOKSTRUCT, $lParam)
	If $nCode < 0 Then Return _WinAPI_CallNextHookEx($hHook, $nCode, $wParam, $lParam)
	If $wParam = $WM_KEYDOWN Then _EvaluateKey(DllStructGetData($tKEYHOOKS, 'vkCode'))
	Return _WinAPI_CallNextHookEx($hHook, $nCode, $wParam, $lParam)
EndFunc   ;==>_KeyProc


Func OnAutoItExit()
	_WinAPI_UnhookWindowsHookEx($hHook)
	DllCallbackFree($hStub_KeyProc)
EndFunc   ;==>OnAutoItExit

Alles anzeigen

**Alina**

Hallo Oscar.

MAl eine FRage. Wieso geht es dann bei mir in den Scripten wo ich mit Barcodescanner einlese, das er den Code liest und dann sofort weiter macht?
Naja, wenn ihm die Lsg. von Dir reicht dann sind wir alle wieder glücklicher und ich habe etwas, das ich aufbewahren kann und ggf. nutze.

**Oscar**

Ich kenne jetzt Deinen Code nicht, aber ich vermute mal, dass Du ein Programm im Vordergrund laufen hast, was dann auf die Eingaben (Inputfeld) reagiert.
Willst Du die Keycodes aber im Hintergrund auslesen lassen, dann wird es halt komplizierter (siehe mein obiges Script).