Performance bei der Funktion _GUICtrlListView_AddArray

horphi

N´abend allerseits,

ich habe eine Frage zur

AutoIt

_GUICtrlListView_AddArray

Wie kann ich diese Funktion beschleunigen?

In meinem Script wird die Liste geleert, die Daten aus einer SQLite DB gelesen, die erste Zeile gelöscht und dann in die Liste wieder eingefügt.

Das ganze dauert bei 335 Einträgen und 20 Reihen ca. 2,3 Sekunden.
Die meiste Zeit braucht dabei _GUICtrlListView_AddArray

Liste leeren : 0.224454070137658

SQL Query: 588.150877758208
Array clearing: 39.1772754310254
Liste befüllen: 1702.26591515458

Kennt das jemand?

AutoIt

Func _ReadMergeDBGUIAll()
	Local $dtStart, $dtStart1, $dtStart2, $dtStart3
	$dtStart = TimerInit()
	_GUICtrlListView_DeleteAllItems($g_idListView)
	$dtStart = TimerDiff($dtStart)
	ConsoleWrite("Liste leeren : " & $dtStart & @CRLF)
	$dtStart1 = TimerInit()
	Global $aResult = _SQLMergeQuery()
	$dtStart1 = TimerDiff($dtStart1)
	ConsoleWrite("SQL Query: " & $dtStart1 & @CRLF)
	$dtStart2 = TimerInit()
	_ArrayDelete($aResult, 0)
	$dtStart2 = TimerDiff($dtStart2)
	ConsoleWrite("Array clearing: " & $dtStart2 & @CRLF)
	$dtStart3 = TimerInit()
	_GUICtrlListView_AddArray($g_idListView, $aResult)
	$dtStart3 = TimerDiff($dtStart3)
	ConsoleWrite("Liste befüllen: " & $dtStart3 & @CRLF)
EndFunc   ;==>_ReadMergeDBGUIAll

Alles anzeigen

VG

horphi

**Kanashius**

Mach nen _guictrllistview_beginupdate vor dem löschen, einfügen,... und nen _guictrllistviewendupdate danach. Das verhindert, dass die anzeige nach jedem einfügen geändert wird und beschleunigt es daher deutlich!

**Andy**

@Kanashius,
_guictrllistview_beginupdate und _guictrllistviewendupdate sind in der Funktion _GUICtrlListView_AddArray enthalten!

@horphi, Cursor auf den Funktionsnamen, ctrl+j springt in die UDF, untersuche die Funktion(en) und vor allem die drei Schleifen mit den Timerbefehlen und finde den "Übeltäter". Ich vermute die DllStructSetData als Zeitfresser, am SendMessage() wird man nicht viel machen können...

horphi

@Andy und @Kanashius

Danke für die Hinweise. Das prüfe ich heute Abend und gebe dann Rückmeldung.

VG

horphi

horphi

Hallo noch mal,

nach einer Zeitmessung ist der größte Teil wie schon von @Andy vermutet in der DLLStructSetData .

Gibt es noch eine andere Listenfunktion, um aus SQLite GUI Listen zubefüllen?

Danke und Gruß,

horphi

AutoIt

Func _GUICtrlListView_AddArray($hWnd, ByRef $aItems)
	Local $bUnicode = _GUICtrlListView_GetUnicodeFormat($hWnd)
	Local $dtStart


	Local $tItem = DllStructCreate($tagLVITEM)
	Local $tBuffer
	If $bUnicode Then
		$tBuffer = DllStructCreate("wchar Text[4096]")
	Else
		$tBuffer = DllStructCreate("char Text[4096]")
	EndIf
	DllStructSetData($tItem, "Mask", $LVIF_TEXT)
	DllStructSetData($tItem, "Text", DllStructGetPtr($tBuffer))
	DllStructSetData($tItem, "TextMax", 4096)


	Local $iLastItem = _GUICtrlListView_GetItemCount($hWnd)
	_GUICtrlListView_BeginUpdate($hWnd)
	$dtStart = TimerInit()
;~ 	*****************************************************************************************************************************************
;~	Zeitfresser
         If IsHWnd($hWnd) Then
		If _WinAPI_InProcess($hWnd, $__g_hLVLastWnd) Then


			For $iI = 0 To UBound($aItems) - 1
				DllStructSetData($tItem, "Item", $iI)
				DllStructSetData($tItem, "SubItem", 0)
				DllStructSetData($tBuffer, "Text", $aItems[$iI][0])
				_SendMessage($hWnd, $LVM_INSERTITEMW, 0, $tItem, 0, "wparam", "struct*")
				For $iJ = 1 To UBound($aItems, $UBOUND_COLUMNS) - 1
					DllStructSetData($tItem, "SubItem", $iJ)
					DllStructSetData($tBuffer, "Text", $aItems[$iI][$iJ])
					_SendMessage($hWnd, $LVM_SETITEMW, 0, $tItem, 0, "wparam", "struct*")
				Next
			Next
;~ 	*****************************************************************************************************************************************
	$dtStart = TimerDiff($dtStart)
	ConsoleWrite("DLL: " & $dtStart & @CRLF)


			Else


			Local $iBuffer = DllStructGetSize($tBuffer)
			Local $iItem = DllStructGetSize($tItem)
			Local $tMemMap
			Local $pMemory = _MemInit($hWnd, $iItem + $iBuffer, $tMemMap)
			Local $pText = $pMemory + $iItem
			DllStructSetData($tItem, "Text", $pText)


			For $iI = 0 To UBound($aItems) - 1
				DllStructSetData($tItem, "Item", $iI + $iLastItem)
				DllStructSetData($tItem, "SubItem", 0)
				DllStructSetData($tBuffer, "Text", $aItems[$iI][0])
				_MemWrite($tMemMap, $tItem, $pMemory, $iItem)
				_MemWrite($tMemMap, $tBuffer, $pText, $iBuffer)
				If $bUnicode Then
					_SendMessage($hWnd, $LVM_INSERTITEMW, 0, $pMemory, 0, "wparam", "ptr")
				Else
					_SendMessage($hWnd, $LVM_INSERTITEMA, 0, $pMemory, 0, "wparam", "ptr")
				EndIf






				For $iJ = 1 To UBound($aItems, $UBOUND_COLUMNS) - 1
					DllStructSetData($tItem, "SubItem", $iJ)
					DllStructSetData($tBuffer, "Text", $aItems[$iI][$iJ])




					_MemWrite($tMemMap, $tItem, $pMemory, $iItem)
					_MemWrite($tMemMap, $tBuffer, $pText, $iBuffer)
					If $bUnicode Then
						_SendMessage($hWnd, $LVM_SETITEMW, 0, $pMemory, 0, "wparam", "ptr")
					Else
						_SendMessage($hWnd, $LVM_SETITEMA, 0, $pMemory, 0, "wparam", "ptr")
					EndIf
				Next
			Next
			_MemFree($tMemMap)
			EndIf


	Else
		Local $pItem = DllStructGetPtr($tItem)
		For $iI = 0 To UBound($aItems) - 1
			DllStructSetData($tItem, "Item", $iI + $iLastItem)
			DllStructSetData($tItem, "SubItem", 0)
			DllStructSetData($tBuffer, "Text", $aItems[$iI][0])
			If $bUnicode Then
				GUICtrlSendMsg($hWnd, $LVM_INSERTITEMW, 0, $pItem)
			Else
				GUICtrlSendMsg($hWnd, $LVM_INSERTITEMA, 0, $pItem)
			EndIf
			For $iJ = 1 To UBound($aItems, $UBOUND_COLUMNS) - 1
				DllStructSetData($tItem, "SubItem", $iJ)
				DllStructSetData($tBuffer, "Text", $aItems[$iI][$iJ])
				If $bUnicode Then
					GUICtrlSendMsg($hWnd, $LVM_SETITEMW, 0, $pItem)
				Else
					GUICtrlSendMsg($hWnd, $LVM_SETITEMA, 0, $pItem)
				EndIf
			Next
		Next
	EndIf
	_GUICtrlListView_EndUpdate($hWnd)
EndFunc   ;==>_GUICtrlListView_AddArray

Alles anzeigen

**Kanashius**

Hiermit:

AutoIt

Func fillListView($array, $sort = true, $lastIsPath = false)
	_GUICtrlListView_BeginUpdate($MainGui_MainListView)
	GUICtrlSetState($WaitLabel_Progress, $GUI_SHOW)
	_GUICtrlListView_DeleteAllItems_self($MainGui_MainListView)
	GUICtrlSetData($WaitLabel, _getLanguageText("pleaseWait") & @crlf & _getLanguageText("listFilling"))
	for $i = 0 to _GUICtrlListView_GetColumnCount($MainGui_MainListView) + 1 step 1
		_GUICtrlListView_DeleteColumn($MainGui_MainListView, 0)
	next
	if $lastIsPath then
		for $i = 1 to $iClumn step 1
			_GUICtrlListView_AddColumn($MainGui_MainListView, $array[$i])
			_GUICtrlListView_SetColumnWidth($MainGui_MainListView, $i - 1, 200)
		next
		_GUICtrlListView_SetColumnWidth($MainGui_MainListView, 4, 100)
		_GUICtrlListView_SetColumnWidth($MainGui_MainListView, 1, 300)
		_GUICtrlListView_SetColumnWidth($MainGui_MainListView, $iClumn - 1, 615)
		_GUICtrlListView_HideColumn($MainGui_MainListView, 0)
		$1perc = (UBound($array) - $iClumn) / 100
		$aktPerc = 0
		for $i = $iClumn + 1 to UBound($array) - 1 step $iClumn
			$string = ""
			for $x = 0 to $iClumn - 2 step 1
				$string &= $array[$i + $x] & "|"
			next
			;$rr=StringSplit($array[$i+$iClumn-1],"\")
			$string &= $array[$i + $iClumn - 1];$rr[$rr[0]]
			GUICtrlCreateListViewItem($string, $MainGui_MainListView)
			if mod(int($i / $iClumn), 2) = 0 then
				GUICtrlSetBkColor(-1, 0xDDDDDD)
			endif
			if int($i / $1perc) <> $aktPerc then
				$aktPerc = int($i / $1perc)
				GUICtrlSetData($WaitLabel_Progress, $aktPerc)
			endif
		next
	else
		for $i = 1 to $iClumn step 1
			_GUICtrlListView_AddColumn($MainGui_MainListView, $array[$i])
			_GUICtrlListView_SetColumnWidth($MainGui_MainListView, $i - 1, 200)
		next
		_GUICtrlListView_HideColumn($MainGui_MainListView, 0)
		$1perc = (UBound($array) - $iClumn) / 100
		$aktPerc = 0
		for $i = $iClumn + 1 to UBound($array) - 1 step $iClumn
			$string = ""
			for $x = 0 to $iClumn - 2 step 1
				$string &= $array[$i + $x] & "|"
			next
			$string &= $array[$i + $iClumn - 1]
			GUICtrlCreateListViewItem($string, $MainGui_MainListView)
			if int($i / $1perc) <> $aktPerc then
				$aktPerc = int($i / $1perc)
				GUICtrlSetData($WaitLabel_Progress, $aktPerc)
			endif
		next
	endif
	if $sort then
		_GUICtrlListView_SimpleSort_self($MainGui_MainListView, false, 1)
	endif
	_GUICtrlListView_EndUpdate($MainGui_MainListView)
	GUICtrlSetState($WaitLabel, $GUI_HIDE)
	GUICtrlSetState($WaitLabel_Progress, $GUI_HIDE)
	GUICtrlSetState($MainGui_ListBox1, $GUI_ENABLE)
	GUICtrlSetState($MainGui_MainListView, $GUI_SHOW)
	GUICtrlSetState($MainGui_MainListView, $GUI_ENABLE)
	GUICtrlSetState($MainGui_Button1, $GUI_ENABLE)
	GUICtrlSetData($MainGui_MainListView_CountLabel, _getLanguageText("entrysInList") & _GUICtrlListView_GetItemCount($MainGui_MainListView))
EndFunc   ;==>fillListView
Func _GUICtrlListView_DeleteAllItems_self($hWnd)
	GUICtrlSetData($WaitLabel_Progress, 0)
	GUICtrlSetData($WaitLabel, _getLanguageText("pleaseWait") & @crlf & _getLanguageText("listClear"))
	; Check if deletion necessary
	If _GUICtrlListView_GetItemCount($hWnd) = 0 Then Return True
	Local Const $LV_WM_SETREDRAW = 0x000B
	; Determine ListView type
	Local $cCID = 0
	If IsHWnd($hWnd) Then
		; Check if the ListView has a ControlID
		$cCID = _WinAPI_GetDlgCtrlID($hWnd)
	Else
		$cCID = $hWnd
		; Get ListView handle
		$hWnd = GUICtrlGetHandle($hWnd)
	EndIf
	; If native ListView - could be either type of item
	If $cCID Then
		; Disable the redrawing message
		GUICtrlSendMsg($cCID, $LV_WM_SETREDRAW, False, 0)
		; Try deleting as native items
		Local $iParam = 0
		Local $var = _GUICtrlListView_GetItemCount($hWnd) / 100 ;PROGRESSBAR
		Local $aktPerc = 0 ;PROGRESSBAR
		For $iIndex = _GUICtrlListView_GetItemCount($hWnd) - 1 To 0 Step -1
			$iParam = _GUICtrlListView_GetItemParam($hWnd, $iIndex)
			; Check if LV item
			If GUICtrlGetState($iParam) > 0 And GUICtrlGetHandle($iParam) = 0 Then
				GUICtrlDelete($iParam)
			EndIf
			if 100 - int($iIndex / $var) <> $aktPerc then ;PROGRESSBAR
				$aktPerc = 100 - int($iIndex / $var)
				GUICtrlSetData($WaitLabel_Progress, $aktPerc)
			endif
		Next
		; Enable the redrawing message
		GUICtrlSendMsg($cCID, $LV_WM_SETREDRAW, True, 0)
		; Return if no items left
		GUICtrlSetData($WaitLabel_Progress, 0)
		If _GUICtrlListView_GetItemCount($hWnd) = 0 Then Return True
	EndIf
	GUICtrlSetData($WaitLabel_Progress, 0)
	; Has to be UDF Listview and/or UDF items
	Return _SendMessage($hWnd, $LVM_DELETEALLITEMS) <> 0
EndFunc   ;==>_GUICtrlListView_DeleteAllItems_self
Func _GUICtrlListView_SimpleSort_self($hWnd, $vSortSense, $iCol, $fToggle = True)
	GUICtrlSetData($WaitLabel_Progress, 0)
	GUICtrlSetData($WaitLabel, _getLanguageText("pleaseWait") & @crlf & _getLanguageText("listSorting"))
	sleep(100)
	Local $iItemCount = _GUICtrlListView_GetItemCount($hWnd)
	If $iItemCount Then
		Local $iDescending = 0
		If UBound($vSortSense) Then
			$iDescending = $vSortSense[$iCol]
		Else
			$iDescending = $vSortSense
		EndIf
		Local $vSeparatorChar = Opt('GUIDataSeparatorChar')
		Local $iColumnCount = _GUICtrlListView_GetColumnCount($hWnd)
		;Local Enum $iIndexValue = $iColumnCount, $iItemParam ; Additional columns for the index value and ItemParam
		Local $aListViewItems[$iItemCount][$iColumnCount + 2]
		;Local $aSelectedItems = StringSplit(_GUICtrlListView_GetSelectedIndices($hWnd), $vSeparatorChar)
		;Local $aCheckedItems = __GUICtrlListView_GetCheckedIndices($hWnd)
		Local $sItemText, $iFocused = -1
		Local $var = $iItemCount / 100 ;PROGRESSBAR
		Local $aktPerc = 0 ;PROGRESSBAR
		For $i = 0 To $iItemCount - 1 ; Rows
			;If $iFocused = -1 Then
			;	If _GUICtrlListView_GetItemFocused($hWnd, $i) Then $iFocused = $i
			;EndIf
			;_GUICtrlListView_SetItemSelected($hWnd, $i, False)
			;_GUICtrlListView_SetItemChecked($hWnd, $i, False)
			For $j = 0 To $iColumnCount - 1 ; Columns
				$sItemText = StringStripWS(_GUICtrlListView_GetItemText($hWnd, $i, $j), 2)
				If(StringIsFloat($sItemText) Or StringIsInt($sItemText)) Then
					$aListViewItems[$i][$j] = Number($sItemText)
				Else
					$aListViewItems[$i][$j] = $sItemText
				EndIf
			Next
			;$aListViewItems[$i][$iIndexValue] = $i ; Index value
			;$aListViewItems[$i][$iItemParam] = _GUICtrlListView_GetItemParam($hWnd, $i) ; ItemParam
			if int(($i / $var) / 2) <> $aktPerc then ;PROGRESSBAR
				$aktPerc = int(($i / $var) / 2)
				GUICtrlSetData($WaitLabel_Progress, $aktPerc)
			endif
		Next
		; Sort the ListView array
		_ArraySort($aListViewItems, $iDescending, 0, 0, $iCol)
		For $i = 0 To $iItemCount - 1 ; Rows
			For $j = 0 To $iColumnCount - 1 ; Columns
				_GUICtrlListView_SetItemText($hWnd, $i, $aListViewItems[$i][$j], $j)
			Next
			;_GUICtrlListView_SetItemParam($hWnd, $i, $aListViewItems[$i][$iItemParam]) ; ItemParam
			#cs
				For $j = 1 To $aSelectedItems[0]
				If $aListViewItems[$i][$iIndexValue] = $aSelectedItems[$j] Then
				If $aListViewItems[$i][$iIndexValue] = $iFocused Then
				_GUICtrlListView_SetItemSelected($hWnd, $i, True, True)
				Else
				_GUICtrlListView_SetItemSelected($hWnd, $i, True)
				EndIf
				ExitLoop
				EndIf
				Next
				For $j = 1 To $aCheckedItems[0]
				If $aListViewItems[$i][$iIndexValue] = $aCheckedItems[$j] Then
				_GUICtrlListView_SetItemChecked($hWnd, $i, True)
				ExitLoop
				EndIf
				Next
			#ce
			if int(50 + (($i / $var) / 2)) <> $aktPerc then ;PROGRESSBAR
				$aktPerc = int(50 + ($i / $var) / 2)
				GUICtrlSetData($WaitLabel_Progress, $aktPerc)
			endif
		Next
		If $fToggle Then ; Automatic sort sense toggle
			If UBound($vSortSense) Then
				$vSortSense[$iCol] = Not $iDescending
			Else
				$vSortSense = Not $iDescending
			EndIf
		EndIf
	EndIf
EndFunc   ;==>_GUICtrlListView_SimpleSort_self

Alles anzeigen

komm ich auf ~2100 Einträge die Sekunde... schneller wüsst ichs nicht.
Ist noch nen bisschen was drumrum mit Progressbar,... deshalb auch die _deleteitem und _sortsimple selber (bearbeitet)

horphi

Hallo @Kanashius,

was ist das für eine Funktion? Ist die in einer UDF verankert, oder von dir?

VG

horphi

**autoBert**

Zitat von horphi

Hallo @Kanashius,

was ist das für eine Funktion? Ist die in einer UDF verankert, oder von dir?

VG

horphi

sind mehrere selbstgestrickte. Wobei diese imho mininmal langsamer sein müßten als _GUICtrlListView_AddArray, da noch andere Aufgaben erledigt werden. Ich wundere mich gerade deshalb über seine Zeiten und würde mich freuen wenn @Kanashius ein kleines Demoskript einstellt, ich habe eine LV mit über 30.000 Items und wäre froh wenn ich die LV < 1 Min (30.000 / 2.000/sec = 15 sec) anzeigenkönnte.

**Kanashius**

So, jetzt hatte ich etwas Zeit.
Die Funktion(-en) stammen aus meinem Projekt Buchsammlung, dass ich mal geschrieben hab. Hab mal nen Beispielscript daraus gebastelt.
Nicht wundern: Man übergibt ein 1D-Array und die Spaltenzahl (hab bei _Sqlite keine Table, sondern ein 1D Array bekommen). Die ersten Einträge sind die Listview Spalten.
Sortiert wird nach der 1. Spalte, wenn man es nutzt. Löschen dauert länger als einfügen

Script:

AutoIt

#include <GuiListView.au3>
#include <GUIConstantsEx.au3>


global $width=800,$height=600
$MainGui=GuiCreate("",$width,$height)
$MainGui_MainListView=GUICtrlCreateListView("",5,5,$width-10,$height-10)
$WaitLabel_Progress=GUICtrlCreateProgress($width/2-105,$height/2+25,200,20)
$WaitLabel=GUICtrlCreateLabel("",$width/2-105,$height/2-25,200,20)
GUISetState(@SW_SHOW)


_FillTimed()


while 1
	$msg=GUIGetMsg()
	if $msg=-3 then exit
WEnd


Func _FillTimed()
	ConsoleWrite("Creating Array"&@crlf)
	local $cols=4,$DataItems[1000000*$cols]
	for $i=0 to UBound($DataItems)/4-1 step 1
		for $j=0 to $cols-1 step 1
			$DataItems[$i*$cols+$j]=$i&":"&$j
		next
	next
	ConsoleWrite("Start Filling"&@crlf)
	$count=15
	for $i=0 to $count-1 step 1
		$timer=TimerInit()
		fillListView($DataItems,$cols,false)
		ConsoleWrite("ItemCount: "&StringFormat("%09i",UBound($DataItems)/$cols)&" with "&StringFormat("%04i",$cols)&" Cols Fill Time: "&Round(TimerDiff($timer)/1000,4)&@crlf)
		ReDim $DataItems[UBound($DataItems)/$cols/2*$cols]
	next
EndFunc


Func fillListView(ByRef $array,$iClumn,$sort = true)
	GUICtrlSetState($MainGui_MainListView,$GUI_HIDE)
	_GUICtrlListView_BeginUpdate($MainGui_MainListView)
	GUICtrlSetState($WaitLabel_Progress, $GUI_SHOW)
	GUICtrlSetData($WaitLabel,"Please Wait while Listview is cleared")
	$timer=TimerInit()																																								;TIMER
	$countItem=_GUICtrlListView_GetItemCount($MainGui_MainListView)																													;TIMER
	$countCols=_GUICtrlListView_GetColumnCount($MainGui_MainListView)																												;TIMER
	_GUICtrlListView_DeleteAllItems_self($MainGui_MainListView)
	ConsoleWrite("ItemCount: "&StringFormat("%09i",$countItem)&" with "&StringFormat("%04i",$countCols)&" Cols Clear Time: "&Round(TimerDiff($timer)/1000,4)&@crlf&@crlf)			;TIMER
	GUICtrlSetData($WaitLabel,"Please Wait while Listview is filled")
	for $i = 0 to _GUICtrlListView_GetColumnCount($MainGui_MainListView) + 1 step 1
		_GUICtrlListView_DeleteColumn($MainGui_MainListView, 0)
	next
	for $i = 0 to $iClumn-1 step 1
		_GUICtrlListView_AddColumn($MainGui_MainListView, $array[$i])
		_GUICtrlListView_SetColumnWidth($MainGui_MainListView, $i, 150)
	next
	$1perc = (UBound($array) - $iClumn) / 100
	$aktPerc = 0
	for $i = $iClumn to UBound($array) - $iClumn step $iClumn
		$string = ""
		for $x = 0 to $iClumn - 2 step 1
			$string &= $array[$i + $x] & "|"
		next
		$string &= $array[$i + $iClumn - 1]
		GUICtrlCreateListViewItem($string, $MainGui_MainListView)
		if int($i / $1perc) <> $aktPerc then
			$aktPerc = int($i / $1perc)
			GUICtrlSetData($WaitLabel_Progress, $aktPerc)
		endif
	next
	if $sort then
		_GUICtrlListView_SimpleSort_self($MainGui_MainListView, false, 1)
	endif
	_GUICtrlListView_EndUpdate($MainGui_MainListView)
	GUICtrlSetState($WaitLabel, $GUI_HIDE)
	GUICtrlSetState($WaitLabel_Progress, $GUI_HIDE)
	GUICtrlSetState($MainGui_MainListView, $GUI_SHOW)
	GUICtrlSetState($MainGui_MainListView, $GUI_ENABLE)
EndFunc   ;==>fillListView


Func _GUICtrlListView_DeleteAllItems_self($hWnd)
	GUICtrlSetData($WaitLabel_Progress, 0)
	GUICtrlSetData($WaitLabel,"Bitte warten!"&@crlf&"Liste wird geleert!")
	; Check if deletion necessary
	If _GUICtrlListView_GetItemCount($hWnd) = 0 Then Return True
	Local Const $LV_WM_SETREDRAW = 0x000B
	; Determine ListView type
	Local $cCID = 0
	If IsHWnd($hWnd) Then
		; Check if the ListView has a ControlID
		$cCID = _WinAPI_GetDlgCtrlID($hWnd)
	Else
		$cCID = $hWnd
		; Get ListView handle
		$hWnd = GUICtrlGetHandle($hWnd)
	EndIf
	; If native ListView - could be either type of item
	If $cCID Then
		; Disable the redrawing message
		GUICtrlSendMsg($cCID, $LV_WM_SETREDRAW, False, 0)
		; Try deleting as native items
		Local $iParam = 0
		Local $var = _GUICtrlListView_GetItemCount($hWnd) / 100 ;PROGRESSBAR
		Local $aktPerc = 0 ;PROGRESSBAR
		For $iIndex = _GUICtrlListView_GetItemCount($hWnd) - 1 To 0 Step -1
			$iParam = _GUICtrlListView_GetItemParam($hWnd, $iIndex)
			; Check if LV item
			If GUICtrlGetState($iParam) > 0 And GUICtrlGetHandle($iParam) = 0 Then
				GUICtrlDelete($iParam)
			EndIf
			if 100 - int($iIndex / $var) <> $aktPerc then ;PROGRESSBAR
				$aktPerc = 100 - int($iIndex / $var)
				GUICtrlSetData($WaitLabel_Progress, $aktPerc)
			endif
		Next
		; Enable the redrawing message
		GUICtrlSendMsg($cCID, $LV_WM_SETREDRAW, True, 0)
		; Return if no items left
		GUICtrlSetData($WaitLabel_Progress, 0)
		If _GUICtrlListView_GetItemCount($hWnd) = 0 Then Return True
	EndIf
	GUICtrlSetData($WaitLabel_Progress, 0)
	; Has to be UDF Listview and/or UDF items
	Return _SendMessage($hWnd, $LVM_DELETEALLITEMS) <> 0
EndFunc   ;==>_GUICtrlListView_DeleteAllItems_self


Func _GUICtrlListView_SimpleSort_self($hWnd, $vSortSense, $iCol, $fToggle = True)
	GUICtrlSetData($WaitLabel_Progress, 0)
	GUICtrlSetData($WaitLabel,"Bitte warten!"&@crlf&"Liste wird sortiert!")
	sleep(100)
	Local $iItemCount = _GUICtrlListView_GetItemCount($hWnd)
	If $iItemCount Then
		Local $iDescending = 0
		If UBound($vSortSense) Then
			$iDescending = $vSortSense[$iCol]
		Else
			$iDescending = $vSortSense
		EndIf
		Local $vSeparatorChar = Opt('GUIDataSeparatorChar')
		Local $iColumnCount = _GUICtrlListView_GetColumnCount($hWnd)
		;Local Enum $iIndexValue = $iColumnCount, $iItemParam ; Additional columns for the index value and ItemParam
		Local $aListViewItems[$iItemCount][$iColumnCount + 2]
		;Local $aSelectedItems = StringSplit(_GUICtrlListView_GetSelectedIndices($hWnd), $vSeparatorChar)
		;Local $aCheckedItems = __GUICtrlListView_GetCheckedIndices($hWnd)
		Local $sItemText, $iFocused = -1
		Local $var = $iItemCount / 100 ;PROGRESSBAR
		Local $aktPerc = 0 ;PROGRESSBAR
		For $i = 0 To $iItemCount - 1 ; Rows
			;If $iFocused = -1 Then
			;	If _GUICtrlListView_GetItemFocused($hWnd, $i) Then $iFocused = $i
			;EndIf
			;_GUICtrlListView_SetItemSelected($hWnd, $i, False)
			;_GUICtrlListView_SetItemChecked($hWnd, $i, False)
			For $j = 0 To $iColumnCount - 1 ; Columns
				$sItemText = StringStripWS(_GUICtrlListView_GetItemText($hWnd, $i, $j), 2)
				If(StringIsFloat($sItemText) Or StringIsInt($sItemText)) Then
					$aListViewItems[$i][$j] = Number($sItemText)
				Else
					$aListViewItems[$i][$j] = $sItemText
				EndIf
			Next
			;$aListViewItems[$i][$iIndexValue] = $i ; Index value
			;$aListViewItems[$i][$iItemParam] = _GUICtrlListView_GetItemParam($hWnd, $i) ; ItemParam
			if int(($i / $var) / 2) <> $aktPerc then ;PROGRESSBAR
				$aktPerc = int(($i / $var) / 2)
				GUICtrlSetData($WaitLabel_Progress, $aktPerc)
			endif
		Next
		; Sort the ListView array
		_ArraySort($aListViewItems, $iDescending, 0, 0, $iCol)
		For $i = 0 To $iItemCount - 1 ; Rows
			For $j = 0 To $iColumnCount - 1 ; Columns
				_GUICtrlListView_SetItemText($hWnd, $i, $aListViewItems[$i][$j], $j)
			Next
			;_GUICtrlListView_SetItemParam($hWnd, $i, $aListViewItems[$i][$iItemParam]) ; ItemParam
			#cs
				For $j = 1 To $aSelectedItems[0]
				If $aListViewItems[$i][$iIndexValue] = $aSelectedItems[$j] Then
				If $aListViewItems[$i][$iIndexValue] = $iFocused Then
				_GUICtrlListView_SetItemSelected($hWnd, $i, True, True)
				Else
				_GUICtrlListView_SetItemSelected($hWnd, $i, True)
				EndIf
				ExitLoop
				EndIf
				Next
				For $j = 1 To $aCheckedItems[0]
				If $aListViewItems[$i][$iIndexValue] = $aCheckedItems[$j] Then
				_GUICtrlListView_SetItemChecked($hWnd, $i, True)
				ExitLoop
				EndIf
				Next
			#ce
			if int(50 + (($i / $var) / 2)) <> $aktPerc then ;PROGRESSBAR
				$aktPerc = int(50 + ($i / $var) / 2)
				GUICtrlSetData($WaitLabel_Progress, $aktPerc)
			endif
		Next
		If $fToggle Then ; Automatic sort sense toggle
			If UBound($vSortSense) Then
				$vSortSense[$iCol] = Not $iDescending
			Else
				$vSortSense = Not $iDescending
			EndIf
		EndIf
	EndIf
EndFunc   ;==>_GUICtrlListView_SimpleSort_self

Alles anzeigen

Messungsergebnisse:

Code

ItemCount: 000000000 with 0000 Cols Clear Time: 0.0005


ItemCount: 001000000 with 0004 Cols Fill Time: 6.2742
ItemCount: 000065530 with 0004 Cols Clear Time: 12.6675


ItemCount: 000500000 with 0004 Cols Fill Time: 16.2384
ItemCount: 000065530 with 0004 Cols Clear Time: 12.7077


ItemCount: 000250000 with 0004 Cols Fill Time: 14.95
ItemCount: 000065530 with 0004 Cols Clear Time: 12.6825


ItemCount: 000125000 with 0004 Cols Fill Time: 14.3645
ItemCount: 000065530 with 0004 Cols Clear Time: 13.5617


ItemCount: 000062500 with 0004 Cols Fill Time: 14.8052
ItemCount: 000062499 with 0004 Cols Clear Time: 12.6485


ItemCount: 000031250 with 0004 Cols Fill Time: 13.2853
ItemCount: 000031249 with 0004 Cols Clear Time: 4.5944


ItemCount: 000015625 with 0004 Cols Fill Time: 4.9158
ItemCount: 000015624 with 0004 Cols Clear Time: 1.8994


ItemCount: 000007812 with 0004 Cols Fill Time: 2.0671
ItemCount: 000007811 with 0004 Cols Clear Time: 0.8013


ItemCount: 000003906 with 0004 Cols Fill Time: 0.8891
ItemCount: 000003905 with 0004 Cols Clear Time: 0.3773


ItemCount: 000001953 with 0004 Cols Fill Time: 0.4274
ItemCount: 000001952 with 0004 Cols Clear Time: 0.1821


ItemCount: 000000976 with 0004 Cols Fill Time: 0.2148
ItemCount: 000000975 with 0004 Cols Clear Time: 0.0917


ItemCount: 000000488 with 0004 Cols Fill Time: 0.1151
ItemCount: 000000487 with 0004 Cols Clear Time: 0.0465


ItemCount: 000000244 with 0004 Cols Fill Time: 0.0646
ItemCount: 000000243 with 0004 Cols Clear Time: 0.0258


ItemCount: 000000122 with 0004 Cols Fill Time: 0.0419
ItemCount: 000000121 with 0004 Cols Clear Time: 0.0115


ItemCount: 000000061 with 0004 Cols Fill Time: 0.026

Alles anzeigen

Ich weiß nur nicht, warum der beim löschen maximal bis 65540 geht...

MfG Kanashius

horphi

Hallo Kanashius,

ist ja ne Top Listenbefüllung.

Frage dazu: geht das auch mit $g_idListView = _GUICtrlListView_Create()?

DAnke und Gruß,

horphi

**Kanashius**

Müsste gehen, probiers aus. Falls nicht, das GuiCtrlCreateListviewItem durch den Befehl aus der UDF ersetzen. Rest sind ja UDF-Befehle.

horphi

Danke dir.

Werde ich bei Gelegenheit einarbeiten.

Viele Grüße,

horphi