Windows Icons fixieren

Yaerox

Ich denke jeder der mit Notebooks arbeitet kennt es:

Notebook steht mit x weiteren Bildschirmen am Arbeitsplatz. Desktop schön aufgeräumt, alles hat seinen Platz. Dann braucht man das Notebook mal unterwegs und alle Icons sind fortan unsortiert am Rand gestapelt.

Da ich viel mit Verknüpfungen arbeite habe ich diese auch hilfreich auf den Desktop angeordnet. Wie kann man dem nun entgegenwirken?
Ich habe jetzt mal einige Minuten recherchiert und folgendes gefunden: http://www.chip.de/downloads/Desktop-Restore_30997925.html

Nun wollt ich mal hören ob noch jemand dieses Problem kennt, alternative Lösungen zu der obigen Software hat oder Erfahrungen mit der Software.

**chip**

Die IconPosition wir in der Registry unter "HKCU\Software\Microsoft\Windows\Shell\Bags\1\Desktop" im Key "ItemPosXXXxXXX" gespeichert. Sprich du kannst dir auch eine Autoit-Lösung bauen.

Micha_he

Ich habe mal eine Lösung gebaut:

Script kompilieren (für x64 muss auch x64 kompiliert sein) und mit Parameter '-save' starten legt eine Ini im Scriptverzeichnis an.
Mit Parameter '-restore' werden die alten Positionen wieder hergestellt. Unter Win7 x64 läuft es noch !

Spoiler anzeigen

AutoIt: SetGet_IconPos.au3

;#################################################################################################
;
;   Titel:   Restore-IconPos-Desktop
;   Datum:   28. Jan. 2015
;   Version: 1.1
;
;	Anmerkungen:
;    
;   -	Die Position der Icons und der Titel wird in einer INI Datei gespeichert
;   -	Das Script wird über Parameter aufgerufen:
;       	-save    = Speichert die Positionen
;       	-restore = Plaziert die Icons wieder da wo sie waren
;	-	Unter einem x64-System, muss das Script auch als 64bit-kompiliertem
;		Script oder mit AutoIt_x64.exe gestartet werden !
;
;
;	History:
;		V1.0	-	Erstrelease
;		V1.1	-	Anzahl wird jetzt mit korrektem Wer in der INI gespeichert
;
;#################################################################################################


;#################################################################################################
; Einfügen der Include Dateien
;#################################################################################################
#include <Constants.au3>
#Include <GuiListView.au3>
#include <File.au3>
#include <Array.au3>


;#################################################################################################
; Optionen setzen
;#################################################################################################
#NoTrayIcon                        ;Kein TrayIcon anzeigen
Opt("MustDeclareVars", 1)         ;Variablen müssen deklariert werden


;#################################################################################################
; Variablen deklarieren
;#################################################################################################
Local $handle                                    ;Handle für den Desktop
Local $anzIcons                                    ;Anzahl der Icons auf dem Desktop
Local $arrIcons[1]                                ;Array für Restore
Local $arrayPos                                    ;Position im Array
Local $txt                                        ;Für das zwischenspeichern von Texten
Local $int                                        ;Als Zähler Variable
Local $icon                                        ;Name des Icon
Local $posX                                        ;X Position
Local $posY                                        ;y Position
Local $Mode    = "Help"                            ;In welchem Modus das Script gestartet wurde
Local $iniFile    = @ScriptDir & "\icons.ini"        ;Pfad zu der Ini-Datei


If @OSArch = "X64" and not @Autoitx64 Then
	Msgbox(64, "Falsche Architektur !", "Unter einem 64bit Betriebssystem, muss auch eine 64bit-Variante" & @CRLF & "des Programms gestartet werden !")
	Exit
EndIf


;#################################################################################################
; Programm Einstigspunkt (POE)
;#################################################################################################
If $CmdLine[0] > 0 Then
    $Mode = $CmdLine[1]
    _CheckIniExist()
    Switch $CmdLine[1]
        Case "-save"
            ToolTip("Positionen der Icons werden gespeichert!",0,0,"Info")
            Sleep(1000)
            _SavePos()
        Case "-restore"
            ToolTip("Icons werden wieder hergestellt!",0,0,"Info")
            Sleep(1000)
            _RestorePos()
        Case Else
            _ShowHelp()
    EndSwitch
Else
    _ShowHelp()
EndIf


Exit 0 ;Programm wird verlassen


;#################################################################################################
; _CheckIniExist
; Diese Funktion prüft ob die INI Datei vohanden ist, falls Nein, wird eine leere Datei
; erstellt. Ist eine vorhanden, wird gelöscht und eine neue erstellt, aber nur bei -save
;#################################################################################################
Func _CheckIniExist()
    IF Not FileExists($iniFile) Then 
        _FileCreate($iniFile)
        If @error Then 
            MsgBox(48,"Fehler","INI-Datei konnte nicht erstellt werden.")
            Exit 1
        EndIf
    ElseIf $Mode = "-save" Then
        If FileDelete($iniFile) = 0 Then
            MsgBox(48,"Fehler","INI-Datei konnte nicht gelöscht werden.")
            Exit 1
        EndIf
    EndIf
EndFunc


;#################################################################################################
; _ShowHelp
; Wenn das Script ohne Parameter gestartet wird, wird diese Hilfe angezeigt, oder wenn ein
; falscher Parameter übergeben wurde.
;#################################################################################################
Func _ShowHelp()
    $txt = "Parameter:" & @CRLF
    $txt &= "-save    = Speichert die Positionen"  & @CRLF
    $txt &= "-restore = Plaziert die Icons wieder da wo sie waren"
    MsgBox(64,"Hilfe - Restore-IconPos-Desktop", $txt)
    Exit 0
EndFunc


;#################################################################################################
; _SavePos
; Speichern der Icon Positionen in der INI Datei
;#################################################################################################
Func _SavePos()
    $handle = ControlGetHandle("Program Manager", "", "SysListView321")
    $anzIcons = _GUICtrlListView_GetItemCount ($handle)
    IniWrite($iniFile,"Global","Anzahl",$anzIcons)
    For $int = 0 To $anzIcons - 1
        IniWrite($iniFile,"IconPos" & $int,"Icon",_GUICtrlListView_GetItemText($handle,$int))
        IniWrite($iniFile,"IconPos" & $int,"X-Pos",_GUICtrlListView_GetItemPositionX ($handle,$int))
        IniWrite($iniFile,"IconPos" & $int,"Y-Pos",_GUICtrlListView_GetItemPositionY ($handle,$int))
    Next
EndFunc




;#################################################################################################
; _RestorePos
; Stellt die Icon Positionen an Hand der INI Datei wieder her
;#################################################################################################
Func _RestorePos()
    $anzIcons = IniRead($iniFile,"Global","Anzahl",-1)
    If $anzIcons = -1 Then 
        MsgBox(48,"Fehler","INI-Datei ist leer.")
        Exit 1
    Else
        $handle = ControlGetHandle("Program Manager", "", "SysListView321")
        ReDim $arrIcons[_GUICtrlListView_GetItemCount ($handle)]
        For $int = 0 To UBound($arrIcons) - 1
            $arrIcons[$int] = _GUICtrlListView_GetItemText($handle,$int)
        Next
        For $int = 0 To $anzIcons - 1
            $icon = IniRead($iniFile,"IconPos" & $int,"Icon",-1)
            $posX = IniRead($iniFile,"IconPos" & $int,"X-Pos",-1)
            $posY = IniRead($iniFile,"IconPos" & $int,"Y-Pos",-1)
            If $icon = -1 Or $posX = -1 Or $posY = -1 Then ContinueLoop
            $arrayPos = _ArraySearch($arrIcons,$icon,0,0,1,False)
            If $arrayPos = -1 Then ContinueLoop
            _GUICtrlListView_SetItemPosition($handle,$arrayPos,$posX,$posY)
        Next
    EndIf
EndFunc

Alles anzeigen

Edit: Gerade getestet, läuft auch unter Win10 x64 noch !

Yaerox

Astrein. Ich danke euch.

@chip ich habe mir sowas gedacht, aber noch keine wirkliche Zeit gehabt ausgiebig zu recherchieren. Danke für den Tipp, dann bau ich mir lieber selber etwas (oder nutze Skripten von Usern hier) als ne unbekannte .exe

**Schnuffel**

zur Übung bestimmt ganz lehrreich, aber ich finde mann kann manchmal auch auf fertige Lösungen zurückgreifen.
Ich verwende seit vielen Jahren zufrieden DeskSave: http://www.heise.de/download/desksave-1132746.html

Micha_he

Yaerox:

Du hast aber unter Windows 64bit, auch eine 64bit kompilierte Version des Scripts getestet, oder ?

Yaerox

Zitat von Micha_he

Yaerox:

Du hast aber unter Windows 64bit, auch eine 64bit kompilierte Version des Scripts getestet, oder ?

Sry, hab grad bemerkt dass ich nur zu blöd war. Man sollte die Parameter auch mit - angeben, statt nur "save" oder "restore". Tut mir leid. Funktioniert nun wie gewünscht. Vielen Dank.