Inputboxen speichern Array

AutoMit

Hallo Freunde der automatisierten Schritte,

auf einer KodaForm Oberfläche habe ich 8 Inputboxen, 2 Checkboxen und 3 Radiobutton. Wie kann ich alle Inputboxen, Checkboxen und Radiobutton der Oberfläche in ein Array einlesen und somit den Inhalt aller Inputboxen in eine ini-Datei in einer Schleife speichern?

Ich möchte nicht 8x die Zeile "iniWrite ..." für die Inputboxen, 2x für die Checkboxen und 3x für die Radioboxen schreiben.

Der linke Wert (Key) ist dabei der Name der Inputbox, z.B. $Input_Monat, in Analogie für Checkboxen und Radiobutton.

Wie es mit einer Input-Box geht, weiß ich

AutoIt

IniWrite(@scriptdir & "\settings.ini","data","name",GuiCtrlRead($Input_Monat))


For $i ...


IniWrite(@scriptdir & "\settings.ini","data","name",GuiCtrlRead( ... diese Stelle müsste wahrscheinlich durch einen Array Wert ersetzt werden ... ))


Next

Viele Grüße
AutoMit

**alpines**

Das ist ganz einfach. Dazu erstellst du am besten einfach die Controls und speicherst sie vorerst individuell ab ($hBox1, $hBox2, ...).
Danach erstellst du ein Array was ungefähr so definiert ist.

AutoIt

Local $aControls[13] = [$hBox1, $hBox2, ...]

Anschließend musst du nur noch mit einer For-Schleife das Control-Array iterieren und kannst sie dann in eine Ini speichern.

AutoIt

For $i = 0 To UBound($aControls) - 1
	IniWrite(@ScriptDir & "\Settings.ini", "Data", $i, GUICtrlRead($aControls[$i]))
Next

Wenn du startest kannst du wieder mit einer For-Schleife das Array füllen. Die Reihenfolge solltest du dabei aber beachten, sonst bringst du noch was durcheinander.

AutoMit

Das ist eine sehr interessante Idee - ich probiere sie aus. Danke!

Gibt es auch eine Art Automatismus, um alle Controls in ein Array einzulesen?

**alpines**

Nein ich glaube nicht, außerdem ist das ja sowieso nur eine Zeile also würde ich mir darüber keine Extragedanken machen.

**BugFix**

Also erst mit Variablen die Ctrl erstellen und danach daraus ein Array zu generieren ist doch doppelt.
Wie wäre es so:

EDIT: Ich habe gleich mal den INI-Lesen/Schreiben Teil mit eingebaut

AutoIt

#include <ButtonConstants.au3>
#include <Constants.au3>
#include <EditConstants.au3>
#include <StaticConstants.au3>
#include <WinAPI.au3>


; Indizes festlegen für die zu erstellenden Ctrl (RB=Radio, IN=Input, etc.)
Local Enum $CB1, $CB2, $IN1, $IN2, $RB1, $RB2, $iAnzahl
; Array für die CTRL erstellen
Local $aCtrl[$iAnzahl]


Local $INI = 'Pfad-INI-Datei'
; Daten einfach unter dem Ctrl-Index ablegen
#cs Muster INI
[control]
1=1
2=1
3=BLA
4=BLUB
5=0
6=1
#ce




$hGui = GUICreate('Test')
$aCtrl[$CB1] = GUICtrlCreateCheckbox('Check 1', 10, 13, 60, 17)
$aCtrl[$CB2] = GUICtrlCreateCheckbox('Check 2', 10, 43, 60, 17)
$aCtrl[$IN1] = GUICtrlCreateInput('', 80, 10, 100, 20)
$aCtrl[$IN2] = GUICtrlCreateInput('', 80, 40, 100, 20)
$aCtrl[$RB1] = GUICtrlCreateRadio('Radio 1', 200, 10, 60, 20)
$aCtrl[$RB2] = GUICtrlCreateRadio('Radio 2', 200, 40, 60, 20)


If FileExists($INI) Then ; aus INI befüllen
	For $i = 0 To UBound($aCtrl) -1
		_CtrlSetFromINI($i)
	Next
EndIf


GUISetState()


While True
	$nMsg = GUIGetMsg()
	If $nMsg = -3 Then
	EndIf
	Switch $nMsg
		Case -3
			; Werte/Status der Ctrl auslesen (z.B. in INI schreiben)
			For $i = 0 To UBound($aCtrl) -1
;~ 				ConsoleWrite(_CtrlGetState_Value($aCtrl[$i]) & @CRLF)
				IniWrite($INI, 'control', $i, _CtrlGetState_Value($aCtrl[$i]))
			Next
			Exit
		Case $aCtrl[$CB1]
			;
		Case $aCtrl[$CB2]
			;
		Case $aCtrl[$RB1]
			;
		Case $aCtrl[$RB2]
			;
	EndSwitch
WEnd


Func _CtrlGetState_Value($_iCtrlID)
	Local $hID = ControlGetHandle($hGui, '', $_iCtrlID)
	Switch __myCtrlGetClass($hID)
		Case 'Radio', 'Checkbox'
			Return BitAND(GUICtrlRead($_iCtrlID), $GUI_CHECKED)
		Case 'Input'
			Return GUICtrlRead($_iCtrlID)
	EndSwitch
EndFunc


Func _CtrlSetFromINI($_iIndex)
	Local $iID = $aCtrl[$_iIndex]
	Local $hID = ControlGetHandle($hGui, '', $iID)
	Switch __myCtrlGetClass($hID)
		Case 'Radio', 'Checkbox'
			GUICtrlSetState($iID, (IniRead($INI, 'control', $iIndex, 0) = 1 ? $GUI_CHECKED : $GUI_UNCHECKED))
		Case 'Input'
			GUICtrlSetData($iID, IniRead($INI, 'control', $iIndex, ''))
	EndSwitch
EndFunc


Func __myCtrlGetClass($hHandle) ;code by SmOke_N, modified by Guiness
    Local Const $GWL_STYLE = -16
    Local $iLong, $sClass
    If IsHWnd($hHandle) = 0 Then
        $hHandle = GUICtrlGetHandle($hHandle)
        If IsHWnd($hHandle) = 0 Then
            Return SetError(1, 0, "Unknown")
        EndIf
    EndIf


    $sClass = _WinAPI_GetClassName($hHandle)
    If @error Then
        Return "Unknown"
    EndIf


    $iLong = _WinAPI_GetWindowLong($hHandle, $GWL_STYLE)
    If @error Then
        Return SetError(2, 0, 0)
    EndIf


    Switch $sClass
        Case "Button"
            Select
                Case BitAND($iLong, $BS_GROUPBOX) = $BS_GROUPBOX
                    Return "Group"
                Case BitAND($iLong, $BS_CHECKBOX) = $BS_CHECKBOX
                    Return "Checkbox"
                Case BitAND($iLong, $BS_AUTOCHECKBOX) = $BS_AUTOCHECKBOX
                    Return "Checkbox"
                Case BitAND($iLong, $BS_RADIOBUTTON) = $BS_RADIOBUTTON
                    Return "Radio"
                Case BitAND($iLong, $BS_AUTORADIOBUTTON) = $BS_AUTORADIOBUTTON
                    Return "Radio"
            EndSelect


        Case "Edit"
            Select
                Case BitAND($iLong, $ES_WANTRETURN) = $ES_WANTRETURN
                    Return "Edit"
                Case Else
                    Return "Input"
            EndSelect


        Case "Static"
            Select
                Case BitAND($iLong, $SS_BITMAP) = $SS_BITMAP
                    Return "Pic"
                Case BitAND($iLong, $SS_ICON) = $SS_ICON
                    Return "Icon"
                Case BitAND($iLong, $SS_LEFT) = $SS_LEFT
                    If BitAND($iLong, $SS_NOTIFY) = $SS_NOTIFY Then
                        Return "Label"
                    EndIf
                    Return "Graphic"
            EndSelect


        Case "ComboBox"
            Return "Combo"
        Case "ListBox"
            Return "List"
        Case "msctls_progress32"
            Return "Progress"
        Case "msctls_trackbar32"
            Return "Slider"
        Case "SysDateTimePick32"
            Return "Date"
        Case "SysListView32"
            Return "ListView"
        Case "SysMonthCal32"
            Return "MonthCal"
        Case "SysTabControl32"
            Return "Tab"
        Case "SysTreeView32"
            Return "TreeView"


    EndSwitch
    Return $sClass
EndFunc

Alles anzeigen

**alpines**

@BugFix, an Enums hatte ich gar nicht gedacht. Das ist ja genial.

AutoMit

Wow BugFix, das sieht gut aus. Danke! Ich schaue mir das am Wochenende in Ruhe an, um die einzelnen Zeilen zu verstehen.